vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68
  69 " Increase history of executed commands (:).
  70 set history=1000
  71
  72 " Increase number of possible undos.
  73 set undolevels=1000
  74
  75 " Remember marks (including the last cursor position) for more files.
  76 if has('viminfo')
  77     set viminfo^='1000
  78 endif
  79
  80 " Use strong encryption if possible, also used for swap/undo files.
  81 if exists('+cryptmethod')
  82     set cryptmethod=blowfish
  83 endif
  84
  85 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  86 " is used multiple times.
  87 if has('autocmd')
  88     augroup vimrc
  89         autocmd!
  90     augroup END
  91 endif
  92
  93
  94 " HELPER FUNCTIONS
  95
  96 " Check if the given syntax group is available. Thanks to bairui in #vim on
  97 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  98 if has('eval')
  99     function! s:HasSyntaxGroup(group)
 100         try
 101             execute 'silent highlight ' . a:group
 102         " \a = [A-Za-z]
 103         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 104             return 0
 105         endtry
 106         return 1
 107     endfunction
 108 endif
 109
 110
 111 " EDIT SETTINGS
 112
 113 " Enable automatic file detection, plugin and indention support.
 114 if has('autocmd')
 115     filetype off " necessary for pathogen to force a reload of ftplugins
 116     filetype plugin indent on
 117 endif
 118
 119 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 120 " existing files.
 121 set fileencodings=utf-8,latin1
 122
 123 " Wrap text after 78 characters.
 124 set textwidth=78
 125
 126 " Set tabs to 4 spaces, use softtabs.
 127 set shiftwidth=4
 128 set softtabstop=4
 129 set expandtab
 130 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 131 set shiftround
 132 " Use the default value for real tabs.
 133 set tabstop=8
 134
 135 " Enable auto indention.
 136 set autoindent
 137
 138 " When joining lines only add one space after a sentence.
 139 set nojoinspaces
 140
 141 " Allow backspacing over autoindent and line breaks.
 142 set backspace=indent,eol
 143
 144 " Start a comment when hitting enter after a commented line (r) and when using
 145 " o or O around a commented line (o).
 146 set formatoptions+=ro
 147 " Don't break a line if was already longer then 'textwidth' when insert mode
 148 " started.
 149 set formatoptions+=l
 150
 151 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 152 " no character) in visual block mode.
 153 set virtualedit=block
 154
 155 " Already display matches while typing the search command. This makes spotting
 156 " errors easy.
 157 set incsearch
 158
 159 " Activate syntax folding.
 160 if has('folding')
 161     set foldmethod=syntax
 162     " Only use fold column if we have enough space (for example not in a
 163     " (virtual) terminal which has only 80 columns).
 164     if &columns > 80
 165         set foldcolumn=2
 166     endif
 167     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 168                      " folding which is not what I want
 169 endif
 170
 171 " Only check case if the searched word contains a capital character.
 172 set ignorecase
 173 set smartcase
 174
 175 " Activate spell checking, use English as default.
 176 if exists('+spell') && has('syntax')
 177     " But not when diffing because spell checking is distracting in this case.
 178     if !&diff
 179         set spell
 180     endif
 181     set spelllang=en_us
 182 endif
 183
 184 " Allow buffers with changes to be hidden. Very important for effective
 185 " editing with multiple buffers. Prevents the "E37: No write since last change
 186 " (add ! to override)" warning.
 187 set hidden
 188
 189
 190 " DISPLAY SETTINGS
 191
 192 " Use a dark background. Doesn't change the background color, only sets text
 193 " colors for a dark terminal.
 194 set background=dark
 195
 196 " Use my color scheme if 256 colors are available.
 197 if &t_Co == 256
 198     colorscheme simon
 199 endif
 200
 201 " Display line numbers.
 202 set number
 203 " But use as little space as possible for the numbers column. Thanks to James
 204 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 205 if exists('+numberwidth')
 206     set numberwidth=1
 207 endif
 208 " Display the ruler with current line/file position. If 'statusline' is used
 209 " then this only affects <C-G>.
 210 set ruler
 211 " Display partial commands in the status line.
 212 set showcmd
 213
 214 " Don't redraw screen when executing macros; increases speed. Thanks to James
 215 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 216 set lazyredraw
 217
 218 " Visualize the line the cursor is currently in.
 219 if exists('+cursorline')
 220     set cursorline
 221 endif
 222
 223 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 224 " remove the highlighting until the next search.
 225 set hlsearch
 226
 227 " Display some special characters.
 228 set list
 229 set listchars=
 230 " Display tabs as ">--------".
 231 set listchars+=tab:>-
 232 " Display trailing whitespace as "-".
 233 set listchars+=trail:-
 234 " Display markers for long lines when wrapping is disabled.
 235 set listchars+=extends:>,precedes:<
 236 " Display non-breakable space as "!".
 237 if v:version >= 700
 238     set listchars+=nbsp:!
 239 endif
 240
 241 " Don't draw the vertical split separator by using space as character. Thanks
 242 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 243 " non-breakable space. But a simple space works as well, as long as the
 244 " current color scheme is not reset.
 245 if has('windows') && has('folding')
 246     set fillchars+=vert:\  " comment to prevent trailing whitespace
 247 endif
 248
 249 if has('statusline')
 250     " Always display the status line even if there is only one window.
 251     set laststatus=2
 252
 253     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 254     " is the highest buffer number, otherwise return nothing. Used in
 255     " 'statusline' to get an overview of available buffer numbers.
 256     function! StatuslineBufferCount()
 257         let l:bufnr = bufnr('$')
 258         if l:bufnr > 1
 259             let l:result = '/'
 260             if exists('*printf')
 261                 let l:result .= printf('%02d', l:bufnr)
 262             else
 263                 " Older Vims don't have printf() (and no .= either). Emulate
 264                 " "%02d".
 265                 if l:bufnr < 10
 266                     let l:result = l:result . '0'
 267                 endif
 268                 let l:result = l:result . l:bufnr
 269             endif
 270             return l:result
 271         else
 272             return ''
 273         endif
 274     endfunction
 275
 276     " Like %f but use relative filename if it's shorter than the absolute path
 277     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 278     " not enough because it doesn't create '../'s.
 279     function! StatuslineRelativeFilename()
 280         " Display only filename for help files.
 281         if &buftype == 'help'
 282             return expand('%:t')
 283         endif
 284         " Special case for scratch files.
 285         if &buftype == 'nofile'
 286             return '[Scratch]'
 287         endif
 288
 289         let l:path = expand('%')
 290         " No file.
 291         if l:path == ''
 292             return '[No Name]'
 293         endif
 294         " Path is already relative, nothing to do.
 295         if stridx(l:path, '/') != 0
 296             return l:path
 297         endif
 298
 299         " Absolute path to this file.
 300         let l:path = expand('%:p')
 301         " Shortened path to this file, thanks to bairui in #vim on Freenode
 302         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 303         " Vim normally uses as %f (minus some exceptions).
 304         let l:original_path = fnamemodify(l:path, ':~')
 305         " Absolute path to the current working directory.
 306         let l:cwd = getcwd()
 307
 308         " Working directory completely contained in path, replace it with a
 309         " relative path. Happens for example when opening a file with netrw.
 310         " %f displays this as absolute path, but we want a relative path of
 311         " course.
 312         if stridx(l:path, l:cwd) == 0
 313             return strpart(l:path, strlen(l:cwd) + 1)
 314         endif
 315
 316         let l:path_list = split(l:path, '/')
 317         let l:cwd_list  = split(l:cwd,  '/')
 318
 319         " Remove the common path.
 320         while l:path_list[0] == l:cwd_list[0]
 321             call remove(l:path_list, 0)
 322             call remove(l:cwd_list,  0)
 323         endwhile
 324
 325         " Add as many '..' as necessary for the relative path and join the
 326         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 327         " the hint to use repeat() instead of a loop.
 328         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 329
 330         " Use the shorter path, either relative or absolute.
 331         if strlen(l:path) < strlen(l:original_path)
 332             return l:path
 333         else
 334             return l:original_path
 335         endif
 336     endfunction
 337
 338     set statusline=
 339     " on the left
 340     set statusline+=%02n  " buffer number
 341     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 342     set statusline+=:
 343     if has('modify_fname')
 344         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 345         set statusline+=\     " space after path
 346     else
 347         set statusline+=%f\   " path to current file in buffer
 348     endif
 349     set statusline+=%h    " [help] if buffer is help file
 350     set statusline+=%w    " [Preview] if buffer is preview buffer
 351     set statusline+=%m    " [+] if buffer was modified,
 352                           " [-] if 'modifiable' is off
 353     set statusline+=%r    " [RO] if buffer is read only
 354
 355     " on the right
 356     set statusline+=%=                " right align
 357     set statusline+=0x%-8B\           " current character under cursor as hex
 358     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 359                                       " column number (%c),
 360                                       " virtual column number if different
 361                                       "                       than %c (%V)
 362     set statusline+=%P                " position in file in percent
 363 endif
 364
 365
 366 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 367
 368 " noremap is used to make sure the right side is executed as is and can't be
 369 " modified by a plugin or other settings. Except for <Nop> which isn't
 370 " affected by mappings.
 371
 372 " Easy way to exit insert mode. jk is preferred because it's faster.
 373 inoremap jj <Esc>
 374 inoremap jk <Esc>
 375 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 376 " (2010-10-15).
 377 cnoremap jj <C-C>
 378 cnoremap jk <C-C>
 379
 380 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 381 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 382 map <Right>  <Nop>
 383 map <Left>   <Nop>
 384 map <Up>     <Nop>
 385 map <Down>   <Nop>
 386 imap <Right> <Nop>
 387 imap <Left>  <Nop>
 388 imap <Up>    <Nop>
 389 imap <Down>  <Nop>
 390 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 391 " below).
 392 cmap <Up>    <Nop>
 393 cmap <Down>  <Nop>
 394 cmap <Right> <Nop>
 395 cmap <Left>  <Nop>
 396
 397 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 398 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 399 cnoremap <C-P> <Up>
 400 cnoremap <C-N> <Down>
 401
 402 if has('eval')
 403 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 404 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 405 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 406 " directly because it also enables that feature for other commands which I
 407 " don't want.
 408
 409     " Set 'nostartofline' for a single movement.
 410     function! s:TemporaryNostartofline(movement)
 411         let l:startofline = &startofline
 412         set nostartofline
 413         execute 'normal! ' . a:movement
 414         let &startofline = l:startofline
 415     endfunction
 416
 417     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 418     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 419     nnoremap <silent> <C-F>
 420         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 421     nnoremap <silent> <C-B>
 422         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 423     nnoremap <silent> <C-D>
 424         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 425     nnoremap <silent> <C-U>
 426         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 427 endif
 428
 429 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 430 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 431 " Only the current buffer is written, thus switching to another buffer works
 432 " too.
 433 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 434
 435 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 436 " in #vim on Freenode (2011-08-15 00:17 CEST).
 437 nnoremap <C-G> 2<C-G>
 438
 439 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 440 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 441 nmap <Space> <C-F>
 442 nmap - <C-B>
 443
 444 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 445 " (2010-05-16 18:38 CEST) for this idea.
 446 nnoremap <silent> gb :bnext<CR>
 447 nnoremap <silent> gB :bprevious<CR>
 448 if has('eval')
 449     " But when starting again at the first buffer, print a warning which
 450     " reminds me that I've already seen that buffer.
 451     function! s:NextBuffer()
 452         " Are we currently on the last buffer and moving to the first?
 453         let l:last_buffer = 0
 454         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 455             let l:last_buffer = 1
 456         endif
 457
 458         " Go to the next buffer.
 459         if !l:last_buffer
 460             bnext
 461
 462         " Go to the first buffer, silent is necessary or the following message
 463         " won't be displayed because it's overwritten by the status message
 464         " displayed when entering a buffer.
 465         else
 466             silent bnext
 467
 468             echohl WarningMsg
 469             echo 'Starting again at first buffer.'
 470             echohl None
 471         endif
 472     endfunction
 473     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 474 endif
 475
 476 " Fast access to buffers.
 477 nnoremap <silent> <Leader>1 :1buffer<CR>
 478 nnoremap <silent> <Leader>2 :2buffer<CR>
 479 nnoremap <silent> <Leader>3 :3buffer<CR>
 480 nnoremap <silent> <Leader>4 :4buffer<CR>
 481 nnoremap <silent> <Leader>5 :5buffer<CR>
 482 nnoremap <silent> <Leader>6 :6buffer<CR>
 483 nnoremap <silent> <Leader>7 :7buffer<CR>
 484 nnoremap <silent> <Leader>8 :8buffer<CR>
 485 nnoremap <silent> <Leader>9 :9buffer<CR>
 486 nnoremap <silent> <Leader>0 :10buffer<CR>
 487
 488 " Make last active window the only window. Similar to <C-W> o.
 489 nnoremap <C-W>O <C-W>p<C-W>o
 490
 491 " Maps to change spell language between English and German and disable spell
 492 " checking.
 493 if exists('+spell')
 494     nnoremap <silent> <Leader>sn :set nospell<CR>
 495     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 496     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 497 endif
 498
 499 " Add semicolon to the end of the line. Thanks to
 500 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 501 " on Freenode for an improved version which doesn't clobber any marks.
 502 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 503
 504 " * and # for selections in visual mode. Thanks to
 505 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 506 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 507 if has('eval')
 508     function! s:VSetSearch()
 509         let l:temp = @@
 510         normal! gvy
 511         " Added \C to force 'noignorecase' while searching the current visual
 512         " selection. I want to search for the exact string in this case.
 513         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 514         let @@ = l:temp
 515     endfunction
 516     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 517     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 518 endif
 519
 520 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 521 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 522 " mailing list for the commands.
 523 if v:version < 700
 524     cnoreabbrev W w
 525     cnoreabbrev Wa wa
 526     cnoreabbrev Wq wq
 527     cnoreabbrev Wqa wqa
 528 else
 529     cnoreabbrev <expr> W
 530         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 531     cnoreabbrev <expr> Wa
 532         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 533     cnoreabbrev <expr> Wq
 534         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 535     cnoreabbrev <expr> Wqa
 536         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 537 endif
 538 " Also fix my typo with "Q".
 539 if v:version < 700
 540     cnoreabbrev Q q
 541     cnoreabbrev Qa qa
 542 else
 543     cnoreabbrev <expr> Q
 544         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 545     cnoreabbrev <expr> Qa
 546         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 547 endif
 548
 549 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 550 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 551 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 552
 553 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 554 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 555 " Vim's source.
 556 inoremap <C-U> <C-G>u<C-U>
 557 " Same for <C-@> (insert previously inserted text and leave insert mode).
 558 inoremap <C-@> <C-G>u<C-@>
 559 " And for <C-A> (insert previously inserted text).
 560 inoremap <C-A> <C-G>u<C-A>
 561 " And for <C-W> (delete word before cursor).
 562 inoremap <C-W> <C-G>u<C-W>
 563
 564 if has('eval')
 565 " New text-objects ii and ai to work on text with the same indentation. Thanks
 566 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 567 " (visited on 2011-11-19).
 568     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 569     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 570     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 571     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 572
 573     function! s:IndTxtObj(inner)
 574         let curline = line(".")
 575         let lastline = line("$")
 576         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 577         let i = i < 0 ? 0 : i
 578         if getline(".") !~ "^\\s*$"
 579             let p = line(".") - 1
 580             let nextblank = getline(p) =~ "^\\s*$"
 581             while p > 0
 582                     \ && ((i == 0 && !nextblank)
 583                         \ || (i > 0 && ((indent(p) >= i
 584                             \ && !(nextblank && a:inner))
 585                             \ || (nextblank && !a:inner))))
 586                 -
 587                 let p = line(".") - 1
 588                 let nextblank = getline(p) =~ "^\\s*$"
 589             endwhile
 590             normal! 0V
 591             call cursor(curline, 0)
 592             let p = line(".") + 1
 593             let nextblank = getline(p) =~ "^\\s*$"
 594             while p <= lastline
 595                     \ && ((i == 0 && !nextblank)
 596                         \ || (i > 0 && ((indent(p) >= i
 597                             \ && !(nextblank && a:inner))
 598                             \ || (nextblank && !a:inner))))
 599                 +
 600                 let p = line(".") + 1
 601                 let nextblank = getline(p) =~ "^\\s*$"
 602             endwhile
 603             normal! $
 604         endif
 605     endfunction
 606 endif
 607
 608
 609 " ABBREVIATIONS
 610
 611 " Fix some of my spelling mistakes (German).
 612 inoreabbrev relle reelle
 613 inoreabbrev reele reelle
 614 " Fix some of my spelling mistakes (English).
 615 inoreabbrev completly completely
 616
 617
 618 " SYNTAX SETTINGS
 619
 620 " Activate syntax coloring.
 621 if has('syntax')
 622     syntax enable
 623
 624 " Don't highlight more than 500 columns as I normally don't have that long
 625 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 626 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 627     if exists('+synmaxcol')
 628         set synmaxcol=500
 629     endif
 630
 631 " Use (limited) syntax based omni completion if no other omni completion is
 632 " available. Taken from :help ft-syntax-omni.
 633     if has('autocmd') && exists('+omnifunc')
 634         augroup vimrc
 635             autocmd FileType *
 636                 \ if &omnifunc == '' |
 637                 \     setlocal omnifunc=syntaxcomplete#Complete |
 638                 \ endif
 639         augroup END
 640     endif
 641
 642 " Function to enable all custom highlights. Necessary as highlights are
 643 " window-local and thus must be set for each new window.
 644     function! s:CustomSyntaxHighlights()
 645         " Not the first time called, nothing to do.
 646         if exists('w:vimrc_syntax_run')
 647             return
 648         endif
 649         let w:vimrc_syntax_run = 1
 650
 651 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 652 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 653 " disabled when necessary with :2match (in Vim >= 700).
 654         if !&diff && exists(':2match')
 655             " Use ColorColumn for overlong lines if available and my color
 656             " scheme is used.
 657             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 658                 2match ColorColumn /\%>78v./
 659             else
 660                 2match Todo /\%>78v./
 661             endif
 662         elseif !&diff
 663             match Todo /\%>78v./
 664         endif
 665
 666         if exists('*matchadd')
 667 " Highlight some important keywords in all documents.
 668             let l:todos = ['TODO', 'XXX', 'FIXME',
 669                          \ 'CHANGED', 'REMOVED', 'DELETED']
 670             " Compatibility fix for Vim 6.4 which can't handle for in function
 671             " (without function it's ignored).
 672             execute '  for l:x in l:todos'
 673                   \ '|     call matchadd("Todo", l:x)'
 674                   \ '| endfor'
 675
 676 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 677             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 678                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 679                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 680                           \ '205f', '2060', '3000', 'feff']
 681             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 682             " it won't work!
 683             execute '  for l:x in l:spaces'
 684                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 685                   \ '| endfor'
 686
 687 " Special highlight for tabs to reduce their visibility in contrast to other
 688 " SpecialKey characters (e.g. ^L).
 689             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 690                 call matchadd('specialKeyTab', '\t')
 691             endif
 692         endif
 693     endfunction
 694 " Enable highlights for the current and all new windows. Thanks to bairui in
 695 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 696     call <SID>CustomSyntaxHighlights()
 697     if has('autocmd')
 698         augroup vimrc
 699             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 700         augroup END
 701     endif
 702
 703 " Settings for specific filetypes.
 704
 705     " C
 706     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 707     " Haskell.
 708     let g:hs_highlight_delimiters = 1
 709     let g:hs_highlight_boolean = 1
 710     let g:hs_highlight_types = 1
 711     let g:hs_highlight_more_types = 1
 712     " Perl.
 713     let g:perl_fold = 1
 714     let g:perl_fold_blocks = 1
 715     let g:perl_nofold_packages = 1
 716     let g:perl_include_pod = 1 " syntax coloring for PODs
 717     " Python.
 718     let g:python_highlight_all = 1
 719     " Shell.
 720     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 721     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 722     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 723     " Vim.
 724     let g:vimsyn_embed = 0      " don't highlight embedded languages
 725     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 726     " XML.
 727     let g:xml_syntax_folding = 1
 728 endif
 729
 730
 731 " PLUGIN SETTINGS
 732
 733 if has('eval')
 734 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 735 " installing/removing/updating plugins simple. (Used for plugins with more
 736 " than one file.) Ignore errors in case pathogen is not installed.
 737     if v:version >= 700
 738         silent! execute 'call pathogen#runtime_append_all_bundles()'
 739     endif
 740
 741 " Settings for securemodelines.
 742     " Only allow items I need (also includes spl which is not enabled by
 743     " default).
 744     let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 745                                           \ 'sw', 'sts', 'noet']
 746
 747 " Settings for the NERD commenter.
 748     " Don't create any mappings I don't want to use.
 749     let g:NERDCreateDefaultMappings = 0
 750     " Map toggle comment.
 751     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 752
 753 " XPTemplate settings.
 754     " Try to maintain snippet rendering even after editing outside of a
 755     " snippet.
 756     let g:xptemplate_strict = 0
 757     " Don't complete any braces automatically.
 758     let g:xptemplate_brace_complete = 0
 759     " Only highlight the current placeholder.
 760     let g:xptemplate_highlight = 'current'
 761 endif
 762
 763
 764 " AUTO COMMANDS
 765
 766 " Use a custom auto group to prevent problems when the vimrc files is sourced
 767 " twice.
 768 if has('autocmd')
 769     augroup vimrc
 770
 771 " Go to last position of opened files. Taken from :help last-position-jump.
 772         autocmd BufReadPost *
 773             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 774             \     execute "normal! g'\"" |
 775             \ endif
 776 " But not for Git commits, go to beginning of the file.
 777         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 778
 779 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 780 " when switching to a help buffer which is in the background with :buffer as
 781 " these options are local to windows (and not only to buffers). This happens
 782 " because I often want to use only one window and thus the help buffer is in
 783 " the background.
 784         autocmd BufWinEnter *.txt
 785             \ if &filetype == 'help' |
 786             \     setlocal nolist |
 787             \     setlocal nonumber |
 788             \ endif
 789
 790 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 791 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 792 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 793 " doesn't exist in older Vims.
 794         if exists('##InsertLeave')
 795             autocmd InsertLeave * set nopaste
 796         endif
 797
 798 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 799 " doesn't exist in older Vims.
 800         if exists('##QuickFixCmdPre')
 801             autocmd QuickFixCmdPre * write
 802         endif
 803
 804 " Don't ignore case while in insert mode, but ignore case in all other modes.
 805 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 806 " capitalization. But while searching (/) 'ignorecase' is used.
 807 " InsertEnter/InsertLeave doesn't exist in older Vims.
 808         if exists('##InsertEnter') && exists('##InsertLeave')
 809             autocmd InsertEnter * set noignorecase
 810             autocmd InsertLeave * set   ignorecase
 811         endif
 812
 813 " AFTER/FTPLUGIN AUTO COMMANDS
 814
 815 " Disable spell checking for files which don't need it.
 816         autocmd FileType deb  setlocal nospell
 817         autocmd FileType diff setlocal nospell
 818         autocmd FileType tar  setlocal nospell
 819 " Fix to allow Vim edit crontab files as crontab doesn't work with
 820 " backupcopy=auto.
 821         autocmd FileType crontab setlocal backupcopy=yes
 822 " Don't use the modeline in git commits as the diff created by `git commit -v`
 823 " may contain one which could change the filetype or other settings of the
 824 " commit buffer. Also make sure we use only 72 characters per line which is
 825 " the recommendation for git commit messages (http://tpope.net/node/106).
 826         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 827                                  \ setlocal textwidth=72
 828 " Use the same comment string as for Vim files in Vimperator files.
 829         autocmd FileType vimperator setlocal commentstring=\"%s
 830 " Use TeX compiler for (La)TeX files.
 831         autocmd FileType tex compiler tex
 832
 833 " FTDETECT AUTO COMMANDS
 834
 835 " Recognize .md as markdown files (Vim default is .mkd).
 836         autocmd BufRead,BufNewFile *.md set filetype=mkd
 837 " Recognize .test as Tcl files.
 838         autocmd BufRead,BufNewFile *.test set filetype=tcl
 839
 840 " OTHER AUTO COMMANDS
 841
 842 " Disable spell checking, displaying of list characters and long lines when
 843 " viewing documentation.
 844         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 845
 846 " Use diff filetype for mercurial patches in patch queue.
 847         autocmd BufReadPost */.hg/patches/* set filetype=diff
 848
 849     augroup END
 850 endif
 851
 852
 853 " CUSTOM FUNCTIONS AND COMMANDS
 854
 855 if has('eval')
 856 " Convenient command to see the difference between the current buffer and the
 857 " file it was loaded from, thus the changes you made. Thanks to the
 858 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 859 " for the diffed file than the filetype for the original file.
 860     if !exists(':DiffOrig')
 861         command DiffOrig
 862             \ let s:diff_orig_filetype = &filetype
 863             \ | vertical new
 864             \ | let &filetype = s:diff_orig_filetype
 865             \ | unlet s:diff_orig_filetype
 866             \ | set buftype=nofile
 867             \ | read ++edit #
 868             \ | 0d_
 869             \ | diffthis
 870             \ | wincmd p
 871             \ | diffthis
 872     endif
 873 endif