vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37 " But store them in ~/.tmp if available.
  38 set directory^=~/.tmp
  39
  40 " Disable modelines as they may cause security problems. Instead use
  41 " securemodelines (Vim script #1876).
  42 set nomodeline
  43
  44 " Complete to longest common string (list:longest) and then complete all full
  45 " matches after another (full). Thanks to pbrisbin
  46 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  47 set wildmode=list:longest,full
  48
  49 " Increase history of executed commands (:).
  50 set history=1000
  51
  52 " Increase number of possible undos.
  53 set undolevels=1000
  54
  55 " Use strong encryption if possible, also used for swap/undo files.
  56 if exists('+cryptmethod')
  57     set cryptmethod=blowfish
  58 endif
  59
  60
  61 " EDIT SETTINGS
  62
  63 " Enable automatic file detection, plugin and indention support.
  64 if has('autocmd')
  65     filetype off " necessary for pathogen to force a reload of ftplugins
  66     filetype plugin indent on
  67 endif
  68
  69 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  70 " existing files.
  71 set fileencodings=utf-8,latin1
  72
  73 " Wrap text after 78 characters.
  74 set textwidth=78
  75
  76 " Set tabs to 4 spaces, use softtabs.
  77 set shiftwidth=4
  78 set softtabstop=4
  79 set expandtab
  80 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  81 set shiftround
  82 " Use the default value for real tabs.
  83 set tabstop=8
  84
  85 " Enable auto indention.
  86 set autoindent
  87
  88 " When joining lines only add one space after a sentence.
  89 set nojoinspaces
  90
  91 " Allow backspacing over autoindent and line breaks.
  92 set backspace=indent,eol
  93
  94 " Start a comment when hitting enter after a commented line (r) and when using
  95 " o or O around a commented line (o).
  96 set formatoptions+=ro
  97 " Don't break a line if was already longer then 'textwidth' when insert mode
  98 " started.
  99 set formatoptions+=l
 100
 101 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 102 " no character) in visual block mode.
 103 set virtualedit=block
 104
 105 " Already display matches while typing the search command. This makes spotting
 106 " errors easy.
 107 set incsearch
 108
 109 " Activate syntax folding.
 110 if has('folding')
 111     set foldmethod=syntax
 112     set foldcolumn=2
 113     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 114                      " folding which is not what I want
 115 endif
 116
 117 " Only check for case if the searched word contains a capital character.
 118 set ignorecase
 119 set smartcase
 120
 121 " Activate spell checking, use English as default. Don't use spell checking
 122 " when diffing.
 123 if exists('+spell') && has('syntax') && !&diff
 124     set spell
 125     set spelllang=en_us
 126 endif
 127
 128 " Allow buffers with changes to be hidden. Very important for effective
 129 " editing with multiple buffers.
 130 set hidden
 131
 132
 133 " DISPLAY SETTINGS
 134
 135 " Use a dark background. Doesn't change the background color, only sets text
 136 " colors for a dark terminal.
 137 set background=dark
 138
 139 " Display line numbers.
 140 set number
 141 " But use as little space as necessary for the numbers column. Thanks to James
 142 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 143 if exists('+numberwidth')
 144     set numberwidth=1
 145 endif
 146 " Display the ruler with current line/file position. If 'statusline' is used
 147 " then this only affects <C-G>.
 148 set ruler
 149 " Display partial commands in the status line.
 150 set showcmd
 151
 152 " Don't redraw screen when executing macros; increases speed. Thanks to James
 153 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 154 set lazyredraw
 155
 156 " Visualize the line the cursor is currently in.
 157 if exists('+cursorline')
 158     set cursorline
 159 endif
 160
 161 " Display tabs, trailing space, non breakable spaces and long lines (when
 162 " wrapping is disabled).
 163 set list
 164 set listchars=trail:-,extends:>
 165 if v:version >= 700
 166     set listchars+=nbsp:!
 167 endif
 168
 169 if has('statusline')
 170     " Always display the status line even if there is only one window.
 171     set laststatus=2
 172
 173     set statusline=
 174     " on the left
 175     set statusline+=%02n: " buffer number
 176     set statusline+=%f\   " path to current file in buffer
 177     set statusline+=%h    " [help] if buffer is help file
 178     set statusline+=%w    " [Preview] if buffer is preview buffer
 179     set statusline+=%m    " [+] if buffer was modified,
 180                           " [-] if 'modifiable' is off
 181     set statusline+=%r    " [RO] if buffer is read only
 182
 183     " on the right
 184     set statusline+=%=                " right align
 185     set statusline+=0x%-8B\           " current character under cursor as hex
 186     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 187                                       " column number (%c),
 188                                       " virtual column number if different
 189                                       "                       than %c (%V)
 190     set statusline+=%P                " position in file in percent
 191 endif
 192
 193
 194 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 195
 196 " Easy way to exit insert mode.
 197 inoremap jj <Esc>
 198 inoremap jk <Esc>
 199 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 200 " (2010-10-15).
 201 cnoremap jj <C-C>
 202 cnoremap jk <C-C>
 203
 204 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 205 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 206 map <Right>  <Nop>
 207 map <Left>   <Nop>
 208 map <Up>     <Nop>
 209 map <Down>   <Nop>
 210 imap <Right> <Nop>
 211 imap <Left>  <Nop>
 212 imap <Up>    <Nop>
 213 imap <Down>  <Nop>
 214 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 215 " below).
 216 cmap <Up>    <Nop>
 217 cmap <Down>  <Nop>
 218 cmap <Right> <Nop>
 219 cmap <Left>  <Nop>
 220
 221 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 222 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 223 cnoremap <C-P> <Up>
 224 cnoremap <C-N> <Down>
 225
 226 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 227 " 20:02 CEST). To suspend without saving either unmap it or use :stop<CR>.
 228 nnoremap <C-Z> :update<CR>:stop<CR>
 229
 230 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 231 " in #vim on Freenode (2011-08-15 00:17 CEST).
 232 nnoremap <C-G> 2<C-G>
 233
 234 " Use <Space> to move down a page and - to move up one like in mutt.
 235 nnoremap <Space> <C-F>
 236 nnoremap - <C-B>
 237
 238 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 239 " (2010-05-16 18:38 CEST) for this idea.
 240 nnoremap <silent> gb :bnext<CR>
 241 nnoremap <silent> gB :bprev<CR>
 242
 243 " Fast access to buffers.
 244 nnoremap <Leader>1 :1b<CR>
 245 nnoremap <Leader>2 :2b<CR>
 246 nnoremap <Leader>3 :3b<CR>
 247 nnoremap <Leader>4 :4b<CR>
 248 nnoremap <Leader>5 :5b<CR>
 249 nnoremap <Leader>6 :6b<CR>
 250 nnoremap <Leader>7 :7b<CR>
 251 nnoremap <Leader>8 :8b<CR>
 252 nnoremap <Leader>9 :9b<CR>
 253 nnoremap <Leader>0 :10b<CR>
 254
 255 " Make last active window the only window. Similar to <C-w> o.
 256 nnoremap <C-W>O <C-W>p<C-W>o
 257
 258 " Maps to change spell language between English and German and disable spell
 259 " checking.
 260 if exists('+spell')
 261     noremap <Leader>sn :set nospell<CR>
 262     noremap <Leader>se :set spell spelllang=en_us<CR>
 263     noremap <Leader>sd :set spell spelllang=de_de<CR>
 264 endif
 265
 266 " Add semicolon to the end of the line. Thanks to
 267 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 268 " on Freenode for an improved version which doesn't clobber any marks.
 269 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 270
 271 " * and # for selections in visual mode. Thanks to
 272 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 273 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 274 if has('eval')
 275     function! s:VSetSearch()
 276         let temp = @@
 277         normal! gvy
 278         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 279         let @@ = temp
 280     endfunction
 281     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 282     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 283 endif
 284
 285 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 286 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 287 " mailing list for the commands.
 288 if v:version < 700
 289     cnoreabbrev W w
 290     cnoreabbrev Wa wa
 291     cnoreabbrev Wq wq
 292     cnoreabbrev Wqa wqa
 293 else
 294     cnoreabbrev <expr> W
 295         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 296     cnoreabbrev <expr> Wa
 297         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 298     cnoreabbrev <expr> Wq
 299         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 300     cnoreabbrev <expr> Wqa
 301         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 302 endif
 303 " Also fix my typo with "Q".
 304 if v:version < 700
 305     cnoreabbrev Q q
 306     cnoreabbrev Qa qa
 307 else
 308     cnoreabbrev <expr> Q
 309         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 310     cnoreabbrev <expr> Qa
 311         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 312 endif
 313
 314 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 315 " if pressed accidentally while in insert mode (happens on Mac when alt
 316 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 317 " no longer set on the console.
 318 if has('mac') || filereadable('/Users/.localized')
 319     inoremap <Char-0xa0> <Space>
 320 endif
 321
 322 " Disable Apple style movements in MacVim.
 323 if has('gui_macvim') && has('eval')
 324     let macvim_skip_cmd_opt_movement = 1
 325 endif
 326
 327 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 328 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 329 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 330
 331
 332 " ABBREVIATIONS
 333
 334 " Fix some of my spelling mistakes.
 335 iabbrev relle reelle
 336 iabbrev reele reelle
 337
 338
 339 " SYNTAX SETTINGS
 340
 341 " Activate syntax coloring.
 342 if has('syntax')
 343     syntax enable
 344
 345 " Don't highlight more than 500 columns as I normally don't have that long
 346 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 347 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 348     if exists('+synmaxcol')
 349         set synmaxcol=500
 350     endif
 351
 352 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 353 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 354 " disabled when necessary with :2match (in Vim >= 700).
 355     if exists(':2match')
 356         2match Todo /\%>78v./
 357     else
 358         match Todo /\%>78v./
 359     endif
 360
 361     if exists('*matchadd')
 362 " Highlight some important keywords in all documents.
 363         for x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 364             call matchadd('Todo', x)
 365         endfor
 366
 367 " Highlight unicode whitespace which is no normal whitespace (0x20).
 368         for x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 369                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 370                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 371                 \ 'feff']
 372             call matchadd('Error', '\%u' . x)
 373         endfor
 374     endif
 375
 376 " Settings for specific filetypes.
 377
 378     " Perl.
 379     let g:perl_fold = 1
 380     let g:perl_fold_blocks = 1
 381     let g:perl_nofold_packages = 1
 382     let g:perl_include_pod = 1 " syntax coloring for PODs
 383
 384 endif
 385
 386
 387 " PLUGIN SETTINGS
 388
 389 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 390 " installing/removing/updating plugins simple. (Used for plugins with more
 391 " than one file.)
 392 if has('eval') && v:version >= 700
 393     execute 'call pathogen#runtime_append_all_bundles()'
 394 endif
 395
 396 " Settings for the NERD commenter.
 397 " Don't create any mappings I don't want to use.
 398 if has('eval')
 399     let NERDCreateDefaultMappings = 0
 400 endif
 401 " Map toggle comment.
 402 map <Leader><Leader> <Plug>NERDCommenterToggle
 403
 404 " XPTemplate settings.
 405 if has('eval')
 406     " Try to maintain snippet rendering even after editing outside of a
 407     " snippet.
 408     let g:xptemplate_strict = 0
 409     " Don't complete any braces automatically.
 410     let g:xptemplate_brace_complete = 0
 411     " Only highlight the current placeholder.
 412     let g:xptemplate_highlight = 'current'
 413 endif
 414
 415
 416 " AUTO COMMANDS
 417
 418 " Use a custom auto group to prevent problems when the vimrc files is sourced
 419 " twice.
 420 if has('autocmd')
 421     augroup vimrc
 422 " Remove all autocmds from the current group.
 423         autocmd!
 424
 425 " Go to last position of opened files. Taken from :help last-position-jump.
 426         autocmd BufReadPost *
 427             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 428             \     execute "normal! g'\"" |
 429             \ endif
 430 " But not for Git commits, go to beginning of the file.
 431         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 432
 433 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 434 " when switching to a help buffer which is in the background with :buffer as
 435 " these options are local to windows (and not only to buffers). This happens
 436 " because I often want to use only one window and thus the help buffer is in
 437 " the background.
 438         autocmd BufWinEnter *.txt
 439             \ if &filetype == 'help' |
 440             \     setlocal nolist |
 441             \     setlocal nonumber |
 442             \ endif
 443
 444 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 445 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 446 " want to paste once and then 'paste' gets automatically unset.
 447         if exists('##InsertLeave')
 448             autocmd InsertLeave * set nopaste
 449         endif
 450
 451 " Save changes when running :mak[e] before 'makeprg' is called.
 452         autocmd QuickFixCmdPre * write
 453
 454 " AFTER/FTPLUGIN AUTO COMMANDS
 455
 456 " Disable spell checking for files which don't need it.
 457         autocmd FileType deb  setlocal nospell
 458         autocmd FileType diff setlocal nospell
 459         autocmd FileType tar  setlocal nospell
 460 " Fix to allow Vim edit crontab files as crontab doesn't work with
 461 " backupcopy=auto.
 462         autocmd FileType crontab setlocal backupcopy=yes
 463 " Don't use the modeline in git commits as the diff created by `git commit -v`
 464 " may contain one which could change the filetype or other settings of the
 465 " commit buffer. Also make sure we use only 72 characters per line which is
 466 " the recommendation for git commit messages (http://tpope.net/node/106).
 467         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 468                                  \ setlocal textwidth=72
 469 " Use the same comment string as for Vim files in Vimperator files.
 470         autocmd FileType vimperator setlocal commentstring=\"%s
 471 " Use tex compiler for (La)TeX files.
 472         autocmd FileType tex compiler tex
 473
 474 " FTDETECT AUTO COMMANDS
 475
 476 " Recognize .md as markdown files (Vim default is .mkd).
 477         autocmd BufRead,BufNewFile *.md set filetype=mkd
 478 " Recognize .test as Tcl files.
 479         autocmd BufRead,BufNewFile *.test set filetype=tcl
 480
 481 " OTHER AUTO COMMANDS
 482
 483 " Disable spell checking, displaying of list characters and long lines when
 484 " viewing documentation.
 485         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 486
 487 " Use diff filetype for mercurial patches in patch queue.
 488         autocmd BufReadPost */.hg/patches/* set filetype=diff
 489
 490     augroup END
 491 endif
 492
 493
 494 " CUSTOM FUNCTIONS
 495
 496 if has('eval')
 497     " New text-objects ii and ai to work on text with the same indentation.
 498     " Thanks to
 499     " http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 500     " (visited on 2011-11-19).
 501     onoremap <silent>ai :<C-u>call IndTxtObj(0)<CR>
 502     onoremap <silent>ii :<C-u>call IndTxtObj(1)<CR>
 503     vnoremap <silent>ai :<C-u>call IndTxtObj(0)<CR><Esc>gv
 504     vnoremap <silent>ii :<C-u>call IndTxtObj(1)<CR><Esc>gv
 505
 506     function! IndTxtObj(inner)
 507         let curline = line(".")
 508         let lastline = line("$")
 509         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 510         let i = i < 0 ? 0 : i
 511         if getline(".") !~ "^\\s*$"
 512             let p = line(".") - 1
 513             let nextblank = getline(p) =~ "^\\s*$"
 514             while p > 0
 515                     \ && ((i == 0 && !nextblank)
 516                         \ || (i > 0 && ((indent(p) >= i
 517                             \ && !(nextblank && a:inner))
 518                             \ || (nextblank && !a:inner))))
 519                 -
 520                 let p = line(".") - 1
 521                 let nextblank = getline(p) =~ "^\\s*$"
 522             endwhile
 523             normal! 0V
 524             call cursor(curline, 0)
 525             let p = line(".") + 1
 526             let nextblank = getline(p) =~ "^\\s*$"
 527             while p <= lastline
 528                     \ && ((i == 0 && !nextblank)
 529                         \ || (i > 0 && ((indent(p) >= i
 530                             \ && !(nextblank && a:inner))
 531                             \ || (nextblank && !a:inner))))
 532                 +
 533                 let p = line(".") + 1
 534                 let nextblank = getline(p) =~ "^\\s*$"
 535             endwhile
 536             normal! $
 537         endif
 538     endfunction
 539
 540 endif