vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37
  38 " Disable modelines as they may cause security problems. Instead use
  39 " securemodelines (Vim script #1876).
  40 set nomodeline
  41
  42 " Complete to longest common string (list:longest) and then complete all full
  43 " matches after another (full). Thanks to pbrisbin
  44 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  45 set wildmode=list:longest,full
  46
  47 " Increase history of executed commands (:).
  48 set history=1000
  49
  50 " Increase number of possible undos.
  51 set undolevels=1000
  52
  53 " Use strong encryption if possible, also used for swap/undo files.
  54 if v:version >= 703
  55     set cryptmethod=blowfish
  56 endif
  57
  58
  59 " EDIT SETTINGS
  60
  61 " Enable automatic file detection, plugin and indention support.
  62 if has('autocmd')
  63     filetype off " necessary for pathogen to force a reload of ftplugins
  64     filetype plugin indent on
  65 endif
  66
  67 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  68 " existing files.
  69 set fileencodings=utf-8,latin1
  70
  71 " Wrap text after 78 characters.
  72 set textwidth=78
  73
  74 " Set tabs to 4 spaces, use softtabs.
  75 set shiftwidth=4
  76 set softtabstop=4
  77 set expandtab
  78 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  79 set shiftround
  80 " Use the default value for real tabs.
  81 set tabstop=8
  82
  83 " Enable auto indention.
  84 set autoindent
  85
  86 " When joining lines only add one space after a sentence.
  87 set nojoinspaces
  88
  89 " Allow backspacing over autoindent and line breaks.
  90 set backspace=indent,eol
  91
  92 " Start a comment when hitting enter after a commented line (r) and when using
  93 " o or O around a commented line (o).
  94 set formatoptions+=ro
  95 " Don't break a line if was already longer then 'textwidth' when insert mode
  96 " started.
  97 set formatoptions+=l
  98
  99 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 100 " no character) in visual block mode.
 101 set virtualedit=block
 102
 103 " Already display matches while typing the search command. This makes spotting
 104 " errors easy.
 105 set incsearch
 106
 107 " Activate syntax folding.
 108 if has('folding')
 109     set foldmethod=syntax
 110     set foldcolumn=2
 111     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 112                      " folding which is not what I want
 113 endif
 114
 115 " Only check for case if the searched word contains a capital character.
 116 set ignorecase
 117 set smartcase
 118
 119 " Activate spell checking, use English as default. Don't use spell checking
 120 " when diffing.
 121 if v:version >= 700 && has('syntax') && !&diff
 122     set spell
 123     set spelllang=en_us
 124 endif
 125
 126 " Allow buffers with changes to be hidden. Very important for effective
 127 " editing with multiple buffers.
 128 set hidden
 129
 130
 131 " DISPLAY SETTINGS
 132
 133 " Use a dark background. Doesn't change the background color, only sets text
 134 " colors for a dark terminal.
 135 set background=dark
 136
 137 " Display line numbers.
 138 set number
 139 " But use as little space as necessary for the numbers column. Thanks to James
 140 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 141 if v:version >= 700
 142     set numberwidth=1
 143 endif
 144 " Display the ruler with current line/file position. If 'statusline' is used
 145 " then this only affects <C-G>.
 146 set ruler
 147 " Display partial commands in the status line.
 148 set showcmd
 149
 150 " Don't redraw screen when executing macros; increases speed. Thanks to James
 151 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 152 set lazyredraw
 153
 154 " Visualize the line the cursor is currently in.
 155 if v:version >= 700
 156     set cursorline
 157 endif
 158
 159 " Display tabs, trailing space, non breakable spaces and long lines (when
 160 " wrapping is disabled).
 161 set list
 162 set listchars=trail:-,extends:>
 163 if v:version >= 700
 164     set listchars+=nbsp:!
 165 endif
 166
 167 if has('statusline')
 168     " Always display the status line even if there is only one window.
 169     set laststatus=2
 170
 171     set statusline=
 172     " on the left
 173     set statusline+=%02n: " buffer number
 174     set statusline+=%f\   " path to current file in buffer
 175     set statusline+=%h    " [help] if buffer is help file
 176     set statusline+=%w    " [Preview] if buffer is preview buffer
 177     set statusline+=%m    " [+] if buffer was modified,
 178                           " [-] if 'modifiable' is off
 179     set statusline+=%r    " [RO] if buffer is read only
 180
 181     " on the right
 182     set statusline+=%=                " right align
 183     set statusline+=0x%-8B\           " current character under cursor as hex
 184     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 185                                       " column number (%c),
 186                                       " virtual column number if different
 187                                       "                       than %c (%V)
 188     set statusline+=%P                " position in file in percent
 189 endif
 190
 191
 192 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 193
 194 " Easy way to exit insert mode.
 195 inoremap jj <Esc>
 196 inoremap jk <Esc>
 197 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 198 " (2010-10-15).
 199 cnoremap jj <C-C>
 200 cnoremap jk <C-C>
 201
 202 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 203 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 204 map <Right>  <Nop>
 205 map <Left>   <Nop>
 206 map <Up>     <Nop>
 207 map <Down>   <Nop>
 208 imap <Right> <Nop>
 209 imap <Left>  <Nop>
 210 imap <Up>    <Nop>
 211 imap <Down>  <Nop>
 212 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 213 " below).
 214 cmap <Up>    <Nop>
 215 cmap <Down>  <Nop>
 216 cmap <Right> <Nop>
 217 cmap <Left>  <Nop>
 218
 219 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 220 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 221 cnoremap <C-P> <Up>
 222 cnoremap <C-N> <Down>
 223
 224 " Use <Space> to move down a page and - to move up one like in mutt.
 225 nnoremap <Space> <C-F>
 226 nnoremap - <C-B>
 227
 228 " Behave like 'scrolloff' but only while searching. Thanks to "Benjamin R.
 229 " Haskell" <vim@benizi.com> from the Vim mailing list (2010-10-26).
 230 nnoremap n nzv3j3k
 231 nnoremap N Nzv3k3j
 232
 233 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 234 " (2010-05-16 18:38 CEST) for this idea.
 235 nnoremap <silent> gb :bnext<CR>
 236 nnoremap <silent> gB :bprev<CR>
 237
 238 " Fast access to buffers.
 239 nnoremap <Leader>1 :1b<CR>
 240 nnoremap <Leader>2 :2b<CR>
 241 nnoremap <Leader>3 :3b<CR>
 242 nnoremap <Leader>4 :4b<CR>
 243 nnoremap <Leader>5 :5b<CR>
 244 nnoremap <Leader>6 :6b<CR>
 245 nnoremap <Leader>7 :7b<CR>
 246 nnoremap <Leader>8 :8b<CR>
 247 nnoremap <Leader>9 :9b<CR>
 248 nnoremap <Leader>0 :10b<CR>
 249
 250 " Make last active window the only window. Similar to <C-w> o.
 251 nnoremap <C-W>O <C-W>p<C-W>o
 252
 253 " Maps to change spell language between English and German and disable spell
 254 " checking.
 255 if v:version >= 700
 256     noremap <Leader>sn :set nospell<CR>
 257     noremap <Leader>se :set spell spelllang=en_us<CR>
 258     noremap <Leader>sd :set spell spelllang=de_de<CR>
 259 endif
 260
 261 " Add semicolon to the end of the line. Thanks to
 262 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 263 " on Freenode for an improved version which doesn't clobber any marks.
 264 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 265
 266 " * and # for selections in visual mode. Thanks to
 267 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 268 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 269 if has('eval')
 270     function! s:VSetSearch()
 271         let temp = @@
 272         normal! gvy
 273         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 274         let @@ = temp
 275     endfunction
 276     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 277     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 278 endif
 279
 280 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 281 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 282 " mailing list for the commands.
 283 if v:version < 700
 284     cnoreabbrev W w
 285     cnoreabbrev Wa wa
 286     cnoreabbrev Wq wq
 287     cnoreabbrev Wqa wqa
 288 else
 289     cnoreabbrev <expr> W
 290         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 291     cnoreabbrev <expr> Wa
 292         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 293     cnoreabbrev <expr> Wq
 294         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 295     cnoreabbrev <expr> Wqa
 296         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 297 endif
 298 " Also fix my typo with "Q".
 299 if v:version < 700
 300     cnoreabbrev Q q
 301     cnoreabbrev Qa qa
 302 else
 303     cnoreabbrev <expr> Q
 304         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 305     cnoreabbrev <expr> Qa
 306         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 307 endif
 308
 309 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 310 " if pressed accidentally while in insert mode (happens on Mac when alt
 311 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 312 " no longer set on the console.
 313 if has('mac') || filereadable('/Users/.localized')
 314     inoremap <Char-0xa0> <Space>
 315 endif
 316
 317 " Disable Apple style movements in MacVim.
 318 if has('gui_macvim') && has('eval')
 319     let macvim_skip_cmd_opt_movement = 1
 320 endif
 321
 322 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 323 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 324 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 325
 326
 327 " ABBREVIATIONS
 328
 329 " Fix some of my spelling mistakes.
 330 iabbrev relle reelle
 331 iabbrev reele reelle
 332
 333
 334 " SYNTAX SETTINGS
 335
 336 " Activate syntax coloring.
 337 if has('syntax')
 338     syntax enable
 339
 340 " Don't highlight more than 500 columns as I normally don't have that long
 341 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 342 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 343     set synmaxcol=500
 344
 345 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 346 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 347 " disabled when necessary with :2match (in Vim >= 700).
 348     if v:version >= 700
 349         2match Todo /\%>78v./
 350     else
 351         match Todo /\%>78v./
 352     endif
 353
 354 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 355     if v:version > 701 || (v:version == 701 && has('patch42'))
 356         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 357     endif
 358 endif
 359
 360
 361 " PLUGIN SETTINGS
 362
 363 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 364 " installing/removing/updating plugins simple. (Used for plugins with more
 365 " than one file.)
 366 if has('eval')
 367     call pathogen#runtime_append_all_bundles()
 368 endif
 369
 370 " Settings for the NERD commenter.
 371 " Don't create any mappings I don't want to use.
 372 if has('eval')
 373     let NERDCreateDefaultMappings = 0
 374 endif
 375 " Map toggle comment.
 376 map <Leader><Leader> <Plug>NERDCommenterToggle
 377
 378 " XPTemplate settings.
 379 if has('eval')
 380     " Try to maintain snippet rendering even after editing outside of a
 381     " snippet.
 382     let g:xptemplate_strict = 0
 383     " Don't complete any braces automatically.
 384     let g:xptemplate_brace_complete = 0
 385     " Only highlight the current placeholder.
 386     let g:xptemplate_highlight = 'current'
 387 endif
 388
 389
 390 " AUTO COMMANDS
 391
 392 " Use a custom auto group to prevent problems when the vimrc files is sourced
 393 " twice.
 394 if has('autocmd')
 395     augroup vimrc
 396         autocmd!
 397
 398 " Go to last position of opened files. Taken from :help last-position-jump.
 399         autocmd BufReadPost *
 400             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 401             \     execute "normal! g'\"" |
 402             \ endif
 403 " But not for Git commits, go to beginning of the file.
 404         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 405
 406 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 407 " when switching to a help buffer which is in the background with :buffer as
 408 " these options are local to windows (and not only to buffers). This happens
 409 " because I often want to use only one window and thus the help buffer is in
 410 " the background.
 411         autocmd BufWinEnter *.txt
 412             \ if &filetype == 'help' |
 413             \     setlocal nolist |
 414             \     setlocal nonumber |
 415             \ endif
 416
 417 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 418 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 419 " want to paste once and then 'paste' gets automatically unset.
 420         autocmd InsertLeave * set nopaste
 421
 422 " AFTER/FTPLUGIN AUTO COMMANDS
 423
 424 " Disable spell checking for files which don't need it.
 425         autocmd FileType deb  setlocal nospell
 426         autocmd FileType diff setlocal nospell
 427         autocmd FileType tar  setlocal nospell
 428 " Fix to allow Vim edit crontab files as crontab doesn't work with
 429 " backupcopy=auto.
 430         autocmd FileType crontab setlocal backupcopy=yes
 431 " Don't use the modeline in git commits as the diff created by `git commit -v`
 432 " may contain one which could change the filetype or other settings of the
 433 " commit buffer. Also make sure we use only 72 characters per line which is
 434 " the recommendation for git commit messages (http://tpope.net/node/106).
 435         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 436                                  \ setlocal textwidth=72
 437 " Allow folding in perl.
 438         autocmd FileType perl let perl_fold = 1 |
 439                             \ let perl_fold_blocks = 1
 440 " Use the same comment string as for Vim files in Vimperator files.
 441         autocmd FileType vimperator setlocal commentstring=\"%s
 442
 443 " FTDETECT AUTO COMMANDS
 444
 445 " Recognize .md as markdown files (Vim default is .mkd).
 446         autocmd BufRead,BufNewFile *.md set filetype=mkd
 447 " Recognize .test as Tcl files.
 448         autocmd BufRead,BufNewFile *.test set filetype=tcl
 449
 450 " OTHER AUTO COMMANDS
 451
 452 " Disable spell checking, displaying of list characters and long lines when
 453 " viewing documentation.
 454         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 455
 456 " Use diff filetype for mercurial patches in patch queue.
 457         autocmd BufReadPost */.hg/patches/* set filetype=diff
 458
 459     augroup END
 460 endif