vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68
  69 " Increase history of executed commands (:).
  70 set history=1000
  71
  72 " Increase number of possible undos.
  73 set undolevels=1000
  74
  75 " Remember marks (including the last cursor position) for more files.
  76 if has('viminfo')
  77     set viminfo^='1000
  78 endif
  79
  80 " Use strong encryption if possible, also used for swap/undo files.
  81 if exists('+cryptmethod')
  82     set cryptmethod=blowfish
  83 endif
  84
  85 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  86 " is used multiple times.
  87 if has('autocmd')
  88     augroup vimrc
  89         autocmd!
  90     augroup END
  91 endif
  92
  93
  94 " HELPER FUNCTIONS
  95
  96 " Check if the given syntax group is available. Thanks to bairui in #vim on
  97 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  98 if has('eval')
  99     function! s:HasSyntaxGroup(group)
 100         try
 101             execute 'silent highlight ' . a:group
 102         " \a = [A-Za-z]
 103         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 104             return 0
 105         endtry
 106         return 1
 107     endfunction
 108 endif
 109
 110
 111 " EDIT SETTINGS
 112
 113 " Enable automatic file detection, plugin and indention support.
 114 if has('autocmd')
 115     filetype off " necessary for pathogen to force a reload of ftplugins
 116     filetype plugin indent on
 117 endif
 118
 119 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 120 " existing files.
 121 set fileencodings=utf-8,latin1
 122
 123 " Always use unix line-endings for new files.
 124 set fileformats=unix,dos
 125
 126 " Wrap text after 78 characters.
 127 set textwidth=78
 128
 129 " Set tabs to 4 spaces, use softtabs.
 130 set shiftwidth=4
 131 set softtabstop=4
 132 set expandtab
 133 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 134 set shiftround
 135 " Use the default value for real tabs.
 136 set tabstop=8
 137
 138 " Enable auto indention.
 139 set autoindent
 140
 141 " When joining lines only add one space after a sentence.
 142 set nojoinspaces
 143
 144 " Allow backspacing over autoindent and line breaks.
 145 set backspace=indent,eol
 146
 147 " Start a comment when hitting enter after a commented line (r) and when using
 148 " o or O around a commented line (o).
 149 set formatoptions+=ro
 150 " Don't break a line if was already longer then 'textwidth' when insert mode
 151 " started.
 152 set formatoptions+=l
 153
 154 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 155 " no character) in visual block mode.
 156 set virtualedit=block
 157
 158 " Already display matches while typing the search command. This makes spotting
 159 " errors easy.
 160 set incsearch
 161
 162 " Activate syntax folding.
 163 if has('folding')
 164     set foldmethod=syntax
 165     " Only use fold column if we have enough space (for example not in a
 166     " (virtual) terminal which has only 80 columns).
 167     if &columns > 80
 168         set foldcolumn=2
 169     endif
 170     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 171                      " folding which is not what I want
 172 endif
 173
 174 " Only check case if the searched word contains a capital character.
 175 set ignorecase
 176 set smartcase
 177
 178 " Activate spell checking, use English as default.
 179 if exists('+spell') && has('syntax')
 180     " But not when diffing because spell checking is distracting in this case.
 181     if !&diff
 182         set spell
 183     endif
 184     set spelllang=en_us
 185 endif
 186
 187 " Allow buffers with changes to be hidden. Very important for effective
 188 " editing with multiple buffers. Prevents the "E37: No write since last change
 189 " (add ! to override)" warning.
 190 set hidden
 191
 192
 193 " DISPLAY SETTINGS
 194
 195 " Use a dark background. Doesn't change the background color, only sets text
 196 " colors for a dark terminal.
 197 set background=dark
 198
 199 " Use my color scheme if 256 colors are available.
 200 if &t_Co == 256
 201     colorscheme simon
 202 endif
 203
 204 " Display line numbers.
 205 set number
 206 " But use as little space as possible for the numbers column. Thanks to James
 207 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 208 if exists('+numberwidth')
 209     set numberwidth=1
 210 endif
 211 " Display the ruler with current line/file position. If 'statusline' is used
 212 " then this only affects <C-G>.
 213 set ruler
 214 " Display partial commands in the status line.
 215 set showcmd
 216
 217 " Don't redraw screen when executing macros; increases speed. Thanks to James
 218 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 219 set lazyredraw
 220
 221 " Visualize the line the cursor is currently in.
 222 if exists('+cursorline')
 223     set cursorline
 224 endif
 225
 226 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 227 " remove the highlighting until the next search.
 228 set hlsearch
 229
 230 " Display some special characters.
 231 set list
 232 set listchars=
 233 " Display tabs as ">--------".
 234 set listchars+=tab:>-
 235 " Display trailing whitespace as "-".
 236 set listchars+=trail:-
 237 " Display markers for long lines when wrapping is disabled.
 238 set listchars+=extends:>,precedes:<
 239 " Display non-breakable space as "!".
 240 if v:version >= 700
 241     set listchars+=nbsp:!
 242 endif
 243
 244 " Don't draw the vertical split separator by using space as character. Thanks
 245 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 246 " non-breakable space. But a simple space works as well, as long as the
 247 " current color scheme is not reset.
 248 if has('windows') && has('folding')
 249     set fillchars+=vert:\  " comment to prevent trailing whitespace
 250 endif
 251
 252 if has('statusline')
 253     " Always display the status line even if there is only one window.
 254     set laststatus=2
 255
 256     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 257     " is the highest buffer number, otherwise return nothing. Used in
 258     " 'statusline' to get an overview of available buffer numbers.
 259     function! StatuslineBufferCount()
 260         let l:bufnr = bufnr('$')
 261         if l:bufnr > 1
 262             let l:result = '/'
 263             if exists('*printf')
 264                 let l:result .= printf('%02d', l:bufnr)
 265             else
 266                 " Older Vims don't have printf() (and no .= either). Emulate
 267                 " "%02d".
 268                 if l:bufnr < 10
 269                     let l:result = l:result . '0'
 270                 endif
 271                 let l:result = l:result . l:bufnr
 272             endif
 273             return l:result
 274         else
 275             return ''
 276         endif
 277     endfunction
 278
 279     " Like %f but use relative filename if it's shorter than the absolute path
 280     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 281     " not enough because it doesn't create '../'s.
 282     function! StatuslineRelativeFilename()
 283         " Display only filename for help files.
 284         if &buftype == 'help'
 285             return expand('%:t')
 286         endif
 287         " Special case for scratch files.
 288         if &buftype == 'nofile'
 289             return '[Scratch]'
 290         endif
 291
 292         let l:path = expand('%')
 293         " No file.
 294         if l:path == ''
 295             return '[No Name]'
 296         endif
 297         " Path is already relative, nothing to do.
 298         if stridx(l:path, '/') != 0
 299             return l:path
 300         endif
 301
 302         " Absolute path to this file.
 303         let l:path = expand('%:p')
 304         " Shortened path to this file, thanks to bairui in #vim on Freenode
 305         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 306         " Vim normally uses as %f (minus some exceptions).
 307         let l:original_path = fnamemodify(l:path, ':~')
 308         " Absolute path to the current working directory.
 309         let l:cwd = getcwd()
 310
 311         " Working directory completely contained in path, replace it with a
 312         " relative path. Happens for example when opening a file with netrw.
 313         " %f displays this as absolute path, but we want a relative path of
 314         " course.
 315         if stridx(l:path, l:cwd) == 0
 316             return strpart(l:path, strlen(l:cwd) + 1)
 317         endif
 318
 319         let l:path_list = split(l:path, '/')
 320         let l:cwd_list  = split(l:cwd,  '/')
 321
 322         " Remove the common path.
 323         while l:path_list[0] == l:cwd_list[0]
 324             call remove(l:path_list, 0)
 325             call remove(l:cwd_list,  0)
 326         endwhile
 327
 328         " Add as many '..' as necessary for the relative path and join the
 329         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 330         " the hint to use repeat() instead of a loop.
 331         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 332
 333         " Use the shorter path, either relative or absolute.
 334         if strlen(l:path) < strlen(l:original_path)
 335             return l:path
 336         else
 337             return l:original_path
 338         endif
 339     endfunction
 340
 341     set statusline=
 342     " on the left
 343     set statusline+=%02n  " buffer number
 344     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 345     set statusline+=:
 346     if has('modify_fname')
 347         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 348         set statusline+=\     " space after path
 349     else
 350         set statusline+=%f\   " path to current file in buffer
 351     endif
 352     set statusline+=%h    " [help] if buffer is help file
 353     set statusline+=%w    " [Preview] if buffer is preview buffer
 354     set statusline+=%m    " [+] if buffer was modified,
 355                           " [-] if 'modifiable' is off
 356     set statusline+=%r    " [RO] if buffer is read only
 357
 358     " on the right
 359     set statusline+=%=                " right align
 360     set statusline+=0x%-8B\           " current character under cursor as hex
 361     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 362                                       " column number (%c),
 363                                       " virtual column number if different
 364                                       "                       than %c (%V)
 365     set statusline+=%P                " position in file in percent
 366 endif
 367
 368
 369 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 370
 371 " noremap is used to make sure the right side is executed as is and can't be
 372 " modified by a plugin or other settings. Except for <Nop> which isn't
 373 " affected by mappings.
 374
 375 " Easy way to exit insert mode. jk is preferred because it's faster.
 376 inoremap jj <Esc>
 377 inoremap jk <Esc>
 378 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 379 " (2010-10-15).
 380 cnoremap jj <C-C>
 381 cnoremap jk <C-C>
 382
 383 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 384 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 385 map <Right>  <Nop>
 386 map <Left>   <Nop>
 387 map <Up>     <Nop>
 388 map <Down>   <Nop>
 389 imap <Right> <Nop>
 390 imap <Left>  <Nop>
 391 imap <Up>    <Nop>
 392 imap <Down>  <Nop>
 393 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 394 " below).
 395 cmap <Up>    <Nop>
 396 cmap <Down>  <Nop>
 397 cmap <Right> <Nop>
 398 cmap <Left>  <Nop>
 399
 400 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 401 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 402 cnoremap <C-P> <Up>
 403 cnoremap <C-N> <Down>
 404
 405 if has('eval')
 406 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 407 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 408 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 409 " directly because it also enables that feature for other commands which I
 410 " don't want.
 411
 412     " Set 'nostartofline' for a single movement.
 413     function! s:TemporaryNostartofline(movement)
 414         let l:startofline = &startofline
 415         set nostartofline
 416         execute 'normal! ' . a:movement
 417         let &startofline = l:startofline
 418     endfunction
 419
 420     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 421     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 422     nnoremap <silent> <C-F>
 423         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 424     nnoremap <silent> <C-B>
 425         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 426     nnoremap <silent> <C-D>
 427         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 428     nnoremap <silent> <C-U>
 429         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 430 endif
 431
 432 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 433 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 434 " Only the current buffer is written, thus switching to another buffer works
 435 " too.
 436 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 437
 438 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 439 " in #vim on Freenode (2011-08-15 00:17 CEST).
 440 nnoremap <C-G> 2<C-G>
 441
 442 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 443 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 444 nmap <Space> <C-F>
 445 nmap - <C-B>
 446
 447 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 448 " (2010-05-16 18:38 CEST) for this idea.
 449 nnoremap <silent> gb :bnext<CR>
 450 nnoremap <silent> gB :bprevious<CR>
 451 if has('eval')
 452     " But when starting again at the first buffer, print a warning which
 453     " reminds me that I've already seen that buffer.
 454     function! s:NextBuffer()
 455         " Are we currently on the last buffer and moving to the first?
 456         let l:last_buffer = 0
 457         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 458             let l:last_buffer = 1
 459         endif
 460
 461         " Go to the next buffer.
 462         if !l:last_buffer
 463             bnext
 464
 465         " Go to the first buffer, silent is necessary or the following message
 466         " won't be displayed because it's overwritten by the status message
 467         " displayed when entering a buffer.
 468         else
 469             silent bnext
 470
 471             echohl WarningMsg
 472             echo 'Starting again at first buffer.'
 473             echohl None
 474         endif
 475     endfunction
 476     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 477 endif
 478
 479 " Fast access to buffers.
 480 nnoremap <silent> <Leader>1 :1buffer<CR>
 481 nnoremap <silent> <Leader>2 :2buffer<CR>
 482 nnoremap <silent> <Leader>3 :3buffer<CR>
 483 nnoremap <silent> <Leader>4 :4buffer<CR>
 484 nnoremap <silent> <Leader>5 :5buffer<CR>
 485 nnoremap <silent> <Leader>6 :6buffer<CR>
 486 nnoremap <silent> <Leader>7 :7buffer<CR>
 487 nnoremap <silent> <Leader>8 :8buffer<CR>
 488 nnoremap <silent> <Leader>9 :9buffer<CR>
 489 nnoremap <silent> <Leader>0 :10buffer<CR>
 490
 491 " Make last active window the only window. Similar to <C-W> o.
 492 nnoremap <C-W>O <C-W>p<C-W>o
 493
 494 " Maps to change spell language between English and German and disable spell
 495 " checking.
 496 if exists('+spell')
 497     nnoremap <silent> <Leader>sn :set nospell<CR>
 498     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 499     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 500 endif
 501
 502 " Add semicolon to the end of the line. Thanks to
 503 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 504 " on Freenode for an improved version which doesn't clobber any marks.
 505 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 506
 507 " * and # for selections in visual mode. Thanks to
 508 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 509 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 510 if has('eval')
 511     function! s:VSetSearch()
 512         let l:temp = @@
 513         normal! gvy
 514         " Added \C to force 'noignorecase' while searching the current visual
 515         " selection. I want to search for the exact string in this case.
 516         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 517         let @@ = l:temp
 518     endfunction
 519     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 520     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 521 endif
 522
 523 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 524 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 525 " mailing list for the commands.
 526 if v:version < 700
 527     cnoreabbrev W w
 528     cnoreabbrev Wa wa
 529     cnoreabbrev Wq wq
 530     cnoreabbrev Wqa wqa
 531 else
 532     cnoreabbrev <expr> W
 533         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 534     cnoreabbrev <expr> Wa
 535         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 536     cnoreabbrev <expr> Wq
 537         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 538     cnoreabbrev <expr> Wqa
 539         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 540 endif
 541 " Also fix my typo with "Q".
 542 if v:version < 700
 543     cnoreabbrev Q q
 544     cnoreabbrev Qa qa
 545 else
 546     cnoreabbrev <expr> Q
 547         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 548     cnoreabbrev <expr> Qa
 549         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 550 endif
 551
 552 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 553 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 554 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 555
 556 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 557 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 558 " Vim's source.
 559 inoremap <C-U> <C-G>u<C-U>
 560 " Same for <C-@> (insert previously inserted text and leave insert mode).
 561 inoremap <C-@> <C-G>u<C-@>
 562 " And for <C-A> (insert previously inserted text).
 563 inoremap <C-A> <C-G>u<C-A>
 564 " And for <C-W> (delete word before cursor).
 565 inoremap <C-W> <C-G>u<C-W>
 566
 567 if has('eval')
 568 " New text-objects ii and ai to work on text with the same indentation. Thanks
 569 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 570 " (visited on 2011-11-19).
 571     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 572     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 573     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 574     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 575
 576     function! s:IndTxtObj(inner)
 577         let curline = line(".")
 578         let lastline = line("$")
 579         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 580         let i = i < 0 ? 0 : i
 581         if getline(".") !~ "^\\s*$"
 582             let p = line(".") - 1
 583             let nextblank = getline(p) =~ "^\\s*$"
 584             while p > 0
 585                     \ && ((i == 0 && !nextblank)
 586                         \ || (i > 0 && ((indent(p) >= i
 587                             \ && !(nextblank && a:inner))
 588                             \ || (nextblank && !a:inner))))
 589                 -
 590                 let p = line(".") - 1
 591                 let nextblank = getline(p) =~ "^\\s*$"
 592             endwhile
 593             normal! 0V
 594             call cursor(curline, 0)
 595             let p = line(".") + 1
 596             let nextblank = getline(p) =~ "^\\s*$"
 597             while p <= lastline
 598                     \ && ((i == 0 && !nextblank)
 599                         \ || (i > 0 && ((indent(p) >= i
 600                             \ && !(nextblank && a:inner))
 601                             \ || (nextblank && !a:inner))))
 602                 +
 603                 let p = line(".") + 1
 604                 let nextblank = getline(p) =~ "^\\s*$"
 605             endwhile
 606             normal! $
 607         endif
 608     endfunction
 609 endif
 610
 611
 612 " ABBREVIATIONS
 613
 614 " Fix some of my spelling mistakes (German).
 615 inoreabbrev relle reelle
 616 inoreabbrev reele reelle
 617 " Fix some of my spelling mistakes (English).
 618 inoreabbrev completly completely
 619
 620
 621 " SYNTAX SETTINGS
 622
 623 " Activate syntax coloring.
 624 if has('syntax')
 625     syntax enable
 626
 627 " Don't highlight more than 500 columns as I normally don't have that long
 628 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 629 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 630     if exists('+synmaxcol')
 631         set synmaxcol=500
 632     endif
 633
 634 " Use (limited) syntax based omni completion if no other omni completion is
 635 " available. Taken from :help ft-syntax-omni.
 636     if has('autocmd') && exists('+omnifunc')
 637         augroup vimrc
 638             autocmd FileType *
 639                 \ if &omnifunc == '' |
 640                 \     setlocal omnifunc=syntaxcomplete#Complete |
 641                 \ endif
 642         augroup END
 643     endif
 644
 645 " Function to enable all custom highlights. Necessary as highlights are
 646 " window-local and thus must be set for each new window.
 647     function! s:CustomSyntaxHighlights()
 648         " Not the first time called, nothing to do.
 649         if exists('w:vimrc_syntax_run')
 650             return
 651         endif
 652         let w:vimrc_syntax_run = 1
 653
 654 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 655 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 656 " disabled when necessary with :2match (in Vim >= 700).
 657         if !&diff && exists(':2match')
 658             " Use ColorColumn for overlong lines if available and my color
 659             " scheme is used.
 660             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 661                 2match ColorColumn /\%>78v./
 662             else
 663                 2match Todo /\%>78v./
 664             endif
 665         elseif !&diff
 666             match Todo /\%>78v./
 667         endif
 668
 669         if exists('*matchadd')
 670 " Highlight some important keywords in all documents.
 671             let l:todos = ['TODO', 'XXX', 'FIXME',
 672                          \ 'CHANGED', 'REMOVED', 'DELETED']
 673             " Compatibility fix for Vim 6.4 which can't handle for in function
 674             " (without function it's ignored).
 675             execute '  for l:x in l:todos'
 676                   \ '|     call matchadd("Todo", l:x)'
 677                   \ '| endfor'
 678
 679 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 680             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 681                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 682                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 683                           \ '205f', '2060', '3000', 'feff']
 684             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 685             " it won't work!
 686             execute '  for l:x in l:spaces'
 687                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 688                   \ '| endfor'
 689
 690 " Special highlight for tabs to reduce their visibility in contrast to other
 691 " SpecialKey characters (e.g. ^L).
 692             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 693                 call matchadd('specialKeyTab', '\t')
 694             endif
 695         endif
 696     endfunction
 697 " Enable highlights for the current and all new windows. Thanks to bairui in
 698 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 699     call <SID>CustomSyntaxHighlights()
 700     if has('autocmd')
 701         augroup vimrc
 702             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 703         augroup END
 704     endif
 705
 706 " Settings for specific filetypes.
 707
 708     " C
 709     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 710     " Haskell.
 711     let g:hs_highlight_delimiters = 1
 712     let g:hs_highlight_boolean = 1
 713     let g:hs_highlight_types = 1
 714     let g:hs_highlight_more_types = 1
 715     " Perl.
 716     let g:perl_fold = 1
 717     let g:perl_fold_blocks = 1
 718     let g:perl_nofold_packages = 1
 719     let g:perl_include_pod = 1 " syntax coloring for PODs
 720     " Python.
 721     let g:python_highlight_all = 1
 722     " Shell.
 723     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 724     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 725     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 726     " Vim.
 727     let g:vimsyn_embed = 0      " don't highlight embedded languages
 728     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 729     " XML.
 730     let g:xml_syntax_folding = 1
 731 endif
 732
 733
 734 " PLUGIN SETTINGS
 735
 736 if has('eval')
 737 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 738 " installing/removing/updating plugins simple. (Used for plugins with more
 739 " than one file.) Ignore errors in case pathogen is not installed.
 740     if v:version >= 700
 741         silent! execute 'call pathogen#runtime_append_all_bundles()'
 742     endif
 743
 744 " Settings for securemodelines.
 745     " Only allow items I need (also includes spl which is not enabled by
 746     " default).
 747     let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 748                                           \ 'sw', 'sts', 'noet']
 749
 750 " Settings for the NERD commenter.
 751     " Don't create any mappings I don't want to use.
 752     let g:NERDCreateDefaultMappings = 0
 753     " Map toggle comment.
 754     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 755
 756 " XPTemplate settings.
 757     " Try to maintain snippet rendering even after editing outside of a
 758     " snippet.
 759     let g:xptemplate_strict = 0
 760     " Don't complete any braces automatically.
 761     let g:xptemplate_brace_complete = 0
 762     " Only highlight the current placeholder.
 763     let g:xptemplate_highlight = 'current'
 764 endif
 765
 766
 767 " AUTO COMMANDS
 768
 769 " Use a custom auto group to prevent problems when the vimrc files is sourced
 770 " twice.
 771 if has('autocmd')
 772     augroup vimrc
 773
 774 " Go to last position of opened files. Taken from :help last-position-jump.
 775         autocmd BufReadPost *
 776             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 777             \     execute "normal! g'\"" |
 778             \ endif
 779 " But not for Git commits, go to beginning of the file.
 780         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 781
 782 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 783 " when switching to a help buffer which is in the background with :buffer as
 784 " these options are local to windows (and not only to buffers). This happens
 785 " because I often want to use only one window and thus the help buffer is in
 786 " the background.
 787         autocmd BufWinEnter *.txt
 788             \ if &filetype == 'help' |
 789             \     setlocal nolist |
 790             \     setlocal nonumber |
 791             \ endif
 792
 793 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 794 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 795 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 796 " doesn't exist in older Vims.
 797         if exists('##InsertLeave')
 798             autocmd InsertLeave * set nopaste
 799         endif
 800
 801 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 802 " doesn't exist in older Vims.
 803         if exists('##QuickFixCmdPre')
 804             autocmd QuickFixCmdPre * write
 805         endif
 806
 807 " Don't ignore case while in insert mode, but ignore case in all other modes.
 808 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 809 " capitalization. But while searching (/) 'ignorecase' is used.
 810 " InsertEnter/InsertLeave doesn't exist in older Vims.
 811         if exists('##InsertEnter') && exists('##InsertLeave')
 812             autocmd InsertEnter * set noignorecase
 813             autocmd InsertLeave * set   ignorecase
 814         endif
 815
 816 " AFTER/FTPLUGIN AUTO COMMANDS
 817
 818 " Disable spell checking for files which don't need it.
 819         autocmd FileType deb  setlocal nospell
 820         autocmd FileType diff setlocal nospell
 821         autocmd FileType tar  setlocal nospell
 822 " Fix to allow Vim edit crontab files as crontab doesn't work with
 823 " backupcopy=auto.
 824         autocmd FileType crontab setlocal backupcopy=yes
 825 " Don't use the modeline in git commits as the diff created by `git commit -v`
 826 " may contain one which could change the filetype or other settings of the
 827 " commit buffer. Also make sure we use only 72 characters per line which is
 828 " the recommendation for git commit messages (http://tpope.net/node/106).
 829         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 830                                  \ setlocal textwidth=72
 831 " Use the same comment string as for Vim files in Vimperator files.
 832         autocmd FileType vimperator setlocal commentstring=\"%s
 833 " Use TeX compiler for (La)TeX files.
 834         autocmd FileType tex compiler tex
 835
 836 " FTDETECT AUTO COMMANDS
 837
 838 " Recognize .md as markdown files (Vim default is .mkd).
 839         autocmd BufRead,BufNewFile *.md set filetype=mkd
 840 " Recognize .test as Tcl files.
 841         autocmd BufRead,BufNewFile *.test set filetype=tcl
 842
 843 " OTHER AUTO COMMANDS
 844
 845 " Disable spell checking, displaying of list characters and long lines when
 846 " viewing documentation.
 847         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 848
 849 " Use diff filetype for mercurial patches in patch queue.
 850         autocmd BufReadPost */.hg/patches/* set filetype=diff
 851
 852     augroup END
 853 endif
 854
 855
 856 " CUSTOM FUNCTIONS AND COMMANDS
 857
 858 if has('eval')
 859 " Convenient command to see the difference between the current buffer and the
 860 " file it was loaded from, thus the changes you made. Thanks to the
 861 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 862 " for the diffed file than the filetype for the original file.
 863     if !exists(':DiffOrig')
 864         command DiffOrig
 865             \ let s:diff_orig_filetype = &filetype
 866             \ | vertical new
 867             \ | let &filetype = s:diff_orig_filetype
 868             \ | unlet s:diff_orig_filetype
 869             \ | set buftype=nofile
 870             \ | read ++edit #
 871             \ | 0d_
 872             \ | diffthis
 873             \ | wincmd p
 874             \ | diffthis
 875     endif
 876 endif