vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     set foldcolumn=2
 143     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 144                      " folding which is not what I want
 145 endif
 146
 147 " Only check for case if the searched word contains a capital character.
 148 set ignorecase
 149 set smartcase
 150
 151 " Activate spell checking, use English as default.
 152 if exists('+spell') && has('syntax')
 153     " But not when diffing as spell checking is distracting in this case.
 154     if !&diff
 155         set spell
 156     endif
 157     set spelllang=en_us
 158 endif
 159
 160 " Allow buffers with changes to be hidden. Very important for effective
 161 " editing with multiple buffers.
 162 set hidden
 163
 164
 165 " DISPLAY SETTINGS
 166
 167 " Use a dark background. Doesn't change the background color, only sets text
 168 " colors for a dark terminal.
 169 set background=dark
 170
 171 " Display line numbers.
 172 set number
 173 " But use as little space as necessary for the numbers column. Thanks to James
 174 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 175 if exists('+numberwidth')
 176     set numberwidth=1
 177 endif
 178 " Display the ruler with current line/file position. If 'statusline' is used
 179 " then this only affects <C-G>.
 180 set ruler
 181 " Display partial commands in the status line.
 182 set showcmd
 183
 184 " Don't redraw screen when executing macros; increases speed. Thanks to James
 185 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 186 set lazyredraw
 187
 188 " Visualize the line the cursor is currently in.
 189 if exists('+cursorline')
 190     set cursorline
 191 endif
 192
 193 " Display tabs, trailing space, non breakable spaces and long lines (when
 194 " wrapping is disabled).
 195 set list
 196 set listchars=trail:-,extends:>
 197 if v:version >= 700
 198     set listchars+=nbsp:!
 199 endif
 200
 201 if has('statusline')
 202     " Always display the status line even if there is only one window.
 203     set laststatus=2
 204
 205     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 206     " is the highest buffer number, otherwise return nothing. Used in
 207     " 'statusline' to get an overview of available buffer numbers.
 208     function! StatuslineBufferCount()
 209         let l:bufnr = bufnr('$')
 210         if l:bufnr > 1
 211             let l:result = '/'
 212             if exists('*printf')
 213                 let l:result .= printf('%02d', l:bufnr)
 214             else
 215                 " Older Vims don't have printf() (and no .= either). Emulate
 216                 " "%02d".
 217                 if l:bufnr < 10
 218                     let l:result = l:result . '0'
 219                 endif
 220                 let l:result = l:result . l:bufnr
 221             endif
 222             return l:result
 223         else
 224             return ''
 225         endif
 226     endfunction
 227
 228     set statusline=
 229     " on the left
 230     set statusline+=%02n  " buffer number
 231     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 232     set statusline+=:
 233     set statusline+=%f\   " path to current file in buffer
 234     set statusline+=%h    " [help] if buffer is help file
 235     set statusline+=%w    " [Preview] if buffer is preview buffer
 236     set statusline+=%m    " [+] if buffer was modified,
 237                           " [-] if 'modifiable' is off
 238     set statusline+=%r    " [RO] if buffer is read only
 239
 240     " on the right
 241     set statusline+=%=                " right align
 242     set statusline+=0x%-8B\           " current character under cursor as hex
 243     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 244                                       " column number (%c),
 245                                       " virtual column number if different
 246                                       "                       than %c (%V)
 247     set statusline+=%P                " position in file in percent
 248 endif
 249
 250
 251 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 252
 253 " noremap is used to make sure the right side is executed as is and can't be
 254 " modified by a plugin or other settings. Except for <Nop> which isn't
 255 " affected by mappings.
 256
 257 " Easy way to exit insert mode.
 258 inoremap jj <Esc>
 259 inoremap jk <Esc>
 260 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 261 " (2010-10-15).
 262 cnoremap jj <C-C>
 263 cnoremap jk <C-C>
 264
 265 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 266 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 267 map <Right>  <Nop>
 268 map <Left>   <Nop>
 269 map <Up>     <Nop>
 270 map <Down>   <Nop>
 271 imap <Right> <Nop>
 272 imap <Left>  <Nop>
 273 imap <Up>    <Nop>
 274 imap <Down>  <Nop>
 275 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 276 " below).
 277 cmap <Up>    <Nop>
 278 cmap <Down>  <Nop>
 279 cmap <Right> <Nop>
 280 cmap <Left>  <Nop>
 281
 282 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 283 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 284 cnoremap <C-P> <Up>
 285 cnoremap <C-N> <Down>
 286
 287 if has('eval')
 288 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 289 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 290 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 291 " directly because it also enables that feature for other commands which I
 292 " don't want.
 293
 294     " Set 'nostartofline' for a single movement.
 295     function! s:TemporaryNostartofline(movement)
 296         let l:startofline = &startofline
 297         set nostartofline
 298         execute 'normal! ' . a:movement
 299         let &startofline = l:startofline
 300     endfunction
 301
 302     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 303     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 304     nnoremap <silent> <C-F>
 305         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 306     nnoremap <silent> <C-B>
 307         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 308     nnoremap <silent> <C-D>
 309         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 310     nnoremap <silent> <C-U>
 311         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 312 endif
 313
 314 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 315 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 316 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 317
 318 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 319 " in #vim on Freenode (2011-08-15 00:17 CEST).
 320 nnoremap <C-G> 2<C-G>
 321
 322 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 323 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 324 nmap <Space> <C-F>
 325 nmap - <C-B>
 326
 327 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 328 " (2010-05-16 18:38 CEST) for this idea.
 329 nnoremap <silent> gb :bnext<CR>
 330 nnoremap <silent> gB :bprev<CR>
 331
 332 " Fast access to buffers.
 333 nnoremap <silent> <Leader>1 :1buffer<CR>
 334 nnoremap <silent> <Leader>2 :2buffer<CR>
 335 nnoremap <silent> <Leader>3 :3buffer<CR>
 336 nnoremap <silent> <Leader>4 :4buffer<CR>
 337 nnoremap <silent> <Leader>5 :5buffer<CR>
 338 nnoremap <silent> <Leader>6 :6buffer<CR>
 339 nnoremap <silent> <Leader>7 :7buffer<CR>
 340 nnoremap <silent> <Leader>8 :8buffer<CR>
 341 nnoremap <silent> <Leader>9 :9buffer<CR>
 342 nnoremap <silent> <Leader>0 :10buffer<CR>
 343
 344 " Make last active window the only window. Similar to <C-W> o.
 345 nnoremap <C-W>O <C-W>p<C-W>o
 346
 347 " Maps to change spell language between English and German and disable spell
 348 " checking.
 349 if exists('+spell')
 350     nnoremap <silent> <Leader>sn :set nospell<CR>
 351     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 352     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 353 endif
 354
 355 " Add semicolon to the end of the line. Thanks to
 356 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 357 " on Freenode for an improved version which doesn't clobber any marks.
 358 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 359
 360 " * and # for selections in visual mode. Thanks to
 361 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 362 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 363 if has('eval')
 364     function! s:VSetSearch()
 365         let l:temp = @@
 366         normal! gvy
 367         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 368         let @@ = l:temp
 369     endfunction
 370     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 371     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 372 endif
 373
 374 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 375 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 376 " mailing list for the commands.
 377 if v:version < 700
 378     cnoreabbrev W w
 379     cnoreabbrev Wa wa
 380     cnoreabbrev Wq wq
 381     cnoreabbrev Wqa wqa
 382 else
 383     cnoreabbrev <expr> W
 384         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 385     cnoreabbrev <expr> Wa
 386         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 387     cnoreabbrev <expr> Wq
 388         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 389     cnoreabbrev <expr> Wqa
 390         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 391 endif
 392 " Also fix my typo with "Q".
 393 if v:version < 700
 394     cnoreabbrev Q q
 395     cnoreabbrev Qa qa
 396 else
 397     cnoreabbrev <expr> Q
 398         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 399     cnoreabbrev <expr> Qa
 400         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 401 endif
 402
 403 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 404 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 405 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 406
 407 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 408 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 409 " Vim's source.
 410 inoremap <C-U> <C-G>u<C-U>
 411 " Same for <C-@> (insert previously inserted text and leave insert mode).
 412 inoremap <C-@> <C-G>u<C-@>
 413 " And for <C-A> (insert previously inserted text).
 414 inoremap <C-A> <C-G>u<C-A>
 415 " And for <C-W> (delete word before cursor).
 416 inoremap <C-W> <C-G>u<C-W>
 417
 418 if has('eval')
 419 " New text-objects ii and ai to work on text with the same indentation. Thanks
 420 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 421 " (visited on 2011-11-19).
 422     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 423     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 424     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 425     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 426
 427     function! s:IndTxtObj(inner)
 428         let curline = line(".")
 429         let lastline = line("$")
 430         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 431         let i = i < 0 ? 0 : i
 432         if getline(".") !~ "^\\s*$"
 433             let p = line(".") - 1
 434             let nextblank = getline(p) =~ "^\\s*$"
 435             while p > 0
 436                     \ && ((i == 0 && !nextblank)
 437                         \ || (i > 0 && ((indent(p) >= i
 438                             \ && !(nextblank && a:inner))
 439                             \ || (nextblank && !a:inner))))
 440                 -
 441                 let p = line(".") - 1
 442                 let nextblank = getline(p) =~ "^\\s*$"
 443             endwhile
 444             normal! 0V
 445             call cursor(curline, 0)
 446             let p = line(".") + 1
 447             let nextblank = getline(p) =~ "^\\s*$"
 448             while p <= lastline
 449                     \ && ((i == 0 && !nextblank)
 450                         \ || (i > 0 && ((indent(p) >= i
 451                             \ && !(nextblank && a:inner))
 452                             \ || (nextblank && !a:inner))))
 453                 +
 454                 let p = line(".") + 1
 455                 let nextblank = getline(p) =~ "^\\s*$"
 456             endwhile
 457             normal! $
 458         endif
 459     endfunction
 460 endif
 461
 462
 463 " ABBREVIATIONS
 464
 465 " Fix some of my spelling mistakes.
 466 iabbrev relle reelle
 467 iabbrev reele reelle
 468
 469
 470 " SYNTAX SETTINGS
 471
 472 " Activate syntax coloring.
 473 if has('syntax')
 474     syntax enable
 475
 476 " Don't highlight more than 500 columns as I normally don't have that long
 477 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 478 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 479     if exists('+synmaxcol')
 480         set synmaxcol=500
 481     endif
 482
 483 " Use (limited) syntax based omni completion if no other omni completion is
 484 " available. Taken from :help ft-syntax-omni.
 485     if has('autocmd') && exists('+omnifunc')
 486         augroup vimrc
 487             autocmd FileType *
 488                 \ if &omnifunc == '' |
 489                 \     setlocal omnifunc=syntaxcomplete#Complete |
 490                 \ endif
 491         augroup END
 492     endif
 493
 494 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 495 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 496 " disabled when necessary with :2match (in Vim >= 700).
 497     if exists(':2match')
 498         2match Todo /\%>78v./
 499     else
 500         match Todo /\%>78v./
 501     endif
 502
 503     if exists('*matchadd')
 504 " Highlight some important keywords in all documents.
 505         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 506             call matchadd('Todo', s:x)
 507         endfor
 508
 509 " Highlight unicode whitespace which is no normal whitespace (0x20).
 510         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 511                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 512                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 513                 \ 'feff']
 514             call matchadd('Error', '\%u' . s:x)
 515         endfor
 516     endif
 517
 518 " Settings for specific filetypes.
 519
 520     " Haskell.
 521     let g:hs_highlight_delimiters = 1
 522     let g:hs_highlight_boolean = 1
 523     let g:hs_highlight_types = 1
 524     let g:hs_highlight_more_types = 1
 525     " Perl.
 526     let g:perl_fold = 1
 527     let g:perl_fold_blocks = 1
 528     let g:perl_nofold_packages = 1
 529     let g:perl_include_pod = 1 " syntax coloring for PODs
 530     " Python.
 531     let g:python_highlight_all = 1
 532     " Vim.
 533     let g:vimsyn_embed = 0      " don't highlight embedded languages
 534     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 535     " XML.
 536     let g:xml_syntax_folding = 1
 537 endif
 538
 539
 540 " PLUGIN SETTINGS
 541
 542 if has('eval')
 543 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 544 " installing/removing/updating plugins simple. (Used for plugins with more
 545 " than one file.)
 546     if v:version >= 700
 547         execute 'call pathogen#runtime_append_all_bundles()'
 548     endif
 549
 550 " Settings for the NERD commenter.
 551     " Don't create any mappings I don't want to use.
 552     let g:NERDCreateDefaultMappings = 0
 553     " Map toggle comment.
 554     map <Leader><Leader> <Plug>NERDCommenterToggle
 555
 556 " XPTemplate settings.
 557     " Try to maintain snippet rendering even after editing outside of a
 558     " snippet.
 559     let g:xptemplate_strict = 0
 560     " Don't complete any braces automatically.
 561     let g:xptemplate_brace_complete = 0
 562     " Only highlight the current placeholder.
 563     let g:xptemplate_highlight = 'current'
 564 endif
 565
 566
 567 " AUTO COMMANDS
 568
 569 " Use a custom auto group to prevent problems when the vimrc files is sourced
 570 " twice.
 571 if has('autocmd')
 572     augroup vimrc
 573
 574 " Go to last position of opened files. Taken from :help last-position-jump.
 575         autocmd BufReadPost *
 576             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 577             \     execute "normal! g'\"" |
 578             \ endif
 579 " But not for Git commits, go to beginning of the file.
 580         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 581
 582 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 583 " when switching to a help buffer which is in the background with :buffer as
 584 " these options are local to windows (and not only to buffers). This happens
 585 " because I often want to use only one window and thus the help buffer is in
 586 " the background.
 587         autocmd BufWinEnter *.txt
 588             \ if &filetype == 'help' |
 589             \     setlocal nolist |
 590             \     setlocal nonumber |
 591             \ endif
 592
 593 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 594 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 595 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 596 " doesn't exist in older Vims.
 597         if exists('##InsertLeave')
 598             autocmd InsertLeave * set nopaste
 599         endif
 600
 601 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 602 " doesn't exist in older Vims.
 603         if exists('##QuickFixCmdPre')
 604             autocmd QuickFixCmdPre * write
 605         endif
 606
 607 " AFTER/FTPLUGIN AUTO COMMANDS
 608
 609 " Disable spell checking for files which don't need it.
 610         autocmd FileType deb  setlocal nospell
 611         autocmd FileType diff setlocal nospell
 612         autocmd FileType tar  setlocal nospell
 613 " Fix to allow Vim edit crontab files as crontab doesn't work with
 614 " backupcopy=auto.
 615         autocmd FileType crontab setlocal backupcopy=yes
 616 " Don't use the modeline in git commits as the diff created by `git commit -v`
 617 " may contain one which could change the filetype or other settings of the
 618 " commit buffer. Also make sure we use only 72 characters per line which is
 619 " the recommendation for git commit messages (http://tpope.net/node/106).
 620         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 621                                  \ setlocal textwidth=72
 622 " Use the same comment string as for Vim files in Vimperator files.
 623         autocmd FileType vimperator setlocal commentstring=\"%s
 624 " Use tex compiler for (La)TeX files.
 625         autocmd FileType tex compiler tex
 626
 627 " FTDETECT AUTO COMMANDS
 628
 629 " Recognize .md as markdown files (Vim default is .mkd).
 630         autocmd BufRead,BufNewFile *.md set filetype=mkd
 631 " Recognize .test as Tcl files.
 632         autocmd BufRead,BufNewFile *.test set filetype=tcl
 633
 634 " OTHER AUTO COMMANDS
 635
 636 " Disable spell checking, displaying of list characters and long lines when
 637 " viewing documentation.
 638         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 639
 640 " Use diff filetype for mercurial patches in patch queue.
 641         autocmd BufReadPost */.hg/patches/* set filetype=diff
 642
 643     augroup END
 644 endif
 645
 646
 647 " CUSTOM FUNCTIONS AND COMMANDS
 648
 649 if has('eval')
 650 " Convenient command to see the difference between the current buffer and the
 651 " file it was loaded from, thus the changes you made. Thanks to the
 652 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 653 " for the diffed file than the filetype for the original file.
 654     if !exists(':DiffOrig')
 655         command DiffOrig
 656             \ let s:diff_orig_filetype = &filetype
 657             \ | vertical new
 658             \ | let &filetype = s:diff_orig_filetype
 659             \ | unlet s:diff_orig_filetype
 660             \ | set buftype=nofile
 661             \ | read ++edit #
 662             \ | 0d_
 663             \ | diffthis
 664             \ | wincmd p
 665             \ | diffthis
 666     endif
 667 endif