vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25     unlet s:save_runtimepath
  26 endif
  27
  28 " Make sure Vim (and not Vi) settings are used.
  29 set nocompatible
  30
  31 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  32 " runtime files).
  33 set runtimepath-=~/.vim
  34 set runtimepath^=~/.vim,~/.vim/runtime
  35
  36 " Don't store swap files in the same directory as the edited file.
  37 set directory-=.
  38 " But store them in ~/.tmp if available.
  39 set directory^=~/.tmp
  40
  41 " Disable modelines as they may cause security problems. Instead use
  42 " securemodelines (Vim script #1876).
  43 set nomodeline
  44
  45 " Complete to longest common string (list:longest) and then complete all full
  46 " matches after another (full). Thanks to pbrisbin
  47 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  48 set wildmode=list:longest,full
  49
  50 " Increase history of executed commands (:).
  51 set history=1000
  52
  53 " Increase number of possible undos.
  54 set undolevels=1000
  55
  56 " Use strong encryption if possible, also used for swap/undo files.
  57 if exists('+cryptmethod')
  58     set cryptmethod=blowfish
  59 endif
  60
  61
  62 " EDIT SETTINGS
  63
  64 " Enable automatic file detection, plugin and indention support.
  65 if has('autocmd')
  66     filetype off " necessary for pathogen to force a reload of ftplugins
  67     filetype plugin indent on
  68 endif
  69
  70 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  71 " existing files.
  72 set fileencodings=utf-8,latin1
  73
  74 " Wrap text after 78 characters.
  75 set textwidth=78
  76
  77 " Set tabs to 4 spaces, use softtabs.
  78 set shiftwidth=4
  79 set softtabstop=4
  80 set expandtab
  81 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  82 set shiftround
  83 " Use the default value for real tabs.
  84 set tabstop=8
  85
  86 " Enable auto indention.
  87 set autoindent
  88
  89 " When joining lines only add one space after a sentence.
  90 set nojoinspaces
  91
  92 " Allow backspacing over autoindent and line breaks.
  93 set backspace=indent,eol
  94
  95 " Start a comment when hitting enter after a commented line (r) and when using
  96 " o or O around a commented line (o).
  97 set formatoptions+=ro
  98 " Don't break a line if was already longer then 'textwidth' when insert mode
  99 " started.
 100 set formatoptions+=l
 101
 102 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 103 " no character) in visual block mode.
 104 set virtualedit=block
 105
 106 " Already display matches while typing the search command. This makes spotting
 107 " errors easy.
 108 set incsearch
 109
 110 " Activate syntax folding.
 111 if has('folding')
 112     set foldmethod=syntax
 113     set foldcolumn=2
 114     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 115                      " folding which is not what I want
 116 endif
 117
 118 " Only check for case if the searched word contains a capital character.
 119 set ignorecase
 120 set smartcase
 121
 122 " Activate spell checking, use English as default. Don't use spell checking
 123 " when diffing.
 124 if exists('+spell') && has('syntax') && !&diff
 125     set spell
 126     set spelllang=en_us
 127 endif
 128
 129 " Allow buffers with changes to be hidden. Very important for effective
 130 " editing with multiple buffers.
 131 set hidden
 132
 133
 134 " DISPLAY SETTINGS
 135
 136 " Use a dark background. Doesn't change the background color, only sets text
 137 " colors for a dark terminal.
 138 set background=dark
 139
 140 " Display line numbers.
 141 set number
 142 " But use as little space as necessary for the numbers column. Thanks to James
 143 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 144 if exists('+numberwidth')
 145     set numberwidth=1
 146 endif
 147 " Display the ruler with current line/file position. If 'statusline' is used
 148 " then this only affects <C-G>.
 149 set ruler
 150 " Display partial commands in the status line.
 151 set showcmd
 152
 153 " Don't redraw screen when executing macros; increases speed. Thanks to James
 154 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 155 set lazyredraw
 156
 157 " Visualize the line the cursor is currently in.
 158 if exists('+cursorline')
 159     set cursorline
 160 endif
 161
 162 " Display tabs, trailing space, non breakable spaces and long lines (when
 163 " wrapping is disabled).
 164 set list
 165 set listchars=trail:-,extends:>
 166 if v:version >= 700
 167     set listchars+=nbsp:!
 168 endif
 169
 170 if has('statusline')
 171     " Always display the status line even if there is only one window.
 172     set laststatus=2
 173
 174     set statusline=
 175     " on the left
 176     set statusline+=%02n: " buffer number
 177     set statusline+=%f\   " path to current file in buffer
 178     set statusline+=%h    " [help] if buffer is help file
 179     set statusline+=%w    " [Preview] if buffer is preview buffer
 180     set statusline+=%m    " [+] if buffer was modified,
 181                           " [-] if 'modifiable' is off
 182     set statusline+=%r    " [RO] if buffer is read only
 183
 184     " on the right
 185     set statusline+=%=                " right align
 186     set statusline+=0x%-8B\           " current character under cursor as hex
 187     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 188                                       " column number (%c),
 189                                       " virtual column number if different
 190                                       "                       than %c (%V)
 191     set statusline+=%P                " position in file in percent
 192 endif
 193
 194
 195 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 196
 197 " Easy way to exit insert mode.
 198 inoremap jj <Esc>
 199 inoremap jk <Esc>
 200 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 201 " (2010-10-15).
 202 cnoremap jj <C-C>
 203 cnoremap jk <C-C>
 204
 205 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 206 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 207 map <Right>  <Nop>
 208 map <Left>   <Nop>
 209 map <Up>     <Nop>
 210 map <Down>   <Nop>
 211 imap <Right> <Nop>
 212 imap <Left>  <Nop>
 213 imap <Up>    <Nop>
 214 imap <Down>  <Nop>
 215 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 216 " below).
 217 cmap <Up>    <Nop>
 218 cmap <Down>  <Nop>
 219 cmap <Right> <Nop>
 220 cmap <Left>  <Nop>
 221
 222 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 223 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 224 cnoremap <C-P> <Up>
 225 cnoremap <C-N> <Down>
 226
 227 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 228 " 20:02 CEST). To suspend without saving either unmap it or use :stop<CR>.
 229 nnoremap <C-Z> :update<CR>:stop<CR>
 230
 231 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 232 " in #vim on Freenode (2011-08-15 00:17 CEST).
 233 nnoremap <C-G> 2<C-G>
 234
 235 " Use <Space> to move down a page and - to move up one like in mutt.
 236 nnoremap <Space> <C-F>
 237 nnoremap - <C-B>
 238
 239 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 240 " (2010-05-16 18:38 CEST) for this idea.
 241 nnoremap <silent> gb :bnext<CR>
 242 nnoremap <silent> gB :bprev<CR>
 243
 244 " Fast access to buffers.
 245 nnoremap <Leader>1 :1b<CR>
 246 nnoremap <Leader>2 :2b<CR>
 247 nnoremap <Leader>3 :3b<CR>
 248 nnoremap <Leader>4 :4b<CR>
 249 nnoremap <Leader>5 :5b<CR>
 250 nnoremap <Leader>6 :6b<CR>
 251 nnoremap <Leader>7 :7b<CR>
 252 nnoremap <Leader>8 :8b<CR>
 253 nnoremap <Leader>9 :9b<CR>
 254 nnoremap <Leader>0 :10b<CR>
 255
 256 " Make last active window the only window. Similar to <C-w> o.
 257 nnoremap <C-W>O <C-W>p<C-W>o
 258
 259 " Maps to change spell language between English and German and disable spell
 260 " checking.
 261 if exists('+spell')
 262     noremap <Leader>sn :set nospell<CR>
 263     noremap <Leader>se :set spell spelllang=en_us<CR>
 264     noremap <Leader>sd :set spell spelllang=de_de<CR>
 265 endif
 266
 267 " Add semicolon to the end of the line. Thanks to
 268 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 269 " on Freenode for an improved version which doesn't clobber any marks.
 270 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 271
 272 " * and # for selections in visual mode. Thanks to
 273 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 274 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 275 if has('eval')
 276     function! s:VSetSearch()
 277         let temp = @@
 278         normal! gvy
 279         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 280         let @@ = temp
 281     endfunction
 282     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 283     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 284 endif
 285
 286 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 287 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 288 " mailing list for the commands.
 289 if v:version < 700
 290     cnoreabbrev W w
 291     cnoreabbrev Wa wa
 292     cnoreabbrev Wq wq
 293     cnoreabbrev Wqa wqa
 294 else
 295     cnoreabbrev <expr> W
 296         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 297     cnoreabbrev <expr> Wa
 298         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 299     cnoreabbrev <expr> Wq
 300         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 301     cnoreabbrev <expr> Wqa
 302         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 303 endif
 304 " Also fix my typo with "Q".
 305 if v:version < 700
 306     cnoreabbrev Q q
 307     cnoreabbrev Qa qa
 308 else
 309     cnoreabbrev <expr> Q
 310         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 311     cnoreabbrev <expr> Qa
 312         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 313 endif
 314
 315 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 316 " if pressed accidentally while in insert mode (happens on Mac when alt
 317 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 318 " no longer set on the console.
 319 if has('mac') || filereadable('/Users/.localized')
 320     inoremap <Char-0xa0> <Space>
 321 endif
 322
 323 " Disable Apple style movements in MacVim.
 324 if has('gui_macvim') && has('eval')
 325     let g:macvim_skip_cmd_opt_movement = 1
 326 endif
 327
 328 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 329 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 330 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 331
 332
 333 " ABBREVIATIONS
 334
 335 " Fix some of my spelling mistakes.
 336 iabbrev relle reelle
 337 iabbrev reele reelle
 338
 339
 340 " SYNTAX SETTINGS
 341
 342 " Activate syntax coloring.
 343 if has('syntax')
 344     syntax enable
 345
 346 " Don't highlight more than 500 columns as I normally don't have that long
 347 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 348 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 349     if exists('+synmaxcol')
 350         set synmaxcol=500
 351     endif
 352
 353 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 354 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 355 " disabled when necessary with :2match (in Vim >= 700).
 356     if exists(':2match')
 357         2match Todo /\%>78v./
 358     else
 359         match Todo /\%>78v./
 360     endif
 361
 362     if exists('*matchadd')
 363 " Highlight some important keywords in all documents.
 364         for x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 365             call matchadd('Todo', x)
 366         endfor
 367
 368 " Highlight unicode whitespace which is no normal whitespace (0x20).
 369         for x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 370                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 371                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 372                 \ 'feff']
 373             call matchadd('Error', '\%u' . x)
 374         endfor
 375     endif
 376
 377 " Settings for specific filetypes.
 378
 379     " Perl.
 380     let g:perl_fold = 1
 381     let g:perl_fold_blocks = 1
 382     let g:perl_nofold_packages = 1
 383     let g:perl_include_pod = 1 " syntax coloring for PODs
 384
 385 endif
 386
 387
 388 " PLUGIN SETTINGS
 389
 390 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 391 " installing/removing/updating plugins simple. (Used for plugins with more
 392 " than one file.)
 393 if has('eval') && v:version >= 700
 394     execute 'call pathogen#runtime_append_all_bundles()'
 395 endif
 396
 397 " Settings for the NERD commenter.
 398 " Don't create any mappings I don't want to use.
 399 if has('eval')
 400     let g:NERDCreateDefaultMappings = 0
 401 endif
 402 " Map toggle comment.
 403 map <Leader><Leader> <Plug>NERDCommenterToggle
 404
 405 " XPTemplate settings.
 406 if has('eval')
 407     " Try to maintain snippet rendering even after editing outside of a
 408     " snippet.
 409     let g:xptemplate_strict = 0
 410     " Don't complete any braces automatically.
 411     let g:xptemplate_brace_complete = 0
 412     " Only highlight the current placeholder.
 413     let g:xptemplate_highlight = 'current'
 414 endif
 415
 416
 417 " AUTO COMMANDS
 418
 419 " Use a custom auto group to prevent problems when the vimrc files is sourced
 420 " twice.
 421 if has('autocmd')
 422     augroup vimrc
 423 " Remove all autocmds from the current group.
 424         autocmd!
 425
 426 " Go to last position of opened files. Taken from :help last-position-jump.
 427         autocmd BufReadPost *
 428             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 429             \     execute "normal! g'\"" |
 430             \ endif
 431 " But not for Git commits, go to beginning of the file.
 432         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 433
 434 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 435 " when switching to a help buffer which is in the background with :buffer as
 436 " these options are local to windows (and not only to buffers). This happens
 437 " because I often want to use only one window and thus the help buffer is in
 438 " the background.
 439         autocmd BufWinEnter *.txt
 440             \ if &filetype == 'help' |
 441             \     setlocal nolist |
 442             \     setlocal nonumber |
 443             \ endif
 444
 445 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 446 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 447 " want to paste once and then 'paste' gets automatically unset.
 448         if exists('##InsertLeave')
 449             autocmd InsertLeave * set nopaste
 450         endif
 451
 452 " Save changes when running :mak[e] before 'makeprg' is called.
 453         autocmd QuickFixCmdPre * write
 454
 455 " AFTER/FTPLUGIN AUTO COMMANDS
 456
 457 " Disable spell checking for files which don't need it.
 458         autocmd FileType deb  setlocal nospell
 459         autocmd FileType diff setlocal nospell
 460         autocmd FileType tar  setlocal nospell
 461 " Fix to allow Vim edit crontab files as crontab doesn't work with
 462 " backupcopy=auto.
 463         autocmd FileType crontab setlocal backupcopy=yes
 464 " Don't use the modeline in git commits as the diff created by `git commit -v`
 465 " may contain one which could change the filetype or other settings of the
 466 " commit buffer. Also make sure we use only 72 characters per line which is
 467 " the recommendation for git commit messages (http://tpope.net/node/106).
 468         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 469                                  \ setlocal textwidth=72
 470 " Use the same comment string as for Vim files in Vimperator files.
 471         autocmd FileType vimperator setlocal commentstring=\"%s
 472 " Use tex compiler for (La)TeX files.
 473         autocmd FileType tex compiler tex
 474
 475 " FTDETECT AUTO COMMANDS
 476
 477 " Recognize .md as markdown files (Vim default is .mkd).
 478         autocmd BufRead,BufNewFile *.md set filetype=mkd
 479 " Recognize .test as Tcl files.
 480         autocmd BufRead,BufNewFile *.test set filetype=tcl
 481
 482 " OTHER AUTO COMMANDS
 483
 484 " Disable spell checking, displaying of list characters and long lines when
 485 " viewing documentation.
 486         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 487
 488 " Use diff filetype for mercurial patches in patch queue.
 489         autocmd BufReadPost */.hg/patches/* set filetype=diff
 490
 491     augroup END
 492 endif
 493
 494
 495 " CUSTOM FUNCTIONS
 496
 497 if has('eval')
 498     " New text-objects ii and ai to work on text with the same indentation.
 499     " Thanks to
 500     " http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 501     " (visited on 2011-11-19).
 502     onoremap <silent>ai :<C-U>call <SID>IndTxtObj(0)<CR>
 503     onoremap <silent>ii :<C-U>call <SID>IndTxtObj(1)<CR>
 504     vnoremap <silent>ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 505     vnoremap <silent>ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 506
 507     function! s:IndTxtObj(inner)
 508         let curline = line(".")
 509         let lastline = line("$")
 510         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 511         let i = i < 0 ? 0 : i
 512         if getline(".") !~ "^\\s*$"
 513             let p = line(".") - 1
 514             let nextblank = getline(p) =~ "^\\s*$"
 515             while p > 0
 516                     \ && ((i == 0 && !nextblank)
 517                         \ || (i > 0 && ((indent(p) >= i
 518                             \ && !(nextblank && a:inner))
 519                             \ || (nextblank && !a:inner))))
 520                 -
 521                 let p = line(".") - 1
 522                 let nextblank = getline(p) =~ "^\\s*$"
 523             endwhile
 524             normal! 0V
 525             call cursor(curline, 0)
 526             let p = line(".") + 1
 527             let nextblank = getline(p) =~ "^\\s*$"
 528             while p <= lastline
 529                     \ && ((i == 0 && !nextblank)
 530                         \ || (i > 0 && ((indent(p) >= i
 531                             \ && !(nextblank && a:inner))
 532                             \ || (nextblank && !a:inner))))
 533                 +
 534                 let p = line(".") + 1
 535                 let nextblank = getline(p) =~ "^\\s*$"
 536             endwhile
 537             normal! $
 538         endif
 539     endfunction
 540
 541 endif