vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Create new split windows on the right (and not left).
 109 set splitright
 110
 111 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 112 " is used multiple times. Necessary to support reloading the vimrc.
 113 if has('autocmd')
 114     augroup vimrc
 115         autocmd!
 116     augroup END
 117 endif
 118
 119
 120 " HELPER FUNCTIONS
 121
 122 if has('eval')
 123 " Check if the given syntax group is available. Thanks to bairui in #vim on
 124 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 125     function! s:HasSyntaxGroup(group)
 126         try
 127             execute 'silent highlight ' . a:group
 128         " \a = [A-Za-z]
 129         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 130             return 0
 131         endtry
 132         return 1
 133     endfunction
 134
 135 " Check if the given Vim version and patch is available.
 136     function! s:HasVersionAndPatch(version, patch)
 137         return v:version > a:version
 138             \ || (v:version == a:version && has('patch' . a:patch))
 139     endfunction
 140 endif
 141
 142
 143 " TERMINAL SETTINGS
 144
 145 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 146 " connections.
 147 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 148     set ttyfast
 149 endif
 150
 151
 152 " EDIT SETTINGS
 153
 154 " Enable automatic file detection, plugin and indention support.
 155 if has('autocmd')
 156     filetype off " necessary for pathogen to force a reload of ftplugins
 157     filetype plugin indent on
 158 endif
 159
 160 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 161 " existing files.
 162 set fileencodings=utf-8,latin1
 163
 164 " Always use unix line-endings for new files.
 165 set fileformats=unix,dos
 166
 167 " Wrap text after 78 characters.
 168 set textwidth=78
 169
 170 " Set tabs to 4 spaces, use softtabs.
 171 set shiftwidth=4
 172 set softtabstop=4
 173 set expandtab
 174 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 175 set shiftround
 176 " Use the default value for real tabs.
 177 set tabstop=8
 178
 179 " Enable auto indention.
 180 set autoindent
 181
 182 " When joining lines only add one space after a sentence.
 183 set nojoinspaces
 184
 185 " Allow backspacing over autoindent and line breaks.
 186 set backspace=indent,eol
 187
 188 " Start a comment when hitting enter after a commented line (r) and when using
 189 " o or O around a commented line (o).
 190 set formatoptions+=ro
 191 " Don't break a line if was already longer then 'textwidth' when insert mode
 192 " started.
 193 set formatoptions+=l
 194 " Remove comment leader when joining lines where it makes sense.
 195 if <SID>HasVersionAndPatch(703, 541)
 196     set formatoptions+=j
 197 endif
 198
 199 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 200 " no character) in visual block mode.
 201 set virtualedit=block
 202
 203 " Already display matches while typing the search command. This makes spotting
 204 " typos easy and searching faster.
 205 set incsearch
 206
 207 " Activate syntax folding.
 208 if has('folding')
 209     set foldmethod=syntax
 210     " Only use fold column if we have enough space (for example not in a
 211     " (virtual) terminal which has only 80 columns).
 212     if &columns > 80
 213         set foldcolumn=2
 214     endif
 215     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 216                      " folding which is not what I want
 217     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 218     set foldopen-=block
 219 endif
 220
 221 " Only check case if the searched word contains a capital character.
 222 set ignorecase
 223 set smartcase
 224
 225 " Activate spell checking, use English as default.
 226 if exists('+spell') && has('syntax')
 227     " But not when diffing because spell checking is distracting in this case.
 228     if !&diff
 229         set spell
 230     endif
 231     set spelllang=en_us
 232 endif
 233
 234 " Allow buffers with changes to be hidden. Very important for effective
 235 " editing with multiple buffers. Prevents the "E37: No write since last change
 236 " (add ! to override)" warning when switching buffers.
 237 set hidden
 238
 239
 240 " DISPLAY SETTINGS
 241
 242 " Use a dark background. Doesn't change the background color, only sets text
 243 " colors for a dark terminal.
 244 set background=dark
 245
 246 " Use my color scheme if 256 colors are available.
 247 if &t_Co == 256 || has('gui_running')
 248     colorscheme simon
 249 endif
 250
 251 " Display line numbers.
 252 set number
 253 " But use as little space as possible for the numbers column. Thanks to James
 254 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 255 if exists('+numberwidth')
 256     set numberwidth=1
 257 endif
 258 " Display the ruler with current line/file position. If 'statusline' is used
 259 " then this only affects <C-G>.
 260 set ruler
 261 " Display partial commands in the status line.
 262 set showcmd
 263
 264 " Don't redraw screen when executing macros; increases speed. Thanks to James
 265 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 266 set lazyredraw
 267
 268 " Visualize the line the cursor is currently in.
 269 if exists('+cursorline')
 270     set cursorline
 271 endif
 272
 273 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 274 " remove the highlighting until the next search.
 275 set hlsearch
 276
 277 " Display some special characters.
 278 set list
 279 set listchars=
 280 " Display tabs as ">--------".
 281 set listchars+=tab:>-
 282 " Display trailing whitespace as "-".
 283 set listchars+=trail:-
 284 " Display markers for long lines when wrapping is disabled.
 285 set listchars+=extends:>,precedes:<
 286 " Display non-breakable space as "!".
 287 if v:version >= 700
 288     set listchars+=nbsp:!
 289 endif
 290
 291 " Don't draw the vertical split separator by using space as character. Thanks
 292 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 293 " non-breakable space. But a simple space works as well, as long as the
 294 " current color scheme is not reset.
 295 if has('windows') && has('folding')
 296     set fillchars+=vert:\  " comment to prevent trailing whitespace
 297 endif
 298
 299 if has('statusline')
 300     " Always display the status line even if there is only one window.
 301     set laststatus=2
 302
 303     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 304     " is the highest buffer number, otherwise return nothing. Used in
 305     " 'statusline' to get an overview of available buffer numbers.
 306     function! StatuslineBufferCount()
 307         let l:bufnr = bufnr('$')
 308         if l:bufnr > 1
 309             let l:result = '/'
 310             if exists('*printf')
 311                 let l:result .= printf('%02d', l:bufnr)
 312             else
 313                 " Older Vims don't have printf() (and no .= either). Emulate
 314                 " "%02d".
 315                 if l:bufnr < 10
 316                     let l:result = l:result . '0'
 317                 endif
 318                 let l:result = l:result . l:bufnr
 319             endif
 320             return l:result
 321         else
 322             return ''
 323         endif
 324     endfunction
 325
 326     " Like %f but use relative filename if it's shorter than the absolute path
 327     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 328     " not enough because it doesn't create '../'s.
 329     function! StatuslineRelativeFilename()
 330         " Display only filename for help files.
 331         if &buftype == 'help'
 332             return expand('%:t')
 333         endif
 334         " Special case for scratch files.
 335         if &buftype == 'nofile'
 336             return '[Scratch]'
 337         endif
 338
 339         let l:path = expand('%')
 340         " No file.
 341         if l:path == ''
 342             return '[No Name]'
 343         endif
 344         " Path is already relative, nothing to do.
 345         if stridx(l:path, '/') != 0
 346             return l:path
 347         endif
 348
 349         " Absolute path to this file.
 350         let l:path = expand('%:p')
 351         " Shortened path to this file, thanks to bairui in #vim on Freenode
 352         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 353         " Vim normally uses as %f (minus some exceptions).
 354         let l:original_path = fnamemodify(l:path, ':~')
 355         " Absolute path to the current working directory.
 356         let l:cwd = getcwd()
 357
 358         " Working directory completely contained in path, replace it with a
 359         " relative path. Happens for example when opening a file with netrw.
 360         " %f displays this as absolute path, but we want a relative path of
 361         " course.
 362         if stridx(l:path, l:cwd) == 0
 363             return strpart(l:path, strlen(l:cwd) + 1)
 364         endif
 365
 366         let l:path_list = split(l:path, '/')
 367         let l:cwd_list  = split(l:cwd,  '/')
 368
 369         " Remove the common path.
 370         while l:path_list[0] == l:cwd_list[0]
 371             call remove(l:path_list, 0)
 372             call remove(l:cwd_list,  0)
 373         endwhile
 374
 375         " Add as many '..' as necessary for the relative path and join the
 376         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 377         " the hint to use repeat() instead of a loop.
 378         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 379
 380         " Use the shorter path, either relative or absolute.
 381         if strlen(l:path) < strlen(l:original_path)
 382             return l:path
 383         else
 384             return l:original_path
 385         endif
 386     endfunction
 387
 388     " Return current syntax group in brackets or nothing if there's none.
 389     function! StatuslineSyntaxGroup()
 390         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 391         if l:group != ''
 392             return '[' . l:group . '] '
 393         else
 394             return ''
 395         endif
 396     endfunction
 397
 398     set statusline=
 399     " on the left
 400     set statusline+=%02n  " buffer number
 401     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 402     set statusline+=:
 403     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 404         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 405         set statusline+=\     " space after path
 406     else
 407         set statusline+=%f\   " path to current file in buffer
 408     endif
 409     set statusline+=%h    " [help] if buffer is help file
 410     set statusline+=%w    " [Preview] if buffer is preview buffer
 411     set statusline+=%m    " [+] if buffer was modified,
 412                           " [-] if 'modifiable' is off
 413     set statusline+=%r    " [RO] if buffer is read only
 414
 415     " on the right
 416     set statusline+=%=                " right align
 417     set statusline+=0x%-8B\           " current character under cursor as hex
 418     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 419                                       " column number (%c),
 420                                       " virtual column number if different
 421                                       "                       than %c (%V)
 422     set statusline+=%P                " position in file in percent
 423 endif
 424
 425
 426 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 427
 428 " noremap is used to make sure the right side is executed as is and can't be
 429 " modified by a plugin or other settings. Except for <Nop> which isn't
 430 " affected by mappings.
 431
 432 " Easy way to exit insert mode. jk is preferred because it's faster.
 433 inoremap jj <Esc>
 434 inoremap jk <Esc>
 435 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 436 " (2010-10-15).
 437 cnoremap jj <C-C>
 438 cnoremap jk <C-C>
 439
 440 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 441 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 442 map <Right>  <Nop>
 443 map <Left>   <Nop>
 444 map <Up>     <Nop>
 445 map <Down>   <Nop>
 446 imap <Right> <Nop>
 447 imap <Left>  <Nop>
 448 imap <Up>    <Nop>
 449 imap <Down>  <Nop>
 450 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 451 " below).
 452 cmap <Up>    <Nop>
 453 cmap <Down>  <Nop>
 454 cmap <Right> <Nop>
 455 cmap <Left>  <Nop>
 456
 457 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 458 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 459 cnoremap <C-P> <Up>
 460 cnoremap <C-N> <Down>
 461
 462 if has('eval')
 463 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 464 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 465 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 466 " directly because it also enables that feature for other commands which I
 467 " don't want.
 468
 469     " Set 'nostartofline' for a single movement.
 470     function! s:TemporaryNostartofline(movement)
 471         let l:startofline = &startofline
 472         set nostartofline
 473         execute 'normal! ' . a:movement
 474         let &startofline = l:startofline
 475     endfunction
 476
 477     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 478     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 479     nnoremap <silent> <C-F>
 480         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 481     nnoremap <silent> <C-B>
 482         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 483     nnoremap <silent> <C-D>
 484         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 485     nnoremap <silent> <C-U>
 486         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 487 endif
 488
 489 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 490 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 491 " Only the current buffer is written, thus switching to another buffer works
 492 " too.
 493 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 494
 495 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 496 " in #vim on Freenode (2011-08-15 00:17 CEST).
 497 nnoremap <C-G> 2<C-G>
 498
 499 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 500 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 501 nmap <Space> <C-F>
 502 nmap - <C-B>
 503
 504 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 505 " (2010-05-16 18:38 CEST) for this idea.
 506 nnoremap <silent> gb :bnext<CR>
 507 nnoremap <silent> gB :bprevious<CR>
 508 if has('eval')
 509     " But when starting again at the first buffer, print a warning which
 510     " reminds me that I've already seen that buffer.
 511     function! s:NextBuffer()
 512         " Are we currently on the last buffer and moving to the first?
 513         let l:last_buffer = 0
 514         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 515             let l:last_buffer = 1
 516         endif
 517
 518         " Go to the next buffer.
 519         if !l:last_buffer
 520             bnext
 521
 522         " Go to the first buffer, silent is necessary or the following message
 523         " won't be displayed because it's overwritten by the status message
 524         " displayed when entering a buffer.
 525         else
 526             silent bnext
 527
 528             echohl WarningMsg
 529             echo 'Starting again at first buffer.'
 530             echohl None
 531         endif
 532     endfunction
 533     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 534 endif
 535
 536 " Fast access to buffers.
 537 nnoremap <silent> <Leader>1 :1buffer<CR>
 538 nnoremap <silent> <Leader>2 :2buffer<CR>
 539 nnoremap <silent> <Leader>3 :3buffer<CR>
 540 nnoremap <silent> <Leader>4 :4buffer<CR>
 541 nnoremap <silent> <Leader>5 :5buffer<CR>
 542 nnoremap <silent> <Leader>6 :6buffer<CR>
 543 nnoremap <silent> <Leader>7 :7buffer<CR>
 544 nnoremap <silent> <Leader>8 :8buffer<CR>
 545 nnoremap <silent> <Leader>9 :9buffer<CR>
 546 nnoremap <silent> <Leader>0 :10buffer<CR>
 547
 548 " Make last active window the only window. Similar to <C-W> o.
 549 nnoremap <C-W>O <C-W>p<C-W>o
 550
 551 " Maps to change spell language between English and German and disable spell
 552 " checking.
 553 if exists('+spell')
 554     nnoremap <silent> <Leader>sn :set nospell<CR>
 555     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 556     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 557 " If no spell support is available, these mappings do nothing.
 558 else
 559     nmap <Leader>sn <Nop>
 560     nmap <Leader>se <Nop>
 561     nmap <Leader>sd <Nop>
 562 endif
 563
 564 " Add semicolon to the end of the line. Thanks to
 565 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 566 " on Freenode for an improved version which doesn't clobber any marks.
 567 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 568
 569 " * and # for selections in visual mode. Thanks to
 570 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 571 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 572 if has('eval')
 573     function! s:VSetSearch()
 574         let l:temp = @@
 575         normal! gvy
 576         " Added \C to force 'noignorecase' while searching the current visual
 577         " selection. I want to search for the exact string in this case.
 578         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 579         let @@ = l:temp
 580     endfunction
 581     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 582     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 583 endif
 584
 585 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 586 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 587 " mailing list for the commands.
 588 if v:version < 700
 589     cnoreabbrev W w
 590     cnoreabbrev Wa wa
 591     cnoreabbrev Wq wq
 592     cnoreabbrev Wqa wqa
 593 else
 594     cnoreabbrev <expr> W
 595         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 596     cnoreabbrev <expr> Wa
 597         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 598     cnoreabbrev <expr> Wq
 599         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 600     cnoreabbrev <expr> Wqa
 601         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 602 endif
 603 " Also fix my typo with "Q".
 604 if v:version < 700
 605     cnoreabbrev Q q
 606     cnoreabbrev Qa qa
 607 else
 608     cnoreabbrev <expr> Q
 609         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 610     cnoreabbrev <expr> Qa
 611         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 612 endif
 613
 614 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 615 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 616 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 617
 618 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 619 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 620 " Vim's source.
 621 inoremap <C-U> <C-G>u<C-U>
 622 " Same for <C-@> (insert previously inserted text and leave insert mode).
 623 inoremap <C-@> <C-G>u<C-@>
 624 " And for <C-A> (insert previously inserted text).
 625 inoremap <C-A> <C-G>u<C-A>
 626 " And for <C-W> (delete word before cursor).
 627 inoremap <C-W> <C-G>u<C-W>
 628
 629 if has('eval')
 630 " New text-objects ii and ai to work on text with the same indentation. Thanks
 631 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 632 " (visited on 2011-11-19).
 633     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 634     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 635     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 636     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 637
 638     function! s:IndTxtObj(inner)
 639         let curline = line(".")
 640         let lastline = line("$")
 641         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 642         let i = i < 0 ? 0 : i
 643         if getline(".") !~ "^\\s*$"
 644             let p = line(".") - 1
 645             let nextblank = getline(p) =~ "^\\s*$"
 646             while p > 0
 647                     \ && ((i == 0 && !nextblank)
 648                         \ || (i > 0 && ((indent(p) >= i
 649                             \ && !(nextblank && a:inner))
 650                             \ || (nextblank && !a:inner))))
 651                 -
 652                 let p = line(".") - 1
 653                 let nextblank = getline(p) =~ "^\\s*$"
 654             endwhile
 655             normal! 0V
 656             call cursor(curline, 0)
 657             let p = line(".") + 1
 658             let nextblank = getline(p) =~ "^\\s*$"
 659             while p <= lastline
 660                     \ && ((i == 0 && !nextblank)
 661                         \ || (i > 0 && ((indent(p) >= i
 662                             \ && !(nextblank && a:inner))
 663                             \ || (nextblank && !a:inner))))
 664                 +
 665                 let p = line(".") + 1
 666                 let nextblank = getline(p) =~ "^\\s*$"
 667             endwhile
 668             normal! $
 669         endif
 670     endfunction
 671 endif
 672
 673
 674 " ABBREVIATIONS
 675
 676 " Fix some of my spelling mistakes (German).
 677 inoreabbrev relle reelle
 678 inoreabbrev reele reelle
 679 " Fix some of my spelling mistakes (English).
 680 inoreabbrev completly completely
 681
 682
 683 " SYNTAX SETTINGS
 684
 685 " Activate syntax coloring.
 686 if has('syntax')
 687     syntax enable
 688
 689 " Don't highlight more than 500 columns as I normally don't have that long
 690 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 691 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 692     if exists('+synmaxcol')
 693         set synmaxcol=500
 694     endif
 695
 696 " Use (limited) syntax based omni completion if no other omni completion is
 697 " available. Taken from :help ft-syntax-omni.
 698     if has('autocmd') && exists('+omnifunc')
 699         augroup vimrc
 700             autocmd FileType *
 701                 \ if &omnifunc == '' |
 702                 \     setlocal omnifunc=syntaxcomplete#Complete |
 703                 \ endif
 704         augroup END
 705     endif
 706
 707 " Function to enable all custom highlights. Necessary as highlights are
 708 " window-local and thus must be set for each new window.
 709     function! s:CustomSyntaxHighlights()
 710         " Not the first time called, nothing to do.
 711         if exists('w:vimrc_syntax_run')
 712             return
 713         endif
 714         let w:vimrc_syntax_run = 1
 715
 716 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 717 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 718 " disabled when necessary with :2match (in Vim >= 700).
 719         if !&diff && exists(':2match')
 720             " Use ColorColumn for overlong lines if available and my color
 721             " scheme is used.
 722             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 723                 2match ColorColumn /\%>78v./
 724             else
 725                 2match Todo /\%>78v./
 726             endif
 727         elseif !&diff
 728             match Todo /\%>78v./
 729         endif
 730
 731         if exists('*matchadd')
 732 " Highlight some important keywords in all documents.
 733             let l:todos = ['TODO', 'XXX', 'FIXME',
 734                          \ 'CHANGED', 'REMOVED', 'DELETED']
 735             " Compatibility fix for Vim 6.4 which can't handle for in function
 736             " (without function it's ignored).
 737             execute '  for l:x in l:todos'
 738                   \ '|     call matchadd("Todo", l:x)'
 739                   \ '| endfor'
 740
 741 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 742             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 743                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 744                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 745                           \ '205f', '2060', '3000', 'feff']
 746             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 747             " it won't work!
 748             execute '  for l:x in l:spaces'
 749                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 750                   \ '| endfor'
 751
 752 " Special highlight for tabs to reduce their visibility in contrast to other
 753 " SpecialKey characters (e.g. ^L).
 754             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 755                 call matchadd('specialKeyTab', '\t')
 756             endif
 757         endif
 758     endfunction
 759 " Enable highlights for the current and all new windows. Thanks to bairui in
 760 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 761     call <SID>CustomSyntaxHighlights()
 762     if has('autocmd')
 763         augroup vimrc
 764             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 765         augroup END
 766     endif
 767
 768 " Settings for specific filetypes.
 769
 770     " C
 771     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 772     " Haskell.
 773     let g:hs_highlight_delimiters = 1
 774     let g:hs_highlight_boolean = 1
 775     let g:hs_highlight_types = 1
 776     let g:hs_highlight_more_types = 1
 777     " Java.
 778     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 779     " Perl.
 780     let g:perl_fold = 1
 781     let g:perl_fold_blocks = 1
 782     let g:perl_nofold_packages = 1
 783     let g:perl_include_pod = 1 " syntax coloring for PODs
 784     " PHP.
 785     let g:php_folding = 3    " fold functions
 786     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 787     let g:php_sql_query = 1  " highlight SQL queries in strings
 788     " Python.
 789     let g:python_highlight_all = 1
 790     " Shell.
 791     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 792     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 793     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 794     " Vim.
 795     let g:vimsyn_embed = 0      " don't highlight embedded languages
 796     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 797     " XML.
 798     let g:xml_syntax_folding = 1
 799 endif
 800
 801
 802 " PLUGIN SETTINGS
 803
 804 if has('eval')
 805 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 806 " installing/removing/updating plugins simple. (Used for plugins with more
 807 " than one file.) Ignore errors in case pathogen is not installed.
 808     if v:version >= 700
 809         silent! execute 'call pathogen#infect()'
 810     endif
 811
 812 " Settings for securemodelines.
 813     " Only allow items I need (also includes spl which is not enabled by
 814     " default).
 815     if v:version >= 700 " need lists
 816         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 817                                               \ 'sw', 'sts', 'noet']
 818     endif
 819
 820 " Settings for the NERD commenter.
 821     " Don't create any mappings I don't want to use.
 822     let g:NERDCreateDefaultMappings = 0
 823     " Map toggle comment.
 824     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 825
 826 " XPTemplate settings.
 827     " Try to maintain snippet rendering even after editing outside of a
 828     " snippet.
 829     let g:xptemplate_strict = 0
 830     " Don't complete any braces automatically.
 831     let g:xptemplate_brace_complete = 0
 832     " Only highlight the current placeholder.
 833     let g:xptemplate_highlight = 'current'
 834
 835 " CtrlP settings.
 836     " Don't manage the working directory (the default setting is too slow for
 837     " me).
 838     let g:ctrlp_working_path_mode = 0
 839     " Path to cache directory. I prefer to keep generated files as local as
 840     " possible.
 841     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 842     " Permanent cache, cleared by a crontab entry.
 843     let g:ctrlp_clear_cache_on_exit = 0
 844
 845 " FSWitch settings.
 846     " Default don't work well for my projects.
 847     augroup vimrc
 848         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 849                           \ | let b:fswitchlocs = './'
 850         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 851                           \ | let b:fswitchlocs = './'
 852     augroup END
 853
 854     " Switch to corresponding header/source file.
 855     nnoremap <silent> <Leader>h :FSHere<CR>
 856 endif
 857
 858
 859 " AUTO COMMANDS
 860
 861 " Use a custom auto group to prevent problems when the vimrc files is sourced
 862 " twice.
 863 if has('autocmd')
 864     augroup vimrc
 865
 866 " Go to last position of opened files. Taken from :help last-position-jump.
 867         autocmd BufReadPost *
 868             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 869             \     execute "normal! g'\"" |
 870             \ endif
 871 " But not for Git commits, go to beginning of the file.
 872         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 873
 874 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 875 " when switching to a help buffer which is in the background with :buffer as
 876 " these options are local to windows (and not only to buffers). This happens
 877 " because I often want to use only one window and thus the help buffer is in
 878 " the background.
 879         autocmd BufWinEnter *.txt
 880             \ if &filetype == 'help' |
 881             \     setlocal nolist |
 882             \     setlocal nonumber |
 883             \ endif
 884
 885 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 886 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 887 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 888 " doesn't exist in older Vims.
 889         if exists('##InsertLeave')
 890             autocmd InsertLeave * set nopaste
 891         endif
 892
 893 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 894 " doesn't exist in older Vims.
 895         if exists('##QuickFixCmdPre')
 896             autocmd QuickFixCmdPre * write
 897         endif
 898
 899 " Don't ignore case while in insert mode, but ignore case in all other modes.
 900 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 901 " capitalization. But while searching (/) 'ignorecase' is used.
 902 " InsertEnter/InsertLeave doesn't exist in older Vims.
 903         if exists('##InsertEnter') && exists('##InsertLeave')
 904             autocmd InsertEnter * set noignorecase
 905             autocmd InsertLeave * set   ignorecase
 906         endif
 907
 908 " Display a warning when editing a file which contains "do not edit" (ignoring
 909 " the case, \c), for example template files which were preprocessed or
 910 " auto-generated files. Especially useful when the header is not displayed on
 911 " the first screen, e.g. when the old position is restored. Not for vimrc
 912 " though.
 913         function! s:SearchForDoNotEditHeader()
 914             if search('\cdo not edit', 'n') == 0
 915                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 916                 return
 917             endif
 918
 919             echohl WarningMsg
 920             echo 'Do not edit this file! (Maybe a template file.)'
 921             echohl None
 922         endfunction
 923         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 924
 925 " AFTER/FTPLUGIN AUTO COMMANDS
 926
 927 " Disable spell checking for files which don't need it.
 928         autocmd FileType deb  setlocal nospell
 929         autocmd FileType diff setlocal nospell
 930         autocmd FileType tar  setlocal nospell
 931 " Fix to allow Vim edit crontab files as crontab doesn't work with
 932 " backupcopy=auto.
 933         autocmd FileType crontab setlocal backupcopy=yes
 934 " Don't use the modeline in git commits as the diff created by `git commit -v`
 935 " may contain one which could change the filetype or other settings of the
 936 " commit buffer. Also make sure we use only 72 characters per line which is
 937 " the recommendation for git commit messages (http://tpope.net/node/106).
 938         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 939                                  \ setlocal textwidth=72
 940 " Use the same comment string as for Vim files in Vimperator files.
 941         autocmd FileType vimperator setlocal commentstring=\"%s
 942 " Use TeX compiler for (La)TeX files.
 943         autocmd FileType tex compiler tex
 944
 945 " FTDETECT AUTO COMMANDS
 946
 947 " Recognize .md as markdown files (Vim default is .mkd).
 948         autocmd BufRead,BufNewFile *.md set filetype=mkd
 949 " Recognize .test as Tcl files.
 950         autocmd BufRead,BufNewFile *.test set filetype=tcl
 951
 952 " OTHER AUTO COMMANDS
 953
 954 " Disable spell checking, displaying of list characters and long lines when
 955 " viewing documentation.
 956         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 957
 958 " Use diff filetype for mercurial patches in patch queue.
 959         autocmd BufReadPost */.hg/patches/* set filetype=diff
 960
 961     augroup END
 962 endif
 963
 964
 965 " CUSTOM FUNCTIONS AND COMMANDS
 966
 967 if has('eval')
 968 " Convenient command to see the difference between the current buffer and the
 969 " file it was loaded from, thus the changes you made. Thanks to the
 970 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 971 " for the diffed file than the filetype for the original file.
 972     if !exists(':DiffOrig')
 973         command DiffOrig
 974             \ let s:diff_orig_filetype = &filetype
 975             \ | vertical new
 976             \ | let &filetype = s:diff_orig_filetype
 977             \ | unlet s:diff_orig_filetype
 978             \ | set buftype=nofile
 979             \ | read ++edit #
 980             \ | 0d_
 981             \ | diffthis
 982             \ | wincmd p
 983             \ | diffthis
 984     endif
 985 endif