vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     " Only use fold column if we have enough space (for example in a (virtual)
 143     " terminals).
 144     if &columns > 80
 145         set foldcolumn=2
 146     endif
 147     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 148                      " folding which is not what I want
 149 endif
 150
 151 " Only check for case if the searched word contains a capital character.
 152 set ignorecase
 153 set smartcase
 154
 155 " Activate spell checking, use English as default.
 156 if exists('+spell') && has('syntax')
 157     " But not when diffing because spell checking is distracting in this case.
 158     if !&diff
 159         set spell
 160     endif
 161     set spelllang=en_us
 162 endif
 163
 164 " Allow buffers with changes to be hidden. Very important for effective
 165 " editing with multiple buffers.
 166 set hidden
 167
 168
 169 " DISPLAY SETTINGS
 170
 171 " Use a dark background. Doesn't change the background color, only sets text
 172 " colors for a dark terminal.
 173 set background=dark
 174
 175 " Display line numbers.
 176 set number
 177 " But use as little space as necessary for the numbers column. Thanks to James
 178 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 179 if exists('+numberwidth')
 180     set numberwidth=1
 181 endif
 182 " Display the ruler with current line/file position. If 'statusline' is used
 183 " then this only affects <C-G>.
 184 set ruler
 185 " Display partial commands in the status line.
 186 set showcmd
 187
 188 " Don't redraw screen when executing macros; increases speed. Thanks to James
 189 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 190 set lazyredraw
 191
 192 " Visualize the line the cursor is currently in.
 193 if exists('+cursorline')
 194     set cursorline
 195 endif
 196
 197 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 198 " remove the highlighting until the next search.
 199 set hlsearch
 200
 201 " Display some special characters.
 202 set list
 203 set listchars=
 204 " Display tabs as ">--------".
 205 set listchars+=tab:>-
 206 " Display trailing whitespace as "-".
 207 set listchars+=trail:-
 208 " Display markers for long lines when wrapping is disabled.
 209 set listchars+=extends:>,precedes:<
 210 " Display non-breakable space as "!".
 211 if v:version >= 700
 212     set listchars+=nbsp:!
 213 endif
 214
 215 if has('statusline')
 216     " Always display the status line even if there is only one window.
 217     set laststatus=2
 218
 219     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 220     " is the highest buffer number, otherwise return nothing. Used in
 221     " 'statusline' to get an overview of available buffer numbers.
 222     function! StatuslineBufferCount()
 223         let l:bufnr = bufnr('$')
 224         if l:bufnr > 1
 225             let l:result = '/'
 226             if exists('*printf')
 227                 let l:result .= printf('%02d', l:bufnr)
 228             else
 229                 " Older Vims don't have printf() (and no .= either). Emulate
 230                 " "%02d".
 231                 if l:bufnr < 10
 232                     let l:result = l:result . '0'
 233                 endif
 234                 let l:result = l:result . l:bufnr
 235             endif
 236             return l:result
 237         else
 238             return ''
 239         endif
 240     endfunction
 241
 242     set statusline=
 243     " on the left
 244     set statusline+=%02n  " buffer number
 245     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 246     set statusline+=:
 247     set statusline+=%f\   " path to current file in buffer
 248     set statusline+=%h    " [help] if buffer is help file
 249     set statusline+=%w    " [Preview] if buffer is preview buffer
 250     set statusline+=%m    " [+] if buffer was modified,
 251                           " [-] if 'modifiable' is off
 252     set statusline+=%r    " [RO] if buffer is read only
 253
 254     " on the right
 255     set statusline+=%=                " right align
 256     set statusline+=0x%-8B\           " current character under cursor as hex
 257     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 258                                       " column number (%c),
 259                                       " virtual column number if different
 260                                       "                       than %c (%V)
 261     set statusline+=%P                " position in file in percent
 262 endif
 263
 264
 265 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 266
 267 " noremap is used to make sure the right side is executed as is and can't be
 268 " modified by a plugin or other settings. Except for <Nop> which isn't
 269 " affected by mappings.
 270
 271 " Easy way to exit insert mode.
 272 inoremap jj <Esc>
 273 inoremap jk <Esc>
 274 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 275 " (2010-10-15).
 276 cnoremap jj <C-C>
 277 cnoremap jk <C-C>
 278
 279 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 280 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 281 map <Right>  <Nop>
 282 map <Left>   <Nop>
 283 map <Up>     <Nop>
 284 map <Down>   <Nop>
 285 imap <Right> <Nop>
 286 imap <Left>  <Nop>
 287 imap <Up>    <Nop>
 288 imap <Down>  <Nop>
 289 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 290 " below).
 291 cmap <Up>    <Nop>
 292 cmap <Down>  <Nop>
 293 cmap <Right> <Nop>
 294 cmap <Left>  <Nop>
 295
 296 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 297 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 298 cnoremap <C-P> <Up>
 299 cnoremap <C-N> <Down>
 300
 301 if has('eval')
 302 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 303 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 304 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 305 " directly because it also enables that feature for other commands which I
 306 " don't want.
 307
 308     " Set 'nostartofline' for a single movement.
 309     function! s:TemporaryNostartofline(movement)
 310         let l:startofline = &startofline
 311         set nostartofline
 312         execute 'normal! ' . a:movement
 313         let &startofline = l:startofline
 314     endfunction
 315
 316     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 317     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 318     nnoremap <silent> <C-F>
 319         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 320     nnoremap <silent> <C-B>
 321         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 322     nnoremap <silent> <C-D>
 323         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 324     nnoremap <silent> <C-U>
 325         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 326 endif
 327
 328 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 329 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 330 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 331
 332 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 333 " in #vim on Freenode (2011-08-15 00:17 CEST).
 334 nnoremap <C-G> 2<C-G>
 335
 336 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 337 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 338 nmap <Space> <C-F>
 339 nmap - <C-B>
 340
 341 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 342 " (2010-05-16 18:38 CEST) for this idea.
 343 nnoremap <silent> gb :bnext<CR>
 344 nnoremap <silent> gB :bprev<CR>
 345
 346 " Fast access to buffers.
 347 nnoremap <silent> <Leader>1 :1buffer<CR>
 348 nnoremap <silent> <Leader>2 :2buffer<CR>
 349 nnoremap <silent> <Leader>3 :3buffer<CR>
 350 nnoremap <silent> <Leader>4 :4buffer<CR>
 351 nnoremap <silent> <Leader>5 :5buffer<CR>
 352 nnoremap <silent> <Leader>6 :6buffer<CR>
 353 nnoremap <silent> <Leader>7 :7buffer<CR>
 354 nnoremap <silent> <Leader>8 :8buffer<CR>
 355 nnoremap <silent> <Leader>9 :9buffer<CR>
 356 nnoremap <silent> <Leader>0 :10buffer<CR>
 357
 358 " Make last active window the only window. Similar to <C-W> o.
 359 nnoremap <C-W>O <C-W>p<C-W>o
 360
 361 " Maps to change spell language between English and German and disable spell
 362 " checking.
 363 if exists('+spell')
 364     nnoremap <silent> <Leader>sn :set nospell<CR>
 365     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 366     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 367 endif
 368
 369 " Add semicolon to the end of the line. Thanks to
 370 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 371 " on Freenode for an improved version which doesn't clobber any marks.
 372 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 373
 374 " * and # for selections in visual mode. Thanks to
 375 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 376 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 377 if has('eval')
 378     function! s:VSetSearch()
 379         let l:temp = @@
 380         normal! gvy
 381         " Added \C to force 'noignorecase' while searching the current visual
 382         " selection. I want to search for the exact string in this case.
 383         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 384         let @@ = l:temp
 385     endfunction
 386     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 387     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 388 endif
 389
 390 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 391 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 392 " mailing list for the commands.
 393 if v:version < 700
 394     cnoreabbrev W w
 395     cnoreabbrev Wa wa
 396     cnoreabbrev Wq wq
 397     cnoreabbrev Wqa wqa
 398 else
 399     cnoreabbrev <expr> W
 400         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 401     cnoreabbrev <expr> Wa
 402         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 403     cnoreabbrev <expr> Wq
 404         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 405     cnoreabbrev <expr> Wqa
 406         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 407 endif
 408 " Also fix my typo with "Q".
 409 if v:version < 700
 410     cnoreabbrev Q q
 411     cnoreabbrev Qa qa
 412 else
 413     cnoreabbrev <expr> Q
 414         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 415     cnoreabbrev <expr> Qa
 416         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 417 endif
 418
 419 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 420 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 421 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 422
 423 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 424 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 425 " Vim's source.
 426 inoremap <C-U> <C-G>u<C-U>
 427 " Same for <C-@> (insert previously inserted text and leave insert mode).
 428 inoremap <C-@> <C-G>u<C-@>
 429 " And for <C-A> (insert previously inserted text).
 430 inoremap <C-A> <C-G>u<C-A>
 431 " And for <C-W> (delete word before cursor).
 432 inoremap <C-W> <C-G>u<C-W>
 433
 434 if has('eval')
 435 " New text-objects ii and ai to work on text with the same indentation. Thanks
 436 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 437 " (visited on 2011-11-19).
 438     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 439     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 440     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 441     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 442
 443     function! s:IndTxtObj(inner)
 444         let curline = line(".")
 445         let lastline = line("$")
 446         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 447         let i = i < 0 ? 0 : i
 448         if getline(".") !~ "^\\s*$"
 449             let p = line(".") - 1
 450             let nextblank = getline(p) =~ "^\\s*$"
 451             while p > 0
 452                     \ && ((i == 0 && !nextblank)
 453                         \ || (i > 0 && ((indent(p) >= i
 454                             \ && !(nextblank && a:inner))
 455                             \ || (nextblank && !a:inner))))
 456                 -
 457                 let p = line(".") - 1
 458                 let nextblank = getline(p) =~ "^\\s*$"
 459             endwhile
 460             normal! 0V
 461             call cursor(curline, 0)
 462             let p = line(".") + 1
 463             let nextblank = getline(p) =~ "^\\s*$"
 464             while p <= lastline
 465                     \ && ((i == 0 && !nextblank)
 466                         \ || (i > 0 && ((indent(p) >= i
 467                             \ && !(nextblank && a:inner))
 468                             \ || (nextblank && !a:inner))))
 469                 +
 470                 let p = line(".") + 1
 471                 let nextblank = getline(p) =~ "^\\s*$"
 472             endwhile
 473             normal! $
 474         endif
 475     endfunction
 476 endif
 477
 478
 479 " ABBREVIATIONS
 480
 481 " Fix some of my spelling mistakes.
 482 iabbrev relle reelle
 483 iabbrev reele reelle
 484
 485
 486 " SYNTAX SETTINGS
 487
 488 " Activate syntax coloring.
 489 if has('syntax')
 490     syntax enable
 491
 492 " Don't highlight more than 500 columns as I normally don't have that long
 493 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 494 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 495     if exists('+synmaxcol')
 496         set synmaxcol=500
 497     endif
 498
 499 " Use (limited) syntax based omni completion if no other omni completion is
 500 " available. Taken from :help ft-syntax-omni.
 501     if has('autocmd') && exists('+omnifunc')
 502         augroup vimrc
 503             autocmd FileType *
 504                 \ if &omnifunc == '' |
 505                 \     setlocal omnifunc=syntaxcomplete#Complete |
 506                 \ endif
 507         augroup END
 508     endif
 509
 510 " Function to enable all custom highlights. Necessary as highlights are
 511 " window-local and thus must be set for each new window.
 512     function! s:CustomSyntaxHighlights()
 513         " Not the first time called, nothing to do.
 514         if exists('w:vimrc_syntax_run')
 515             return
 516         endif
 517         let w:vimrc_syntax_run = 1
 518
 519 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 520 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 521 " disabled when necessary with :2match (in Vim >= 700).
 522         if exists(':2match')
 523             2match Todo /\%>78v./
 524         else
 525             match Todo /\%>78v./
 526         endif
 527
 528         if exists('*matchadd')
 529 " Highlight some important keywords in all documents.
 530             let l:todos = ['TODO', 'XXX', 'FIXME',
 531                          \ 'CHANGED', 'REMOVED', 'DELETED']
 532             " Compatibility fix for Vim 6.4 which can't handle for in function
 533             " (without function it's ignored).
 534             execute '  for l:x in l:todos'
 535                   \ '|     call matchadd("Todo", l:x)'
 536                   \ '| endfor'
 537
 538 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 539             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 540                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 541                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 542                           \ '205f', '2060', '3000', 'feff']
 543             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 544             " it won't work!
 545             execute '  for l:x in l:spaces'
 546                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 547                   \ '| endfor'
 548         endif
 549     endfunction
 550 " Enable highlights for the current and all new windows. Thanks to bairui in
 551 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 552     call <SID>CustomSyntaxHighlights()
 553     if has('autocmd')
 554         augroup vimrc
 555             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 556         augroup END
 557     endif
 558
 559 " Settings for specific filetypes.
 560
 561     " Haskell.
 562     let g:hs_highlight_delimiters = 1
 563     let g:hs_highlight_boolean = 1
 564     let g:hs_highlight_types = 1
 565     let g:hs_highlight_more_types = 1
 566     " Perl.
 567     let g:perl_fold = 1
 568     let g:perl_fold_blocks = 1
 569     let g:perl_nofold_packages = 1
 570     let g:perl_include_pod = 1 " syntax coloring for PODs
 571     " Python.
 572     let g:python_highlight_all = 1
 573     " Shell.
 574     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 575     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 576     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 577     " Vim.
 578     let g:vimsyn_embed = 0      " don't highlight embedded languages
 579     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 580     " XML.
 581     let g:xml_syntax_folding = 1
 582 endif
 583
 584
 585 " PLUGIN SETTINGS
 586
 587 if has('eval')
 588 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 589 " installing/removing/updating plugins simple. (Used for plugins with more
 590 " than one file.) Ignore errors in case pathogen is not installed.
 591     if v:version >= 700
 592         silent! execute 'call pathogen#runtime_append_all_bundles()'
 593     endif
 594
 595 " Settings for the NERD commenter.
 596     " Don't create any mappings I don't want to use.
 597     let g:NERDCreateDefaultMappings = 0
 598     " Map toggle comment.
 599     map <Leader><Leader> <Plug>NERDCommenterToggle
 600
 601 " XPTemplate settings.
 602     " Try to maintain snippet rendering even after editing outside of a
 603     " snippet.
 604     let g:xptemplate_strict = 0
 605     " Don't complete any braces automatically.
 606     let g:xptemplate_brace_complete = 0
 607     " Only highlight the current placeholder.
 608     let g:xptemplate_highlight = 'current'
 609 endif
 610
 611
 612 " AUTO COMMANDS
 613
 614 " Use a custom auto group to prevent problems when the vimrc files is sourced
 615 " twice.
 616 if has('autocmd')
 617     augroup vimrc
 618
 619 " Go to last position of opened files. Taken from :help last-position-jump.
 620         autocmd BufReadPost *
 621             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 622             \     execute "normal! g'\"" |
 623             \ endif
 624 " But not for Git commits, go to beginning of the file.
 625         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 626
 627 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 628 " when switching to a help buffer which is in the background with :buffer as
 629 " these options are local to windows (and not only to buffers). This happens
 630 " because I often want to use only one window and thus the help buffer is in
 631 " the background.
 632         autocmd BufWinEnter *.txt
 633             \ if &filetype == 'help' |
 634             \     setlocal nolist |
 635             \     setlocal nonumber |
 636             \ endif
 637
 638 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 639 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 640 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 641 " doesn't exist in older Vims.
 642         if exists('##InsertLeave')
 643             autocmd InsertLeave * set nopaste
 644         endif
 645
 646 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 647 " doesn't exist in older Vims.
 648         if exists('##QuickFixCmdPre')
 649             autocmd QuickFixCmdPre * write
 650         endif
 651
 652 " Don't ignore case while in insert mode, but ignore case in all other modes.
 653 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 654 " capitalization. But while searching (/) 'ignorecase' is used.
 655 " InsertEnter/InsertLeave doesn't exist in older Vims.
 656         if exists('##InsertEnter') && exists('##InsertLeave')
 657             autocmd InsertEnter * set noignorecase
 658             autocmd InsertLeave * set   ignorecase
 659         endif
 660
 661 " AFTER/FTPLUGIN AUTO COMMANDS
 662
 663 " Disable spell checking for files which don't need it.
 664         autocmd FileType deb  setlocal nospell
 665         autocmd FileType diff setlocal nospell
 666         autocmd FileType tar  setlocal nospell
 667 " Fix to allow Vim edit crontab files as crontab doesn't work with
 668 " backupcopy=auto.
 669         autocmd FileType crontab setlocal backupcopy=yes
 670 " Don't use the modeline in git commits as the diff created by `git commit -v`
 671 " may contain one which could change the filetype or other settings of the
 672 " commit buffer. Also make sure we use only 72 characters per line which is
 673 " the recommendation for git commit messages (http://tpope.net/node/106).
 674         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 675                                  \ setlocal textwidth=72
 676 " Use the same comment string as for Vim files in Vimperator files.
 677         autocmd FileType vimperator setlocal commentstring=\"%s
 678 " Use tex compiler for (La)TeX files.
 679         autocmd FileType tex compiler tex
 680
 681 " FTDETECT AUTO COMMANDS
 682
 683 " Recognize .md as markdown files (Vim default is .mkd).
 684         autocmd BufRead,BufNewFile *.md set filetype=mkd
 685 " Recognize .test as Tcl files.
 686         autocmd BufRead,BufNewFile *.test set filetype=tcl
 687
 688 " OTHER AUTO COMMANDS
 689
 690 " Disable spell checking, displaying of list characters and long lines when
 691 " viewing documentation.
 692         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 693
 694 " Use diff filetype for mercurial patches in patch queue.
 695         autocmd BufReadPost */.hg/patches/* set filetype=diff
 696
 697     augroup END
 698 endif
 699
 700
 701 " CUSTOM FUNCTIONS AND COMMANDS
 702
 703 if has('eval')
 704 " Convenient command to see the difference between the current buffer and the
 705 " file it was loaded from, thus the changes you made. Thanks to the
 706 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 707 " for the diffed file than the filetype for the original file.
 708     if !exists(':DiffOrig')
 709         command DiffOrig
 710             \ let s:diff_orig_filetype = &filetype
 711             \ | vertical new
 712             \ | let &filetype = s:diff_orig_filetype
 713             \ | unlet s:diff_orig_filetype
 714             \ | set buftype=nofile
 715             \ | read ++edit #
 716             \ | 0d_
 717             \ | diffthis
 718             \ | wincmd p
 719             \ | diffthis
 720     endif
 721 endif