vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 109 " is used multiple times. Necessary to support reloading the vimrc.
 110 if has('autocmd')
 111     augroup vimrc
 112         autocmd!
 113     augroup END
 114 endif
 115
 116
 117 " HELPER FUNCTIONS
 118
 119 if has('eval')
 120 " Check if the given syntax group is available. Thanks to bairui in #vim on
 121 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 122     function! s:HasSyntaxGroup(group)
 123         try
 124             execute 'silent highlight ' . a:group
 125         " \a = [A-Za-z]
 126         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 127             return 0
 128         endtry
 129         return 1
 130     endfunction
 131
 132 " Check if the given Vim version and patch is available.
 133     function! s:HasVersionAndPatch(version, patch)
 134         return v:version > a:version
 135             \ || (v:version == a:version && has('patch' . a:patch))
 136     endfunction
 137 endif
 138
 139
 140 " EDIT SETTINGS
 141
 142 " Enable automatic file detection, plugin and indention support.
 143 if has('autocmd')
 144     filetype off " necessary for pathogen to force a reload of ftplugins
 145     filetype plugin indent on
 146 endif
 147
 148 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 149 " existing files.
 150 set fileencodings=utf-8,latin1
 151
 152 " Always use unix line-endings for new files.
 153 set fileformats=unix,dos
 154
 155 " Wrap text after 78 characters.
 156 set textwidth=78
 157
 158 " Set tabs to 4 spaces, use softtabs.
 159 set shiftwidth=4
 160 set softtabstop=4
 161 set expandtab
 162 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 163 set shiftround
 164 " Use the default value for real tabs.
 165 set tabstop=8
 166
 167 " Enable auto indention.
 168 set autoindent
 169
 170 " When joining lines only add one space after a sentence.
 171 set nojoinspaces
 172
 173 " Allow backspacing over autoindent and line breaks.
 174 set backspace=indent,eol
 175
 176 " Start a comment when hitting enter after a commented line (r) and when using
 177 " o or O around a commented line (o).
 178 set formatoptions+=ro
 179 " Don't break a line if was already longer then 'textwidth' when insert mode
 180 " started.
 181 set formatoptions+=l
 182 " Remove comment leader when joining lines where it makes sense.
 183 if <SID>HasVersionAndPatch(703, 541)
 184     set formatoptions+=j
 185 endif
 186
 187 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 188 " no character) in visual block mode.
 189 set virtualedit=block
 190
 191 " Already display matches while typing the search command. This makes spotting
 192 " typos easy and searching faster.
 193 set incsearch
 194
 195 " Activate syntax folding.
 196 if has('folding')
 197     set foldmethod=syntax
 198     " Only use fold column if we have enough space (for example not in a
 199     " (virtual) terminal which has only 80 columns).
 200     if &columns > 80
 201         set foldcolumn=2
 202     endif
 203     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 204                      " folding which is not what I want
 205     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 206     set foldopen-=block
 207 endif
 208
 209 " Only check case if the searched word contains a capital character.
 210 set ignorecase
 211 set smartcase
 212
 213 " Activate spell checking, use English as default.
 214 if exists('+spell') && has('syntax')
 215     " But not when diffing because spell checking is distracting in this case.
 216     if !&diff
 217         set spell
 218     endif
 219     set spelllang=en_us
 220 endif
 221
 222 " Allow buffers with changes to be hidden. Very important for effective
 223 " editing with multiple buffers. Prevents the "E37: No write since last change
 224 " (add ! to override)" warning when switching buffers.
 225 set hidden
 226
 227
 228 " DISPLAY SETTINGS
 229
 230 " Use a dark background. Doesn't change the background color, only sets text
 231 " colors for a dark terminal.
 232 set background=dark
 233
 234 " Use my color scheme if 256 colors are available.
 235 if &t_Co == 256 || has('gui_running')
 236     colorscheme simon
 237 endif
 238
 239 " Display line numbers.
 240 set number
 241 " But use as little space as possible for the numbers column. Thanks to James
 242 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 243 if exists('+numberwidth')
 244     set numberwidth=1
 245 endif
 246 " Display the ruler with current line/file position. If 'statusline' is used
 247 " then this only affects <C-G>.
 248 set ruler
 249 " Display partial commands in the status line.
 250 set showcmd
 251
 252 " Don't redraw screen when executing macros; increases speed. Thanks to James
 253 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 254 set lazyredraw
 255
 256 " Visualize the line the cursor is currently in.
 257 if exists('+cursorline')
 258     set cursorline
 259 endif
 260
 261 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 262 " remove the highlighting until the next search.
 263 set hlsearch
 264
 265 " Display some special characters.
 266 set list
 267 set listchars=
 268 " Display tabs as ">--------".
 269 set listchars+=tab:>-
 270 " Display trailing whitespace as "-".
 271 set listchars+=trail:-
 272 " Display markers for long lines when wrapping is disabled.
 273 set listchars+=extends:>,precedes:<
 274 " Display non-breakable space as "!".
 275 if v:version >= 700
 276     set listchars+=nbsp:!
 277 endif
 278
 279 " Don't draw the vertical split separator by using space as character. Thanks
 280 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 281 " non-breakable space. But a simple space works as well, as long as the
 282 " current color scheme is not reset.
 283 if has('windows') && has('folding')
 284     set fillchars+=vert:\  " comment to prevent trailing whitespace
 285 endif
 286
 287 if has('statusline')
 288     " Always display the status line even if there is only one window.
 289     set laststatus=2
 290
 291     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 292     " is the highest buffer number, otherwise return nothing. Used in
 293     " 'statusline' to get an overview of available buffer numbers.
 294     function! StatuslineBufferCount()
 295         let l:bufnr = bufnr('$')
 296         if l:bufnr > 1
 297             let l:result = '/'
 298             if exists('*printf')
 299                 let l:result .= printf('%02d', l:bufnr)
 300             else
 301                 " Older Vims don't have printf() (and no .= either). Emulate
 302                 " "%02d".
 303                 if l:bufnr < 10
 304                     let l:result = l:result . '0'
 305                 endif
 306                 let l:result = l:result . l:bufnr
 307             endif
 308             return l:result
 309         else
 310             return ''
 311         endif
 312     endfunction
 313
 314     " Like %f but use relative filename if it's shorter than the absolute path
 315     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 316     " not enough because it doesn't create '../'s.
 317     function! StatuslineRelativeFilename()
 318         " Display only filename for help files.
 319         if &buftype == 'help'
 320             return expand('%:t')
 321         endif
 322         " Special case for scratch files.
 323         if &buftype == 'nofile'
 324             return '[Scratch]'
 325         endif
 326
 327         let l:path = expand('%')
 328         " No file.
 329         if l:path == ''
 330             return '[No Name]'
 331         endif
 332         " Path is already relative, nothing to do.
 333         if stridx(l:path, '/') != 0
 334             return l:path
 335         endif
 336
 337         " Absolute path to this file.
 338         let l:path = expand('%:p')
 339         " Shortened path to this file, thanks to bairui in #vim on Freenode
 340         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 341         " Vim normally uses as %f (minus some exceptions).
 342         let l:original_path = fnamemodify(l:path, ':~')
 343         " Absolute path to the current working directory.
 344         let l:cwd = getcwd()
 345
 346         " Working directory completely contained in path, replace it with a
 347         " relative path. Happens for example when opening a file with netrw.
 348         " %f displays this as absolute path, but we want a relative path of
 349         " course.
 350         if stridx(l:path, l:cwd) == 0
 351             return strpart(l:path, strlen(l:cwd) + 1)
 352         endif
 353
 354         let l:path_list = split(l:path, '/')
 355         let l:cwd_list  = split(l:cwd,  '/')
 356
 357         " Remove the common path.
 358         while l:path_list[0] == l:cwd_list[0]
 359             call remove(l:path_list, 0)
 360             call remove(l:cwd_list,  0)
 361         endwhile
 362
 363         " Add as many '..' as necessary for the relative path and join the
 364         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 365         " the hint to use repeat() instead of a loop.
 366         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 367
 368         " Use the shorter path, either relative or absolute.
 369         if strlen(l:path) < strlen(l:original_path)
 370             return l:path
 371         else
 372             return l:original_path
 373         endif
 374     endfunction
 375
 376     set statusline=
 377     " on the left
 378     set statusline+=%02n  " buffer number
 379     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 380     set statusline+=:
 381     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 382         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 383         set statusline+=\     " space after path
 384     else
 385         set statusline+=%f\   " path to current file in buffer
 386     endif
 387     set statusline+=%h    " [help] if buffer is help file
 388     set statusline+=%w    " [Preview] if buffer is preview buffer
 389     set statusline+=%m    " [+] if buffer was modified,
 390                           " [-] if 'modifiable' is off
 391     set statusline+=%r    " [RO] if buffer is read only
 392
 393     " on the right
 394     set statusline+=%=                " right align
 395     set statusline+=0x%-8B\           " current character under cursor as hex
 396     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 397                                       " column number (%c),
 398                                       " virtual column number if different
 399                                       "                       than %c (%V)
 400     set statusline+=%P                " position in file in percent
 401 endif
 402
 403
 404 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 405
 406 " noremap is used to make sure the right side is executed as is and can't be
 407 " modified by a plugin or other settings. Except for <Nop> which isn't
 408 " affected by mappings.
 409
 410 " Easy way to exit insert mode. jk is preferred because it's faster.
 411 inoremap jj <Esc>
 412 inoremap jk <Esc>
 413 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 414 " (2010-10-15).
 415 cnoremap jj <C-C>
 416 cnoremap jk <C-C>
 417
 418 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 419 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 420 map <Right>  <Nop>
 421 map <Left>   <Nop>
 422 map <Up>     <Nop>
 423 map <Down>   <Nop>
 424 imap <Right> <Nop>
 425 imap <Left>  <Nop>
 426 imap <Up>    <Nop>
 427 imap <Down>  <Nop>
 428 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 429 " below).
 430 cmap <Up>    <Nop>
 431 cmap <Down>  <Nop>
 432 cmap <Right> <Nop>
 433 cmap <Left>  <Nop>
 434
 435 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 436 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 437 cnoremap <C-P> <Up>
 438 cnoremap <C-N> <Down>
 439
 440 if has('eval')
 441 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 442 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 443 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 444 " directly because it also enables that feature for other commands which I
 445 " don't want.
 446
 447     " Set 'nostartofline' for a single movement.
 448     function! s:TemporaryNostartofline(movement)
 449         let l:startofline = &startofline
 450         set nostartofline
 451         execute 'normal! ' . a:movement
 452         let &startofline = l:startofline
 453     endfunction
 454
 455     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 456     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 457     nnoremap <silent> <C-F>
 458         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 459     nnoremap <silent> <C-B>
 460         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 461     nnoremap <silent> <C-D>
 462         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 463     nnoremap <silent> <C-U>
 464         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 465 endif
 466
 467 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 468 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 469 " Only the current buffer is written, thus switching to another buffer works
 470 " too.
 471 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 472
 473 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 474 " in #vim on Freenode (2011-08-15 00:17 CEST).
 475 nnoremap <C-G> 2<C-G>
 476
 477 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 478 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 479 nmap <Space> <C-F>
 480 nmap - <C-B>
 481
 482 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 483 " (2010-05-16 18:38 CEST) for this idea.
 484 nnoremap <silent> gb :bnext<CR>
 485 nnoremap <silent> gB :bprevious<CR>
 486 if has('eval')
 487     " But when starting again at the first buffer, print a warning which
 488     " reminds me that I've already seen that buffer.
 489     function! s:NextBuffer()
 490         " Are we currently on the last buffer and moving to the first?
 491         let l:last_buffer = 0
 492         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 493             let l:last_buffer = 1
 494         endif
 495
 496         " Go to the next buffer.
 497         if !l:last_buffer
 498             bnext
 499
 500         " Go to the first buffer, silent is necessary or the following message
 501         " won't be displayed because it's overwritten by the status message
 502         " displayed when entering a buffer.
 503         else
 504             silent bnext
 505
 506             echohl WarningMsg
 507             echo 'Starting again at first buffer.'
 508             echohl None
 509         endif
 510     endfunction
 511     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 512 endif
 513
 514 " Fast access to buffers.
 515 nnoremap <silent> <Leader>1 :1buffer<CR>
 516 nnoremap <silent> <Leader>2 :2buffer<CR>
 517 nnoremap <silent> <Leader>3 :3buffer<CR>
 518 nnoremap <silent> <Leader>4 :4buffer<CR>
 519 nnoremap <silent> <Leader>5 :5buffer<CR>
 520 nnoremap <silent> <Leader>6 :6buffer<CR>
 521 nnoremap <silent> <Leader>7 :7buffer<CR>
 522 nnoremap <silent> <Leader>8 :8buffer<CR>
 523 nnoremap <silent> <Leader>9 :9buffer<CR>
 524 nnoremap <silent> <Leader>0 :10buffer<CR>
 525
 526 " Make last active window the only window. Similar to <C-W> o.
 527 nnoremap <C-W>O <C-W>p<C-W>o
 528
 529 " Maps to change spell language between English and German and disable spell
 530 " checking.
 531 if exists('+spell')
 532     nnoremap <silent> <Leader>sn :set nospell<CR>
 533     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 534     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 535 endif
 536
 537 " Add semicolon to the end of the line. Thanks to
 538 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 539 " on Freenode for an improved version which doesn't clobber any marks.
 540 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 541
 542 " * and # for selections in visual mode. Thanks to
 543 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 544 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 545 if has('eval')
 546     function! s:VSetSearch()
 547         let l:temp = @@
 548         normal! gvy
 549         " Added \C to force 'noignorecase' while searching the current visual
 550         " selection. I want to search for the exact string in this case.
 551         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 552         let @@ = l:temp
 553     endfunction
 554     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 555     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 556 endif
 557
 558 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 559 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 560 " mailing list for the commands.
 561 if v:version < 700
 562     cnoreabbrev W w
 563     cnoreabbrev Wa wa
 564     cnoreabbrev Wq wq
 565     cnoreabbrev Wqa wqa
 566 else
 567     cnoreabbrev <expr> W
 568         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 569     cnoreabbrev <expr> Wa
 570         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 571     cnoreabbrev <expr> Wq
 572         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 573     cnoreabbrev <expr> Wqa
 574         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 575 endif
 576 " Also fix my typo with "Q".
 577 if v:version < 700
 578     cnoreabbrev Q q
 579     cnoreabbrev Qa qa
 580 else
 581     cnoreabbrev <expr> Q
 582         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 583     cnoreabbrev <expr> Qa
 584         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 585 endif
 586
 587 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 588 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 589 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 590
 591 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 592 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 593 " Vim's source.
 594 inoremap <C-U> <C-G>u<C-U>
 595 " Same for <C-@> (insert previously inserted text and leave insert mode).
 596 inoremap <C-@> <C-G>u<C-@>
 597 " And for <C-A> (insert previously inserted text).
 598 inoremap <C-A> <C-G>u<C-A>
 599 " And for <C-W> (delete word before cursor).
 600 inoremap <C-W> <C-G>u<C-W>
 601
 602 if has('eval')
 603 " New text-objects ii and ai to work on text with the same indentation. Thanks
 604 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 605 " (visited on 2011-11-19).
 606     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 607     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 608     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 609     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 610
 611     function! s:IndTxtObj(inner)
 612         let curline = line(".")
 613         let lastline = line("$")
 614         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 615         let i = i < 0 ? 0 : i
 616         if getline(".") !~ "^\\s*$"
 617             let p = line(".") - 1
 618             let nextblank = getline(p) =~ "^\\s*$"
 619             while p > 0
 620                     \ && ((i == 0 && !nextblank)
 621                         \ || (i > 0 && ((indent(p) >= i
 622                             \ && !(nextblank && a:inner))
 623                             \ || (nextblank && !a:inner))))
 624                 -
 625                 let p = line(".") - 1
 626                 let nextblank = getline(p) =~ "^\\s*$"
 627             endwhile
 628             normal! 0V
 629             call cursor(curline, 0)
 630             let p = line(".") + 1
 631             let nextblank = getline(p) =~ "^\\s*$"
 632             while p <= lastline
 633                     \ && ((i == 0 && !nextblank)
 634                         \ || (i > 0 && ((indent(p) >= i
 635                             \ && !(nextblank && a:inner))
 636                             \ || (nextblank && !a:inner))))
 637                 +
 638                 let p = line(".") + 1
 639                 let nextblank = getline(p) =~ "^\\s*$"
 640             endwhile
 641             normal! $
 642         endif
 643     endfunction
 644 endif
 645
 646
 647 " ABBREVIATIONS
 648
 649 " Fix some of my spelling mistakes (German).
 650 inoreabbrev relle reelle
 651 inoreabbrev reele reelle
 652 " Fix some of my spelling mistakes (English).
 653 inoreabbrev completly completely
 654
 655
 656 " SYNTAX SETTINGS
 657
 658 " Activate syntax coloring.
 659 if has('syntax')
 660     syntax enable
 661
 662 " Don't highlight more than 500 columns as I normally don't have that long
 663 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 664 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 665     if exists('+synmaxcol')
 666         set synmaxcol=500
 667     endif
 668
 669 " Use (limited) syntax based omni completion if no other omni completion is
 670 " available. Taken from :help ft-syntax-omni.
 671     if has('autocmd') && exists('+omnifunc')
 672         augroup vimrc
 673             autocmd FileType *
 674                 \ if &omnifunc == '' |
 675                 \     setlocal omnifunc=syntaxcomplete#Complete |
 676                 \ endif
 677         augroup END
 678     endif
 679
 680 " Function to enable all custom highlights. Necessary as highlights are
 681 " window-local and thus must be set for each new window.
 682     function! s:CustomSyntaxHighlights()
 683         " Not the first time called, nothing to do.
 684         if exists('w:vimrc_syntax_run')
 685             return
 686         endif
 687         let w:vimrc_syntax_run = 1
 688
 689 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 690 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 691 " disabled when necessary with :2match (in Vim >= 700).
 692         if !&diff && exists(':2match')
 693             " Use ColorColumn for overlong lines if available and my color
 694             " scheme is used.
 695             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 696                 2match ColorColumn /\%>78v./
 697             else
 698                 2match Todo /\%>78v./
 699             endif
 700         elseif !&diff
 701             match Todo /\%>78v./
 702         endif
 703
 704         if exists('*matchadd')
 705 " Highlight some important keywords in all documents.
 706             let l:todos = ['TODO', 'XXX', 'FIXME',
 707                          \ 'CHANGED', 'REMOVED', 'DELETED']
 708             " Compatibility fix for Vim 6.4 which can't handle for in function
 709             " (without function it's ignored).
 710             execute '  for l:x in l:todos'
 711                   \ '|     call matchadd("Todo", l:x)'
 712                   \ '| endfor'
 713
 714 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 715             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 716                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 717                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 718                           \ '205f', '2060', '3000', 'feff']
 719             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 720             " it won't work!
 721             execute '  for l:x in l:spaces'
 722                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 723                   \ '| endfor'
 724
 725 " Special highlight for tabs to reduce their visibility in contrast to other
 726 " SpecialKey characters (e.g. ^L).
 727             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 728                 call matchadd('specialKeyTab', '\t')
 729             endif
 730         endif
 731     endfunction
 732 " Enable highlights for the current and all new windows. Thanks to bairui in
 733 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 734     call <SID>CustomSyntaxHighlights()
 735     if has('autocmd')
 736         augroup vimrc
 737             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 738         augroup END
 739     endif
 740
 741 " Settings for specific filetypes.
 742
 743     " C
 744     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 745     " Haskell.
 746     let g:hs_highlight_delimiters = 1
 747     let g:hs_highlight_boolean = 1
 748     let g:hs_highlight_types = 1
 749     let g:hs_highlight_more_types = 1
 750     " Perl.
 751     let g:perl_fold = 1
 752     let g:perl_fold_blocks = 1
 753     let g:perl_nofold_packages = 1
 754     let g:perl_include_pod = 1 " syntax coloring for PODs
 755     " Python.
 756     let g:python_highlight_all = 1
 757     " Shell.
 758     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 759     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 760     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 761     " Vim.
 762     let g:vimsyn_embed = 0      " don't highlight embedded languages
 763     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 764     " XML.
 765     let g:xml_syntax_folding = 1
 766 endif
 767
 768
 769 " PLUGIN SETTINGS
 770
 771 if has('eval')
 772 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 773 " installing/removing/updating plugins simple. (Used for plugins with more
 774 " than one file.) Ignore errors in case pathogen is not installed.
 775     if v:version >= 700
 776         silent! execute 'call pathogen#infect()'
 777     endif
 778
 779 " Settings for securemodelines.
 780     " Only allow items I need (also includes spl which is not enabled by
 781     " default).
 782     if v:version >= 700 " need lists
 783         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 784                                               \ 'sw', 'sts', 'noet']
 785     endif
 786
 787 " Settings for the NERD commenter.
 788     " Don't create any mappings I don't want to use.
 789     let g:NERDCreateDefaultMappings = 0
 790     " Map toggle comment.
 791     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 792
 793 " XPTemplate settings.
 794     " Try to maintain snippet rendering even after editing outside of a
 795     " snippet.
 796     let g:xptemplate_strict = 0
 797     " Don't complete any braces automatically.
 798     let g:xptemplate_brace_complete = 0
 799     " Only highlight the current placeholder.
 800     let g:xptemplate_highlight = 'current'
 801
 802 " CtrlP settings.
 803     " Don't manage the working directory (the default setting is too slow for
 804     " me).
 805     let g:ctrlp_working_path_mode = 0
 806     " Path to cache directory. I prefer to keep generated files as local as
 807     " possible.
 808     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 809     " Permanent cache, cleared by a crontab entry.
 810     let g:ctrlp_clear_cache_on_exit = 0
 811 endif
 812
 813
 814 " AUTO COMMANDS
 815
 816 " Use a custom auto group to prevent problems when the vimrc files is sourced
 817 " twice.
 818 if has('autocmd')
 819     augroup vimrc
 820
 821 " Go to last position of opened files. Taken from :help last-position-jump.
 822         autocmd BufReadPost *
 823             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 824             \     execute "normal! g'\"" |
 825             \ endif
 826 " But not for Git commits, go to beginning of the file.
 827         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 828
 829 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 830 " when switching to a help buffer which is in the background with :buffer as
 831 " these options are local to windows (and not only to buffers). This happens
 832 " because I often want to use only one window and thus the help buffer is in
 833 " the background.
 834         autocmd BufWinEnter *.txt
 835             \ if &filetype == 'help' |
 836             \     setlocal nolist |
 837             \     setlocal nonumber |
 838             \ endif
 839
 840 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 841 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 842 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 843 " doesn't exist in older Vims.
 844         if exists('##InsertLeave')
 845             autocmd InsertLeave * set nopaste
 846         endif
 847
 848 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 849 " doesn't exist in older Vims.
 850         if exists('##QuickFixCmdPre')
 851             autocmd QuickFixCmdPre * write
 852         endif
 853
 854 " Don't ignore case while in insert mode, but ignore case in all other modes.
 855 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 856 " capitalization. But while searching (/) 'ignorecase' is used.
 857 " InsertEnter/InsertLeave doesn't exist in older Vims.
 858         if exists('##InsertEnter') && exists('##InsertLeave')
 859             autocmd InsertEnter * set noignorecase
 860             autocmd InsertLeave * set   ignorecase
 861         endif
 862
 863 " Display a warning when editing a file which contains "do not edit" (ignoring
 864 " the case, \c), for example template files which were preprocessed or
 865 " auto-generated files. Especially useful when the header is not displayed on
 866 " the first screen, e.g. when the old position is restored. Not for vimrc
 867 " though.
 868         function! s:SearchForDoNotEditHeader()
 869             if search('\cdo not edit', 'n') == 0
 870                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 871                 return
 872             endif
 873
 874             echohl WarningMsg
 875             echo 'Do not edit this file! (Maybe a template file.)'
 876             echohl None
 877         endfunction
 878         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 879
 880 " AFTER/FTPLUGIN AUTO COMMANDS
 881
 882 " Disable spell checking for files which don't need it.
 883         autocmd FileType deb  setlocal nospell
 884         autocmd FileType diff setlocal nospell
 885         autocmd FileType tar  setlocal nospell
 886 " Fix to allow Vim edit crontab files as crontab doesn't work with
 887 " backupcopy=auto.
 888         autocmd FileType crontab setlocal backupcopy=yes
 889 " Don't use the modeline in git commits as the diff created by `git commit -v`
 890 " may contain one which could change the filetype or other settings of the
 891 " commit buffer. Also make sure we use only 72 characters per line which is
 892 " the recommendation for git commit messages (http://tpope.net/node/106).
 893         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 894                                  \ setlocal textwidth=72
 895 " Use the same comment string as for Vim files in Vimperator files.
 896         autocmd FileType vimperator setlocal commentstring=\"%s
 897 " Use TeX compiler for (La)TeX files.
 898         autocmd FileType tex compiler tex
 899
 900 " FTDETECT AUTO COMMANDS
 901
 902 " Recognize .md as markdown files (Vim default is .mkd).
 903         autocmd BufRead,BufNewFile *.md set filetype=mkd
 904 " Recognize .test as Tcl files.
 905         autocmd BufRead,BufNewFile *.test set filetype=tcl
 906
 907 " OTHER AUTO COMMANDS
 908
 909 " Disable spell checking, displaying of list characters and long lines when
 910 " viewing documentation.
 911         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 912
 913 " Use diff filetype for mercurial patches in patch queue.
 914         autocmd BufReadPost */.hg/patches/* set filetype=diff
 915
 916     augroup END
 917 endif
 918
 919
 920 " CUSTOM FUNCTIONS AND COMMANDS
 921
 922 if has('eval')
 923 " Convenient command to see the difference between the current buffer and the
 924 " file it was loaded from, thus the changes you made. Thanks to the
 925 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 926 " for the diffed file than the filetype for the original file.
 927     if !exists(':DiffOrig')
 928         command DiffOrig
 929             \ let s:diff_orig_filetype = &filetype
 930             \ | vertical new
 931             \ | let &filetype = s:diff_orig_filetype
 932             \ | unlet s:diff_orig_filetype
 933             \ | set buftype=nofile
 934             \ | read ++edit #
 935             \ | 0d_
 936             \ | diffthis
 937             \ | wincmd p
 938             \ | diffthis
 939     endif
 940 endif