vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Create new split windows on the right (and not left).
 109 set splitright
 110
 111 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 112 " is used multiple times. Necessary to support reloading the vimrc.
 113 if has('autocmd')
 114     augroup vimrc
 115         autocmd!
 116     augroup END
 117 endif
 118
 119
 120 " HELPER FUNCTIONS
 121
 122 if has('eval')
 123 " Check if the given syntax group is available. Thanks to bairui in #vim on
 124 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 125     function! s:HasSyntaxGroup(group)
 126         try
 127             execute 'silent highlight ' . a:group
 128         " \a = [A-Za-z]
 129         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 130             return 0
 131         endtry
 132         return 1
 133     endfunction
 134
 135 " Check if the given Vim version and patch is available.
 136     function! s:HasVersionAndPatch(version, patch)
 137         return v:version > a:version
 138             \ || (v:version == a:version && has('patch' . a:patch))
 139     endfunction
 140 endif
 141
 142
 143 " EDIT SETTINGS
 144
 145 " Enable automatic file detection, plugin and indention support.
 146 if has('autocmd')
 147     filetype off " necessary for pathogen to force a reload of ftplugins
 148     filetype plugin indent on
 149 endif
 150
 151 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 152 " existing files.
 153 set fileencodings=utf-8,latin1
 154
 155 " Always use unix line-endings for new files.
 156 set fileformats=unix,dos
 157
 158 " Wrap text after 78 characters.
 159 set textwidth=78
 160
 161 " Set tabs to 4 spaces, use softtabs.
 162 set shiftwidth=4
 163 set softtabstop=4
 164 set expandtab
 165 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 166 set shiftround
 167 " Use the default value for real tabs.
 168 set tabstop=8
 169
 170 " Enable auto indention.
 171 set autoindent
 172
 173 " When joining lines only add one space after a sentence.
 174 set nojoinspaces
 175
 176 " Allow backspacing over autoindent and line breaks.
 177 set backspace=indent,eol
 178
 179 " Start a comment when hitting enter after a commented line (r) and when using
 180 " o or O around a commented line (o).
 181 set formatoptions+=ro
 182 " Don't break a line if was already longer then 'textwidth' when insert mode
 183 " started.
 184 set formatoptions+=l
 185 " Remove comment leader when joining lines where it makes sense.
 186 if <SID>HasVersionAndPatch(703, 541)
 187     set formatoptions+=j
 188 endif
 189
 190 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 191 " no character) in visual block mode.
 192 set virtualedit=block
 193
 194 " Already display matches while typing the search command. This makes spotting
 195 " typos easy and searching faster.
 196 set incsearch
 197
 198 " Activate syntax folding.
 199 if has('folding')
 200     set foldmethod=syntax
 201     " Only use fold column if we have enough space (for example not in a
 202     " (virtual) terminal which has only 80 columns).
 203     if &columns > 80
 204         set foldcolumn=2
 205     endif
 206     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 207                      " folding which is not what I want
 208     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 209     set foldopen-=block
 210 endif
 211
 212 " Only check case if the searched word contains a capital character.
 213 set ignorecase
 214 set smartcase
 215
 216 " Activate spell checking, use English as default.
 217 if exists('+spell') && has('syntax')
 218     " But not when diffing because spell checking is distracting in this case.
 219     if !&diff
 220         set spell
 221     endif
 222     set spelllang=en_us
 223 endif
 224
 225 " Allow buffers with changes to be hidden. Very important for effective
 226 " editing with multiple buffers. Prevents the "E37: No write since last change
 227 " (add ! to override)" warning when switching buffers.
 228 set hidden
 229
 230
 231 " DISPLAY SETTINGS
 232
 233 " Use a dark background. Doesn't change the background color, only sets text
 234 " colors for a dark terminal.
 235 set background=dark
 236
 237 " Use my color scheme if 256 colors are available.
 238 if &t_Co == 256 || has('gui_running')
 239     colorscheme simon
 240 endif
 241
 242 " Display line numbers.
 243 set number
 244 " But use as little space as possible for the numbers column. Thanks to James
 245 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 246 if exists('+numberwidth')
 247     set numberwidth=1
 248 endif
 249 " Display the ruler with current line/file position. If 'statusline' is used
 250 " then this only affects <C-G>.
 251 set ruler
 252 " Display partial commands in the status line.
 253 set showcmd
 254
 255 " Don't redraw screen when executing macros; increases speed. Thanks to James
 256 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 257 set lazyredraw
 258
 259 " Visualize the line the cursor is currently in.
 260 if exists('+cursorline')
 261     set cursorline
 262 endif
 263
 264 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 265 " remove the highlighting until the next search.
 266 set hlsearch
 267
 268 " Display some special characters.
 269 set list
 270 set listchars=
 271 " Display tabs as ">--------".
 272 set listchars+=tab:>-
 273 " Display trailing whitespace as "-".
 274 set listchars+=trail:-
 275 " Display markers for long lines when wrapping is disabled.
 276 set listchars+=extends:>,precedes:<
 277 " Display non-breakable space as "!".
 278 if v:version >= 700
 279     set listchars+=nbsp:!
 280 endif
 281
 282 " Don't draw the vertical split separator by using space as character. Thanks
 283 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 284 " non-breakable space. But a simple space works as well, as long as the
 285 " current color scheme is not reset.
 286 if has('windows') && has('folding')
 287     set fillchars+=vert:\  " comment to prevent trailing whitespace
 288 endif
 289
 290 if has('statusline')
 291     " Always display the status line even if there is only one window.
 292     set laststatus=2
 293
 294     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 295     " is the highest buffer number, otherwise return nothing. Used in
 296     " 'statusline' to get an overview of available buffer numbers.
 297     function! StatuslineBufferCount()
 298         let l:bufnr = bufnr('$')
 299         if l:bufnr > 1
 300             let l:result = '/'
 301             if exists('*printf')
 302                 let l:result .= printf('%02d', l:bufnr)
 303             else
 304                 " Older Vims don't have printf() (and no .= either). Emulate
 305                 " "%02d".
 306                 if l:bufnr < 10
 307                     let l:result = l:result . '0'
 308                 endif
 309                 let l:result = l:result . l:bufnr
 310             endif
 311             return l:result
 312         else
 313             return ''
 314         endif
 315     endfunction
 316
 317     " Like %f but use relative filename if it's shorter than the absolute path
 318     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 319     " not enough because it doesn't create '../'s.
 320     function! StatuslineRelativeFilename()
 321         " Display only filename for help files.
 322         if &buftype == 'help'
 323             return expand('%:t')
 324         endif
 325         " Special case for scratch files.
 326         if &buftype == 'nofile'
 327             return '[Scratch]'
 328         endif
 329
 330         let l:path = expand('%')
 331         " No file.
 332         if l:path == ''
 333             return '[No Name]'
 334         endif
 335         " Path is already relative, nothing to do.
 336         if stridx(l:path, '/') != 0
 337             return l:path
 338         endif
 339
 340         " Absolute path to this file.
 341         let l:path = expand('%:p')
 342         " Shortened path to this file, thanks to bairui in #vim on Freenode
 343         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 344         " Vim normally uses as %f (minus some exceptions).
 345         let l:original_path = fnamemodify(l:path, ':~')
 346         " Absolute path to the current working directory.
 347         let l:cwd = getcwd()
 348
 349         " Working directory completely contained in path, replace it with a
 350         " relative path. Happens for example when opening a file with netrw.
 351         " %f displays this as absolute path, but we want a relative path of
 352         " course.
 353         if stridx(l:path, l:cwd) == 0
 354             return strpart(l:path, strlen(l:cwd) + 1)
 355         endif
 356
 357         let l:path_list = split(l:path, '/')
 358         let l:cwd_list  = split(l:cwd,  '/')
 359
 360         " Remove the common path.
 361         while l:path_list[0] == l:cwd_list[0]
 362             call remove(l:path_list, 0)
 363             call remove(l:cwd_list,  0)
 364         endwhile
 365
 366         " Add as many '..' as necessary for the relative path and join the
 367         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 368         " the hint to use repeat() instead of a loop.
 369         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 370
 371         " Use the shorter path, either relative or absolute.
 372         if strlen(l:path) < strlen(l:original_path)
 373             return l:path
 374         else
 375             return l:original_path
 376         endif
 377     endfunction
 378
 379     " Return current syntax group in brackets or nothing if there's none.
 380     function! StatuslineSyntaxGroup()
 381         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 382         if l:group != ''
 383             return '[' . l:group . '] '
 384         else
 385             return ''
 386         endif
 387     endfunction
 388
 389     set statusline=
 390     " on the left
 391     set statusline+=%02n  " buffer number
 392     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 393     set statusline+=:
 394     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 395         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 396         set statusline+=\     " space after path
 397     else
 398         set statusline+=%f\   " path to current file in buffer
 399     endif
 400     set statusline+=%h    " [help] if buffer is help file
 401     set statusline+=%w    " [Preview] if buffer is preview buffer
 402     set statusline+=%m    " [+] if buffer was modified,
 403                           " [-] if 'modifiable' is off
 404     set statusline+=%r    " [RO] if buffer is read only
 405
 406     " on the right
 407     set statusline+=%=                " right align
 408     set statusline+=0x%-8B\           " current character under cursor as hex
 409     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 410                                       " column number (%c),
 411                                       " virtual column number if different
 412                                       "                       than %c (%V)
 413     set statusline+=%P                " position in file in percent
 414 endif
 415
 416
 417 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 418
 419 " noremap is used to make sure the right side is executed as is and can't be
 420 " modified by a plugin or other settings. Except for <Nop> which isn't
 421 " affected by mappings.
 422
 423 " Easy way to exit insert mode. jk is preferred because it's faster.
 424 inoremap jj <Esc>
 425 inoremap jk <Esc>
 426 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 427 " (2010-10-15).
 428 cnoremap jj <C-C>
 429 cnoremap jk <C-C>
 430
 431 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 432 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 433 map <Right>  <Nop>
 434 map <Left>   <Nop>
 435 map <Up>     <Nop>
 436 map <Down>   <Nop>
 437 imap <Right> <Nop>
 438 imap <Left>  <Nop>
 439 imap <Up>    <Nop>
 440 imap <Down>  <Nop>
 441 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 442 " below).
 443 cmap <Up>    <Nop>
 444 cmap <Down>  <Nop>
 445 cmap <Right> <Nop>
 446 cmap <Left>  <Nop>
 447
 448 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 449 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 450 cnoremap <C-P> <Up>
 451 cnoremap <C-N> <Down>
 452
 453 if has('eval')
 454 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 455 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 456 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 457 " directly because it also enables that feature for other commands which I
 458 " don't want.
 459
 460     " Set 'nostartofline' for a single movement.
 461     function! s:TemporaryNostartofline(movement)
 462         let l:startofline = &startofline
 463         set nostartofline
 464         execute 'normal! ' . a:movement
 465         let &startofline = l:startofline
 466     endfunction
 467
 468     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 469     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 470     nnoremap <silent> <C-F>
 471         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 472     nnoremap <silent> <C-B>
 473         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 474     nnoremap <silent> <C-D>
 475         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 476     nnoremap <silent> <C-U>
 477         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 478 endif
 479
 480 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 481 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 482 " Only the current buffer is written, thus switching to another buffer works
 483 " too.
 484 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 485
 486 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 487 " in #vim on Freenode (2011-08-15 00:17 CEST).
 488 nnoremap <C-G> 2<C-G>
 489
 490 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 491 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 492 nmap <Space> <C-F>
 493 nmap - <C-B>
 494
 495 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 496 " (2010-05-16 18:38 CEST) for this idea.
 497 nnoremap <silent> gb :bnext<CR>
 498 nnoremap <silent> gB :bprevious<CR>
 499 if has('eval')
 500     " But when starting again at the first buffer, print a warning which
 501     " reminds me that I've already seen that buffer.
 502     function! s:NextBuffer()
 503         " Are we currently on the last buffer and moving to the first?
 504         let l:last_buffer = 0
 505         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 506             let l:last_buffer = 1
 507         endif
 508
 509         " Go to the next buffer.
 510         if !l:last_buffer
 511             bnext
 512
 513         " Go to the first buffer, silent is necessary or the following message
 514         " won't be displayed because it's overwritten by the status message
 515         " displayed when entering a buffer.
 516         else
 517             silent bnext
 518
 519             echohl WarningMsg
 520             echo 'Starting again at first buffer.'
 521             echohl None
 522         endif
 523     endfunction
 524     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 525 endif
 526
 527 " Fast access to buffers.
 528 nnoremap <silent> <Leader>1 :1buffer<CR>
 529 nnoremap <silent> <Leader>2 :2buffer<CR>
 530 nnoremap <silent> <Leader>3 :3buffer<CR>
 531 nnoremap <silent> <Leader>4 :4buffer<CR>
 532 nnoremap <silent> <Leader>5 :5buffer<CR>
 533 nnoremap <silent> <Leader>6 :6buffer<CR>
 534 nnoremap <silent> <Leader>7 :7buffer<CR>
 535 nnoremap <silent> <Leader>8 :8buffer<CR>
 536 nnoremap <silent> <Leader>9 :9buffer<CR>
 537 nnoremap <silent> <Leader>0 :10buffer<CR>
 538
 539 " Make last active window the only window. Similar to <C-W> o.
 540 nnoremap <C-W>O <C-W>p<C-W>o
 541
 542 " Maps to change spell language between English and German and disable spell
 543 " checking.
 544 if exists('+spell')
 545     nnoremap <silent> <Leader>sn :set nospell<CR>
 546     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 547     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 548 " If no spell support is available, these mappings do nothing.
 549 else
 550     nmap <Leader>sn <Nop>
 551     nmap <Leader>se <Nop>
 552     nmap <Leader>sd <Nop>
 553 endif
 554
 555 " Add semicolon to the end of the line. Thanks to
 556 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 557 " on Freenode for an improved version which doesn't clobber any marks.
 558 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 559
 560 " * and # for selections in visual mode. Thanks to
 561 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 562 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 563 if has('eval')
 564     function! s:VSetSearch()
 565         let l:temp = @@
 566         normal! gvy
 567         " Added \C to force 'noignorecase' while searching the current visual
 568         " selection. I want to search for the exact string in this case.
 569         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 570         let @@ = l:temp
 571     endfunction
 572     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 573     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 574 endif
 575
 576 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 577 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 578 " mailing list for the commands.
 579 if v:version < 700
 580     cnoreabbrev W w
 581     cnoreabbrev Wa wa
 582     cnoreabbrev Wq wq
 583     cnoreabbrev Wqa wqa
 584 else
 585     cnoreabbrev <expr> W
 586         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 587     cnoreabbrev <expr> Wa
 588         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 589     cnoreabbrev <expr> Wq
 590         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 591     cnoreabbrev <expr> Wqa
 592         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 593 endif
 594 " Also fix my typo with "Q".
 595 if v:version < 700
 596     cnoreabbrev Q q
 597     cnoreabbrev Qa qa
 598 else
 599     cnoreabbrev <expr> Q
 600         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 601     cnoreabbrev <expr> Qa
 602         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 603 endif
 604
 605 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 606 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 607 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 608
 609 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 610 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 611 " Vim's source.
 612 inoremap <C-U> <C-G>u<C-U>
 613 " Same for <C-@> (insert previously inserted text and leave insert mode).
 614 inoremap <C-@> <C-G>u<C-@>
 615 " And for <C-A> (insert previously inserted text).
 616 inoremap <C-A> <C-G>u<C-A>
 617 " And for <C-W> (delete word before cursor).
 618 inoremap <C-W> <C-G>u<C-W>
 619
 620 if has('eval')
 621 " New text-objects ii and ai to work on text with the same indentation. Thanks
 622 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 623 " (visited on 2011-11-19).
 624     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 625     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 626     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 627     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 628
 629     function! s:IndTxtObj(inner)
 630         let curline = line(".")
 631         let lastline = line("$")
 632         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 633         let i = i < 0 ? 0 : i
 634         if getline(".") !~ "^\\s*$"
 635             let p = line(".") - 1
 636             let nextblank = getline(p) =~ "^\\s*$"
 637             while p > 0
 638                     \ && ((i == 0 && !nextblank)
 639                         \ || (i > 0 && ((indent(p) >= i
 640                             \ && !(nextblank && a:inner))
 641                             \ || (nextblank && !a:inner))))
 642                 -
 643                 let p = line(".") - 1
 644                 let nextblank = getline(p) =~ "^\\s*$"
 645             endwhile
 646             normal! 0V
 647             call cursor(curline, 0)
 648             let p = line(".") + 1
 649             let nextblank = getline(p) =~ "^\\s*$"
 650             while p <= lastline
 651                     \ && ((i == 0 && !nextblank)
 652                         \ || (i > 0 && ((indent(p) >= i
 653                             \ && !(nextblank && a:inner))
 654                             \ || (nextblank && !a:inner))))
 655                 +
 656                 let p = line(".") + 1
 657                 let nextblank = getline(p) =~ "^\\s*$"
 658             endwhile
 659             normal! $
 660         endif
 661     endfunction
 662 endif
 663
 664
 665 " ABBREVIATIONS
 666
 667 " Fix some of my spelling mistakes (German).
 668 inoreabbrev relle reelle
 669 inoreabbrev reele reelle
 670 " Fix some of my spelling mistakes (English).
 671 inoreabbrev completly completely
 672
 673
 674 " SYNTAX SETTINGS
 675
 676 " Activate syntax coloring.
 677 if has('syntax')
 678     syntax enable
 679
 680 " Don't highlight more than 500 columns as I normally don't have that long
 681 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 682 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 683     if exists('+synmaxcol')
 684         set synmaxcol=500
 685     endif
 686
 687 " Use (limited) syntax based omni completion if no other omni completion is
 688 " available. Taken from :help ft-syntax-omni.
 689     if has('autocmd') && exists('+omnifunc')
 690         augroup vimrc
 691             autocmd FileType *
 692                 \ if &omnifunc == '' |
 693                 \     setlocal omnifunc=syntaxcomplete#Complete |
 694                 \ endif
 695         augroup END
 696     endif
 697
 698 " Function to enable all custom highlights. Necessary as highlights are
 699 " window-local and thus must be set for each new window.
 700     function! s:CustomSyntaxHighlights()
 701         " Not the first time called, nothing to do.
 702         if exists('w:vimrc_syntax_run')
 703             return
 704         endif
 705         let w:vimrc_syntax_run = 1
 706
 707 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 708 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 709 " disabled when necessary with :2match (in Vim >= 700).
 710         if !&diff && exists(':2match')
 711             " Use ColorColumn for overlong lines if available and my color
 712             " scheme is used.
 713             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 714                 2match ColorColumn /\%>78v./
 715             else
 716                 2match Todo /\%>78v./
 717             endif
 718         elseif !&diff
 719             match Todo /\%>78v./
 720         endif
 721
 722         if exists('*matchadd')
 723 " Highlight some important keywords in all documents.
 724             let l:todos = ['TODO', 'XXX', 'FIXME',
 725                          \ 'CHANGED', 'REMOVED', 'DELETED']
 726             " Compatibility fix for Vim 6.4 which can't handle for in function
 727             " (without function it's ignored).
 728             execute '  for l:x in l:todos'
 729                   \ '|     call matchadd("Todo", l:x)'
 730                   \ '| endfor'
 731
 732 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 733             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 734                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 735                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 736                           \ '205f', '2060', '3000', 'feff']
 737             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 738             " it won't work!
 739             execute '  for l:x in l:spaces'
 740                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 741                   \ '| endfor'
 742
 743 " Special highlight for tabs to reduce their visibility in contrast to other
 744 " SpecialKey characters (e.g. ^L).
 745             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 746                 call matchadd('specialKeyTab', '\t')
 747             endif
 748         endif
 749     endfunction
 750 " Enable highlights for the current and all new windows. Thanks to bairui in
 751 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 752     call <SID>CustomSyntaxHighlights()
 753     if has('autocmd')
 754         augroup vimrc
 755             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 756         augroup END
 757     endif
 758
 759 " Settings for specific filetypes.
 760
 761     " C
 762     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 763     " Haskell.
 764     let g:hs_highlight_delimiters = 1
 765     let g:hs_highlight_boolean = 1
 766     let g:hs_highlight_types = 1
 767     let g:hs_highlight_more_types = 1
 768     " Java.
 769     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 770     " Perl.
 771     let g:perl_fold = 1
 772     let g:perl_fold_blocks = 1
 773     let g:perl_nofold_packages = 1
 774     let g:perl_include_pod = 1 " syntax coloring for PODs
 775     " PHP.
 776     let g:php_folding = 3    " fold functions
 777     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 778     let g:php_sql_query = 1  " highlight SQL queries in strings
 779     " Python.
 780     let g:python_highlight_all = 1
 781     " Shell.
 782     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 783     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 784     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 785     " Vim.
 786     let g:vimsyn_embed = 0      " don't highlight embedded languages
 787     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 788     " XML.
 789     let g:xml_syntax_folding = 1
 790 endif
 791
 792
 793 " PLUGIN SETTINGS
 794
 795 if has('eval')
 796 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 797 " installing/removing/updating plugins simple. (Used for plugins with more
 798 " than one file.) Ignore errors in case pathogen is not installed.
 799     if v:version >= 700
 800         silent! execute 'call pathogen#infect()'
 801     endif
 802
 803 " Settings for securemodelines.
 804     " Only allow items I need (also includes spl which is not enabled by
 805     " default).
 806     if v:version >= 700 " need lists
 807         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 808                                               \ 'sw', 'sts', 'noet']
 809     endif
 810
 811 " Settings for the NERD commenter.
 812     " Don't create any mappings I don't want to use.
 813     let g:NERDCreateDefaultMappings = 0
 814     " Map toggle comment.
 815     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 816
 817 " XPTemplate settings.
 818     " Try to maintain snippet rendering even after editing outside of a
 819     " snippet.
 820     let g:xptemplate_strict = 0
 821     " Don't complete any braces automatically.
 822     let g:xptemplate_brace_complete = 0
 823     " Only highlight the current placeholder.
 824     let g:xptemplate_highlight = 'current'
 825
 826 " CtrlP settings.
 827     " Don't manage the working directory (the default setting is too slow for
 828     " me).
 829     let g:ctrlp_working_path_mode = 0
 830     " Path to cache directory. I prefer to keep generated files as local as
 831     " possible.
 832     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 833     " Permanent cache, cleared by a crontab entry.
 834     let g:ctrlp_clear_cache_on_exit = 0
 835
 836 " FSWitch settings.
 837     " Default don't work well for my projects.
 838     augroup vimrc
 839         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 840                           \ | let b:fswitchlocs = './'
 841         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 842                           \ | let b:fswitchlocs = './'
 843     augroup END
 844
 845     " Switch to corresponding header/source file.
 846     nnoremap <silent> <Leader>h :FSHere<CR>
 847 endif
 848
 849
 850 " AUTO COMMANDS
 851
 852 " Use a custom auto group to prevent problems when the vimrc files is sourced
 853 " twice.
 854 if has('autocmd')
 855     augroup vimrc
 856
 857 " Go to last position of opened files. Taken from :help last-position-jump.
 858         autocmd BufReadPost *
 859             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 860             \     execute "normal! g'\"" |
 861             \ endif
 862 " But not for Git commits, go to beginning of the file.
 863         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 864
 865 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 866 " when switching to a help buffer which is in the background with :buffer as
 867 " these options are local to windows (and not only to buffers). This happens
 868 " because I often want to use only one window and thus the help buffer is in
 869 " the background.
 870         autocmd BufWinEnter *.txt
 871             \ if &filetype == 'help' |
 872             \     setlocal nolist |
 873             \     setlocal nonumber |
 874             \ endif
 875
 876 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 877 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 878 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 879 " doesn't exist in older Vims.
 880         if exists('##InsertLeave')
 881             autocmd InsertLeave * set nopaste
 882         endif
 883
 884 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 885 " doesn't exist in older Vims.
 886         if exists('##QuickFixCmdPre')
 887             autocmd QuickFixCmdPre * write
 888         endif
 889
 890 " Don't ignore case while in insert mode, but ignore case in all other modes.
 891 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 892 " capitalization. But while searching (/) 'ignorecase' is used.
 893 " InsertEnter/InsertLeave doesn't exist in older Vims.
 894         if exists('##InsertEnter') && exists('##InsertLeave')
 895             autocmd InsertEnter * set noignorecase
 896             autocmd InsertLeave * set   ignorecase
 897         endif
 898
 899 " Display a warning when editing a file which contains "do not edit" (ignoring
 900 " the case, \c), for example template files which were preprocessed or
 901 " auto-generated files. Especially useful when the header is not displayed on
 902 " the first screen, e.g. when the old position is restored. Not for vimrc
 903 " though.
 904         function! s:SearchForDoNotEditHeader()
 905             if search('\cdo not edit', 'n') == 0
 906                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 907                 return
 908             endif
 909
 910             echohl WarningMsg
 911             echo 'Do not edit this file! (Maybe a template file.)'
 912             echohl None
 913         endfunction
 914         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 915
 916 " AFTER/FTPLUGIN AUTO COMMANDS
 917
 918 " Disable spell checking for files which don't need it.
 919         autocmd FileType deb  setlocal nospell
 920         autocmd FileType diff setlocal nospell
 921         autocmd FileType tar  setlocal nospell
 922 " Fix to allow Vim edit crontab files as crontab doesn't work with
 923 " backupcopy=auto.
 924         autocmd FileType crontab setlocal backupcopy=yes
 925 " Don't use the modeline in git commits as the diff created by `git commit -v`
 926 " may contain one which could change the filetype or other settings of the
 927 " commit buffer. Also make sure we use only 72 characters per line which is
 928 " the recommendation for git commit messages (http://tpope.net/node/106).
 929         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 930                                  \ setlocal textwidth=72
 931 " Use the same comment string as for Vim files in Vimperator files.
 932         autocmd FileType vimperator setlocal commentstring=\"%s
 933 " Use TeX compiler for (La)TeX files.
 934         autocmd FileType tex compiler tex
 935
 936 " FTDETECT AUTO COMMANDS
 937
 938 " Recognize .md as markdown files (Vim default is .mkd).
 939         autocmd BufRead,BufNewFile *.md set filetype=mkd
 940 " Recognize .test as Tcl files.
 941         autocmd BufRead,BufNewFile *.test set filetype=tcl
 942
 943 " OTHER AUTO COMMANDS
 944
 945 " Disable spell checking, displaying of list characters and long lines when
 946 " viewing documentation.
 947         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 948
 949 " Use diff filetype for mercurial patches in patch queue.
 950         autocmd BufReadPost */.hg/patches/* set filetype=diff
 951
 952     augroup END
 953 endif
 954
 955
 956 " CUSTOM FUNCTIONS AND COMMANDS
 957
 958 if has('eval')
 959 " Convenient command to see the difference between the current buffer and the
 960 " file it was loaded from, thus the changes you made. Thanks to the
 961 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 962 " for the diffed file than the filetype for the original file.
 963     if !exists(':DiffOrig')
 964         command DiffOrig
 965             \ let s:diff_orig_filetype = &filetype
 966             \ | vertical new
 967             \ | let &filetype = s:diff_orig_filetype
 968             \ | unlet s:diff_orig_filetype
 969             \ | set buftype=nofile
 970             \ | read ++edit #
 971             \ | 0d_
 972             \ | diffthis
 973             \ | wincmd p
 974             \ | diffthis
 975     endif
 976 endif