vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 109 " is used multiple times. Necessary to support reloading the vimrc.
 110 if has('autocmd')
 111     augroup vimrc
 112         autocmd!
 113     augroup END
 114 endif
 115
 116
 117 " HELPER FUNCTIONS
 118
 119 if has('eval')
 120 " Check if the given syntax group is available. Thanks to bairui in #vim on
 121 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 122     function! s:HasSyntaxGroup(group)
 123         try
 124             execute 'silent highlight ' . a:group
 125         " \a = [A-Za-z]
 126         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 127             return 0
 128         endtry
 129         return 1
 130     endfunction
 131
 132 " Check if the given Vim version and patch is available.
 133     function! s:HasVersionAndPatch(version, patch)
 134         return v:version > a:version
 135             \ || (v:version == a:version && has('patch' . a:patch))
 136     endfunction
 137 endif
 138
 139
 140 " TERMINAL SETTINGS
 141
 142 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 143 " connections.
 144 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 145     set ttyfast
 146 endif
 147
 148
 149 " EDIT SETTINGS
 150
 151 " Enable automatic file detection, plugin and indention support.
 152 if has('autocmd')
 153     filetype off " necessary for pathogen to force a reload of ftplugins
 154     filetype plugin indent on
 155 endif
 156
 157 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 158 " existing files.
 159 set fileencodings=utf-8,latin1
 160
 161 " Always use unix line-endings for new files.
 162 set fileformats=unix,dos
 163
 164 " Wrap text after 78 characters.
 165 set textwidth=78
 166
 167 " Set tabs to 4 spaces, use softtabs.
 168 set shiftwidth=4
 169 set softtabstop=4
 170 set expandtab
 171 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 172 set shiftround
 173 " Use the default value for real tabs.
 174 set tabstop=8
 175
 176 " Enable auto indention.
 177 set autoindent
 178
 179 " When joining lines only add one space after a sentence.
 180 set nojoinspaces
 181
 182 " Allow backspacing over autoindent and line breaks.
 183 set backspace=indent,eol
 184
 185 " Start a comment when hitting enter after a commented line (r) and when using
 186 " o or O around a commented line (o).
 187 set formatoptions+=ro
 188 " Don't break a line if was already longer then 'textwidth' when insert mode
 189 " started.
 190 set formatoptions+=l
 191 " Remove comment leader when joining lines where it makes sense.
 192 if <SID>HasVersionAndPatch(703, 541)
 193     set formatoptions+=j
 194 endif
 195
 196 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 197 " no character) in visual block mode.
 198 set virtualedit=block
 199
 200 " Already display matches while typing the search command. This makes spotting
 201 " typos easy and searching faster.
 202 set incsearch
 203
 204 " Activate syntax folding.
 205 if has('folding')
 206     set foldmethod=syntax
 207     " Only use fold column if we have enough space (for example not in a
 208     " (virtual) terminal which has only 80 columns).
 209     if &columns > 80
 210         set foldcolumn=2
 211     endif
 212     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 213                      " folding which is not what I want
 214     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 215     set foldopen-=block
 216 endif
 217
 218 " Only check case if the searched word contains a capital character.
 219 set ignorecase
 220 set smartcase
 221
 222 " Activate spell checking, use English as default.
 223 if exists('+spell') && has('syntax')
 224     " But not when diffing because spell checking is distracting in this case.
 225     if !&diff
 226         set spell
 227     endif
 228     set spelllang=en_us
 229 endif
 230
 231 " Allow buffers with changes to be hidden. Very important for effective
 232 " editing with multiple buffers. Prevents the "E37: No write since last change
 233 " (add ! to override)" warning when switching buffers.
 234 set hidden
 235
 236 " When splitting vertically put the new window right of the current one.
 237 if has('vertsplit')
 238     set splitright
 239 endif
 240
 241
 242 " DISPLAY SETTINGS
 243
 244 " Use a dark background. Doesn't change the background color, only sets text
 245 " colors for a dark terminal.
 246 set background=dark
 247
 248 " Use my color scheme if 256 colors are available.
 249 if &t_Co == 256 || has('gui_running')
 250     colorscheme simon
 251 endif
 252
 253 " Display line numbers.
 254 set number
 255 " But use as little space as possible for the numbers column. Thanks to James
 256 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 257 if exists('+numberwidth')
 258     set numberwidth=1
 259 endif
 260 " Display the ruler with current line/file position. If 'statusline' is used
 261 " then this only affects <C-G>.
 262 set ruler
 263 " Display partial commands in the status line.
 264 set showcmd
 265
 266 " Don't redraw screen when executing macros; increases speed. Thanks to James
 267 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 268 set lazyredraw
 269
 270 " Visualize the line the cursor is currently in.
 271 if exists('+cursorline')
 272     set cursorline
 273 endif
 274
 275 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 276 " remove the highlighting until the next search.
 277 set hlsearch
 278
 279 " Display some special characters.
 280 set list
 281 set listchars=
 282 " Display tabs as ">--------".
 283 set listchars+=tab:>-
 284 " Display trailing whitespace as "-".
 285 set listchars+=trail:-
 286 " Display markers for long lines when wrapping is disabled.
 287 set listchars+=extends:>,precedes:<
 288 " Display non-breakable space as "!".
 289 if v:version >= 700
 290     set listchars+=nbsp:!
 291 endif
 292
 293 " Don't draw the vertical split separator by using space as character. Thanks
 294 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 295 " non-breakable space. But a simple space works as well, as long as the
 296 " current color scheme is not reset.
 297 if has('windows') && has('folding')
 298     set fillchars+=vert:\  " comment to prevent trailing whitespace
 299 endif
 300
 301 if has('statusline')
 302     " Always display the status line even if there is only one window.
 303     set laststatus=2
 304
 305     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 306     " is the highest buffer number, otherwise return nothing. Used in
 307     " 'statusline' to get an overview of available buffer numbers.
 308     function! s:StatuslineBufferCount()
 309         let l:bufnr = bufnr('$')
 310         if l:bufnr > 1
 311             let l:result = '/'
 312             if exists('*printf')
 313                 let l:result .= printf('%02d', l:bufnr)
 314             else
 315                 " Older Vims don't have printf() (and no .= either). Emulate
 316                 " "%02d".
 317                 if l:bufnr < 10
 318                     let l:result = l:result . '0'
 319                 endif
 320                 let l:result = l:result . l:bufnr
 321             endif
 322             return l:result
 323         else
 324             return ''
 325         endif
 326     endfunction
 327
 328     " Like %f but use relative filename if it's shorter than the absolute path
 329     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 330     " not enough because it doesn't create '../'s.
 331     function! s:StatuslineRelativeFilename()
 332         " Display only filename for help files.
 333         if &buftype == 'help'
 334             return expand('%:t')
 335         endif
 336         " Special case for scratch files.
 337         if &buftype == 'nofile'
 338             return '[Scratch]'
 339         endif
 340
 341         let l:path = expand('%')
 342         " No file.
 343         if l:path == ''
 344             return '[No Name]'
 345         endif
 346         " Path is already relative, nothing to do.
 347         if stridx(l:path, '/') != 0
 348             return l:path
 349         endif
 350
 351         " Absolute path to this file.
 352         let l:path = expand('%:p')
 353         " Shortened path to this file, thanks to bairui in #vim on Freenode
 354         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 355         " Vim normally uses as %f (minus some exceptions).
 356         let l:original_path = fnamemodify(l:path, ':~')
 357         " Absolute path to the current working directory.
 358         let l:cwd = getcwd()
 359
 360         " Working directory completely contained in path, replace it with a
 361         " relative path. Happens for example when opening a file with netrw.
 362         " %f displays this as absolute path, but we want a relative path of
 363         " course.
 364         if stridx(l:path, l:cwd) == 0
 365             return strpart(l:path, strlen(l:cwd) + 1)
 366         endif
 367
 368         let l:path_list = split(l:path, '/')
 369         let l:cwd_list  = split(l:cwd,  '/')
 370
 371         " Remove the common path.
 372         while l:path_list[0] == l:cwd_list[0]
 373             call remove(l:path_list, 0)
 374             call remove(l:cwd_list,  0)
 375         endwhile
 376
 377         " Add as many '..' as necessary for the relative path and join the
 378         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 379         " the hint to use repeat() instead of a loop.
 380         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 381
 382         " Use the shorter path, either relative or absolute.
 383         if strlen(l:path) < strlen(l:original_path)
 384             return l:path
 385         else
 386             return l:original_path
 387         endif
 388     endfunction
 389
 390     " Display unexpected 'fileformat' and 'fileencoding' settings.
 391     function! s:StatuslineFileFormat()
 392         if &fileformat != 'unix'
 393             return '[' . &fileformat . ']'
 394         else
 395             return ''
 396         endif
 397     endfunction
 398     function! s:StatuslineFileEncoding()
 399         if &fileencoding != '' && &fileencoding != 'utf-8'
 400                 \ && &filetype != 'help'
 401             return '[' . &fileencoding . ']'
 402         else
 403             return ''
 404         endif
 405     endfunction
 406
 407     " Return current syntax group in brackets or nothing if there's none.
 408     function! s:StatuslineSyntaxGroup()
 409         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 410         if l:group != ''
 411             return '[' . l:group . '] '
 412         else
 413             return ''
 414         endif
 415     endfunction
 416
 417     " Short function names to make 'statusline' more readable.
 418     function! SBC()
 419         return <SID>StatuslineBufferCount()
 420     endfunction
 421     function! SRF()
 422         return <SID>StatuslineRelativeFilename()
 423     endfunction
 424     function! SFF()
 425         return <SID>StatuslineFileFormat()
 426     endfunction
 427     function! SFE()
 428         return <SID>StatuslineFileEncoding()
 429     endfunction
 430     function! SSG()
 431         return <SID>StatuslineSyntaxGroup()
 432     endfunction
 433
 434     set statusline=
 435     " on the left
 436     set statusline+=%02n              " buffer number
 437     set statusline+=%{SBC()}          " highest buffer number
 438     set statusline+=:
 439     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 440         set statusline+=%{SRF()}      " path to current file
 441         set statusline+=\             " space after path
 442     else
 443         set statusline+=%f\           " path to current file in buffer
 444     endif
 445     set statusline+=%h                " [help] if buffer is help file
 446     set statusline+=%w                " [Preview] if buffer is preview buffer
 447     set statusline+=%m                " [+] if buffer was modified,
 448                                       " [-] if 'modifiable' is off
 449     set statusline+=%r                " [RO] if buffer is read only
 450     if v:version >= 700               " %#..# needs 7.0
 451         set statusline+=%#Error#      " display warnings
 452         set statusline+=%{SFF()}      "   - unexpected file format
 453         set statusline+=%{SFE()}      "   - unexpected file encoding
 454         set statusline+=%##           " continue with normal colors
 455     endif
 456
 457     " on the right
 458     set statusline+=%=                " right align
 459     set statusline+=0x%-8B\           " current character under cursor as hex
 460     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 461                                       " column number (%c),
 462                                       " virtual column number if different
 463                                       "                       than %c (%V)
 464     set statusline+=%P                " position in file in percent
 465 endif
 466
 467
 468 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 469
 470 " noremap is used to make sure the right side is executed as is and can't be
 471 " modified by a plugin or other settings. Except for <Nop> which isn't
 472 " affected by mappings.
 473
 474 " Easy way to exit insert mode. jk is preferred because it's faster.
 475 inoremap jj <Esc>
 476 inoremap jk <Esc>
 477 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 478 " (2010-10-15).
 479 cnoremap jj <C-C>
 480 cnoremap jk <C-C>
 481
 482 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 483 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 484 map <Right>  <Nop>
 485 map <Left>   <Nop>
 486 map <Up>     <Nop>
 487 map <Down>   <Nop>
 488 imap <Right> <Nop>
 489 imap <Left>  <Nop>
 490 imap <Up>    <Nop>
 491 imap <Down>  <Nop>
 492 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 493 " below).
 494 cmap <Up>    <Nop>
 495 cmap <Down>  <Nop>
 496 cmap <Right> <Nop>
 497 cmap <Left>  <Nop>
 498
 499 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 500 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 501 cnoremap <C-P> <Up>
 502 cnoremap <C-N> <Down>
 503
 504 if has('eval')
 505 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 506 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 507 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 508 " directly because it also enables that feature for other commands which I
 509 " don't want.
 510
 511     " Set 'nostartofline' for a single movement.
 512     function! s:TemporaryNostartofline(movement)
 513         let l:startofline = &startofline
 514         set nostartofline
 515         execute 'normal! ' . a:movement
 516         let &startofline = l:startofline
 517     endfunction
 518
 519     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 520     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 521     nnoremap <silent> <C-F>
 522         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 523     nnoremap <silent> <C-B>
 524         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 525     nnoremap <silent> <C-D>
 526         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 527     nnoremap <silent> <C-U>
 528         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 529 endif
 530
 531 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 532 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 533 " Only the current buffer is written, thus switching to another buffer works
 534 " too.
 535 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 536
 537 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 538 " in #vim on Freenode (2011-08-15 00:17 CEST).
 539 nnoremap <C-G> 2<C-G>
 540
 541 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 542 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 543 nmap <Space> <C-F>
 544 nmap - <C-B>
 545
 546 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 547 " (2010-05-16 18:38 CEST) for this idea.
 548 nnoremap <silent> gb :bnext<CR>
 549 nnoremap <silent> gB :bprevious<CR>
 550 if has('eval')
 551     " But when starting again at the first buffer, print a warning which
 552     " reminds me that I've already seen that buffer.
 553     function! s:NextBuffer()
 554         " Are we currently on the last buffer and moving to the first?
 555         let l:last_buffer = 0
 556         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 557             let l:last_buffer = 1
 558         endif
 559
 560         " Go to the next buffer.
 561         if !l:last_buffer
 562             bnext
 563
 564         " Go to the first buffer, silent is necessary or the following message
 565         " won't be displayed because it's overwritten by the status message
 566         " displayed when entering a buffer.
 567         else
 568             silent bnext
 569
 570             echohl WarningMsg
 571             echo 'Starting again at first buffer.'
 572             echohl None
 573         endif
 574     endfunction
 575     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 576 endif
 577
 578 " Fast access to buffers.
 579 nnoremap <silent> <Leader>1 :1buffer<CR>
 580 nnoremap <silent> <Leader>2 :2buffer<CR>
 581 nnoremap <silent> <Leader>3 :3buffer<CR>
 582 nnoremap <silent> <Leader>4 :4buffer<CR>
 583 nnoremap <silent> <Leader>5 :5buffer<CR>
 584 nnoremap <silent> <Leader>6 :6buffer<CR>
 585 nnoremap <silent> <Leader>7 :7buffer<CR>
 586 nnoremap <silent> <Leader>8 :8buffer<CR>
 587 nnoremap <silent> <Leader>9 :9buffer<CR>
 588 nnoremap <silent> <Leader>0 :10buffer<CR>
 589
 590 " Make last active window the only window. Similar to <C-W> o.
 591 nnoremap <C-W>O <C-W>p<C-W>o
 592
 593 " Maps to change spell language between English and German and disable spell
 594 " checking.
 595 if exists('+spell')
 596     nnoremap <silent> <Leader>sn :set nospell<CR>
 597     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 598     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 599 " If no spell support is available, these mappings do nothing.
 600 else
 601     nmap <Leader>sn <Nop>
 602     nmap <Leader>se <Nop>
 603     nmap <Leader>sd <Nop>
 604 endif
 605
 606 " Add semicolon to the end of the line. Thanks to
 607 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 608 " on Freenode for an improved version which doesn't clobber any marks.
 609 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 610
 611 " * and # for selections in visual mode. Thanks to
 612 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 613 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 614 if has('eval')
 615     function! s:VSetSearch()
 616         let l:temp = @@ " unnamed register
 617         normal! gvy
 618         " Added \C to force 'noignorecase' while searching the current visual
 619         " selection. I want to search for the exact string in this case.
 620         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 621         let @@ = l:temp
 622     endfunction
 623     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 624     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 625 endif
 626
 627 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 628 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 629 " mailing list for the commands.
 630 if v:version < 700
 631     cnoreabbrev W w
 632     cnoreabbrev Wa wa
 633     cnoreabbrev Wq wq
 634     cnoreabbrev Wqa wqa
 635 else
 636     cnoreabbrev <expr> W
 637         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 638     cnoreabbrev <expr> Wa
 639         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 640     cnoreabbrev <expr> Wq
 641         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 642     cnoreabbrev <expr> Wqa
 643         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 644 endif
 645 " Also fix my typo with "Q".
 646 if v:version < 700
 647     cnoreabbrev Q q
 648     cnoreabbrev Qa qa
 649 else
 650     cnoreabbrev <expr> Q
 651         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 652     cnoreabbrev <expr> Qa
 653         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 654 endif
 655
 656 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 657 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 658 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 659
 660 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 661 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 662 " Vim's source.
 663 inoremap <C-U> <C-G>u<C-U>
 664 " Same for <C-@> (insert previously inserted text and leave insert mode).
 665 inoremap <C-@> <C-G>u<C-@>
 666 " And for <C-A> (insert previously inserted text).
 667 inoremap <C-A> <C-G>u<C-A>
 668 " And for <C-W> (delete word before cursor).
 669 inoremap <C-W> <C-G>u<C-W>
 670
 671 if has('eval')
 672 " New text-objects ii and ai to work on text with the same indentation. Thanks
 673 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 674 " (visited on 2011-11-19).
 675     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 676     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 677     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 678     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 679
 680     function! s:IndTxtObj(inner)
 681         let curline = line(".")
 682         let lastline = line("$")
 683         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 684         let i = i < 0 ? 0 : i
 685         if getline(".") !~ "^\\s*$"
 686             let p = line(".") - 1
 687             let nextblank = getline(p) =~ "^\\s*$"
 688             while p > 0
 689                     \ && ((i == 0 && !nextblank)
 690                         \ || (i > 0 && ((indent(p) >= i
 691                             \ && !(nextblank && a:inner))
 692                             \ || (nextblank && !a:inner))))
 693                 -
 694                 let p = line(".") - 1
 695                 let nextblank = getline(p) =~ "^\\s*$"
 696             endwhile
 697             normal! 0V
 698             call cursor(curline, 0)
 699             let p = line(".") + 1
 700             let nextblank = getline(p) =~ "^\\s*$"
 701             while p <= lastline
 702                     \ && ((i == 0 && !nextblank)
 703                         \ || (i > 0 && ((indent(p) >= i
 704                             \ && !(nextblank && a:inner))
 705                             \ || (nextblank && !a:inner))))
 706                 +
 707                 let p = line(".") + 1
 708                 let nextblank = getline(p) =~ "^\\s*$"
 709             endwhile
 710             normal! $
 711         endif
 712     endfunction
 713 endif
 714
 715
 716 " ABBREVIATIONS
 717
 718 " Fix some of my spelling mistakes (German).
 719 inoreabbrev relle reelle
 720 inoreabbrev reele reelle
 721 " Fix some of my spelling mistakes (English).
 722 inoreabbrev completly completely
 723
 724
 725 " SYNTAX SETTINGS
 726
 727 " Activate syntax coloring.
 728 if has('syntax')
 729     syntax enable
 730
 731 " Don't highlight more than 500 columns as I normally don't have that long
 732 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 733 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 734     if exists('+synmaxcol')
 735         set synmaxcol=500
 736     endif
 737
 738 " Use (limited) syntax based omni completion if no other omni completion is
 739 " available. Taken from :help ft-syntax-omni.
 740     if has('autocmd') && exists('+omnifunc')
 741         augroup vimrc
 742             autocmd FileType *
 743                 \ if &omnifunc == '' |
 744                 \     setlocal omnifunc=syntaxcomplete#Complete |
 745                 \ endif
 746         augroup END
 747     endif
 748
 749 " Function to enable all custom highlights. Necessary as highlights are
 750 " window-local and thus must be set for each new window.
 751     function! s:CustomSyntaxHighlights()
 752         " Not the first time called, nothing to do.
 753         if exists('w:vimrc_syntax_run')
 754             return
 755         endif
 756         let w:vimrc_syntax_run = 1
 757
 758 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 759 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 760 " disabled when necessary with :2match (in Vim >= 700).
 761         if !&diff && exists(':2match')
 762             " Use ColorColumn for overlong lines if available and my color
 763             " scheme is used.
 764             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 765                 2match ColorColumn /\%>78v./
 766             else
 767                 2match Todo /\%>78v./
 768             endif
 769         elseif !&diff
 770             match Todo /\%>78v./
 771         endif
 772
 773         if exists('*matchadd')
 774 " Highlight some important keywords in all documents.
 775             let l:todos = ['TODO', 'XXX', 'FIXME',
 776                          \ 'CHANGED', 'REMOVED', 'DELETED']
 777             " Compatibility fix for Vim 6.4 which can't handle for in function
 778             " (without function it's ignored).
 779             execute '  for l:x in l:todos'
 780                   \ '|     call matchadd("Todo", l:x)'
 781                   \ '| endfor'
 782
 783 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 784             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 785                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 786                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 787                           \ '205f', '2060', '3000', 'feff']
 788             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 789             " it won't work!
 790             execute '  for l:x in l:spaces'
 791                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 792                   \ '| endfor'
 793
 794 " Special highlight for tabs to reduce their visibility in contrast to other
 795 " SpecialKey characters (e.g. ^L).
 796             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 797                 call matchadd('specialKeyTab', '\t')
 798             endif
 799         endif
 800     endfunction
 801 " Enable highlights for the current and all new windows. Thanks to bairui in
 802 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 803     call <SID>CustomSyntaxHighlights()
 804     if has('autocmd')
 805         augroup vimrc
 806             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 807         augroup END
 808     endif
 809
 810 " Settings for specific filetypes.
 811
 812     " C
 813     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 814     " Haskell.
 815     let g:hs_highlight_delimiters = 1
 816     let g:hs_highlight_boolean = 1
 817     let g:hs_highlight_types = 1
 818     let g:hs_highlight_more_types = 1
 819     " Java.
 820     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 821     " Perl.
 822     let g:perl_fold = 1
 823     let g:perl_fold_blocks = 1
 824     let g:perl_nofold_packages = 1
 825     let g:perl_include_pod = 1 " syntax coloring for PODs
 826     " PHP.
 827     let g:php_folding = 3    " fold functions
 828     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 829     let g:php_sql_query = 1  " highlight SQL queries in strings
 830     " Python.
 831     let g:python_highlight_all = 1
 832     " Shell.
 833     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 834     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 835     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 836     " Vim.
 837     let g:vimsyn_embed = 0      " don't highlight embedded languages
 838     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 839     " XML.
 840     let g:xml_syntax_folding = 1
 841 endif
 842
 843
 844 " PLUGIN SETTINGS
 845
 846 if has('eval')
 847 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 848 " installing/removing/updating plugins simple. (Used for plugins with more
 849 " than one file.) Ignore errors in case pathogen is not installed.
 850     if v:version >= 700
 851         silent! execute 'call pathogen#infect()'
 852     endif
 853
 854 " Settings for securemodelines.
 855     " Only allow items I need (also includes spl which is not enabled by
 856     " default).
 857     if v:version >= 700 " need lists
 858         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 859                                               \ 'sw', 'sts', 'noet']
 860     endif
 861
 862 " Settings for the NERD commenter.
 863     " Don't create any mappings I don't want to use.
 864     let g:NERDCreateDefaultMappings = 0
 865     " Map toggle comment.
 866     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 867
 868 " XPTemplate settings.
 869     " Try to maintain snippet rendering even after editing outside of a
 870     " snippet.
 871     let g:xptemplate_strict = 0
 872     " Don't complete any braces automatically.
 873     let g:xptemplate_brace_complete = 0
 874     " Only highlight the current placeholder.
 875     let g:xptemplate_highlight = 'current'
 876
 877 " CtrlP settings.
 878     " Don't manage the working directory (the default setting is too slow for
 879     " me).
 880     let g:ctrlp_working_path_mode = 0
 881     " Path to cache directory. I prefer to keep generated files as local as
 882     " possible.
 883     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 884     " Permanent cache, cleared by a crontab entry.
 885     let g:ctrlp_clear_cache_on_exit = 0
 886
 887 " FSWitch settings.
 888     " Default don't work well for my projects.
 889     augroup vimrc
 890         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 891                           \ | let b:fswitchlocs = './'
 892         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 893                           \ | let b:fswitchlocs = './'
 894     augroup END
 895
 896     " Switch to corresponding header/source file.
 897     nnoremap <silent> <Leader>h :FSHere<CR>
 898 endif
 899
 900
 901 " AUTO COMMANDS
 902
 903 " Use a custom auto group to prevent problems when the vimrc files is sourced
 904 " twice.
 905 if has('autocmd')
 906     augroup vimrc
 907
 908 " Go to last position of opened files. Taken from :help last-position-jump.
 909         autocmd BufReadPost *
 910             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 911             \     execute "normal! g'\"" |
 912             \ endif
 913 " But not for Git commits, go to beginning of the file.
 914         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 915
 916 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 917 " when switching to a help buffer which is in the background with :buffer as
 918 " these options are local to windows (and not only to buffers). This happens
 919 " because I often want to use only one window and thus the help buffer is in
 920 " the background.
 921         autocmd BufWinEnter *.txt
 922             \ if &filetype == 'help' |
 923             \     setlocal nolist |
 924             \     setlocal nonumber |
 925             \ endif
 926
 927 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 928 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 929 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 930 " doesn't exist in older Vims.
 931         if exists('##InsertLeave')
 932             autocmd InsertLeave * set nopaste
 933         endif
 934
 935 " Write all files when running :mak[e] before 'makeprg' is called.
 936 " QuickFixCmdPre doesn't exist in older Vims.
 937         if exists('##QuickFixCmdPre')
 938             autocmd QuickFixCmdPre * wall
 939         endif
 940
 941 " Don't ignore case while in insert mode, but ignore case in all other modes.
 942 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 943 " capitalization. But while searching (/) 'ignorecase' is used.
 944 " InsertEnter/InsertLeave doesn't exist in older Vims.
 945         if exists('##InsertEnter') && exists('##InsertLeave')
 946             autocmd InsertEnter * set noignorecase
 947             autocmd InsertLeave * set   ignorecase
 948         endif
 949
 950 " Display a warning when editing a file which contains "do not edit" (ignoring
 951 " the case, \c), for example template files which were preprocessed or
 952 " auto-generated files. Especially useful when the header is not displayed on
 953 " the first screen, e.g. when the old position is restored. Not for vimrc
 954 " though.
 955         function! s:SearchForDoNotEditHeader()
 956             if search('\cdo not edit', 'n') == 0
 957                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 958                 return
 959             endif
 960
 961             echoerr 'Do not edit this file! (Maybe a template file.)'
 962         endfunction
 963         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 964
 965 " AFTER/FTPLUGIN AUTO COMMANDS
 966
 967 " Disable spell checking for files which don't need it.
 968         autocmd FileType deb  setlocal nospell
 969         autocmd FileType diff setlocal nospell
 970         autocmd FileType tar  setlocal nospell
 971 " Fix to allow Vim edit crontab files as crontab doesn't work with
 972 " backupcopy=auto.
 973         autocmd FileType crontab setlocal backupcopy=yes
 974 " Don't use the modeline in git commits as the diff created by `git commit -v`
 975 " may contain one which could change the filetype or other settings of the
 976 " commit buffer. Also make sure we use only 72 characters per line which is
 977 " the recommendation for git commit messages (http://tpope.net/node/106).
 978         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 979                                  \ setlocal textwidth=72
 980 " Use the same comment string as for Vim files in Vimperator files.
 981         autocmd FileType vimperator setlocal commentstring=\"%s
 982 " Use TeX compiler for (La)TeX files.
 983         autocmd FileType tex compiler tex
 984
 985 " FTDETECT AUTO COMMANDS
 986
 987 " Recognize .md as markdown files (Vim default is .mkd).
 988         autocmd BufRead,BufNewFile *.md set filetype=mkd
 989 " Recognize .test as Tcl files.
 990         autocmd BufRead,BufNewFile *.test set filetype=tcl
 991
 992 " OTHER AUTO COMMANDS
 993
 994 " Disable spell checking, displaying of list characters and long lines when
 995 " viewing documentation.
 996         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 997
 998 " Use diff filetype for mercurial patches in patch queue.
 999         autocmd BufReadPost */.hg/patches/* set filetype=diff
1000
1001     augroup END
1002 endif
1003
1004
1005 " CUSTOM FUNCTIONS AND COMMANDS
1006
1007 if has('eval')
1008 " Convenient command to see the difference between the current buffer and the
1009 " file it was loaded from, thus the changes you made. Thanks to the
1010 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1011 " for the diffed file than the filetype for the original file.
1012     if !exists(':DiffOrig')
1013         command DiffOrig
1014             \ let s:diff_orig_filetype = &filetype
1015             \ | vertical new
1016             \ | let &filetype = s:diff_orig_filetype
1017             \ | unlet s:diff_orig_filetype
1018             \ | set buftype=nofile
1019             \ | read ++edit #
1020             \ | 0d_
1021             \ | diffthis
1022             \ | wincmd p
1023             \ | diffthis
1024     endif
1025 endif