vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " HELPER FUNCTIONS
  92
  93 " Check if the given syntax group is available. Thanks to bairui in #vim on
  94 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  95 if has('eval')
  96     function! s:HasSyntaxGroup(group)
  97         try
  98             execute 'silent highlight ' . a:group
  99         " \a = [A-Za-z]
 100         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 101             return 0
 102         endtry
 103         return 1
 104     endfunction
 105 endif
 106
 107
 108 " EDIT SETTINGS
 109
 110 " Enable automatic file detection, plugin and indention support.
 111 if has('autocmd')
 112     filetype off " necessary for pathogen to force a reload of ftplugins
 113     filetype plugin indent on
 114 endif
 115
 116 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 117 " existing files.
 118 set fileencodings=utf-8,latin1
 119
 120 " Wrap text after 78 characters.
 121 set textwidth=78
 122
 123 " Set tabs to 4 spaces, use softtabs.
 124 set shiftwidth=4
 125 set softtabstop=4
 126 set expandtab
 127 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 128 set shiftround
 129 " Use the default value for real tabs.
 130 set tabstop=8
 131
 132 " Enable auto indention.
 133 set autoindent
 134
 135 " When joining lines only add one space after a sentence.
 136 set nojoinspaces
 137
 138 " Allow backspacing over autoindent and line breaks.
 139 set backspace=indent,eol
 140
 141 " Start a comment when hitting enter after a commented line (r) and when using
 142 " o or O around a commented line (o).
 143 set formatoptions+=ro
 144 " Don't break a line if was already longer then 'textwidth' when insert mode
 145 " started.
 146 set formatoptions+=l
 147
 148 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 149 " no character) in visual block mode.
 150 set virtualedit=block
 151
 152 " Already display matches while typing the search command. This makes spotting
 153 " errors easy.
 154 set incsearch
 155
 156 " Activate syntax folding.
 157 if has('folding')
 158     set foldmethod=syntax
 159     " Only use fold column if we have enough space (for example in a (virtual)
 160     " terminals).
 161     if &columns > 80
 162         set foldcolumn=2
 163     endif
 164     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 165                      " folding which is not what I want
 166 endif
 167
 168 " Only check case if the searched word contains a capital character.
 169 set ignorecase
 170 set smartcase
 171
 172 " Activate spell checking, use English as default.
 173 if exists('+spell') && has('syntax')
 174     " But not when diffing because spell checking is distracting in this case.
 175     if !&diff
 176         set spell
 177     endif
 178     set spelllang=en_us
 179 endif
 180
 181 " Allow buffers with changes to be hidden. Very important for effective
 182 " editing with multiple buffers. Prevents the "E37: No write since last change
 183 " (add ! to override)" warning.
 184 set hidden
 185
 186
 187 " DISPLAY SETTINGS
 188
 189 " Use a dark background. Doesn't change the background color, only sets text
 190 " colors for a dark terminal.
 191 set background=dark
 192
 193 " Use my color scheme if 256 colors are available.
 194 if &t_Co == 256
 195     colorscheme simon
 196 endif
 197
 198 " Display line numbers.
 199 set number
 200 " But use as little space as possible for the numbers column. Thanks to James
 201 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 202 if exists('+numberwidth')
 203     set numberwidth=1
 204 endif
 205 " Display the ruler with current line/file position. If 'statusline' is used
 206 " then this only affects <C-G>.
 207 set ruler
 208 " Display partial commands in the status line.
 209 set showcmd
 210
 211 " Don't redraw screen when executing macros; increases speed. Thanks to James
 212 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 213 set lazyredraw
 214
 215 " Visualize the line the cursor is currently in.
 216 if exists('+cursorline')
 217     set cursorline
 218 endif
 219
 220 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 221 " remove the highlighting until the next search.
 222 set hlsearch
 223
 224 " Display some special characters.
 225 set list
 226 set listchars=
 227 " Display tabs as ">--------".
 228 set listchars+=tab:>-
 229 " Display trailing whitespace as "-".
 230 set listchars+=trail:-
 231 " Display markers for long lines when wrapping is disabled.
 232 set listchars+=extends:>,precedes:<
 233 " Display non-breakable space as "!".
 234 if v:version >= 700
 235     set listchars+=nbsp:!
 236 endif
 237
 238 if has('statusline')
 239     " Always display the status line even if there is only one window.
 240     set laststatus=2
 241
 242     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 243     " is the highest buffer number, otherwise return nothing. Used in
 244     " 'statusline' to get an overview of available buffer numbers.
 245     function! StatuslineBufferCount()
 246         let l:bufnr = bufnr('$')
 247         if l:bufnr > 1
 248             let l:result = '/'
 249             if exists('*printf')
 250                 let l:result .= printf('%02d', l:bufnr)
 251             else
 252                 " Older Vims don't have printf() (and no .= either). Emulate
 253                 " "%02d".
 254                 if l:bufnr < 10
 255                     let l:result = l:result . '0'
 256                 endif
 257                 let l:result = l:result . l:bufnr
 258             endif
 259             return l:result
 260         else
 261             return ''
 262         endif
 263     endfunction
 264
 265     set statusline=
 266     " on the left
 267     set statusline+=%02n  " buffer number
 268     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 269     set statusline+=:
 270     set statusline+=%f\   " path to current file in buffer
 271     set statusline+=%h    " [help] if buffer is help file
 272     set statusline+=%w    " [Preview] if buffer is preview buffer
 273     set statusline+=%m    " [+] if buffer was modified,
 274                           " [-] if 'modifiable' is off
 275     set statusline+=%r    " [RO] if buffer is read only
 276
 277     " on the right
 278     set statusline+=%=                " right align
 279     set statusline+=0x%-8B\           " current character under cursor as hex
 280     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 281                                       " column number (%c),
 282                                       " virtual column number if different
 283                                       "                       than %c (%V)
 284     set statusline+=%P                " position in file in percent
 285 endif
 286
 287
 288 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 289
 290 " noremap is used to make sure the right side is executed as is and can't be
 291 " modified by a plugin or other settings. Except for <Nop> which isn't
 292 " affected by mappings.
 293
 294 " Easy way to exit insert mode.
 295 inoremap jj <Esc>
 296 inoremap jk <Esc>
 297 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 298 " (2010-10-15).
 299 cnoremap jj <C-C>
 300 cnoremap jk <C-C>
 301
 302 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 303 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 304 map <Right>  <Nop>
 305 map <Left>   <Nop>
 306 map <Up>     <Nop>
 307 map <Down>   <Nop>
 308 imap <Right> <Nop>
 309 imap <Left>  <Nop>
 310 imap <Up>    <Nop>
 311 imap <Down>  <Nop>
 312 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 313 " below).
 314 cmap <Up>    <Nop>
 315 cmap <Down>  <Nop>
 316 cmap <Right> <Nop>
 317 cmap <Left>  <Nop>
 318
 319 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 320 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 321 cnoremap <C-P> <Up>
 322 cnoremap <C-N> <Down>
 323
 324 if has('eval')
 325 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 326 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 327 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 328 " directly because it also enables that feature for other commands which I
 329 " don't want.
 330
 331     " Set 'nostartofline' for a single movement.
 332     function! s:TemporaryNostartofline(movement)
 333         let l:startofline = &startofline
 334         set nostartofline
 335         execute 'normal! ' . a:movement
 336         let &startofline = l:startofline
 337     endfunction
 338
 339     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 340     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 341     nnoremap <silent> <C-F>
 342         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 343     nnoremap <silent> <C-B>
 344         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 345     nnoremap <silent> <C-D>
 346         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 347     nnoremap <silent> <C-U>
 348         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 349 endif
 350
 351 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 352 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 353 " Only the current buffer is written.
 354 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 355
 356 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 357 " in #vim on Freenode (2011-08-15 00:17 CEST).
 358 nnoremap <C-G> 2<C-G>
 359
 360 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 361 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 362 nmap <Space> <C-F>
 363 nmap - <C-B>
 364
 365 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 366 " (2010-05-16 18:38 CEST) for this idea.
 367 nnoremap <silent> gb :bnext<CR>
 368 nnoremap <silent> gB :bprevious<CR>
 369
 370 " Fast access to buffers.
 371 nnoremap <silent> <Leader>1 :1buffer<CR>
 372 nnoremap <silent> <Leader>2 :2buffer<CR>
 373 nnoremap <silent> <Leader>3 :3buffer<CR>
 374 nnoremap <silent> <Leader>4 :4buffer<CR>
 375 nnoremap <silent> <Leader>5 :5buffer<CR>
 376 nnoremap <silent> <Leader>6 :6buffer<CR>
 377 nnoremap <silent> <Leader>7 :7buffer<CR>
 378 nnoremap <silent> <Leader>8 :8buffer<CR>
 379 nnoremap <silent> <Leader>9 :9buffer<CR>
 380 nnoremap <silent> <Leader>0 :10buffer<CR>
 381
 382 " Make last active window the only window. Similar to <C-W> o.
 383 nnoremap <C-W>O <C-W>p<C-W>o
 384
 385 " Maps to change spell language between English and German and disable spell
 386 " checking.
 387 if exists('+spell')
 388     nnoremap <silent> <Leader>sn :set nospell<CR>
 389     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 390     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 391 endif
 392
 393 " Add semicolon to the end of the line. Thanks to
 394 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 395 " on Freenode for an improved version which doesn't clobber any marks.
 396 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 397
 398 " * and # for selections in visual mode. Thanks to
 399 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 400 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 401 if has('eval')
 402     function! s:VSetSearch()
 403         let l:temp = @@
 404         normal! gvy
 405         " Added \C to force 'noignorecase' while searching the current visual
 406         " selection. I want to search for the exact string in this case.
 407         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 408         let @@ = l:temp
 409     endfunction
 410     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 411     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 412 endif
 413
 414 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 415 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 416 " mailing list for the commands.
 417 if v:version < 700
 418     cnoreabbrev W w
 419     cnoreabbrev Wa wa
 420     cnoreabbrev Wq wq
 421     cnoreabbrev Wqa wqa
 422 else
 423     cnoreabbrev <expr> W
 424         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 425     cnoreabbrev <expr> Wa
 426         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 427     cnoreabbrev <expr> Wq
 428         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 429     cnoreabbrev <expr> Wqa
 430         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 431 endif
 432 " Also fix my typo with "Q".
 433 if v:version < 700
 434     cnoreabbrev Q q
 435     cnoreabbrev Qa qa
 436 else
 437     cnoreabbrev <expr> Q
 438         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 439     cnoreabbrev <expr> Qa
 440         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 441 endif
 442
 443 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 444 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 445 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 446
 447 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 448 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 449 " Vim's source.
 450 inoremap <C-U> <C-G>u<C-U>
 451 " Same for <C-@> (insert previously inserted text and leave insert mode).
 452 inoremap <C-@> <C-G>u<C-@>
 453 " And for <C-A> (insert previously inserted text).
 454 inoremap <C-A> <C-G>u<C-A>
 455 " And for <C-W> (delete word before cursor).
 456 inoremap <C-W> <C-G>u<C-W>
 457
 458 if has('eval')
 459 " New text-objects ii and ai to work on text with the same indentation. Thanks
 460 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 461 " (visited on 2011-11-19).
 462     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 463     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 464     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 465     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 466
 467     function! s:IndTxtObj(inner)
 468         let curline = line(".")
 469         let lastline = line("$")
 470         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 471         let i = i < 0 ? 0 : i
 472         if getline(".") !~ "^\\s*$"
 473             let p = line(".") - 1
 474             let nextblank = getline(p) =~ "^\\s*$"
 475             while p > 0
 476                     \ && ((i == 0 && !nextblank)
 477                         \ || (i > 0 && ((indent(p) >= i
 478                             \ && !(nextblank && a:inner))
 479                             \ || (nextblank && !a:inner))))
 480                 -
 481                 let p = line(".") - 1
 482                 let nextblank = getline(p) =~ "^\\s*$"
 483             endwhile
 484             normal! 0V
 485             call cursor(curline, 0)
 486             let p = line(".") + 1
 487             let nextblank = getline(p) =~ "^\\s*$"
 488             while p <= lastline
 489                     \ && ((i == 0 && !nextblank)
 490                         \ || (i > 0 && ((indent(p) >= i
 491                             \ && !(nextblank && a:inner))
 492                             \ || (nextblank && !a:inner))))
 493                 +
 494                 let p = line(".") + 1
 495                 let nextblank = getline(p) =~ "^\\s*$"
 496             endwhile
 497             normal! $
 498         endif
 499     endfunction
 500 endif
 501
 502
 503 " ABBREVIATIONS
 504
 505 " Fix some of my spelling mistakes.
 506 inoreabbrev relle reelle
 507 inoreabbrev reele reelle
 508
 509
 510 " SYNTAX SETTINGS
 511
 512 " Activate syntax coloring.
 513 if has('syntax')
 514     syntax enable
 515
 516 " Don't highlight more than 500 columns as I normally don't have that long
 517 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 518 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 519     if exists('+synmaxcol')
 520         set synmaxcol=500
 521     endif
 522
 523 " Use (limited) syntax based omni completion if no other omni completion is
 524 " available. Taken from :help ft-syntax-omni.
 525     if has('autocmd') && exists('+omnifunc')
 526         augroup vimrc
 527             autocmd FileType *
 528                 \ if &omnifunc == '' |
 529                 \     setlocal omnifunc=syntaxcomplete#Complete |
 530                 \ endif
 531         augroup END
 532     endif
 533
 534 " Function to enable all custom highlights. Necessary as highlights are
 535 " window-local and thus must be set for each new window.
 536     function! s:CustomSyntaxHighlights()
 537         " Not the first time called, nothing to do.
 538         if exists('w:vimrc_syntax_run')
 539             return
 540         endif
 541         let w:vimrc_syntax_run = 1
 542
 543 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 544 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 545 " disabled when necessary with :2match (in Vim >= 700).
 546         if !&diff && exists(':2match')
 547             " Use ColorColumn for overlong lines if available and my color
 548             " scheme is used.
 549             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 550                 2match ColorColumn /\%>78v./
 551             else
 552                 2match Todo /\%>78v./
 553             endif
 554         elseif !&diff
 555             match Todo /\%>78v./
 556         endif
 557
 558         if exists('*matchadd')
 559 " Highlight some important keywords in all documents.
 560             let l:todos = ['TODO', 'XXX', 'FIXME',
 561                          \ 'CHANGED', 'REMOVED', 'DELETED']
 562             " Compatibility fix for Vim 6.4 which can't handle for in function
 563             " (without function it's ignored).
 564             execute '  for l:x in l:todos'
 565                   \ '|     call matchadd("Todo", l:x)'
 566                   \ '| endfor'
 567
 568 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 569             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 570                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 571                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 572                           \ '205f', '2060', '3000', 'feff']
 573             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 574             " it won't work!
 575             execute '  for l:x in l:spaces'
 576                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 577                   \ '| endfor'
 578
 579 " Reduce visibility of tabs in contrast to normal SpecialKeys.
 580             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 581                 call matchadd('specialKeyTab', '\t')
 582             endif
 583         endif
 584     endfunction
 585 " Enable highlights for the current and all new windows. Thanks to bairui in
 586 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 587     call <SID>CustomSyntaxHighlights()
 588     if has('autocmd')
 589         augroup vimrc
 590             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 591         augroup END
 592     endif
 593
 594 " Settings for specific filetypes.
 595
 596     " Haskell.
 597     let g:hs_highlight_delimiters = 1
 598     let g:hs_highlight_boolean = 1
 599     let g:hs_highlight_types = 1
 600     let g:hs_highlight_more_types = 1
 601     " Perl.
 602     let g:perl_fold = 1
 603     let g:perl_fold_blocks = 1
 604     let g:perl_nofold_packages = 1
 605     let g:perl_include_pod = 1 " syntax coloring for PODs
 606     " Python.
 607     let g:python_highlight_all = 1
 608     " Shell.
 609     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 610     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 611     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 612     " Vim.
 613     let g:vimsyn_embed = 0      " don't highlight embedded languages
 614     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 615     " XML.
 616     let g:xml_syntax_folding = 1
 617 endif
 618
 619
 620 " PLUGIN SETTINGS
 621
 622 if has('eval')
 623 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 624 " installing/removing/updating plugins simple. (Used for plugins with more
 625 " than one file.) Ignore errors in case pathogen is not installed.
 626     if v:version >= 700
 627         silent! execute 'call pathogen#runtime_append_all_bundles()'
 628     endif
 629
 630 " Settings for the NERD commenter.
 631     " Don't create any mappings I don't want to use.
 632     let g:NERDCreateDefaultMappings = 0
 633     " Map toggle comment.
 634     map <Leader><Leader> <Plug>NERDCommenterToggle
 635
 636 " XPTemplate settings.
 637     " Try to maintain snippet rendering even after editing outside of a
 638     " snippet.
 639     let g:xptemplate_strict = 0
 640     " Don't complete any braces automatically.
 641     let g:xptemplate_brace_complete = 0
 642     " Only highlight the current placeholder.
 643     let g:xptemplate_highlight = 'current'
 644 endif
 645
 646
 647 " AUTO COMMANDS
 648
 649 " Use a custom auto group to prevent problems when the vimrc files is sourced
 650 " twice.
 651 if has('autocmd')
 652     augroup vimrc
 653
 654 " Go to last position of opened files. Taken from :help last-position-jump.
 655         autocmd BufReadPost *
 656             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 657             \     execute "normal! g'\"" |
 658             \ endif
 659 " But not for Git commits, go to beginning of the file.
 660         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 661
 662 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 663 " when switching to a help buffer which is in the background with :buffer as
 664 " these options are local to windows (and not only to buffers). This happens
 665 " because I often want to use only one window and thus the help buffer is in
 666 " the background.
 667         autocmd BufWinEnter *.txt
 668             \ if &filetype == 'help' |
 669             \     setlocal nolist |
 670             \     setlocal nonumber |
 671             \ endif
 672
 673 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 674 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 675 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 676 " doesn't exist in older Vims.
 677         if exists('##InsertLeave')
 678             autocmd InsertLeave * set nopaste
 679         endif
 680
 681 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 682 " doesn't exist in older Vims.
 683         if exists('##QuickFixCmdPre')
 684             autocmd QuickFixCmdPre * write
 685         endif
 686
 687 " Don't ignore case while in insert mode, but ignore case in all other modes.
 688 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 689 " capitalization. But while searching (/) 'ignorecase' is used.
 690 " InsertEnter/InsertLeave doesn't exist in older Vims.
 691         if exists('##InsertEnter') && exists('##InsertLeave')
 692             autocmd InsertEnter * set noignorecase
 693             autocmd InsertLeave * set   ignorecase
 694         endif
 695
 696 " AFTER/FTPLUGIN AUTO COMMANDS
 697
 698 " Disable spell checking for files which don't need it.
 699         autocmd FileType deb  setlocal nospell
 700         autocmd FileType diff setlocal nospell
 701         autocmd FileType tar  setlocal nospell
 702 " Fix to allow Vim edit crontab files as crontab doesn't work with
 703 " backupcopy=auto.
 704         autocmd FileType crontab setlocal backupcopy=yes
 705 " Don't use the modeline in git commits as the diff created by `git commit -v`
 706 " may contain one which could change the filetype or other settings of the
 707 " commit buffer. Also make sure we use only 72 characters per line which is
 708 " the recommendation for git commit messages (http://tpope.net/node/106).
 709         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 710                                  \ setlocal textwidth=72
 711 " Use the same comment string as for Vim files in Vimperator files.
 712         autocmd FileType vimperator setlocal commentstring=\"%s
 713 " Use tex compiler for (La)TeX files.
 714         autocmd FileType tex compiler tex
 715
 716 " FTDETECT AUTO COMMANDS
 717
 718 " Recognize .md as markdown files (Vim default is .mkd).
 719         autocmd BufRead,BufNewFile *.md set filetype=mkd
 720 " Recognize .test as Tcl files.
 721         autocmd BufRead,BufNewFile *.test set filetype=tcl
 722
 723 " OTHER AUTO COMMANDS
 724
 725 " Disable spell checking, displaying of list characters and long lines when
 726 " viewing documentation.
 727         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 728
 729 " Use diff filetype for mercurial patches in patch queue.
 730         autocmd BufReadPost */.hg/patches/* set filetype=diff
 731
 732     augroup END
 733 endif
 734
 735
 736 " CUSTOM FUNCTIONS AND COMMANDS
 737
 738 if has('eval')
 739 " Convenient command to see the difference between the current buffer and the
 740 " file it was loaded from, thus the changes you made. Thanks to the
 741 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 742 " for the diffed file than the filetype for the original file.
 743     if !exists(':DiffOrig')
 744         command DiffOrig
 745             \ let s:diff_orig_filetype = &filetype
 746             \ | vertical new
 747             \ | let &filetype = s:diff_orig_filetype
 748             \ | unlet s:diff_orig_filetype
 749             \ | set buftype=nofile
 750             \ | read ++edit #
 751             \ | 0d_
 752             \ | diffthis
 753             \ | wincmd p
 754             \ | diffthis
 755     endif
 756 endif