vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2013  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  45 " affect reading files in different encodings, see 'fileencodings' for that.
  46 set encoding=utf-8
  47
  48 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  49 " runtime files) if available.
  50 set runtimepath-=~/.vim
  51 set runtimepath^=~/.vim,~/.vim/runtime
  52
  53 " Don't store swap files in the same directory as the edited file, but only if
  54 " we have a "safe" writable directory available.
  55 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  56     set directory-=.
  57 endif
  58 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  59 set directory^=~/.tmp
  60
  61 " Disable modelines as they may cause security problems. Instead use
  62 " securemodelines (Vim script #1876).
  63 set nomodeline
  64
  65 " Complete to longest common string (list:longest) and then complete all full
  66 " matches after another (full). Thanks to pbrisbin
  67 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  68 set wildmode=list:longest,full
  69 " Ignore case when completing files/directories.
  70 if exists('+wildignorecase')
  71     set wildignorecase
  72 endif
  73
  74 " Ignore files with the following extensions because I almost never want to
  75 " edit them in Vim (specifying them manually still works of course).
  76 set wildignore=
  77 " C
  78 set wildignore+=*.o,*.d,*.so
  79 " Java
  80 set wildignore+=*.class
  81 " LaTeX
  82 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  83 " Python
  84 set wildignore+=*.pyc
  85
  86 " Show completion menu even if only one entry matches.
  87 if exists('+completeopt')
  88     set completeopt+=menuone
  89 endif
  90
  91 " Increase history of executed commands (:) and search patterns (/).
  92 set history=1000
  93
  94 " Increase number of possible undos.
  95 set undolevels=1000
  96
  97 " Remember marks (including the last cursor position) for more files. ^= is
  98 " necessary because 'viminfo' is parsed from the beginning and the first match
  99 " is used.
 100 if has('viminfo')
 101     set viminfo^='1000
 102 endif
 103
 104 " Use strong encryption if possible, also used for swap/undo files.
 105 if exists('+cryptmethod')
 106     set cryptmethod=blowfish
 107 endif
 108
 109 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 110 " is used multiple times. Necessary to support reloading the vimrc.
 111 if has('autocmd')
 112     augroup vimrc
 113         autocmd!
 114     augroup END
 115 endif
 116
 117
 118 " HELPER FUNCTIONS
 119
 120 if has('eval')
 121 " Check if the given syntax group is available. Thanks to bairui in #vim on
 122 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 123     function! s:HasSyntaxGroup(group)
 124         try
 125             execute 'silent highlight ' . a:group
 126         " \a = [A-Za-z]
 127         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 128             return 0
 129         endtry
 130         return 1
 131     endfunction
 132
 133 " Check if the given Vim version and patch is available.
 134     function! s:HasVersionAndPatch(version, patch)
 135         return v:version > a:version
 136             \ || (v:version == a:version && has('patch' . a:patch))
 137     endfunction
 138 endif
 139
 140
 141 " TERMINAL SETTINGS
 142
 143 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 144 " connections.
 145 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 146     set ttyfast
 147 endif
 148
 149
 150 " EDIT SETTINGS
 151
 152 " Enable automatic file detection, plugin and indention support.
 153 if has('autocmd')
 154     filetype off " necessary for pathogen to force a reload of ftplugins
 155     filetype plugin indent on
 156 endif
 157
 158 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 159 " existing files.
 160 set fileencodings=utf-8,latin1
 161
 162 " Always use unix line-endings for new files.
 163 set fileformats=unix,dos
 164
 165 " Wrap text after 78 characters.
 166 set textwidth=78
 167
 168 " Set tabs to 4 spaces, use softtabs.
 169 set shiftwidth=4
 170 set softtabstop=4
 171 set expandtab
 172 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 173 set shiftround
 174 " Use the default value for real tabs.
 175 set tabstop=8
 176
 177 " Enable auto indention.
 178 set autoindent
 179
 180 " When joining lines only add one space after a sentence.
 181 set nojoinspaces
 182
 183 " Allow backspacing over autoindent and line breaks.
 184 set backspace=indent,eol
 185
 186 " Start a comment when hitting enter after a commented line (r) and when using
 187 " o or O around a commented line (o).
 188 set formatoptions+=ro
 189 " Don't break a line if was already longer then 'textwidth' when insert mode
 190 " started.
 191 set formatoptions+=l
 192 " Remove comment leader when joining lines where it makes sense.
 193 if s:HasVersionAndPatch(703, 541)
 194     set formatoptions+=j
 195 endif
 196
 197 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 198 " no character) in visual block mode.
 199 set virtualedit=block
 200
 201 " Already display matches while typing the search command. This makes spotting
 202 " typos easy and searching faster.
 203 set incsearch
 204
 205 " Activate syntax folding.
 206 if has('folding')
 207     set foldmethod=syntax
 208     " Only use fold column if we have enough space (for example not in a
 209     " (virtual) terminal which has only 80 columns).
 210     if &columns > 80
 211         set foldcolumn=2
 212     endif
 213     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 214                      " folding which is not what I want
 215     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 216     set foldopen-=block
 217 endif
 218
 219 " Only check case if the searched word contains a capital character.
 220 set ignorecase
 221 set smartcase
 222
 223 " Activate spell checking, use English as default.
 224 if exists('+spell') && has('syntax')
 225     " But not when diffing because spell checking is distracting in this case.
 226     if !&diff
 227         set spell
 228     endif
 229     set spelllang=en_us
 230 endif
 231
 232 " Allow buffers with changes to be hidden. Very important for efficient
 233 " editing with multiple buffers. Prevents the "E37: No write since last change
 234 " (add ! to override)" warning when switching modified buffers.
 235 set hidden
 236
 237 " When splitting vertically put the new window right of the current one.
 238 if has('vertsplit')
 239     set splitright
 240 endif
 241
 242
 243 " DISPLAY SETTINGS
 244
 245 " Use a dark background. Doesn't change the background color, only sets text
 246 " colors for a dark terminal.
 247 set background=dark
 248
 249 " Use my color scheme if 256 colors are available.
 250 if &t_Co == 256 || has('gui_running')
 251     colorscheme simon
 252 endif
 253
 254 " Display line numbers.
 255 set number
 256 " But use as little space as possible for the numbers column. Thanks to James
 257 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 258 if exists('+numberwidth')
 259     set numberwidth=1
 260 endif
 261 " Display the ruler with current line/file position. If 'statusline' is used
 262 " then this only affects <C-G>.
 263 set ruler
 264 " Display partial commands in the status line.
 265 set showcmd
 266
 267 " Don't redraw screen when executing macros; increases speed. Thanks to James
 268 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 269 set lazyredraw
 270
 271 " Visualize the line the cursor is currently in.
 272 if exists('+cursorline')
 273     set cursorline
 274 endif
 275
 276 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 277 " remove the highlighting until the next search.
 278 set hlsearch
 279
 280 " Display some special characters.
 281 set list
 282 set listchars=
 283 " Display tabs as ">--------".
 284 set listchars+=tab:>-
 285 " Display trailing whitespace as "-".
 286 set listchars+=trail:-
 287 " Display markers for long lines when wrapping is disabled.
 288 set listchars+=extends:>,precedes:<
 289 " Display non-breakable space as "!".
 290 if v:version >= 700
 291     set listchars+=nbsp:!
 292 endif
 293
 294 " Don't draw the vertical split separator by using space as character. Thanks
 295 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 296 " non-breakable space. But a simple space works as well, as long as the
 297 " current color scheme is not reset.
 298 if has('windows') && has('folding')
 299     set fillchars+=vert:\  " comment to prevent trailing whitespace
 300 endif
 301
 302 if has('statusline')
 303     " Always display the status line even if there is only one window.
 304     set laststatus=2
 305
 306     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 307     " is the highest buffer number, otherwise return nothing. Used in
 308     " 'statusline' to get an overview of available buffer numbers.
 309     function! s:StatuslineBufferCount()
 310         let l:bufnr = bufnr('$')
 311         if l:bufnr > 1
 312             let l:result = '/'
 313             if exists('*printf')
 314                 let l:result .= printf('%02d', l:bufnr)
 315             else
 316                 " Older Vims don't have printf() (and no .= either). Emulate
 317                 " "%02d".
 318                 if l:bufnr < 10
 319                     let l:result = l:result . '0'
 320                 endif
 321                 let l:result = l:result . l:bufnr
 322             endif
 323             return l:result
 324         else
 325             return ''
 326         endif
 327     endfunction
 328
 329     " Like %f but use relative filename if it's shorter than the absolute path
 330     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 331     " not enough because it doesn't create '../'s.
 332     function! s:StatuslineRelativeFilename()
 333         " Display only filename for help files.
 334         if &buftype == 'help'
 335             return expand('%:t')
 336         endif
 337         " Special case for scratch files.
 338         if &buftype == 'nofile'
 339             return '[Scratch]'
 340         endif
 341
 342         let l:path = expand('%')
 343         " No file.
 344         if l:path == ''
 345             return '[No Name]'
 346         endif
 347         " Path is already relative, nothing to do.
 348         if stridx(l:path, '/') != 0
 349             return l:path
 350         endif
 351
 352         " Absolute path to this file.
 353         let l:path = expand('%:p')
 354         " Shortened path to this file, thanks to bairui in #vim on Freenode
 355         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 356         " Vim normally uses as %f (minus some exceptions).
 357         let l:original_path = fnamemodify(l:path, ':~')
 358         " Absolute path to the current working directory.
 359         let l:cwd = getcwd()
 360
 361         " Working directory completely contained in path, replace it with a
 362         " relative path. Happens for example when opening a file with netrw.
 363         " %f displays this as absolute path, but we want a relative path of
 364         " course.
 365         if stridx(l:path, l:cwd) == 0
 366             return strpart(l:path, strlen(l:cwd) + 1)
 367         endif
 368
 369         let l:path_list = split(l:path, '/')
 370         let l:cwd_list  = split(l:cwd,  '/')
 371
 372         " Remove the common path.
 373         while l:path_list[0] == l:cwd_list[0]
 374             call remove(l:path_list, 0)
 375             call remove(l:cwd_list,  0)
 376         endwhile
 377
 378         " Add as many '..' as necessary for the relative path and join the
 379         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 380         " the hint to use repeat() instead of a loop.
 381         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 382
 383         " Use the shorter path, either relative or absolute.
 384         if strlen(l:path) < strlen(l:original_path)
 385             return l:path
 386         else
 387             return l:original_path
 388         endif
 389     endfunction
 390
 391     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 392     function! s:StatuslineFileFormat()
 393         if &fileformat != 'unix'
 394             return '[' . &fileformat . ']'
 395         else
 396             return ''
 397         endif
 398     endfunction
 399     function! s:StatuslineFileEncoding()
 400         if &fileencoding != '' && &fileencoding != 'utf-8'
 401                 \ && &filetype != 'help'
 402             return '[' . &fileencoding . ']'
 403         else
 404             return ''
 405         endif
 406     endfunction
 407     function! s:StatuslineFileBOMB()
 408         if exists('+bomb') && &bomb
 409             return '[BOM]'
 410         else
 411             return ''
 412         endif
 413     endfunction
 414
 415     " Return current syntax group in brackets or nothing if there's none.
 416     function! s:StatuslineSyntaxGroup()
 417         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 418         if l:group != ''
 419             return '[' . l:group . '] '
 420         else
 421             return ''
 422         endif
 423     endfunction
 424
 425     " Short function names to make 'statusline' more readable.
 426     function! SBC()
 427         return s:StatuslineBufferCount()
 428     endfunction
 429     function! SRF()
 430         return s:StatuslineRelativeFilename()
 431     endfunction
 432     function! SFF()
 433         return s:StatuslineFileFormat()
 434     endfunction
 435     function! SFE()
 436         return s:StatuslineFileEncoding()
 437     endfunction
 438     function! SFB()
 439         return s:StatuslineFileBOMB()
 440     endfunction
 441     function! SSG()
 442         return s:StatuslineSyntaxGroup()
 443     endfunction
 444
 445     set statusline=
 446     " on the left
 447     set statusline+=%02n              " buffer number
 448     set statusline+=%{SBC()}          " highest buffer number
 449     set statusline+=:
 450     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 451         set statusline+=%{SRF()}      " path to current file
 452         set statusline+=\             " space after path
 453     else
 454         set statusline+=%f\           " path to current file in buffer
 455     endif
 456     set statusline+=%h                " [help] if buffer is help file
 457     set statusline+=%w                " [Preview] if buffer is preview buffer
 458     set statusline+=%m                " [+] if buffer was modified,
 459                                       " [-] if 'modifiable' is off
 460     set statusline+=%r                " [RO] if buffer is read only
 461     if v:version >= 700               " %#..# needs 7.0
 462         set statusline+=%#Error#      " display warnings
 463         set statusline+=%{SFF()}      "   - unexpected file format
 464         set statusline+=%{SFE()}      "   - unexpected file encoding
 465         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 466         set statusline+=%##           " continue with normal colors
 467     endif
 468
 469     " on the right
 470     set statusline+=%=                " right align
 471     set statusline+=0x%-8B\           " current character under cursor as hex
 472     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 473                                       " column number (%c),
 474                                       " virtual column number if different
 475                                       "                       than %c (%V)
 476     set statusline+=%P                " position in file in percent
 477 endif
 478
 479
 480 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 481
 482 " noremap is used to make sure the right side is executed as is and can't be
 483 " modified by a plugin or other settings. Except for <Nop> which isn't
 484 " affected by mappings.
 485
 486 " Easy way to exit insert mode (jj is too slow).
 487 inoremap jk <Esc>
 488 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 489 " (2010-10-15).
 490 cnoremap jk <C-C>
 491
 492 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 493 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 494 map <Right>  <Nop>
 495 map <Left>   <Nop>
 496 map <Up>     <Nop>
 497 map <Down>   <Nop>
 498 imap <Right> <Nop>
 499 imap <Left>  <Nop>
 500 imap <Up>    <Nop>
 501 imap <Down>  <Nop>
 502 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 503 " below).
 504 cmap <Up>    <Nop>
 505 cmap <Down>  <Nop>
 506 cmap <Right> <Nop>
 507 cmap <Left>  <Nop>
 508
 509 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 510 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 511 cnoremap <C-P> <Up>
 512 cnoremap <C-N> <Down>
 513
 514 if has('eval')
 515 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 516 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 517 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 518 " directly because it also enables that feature for other commands which I
 519 " don't want.
 520
 521     " Set 'nostartofline' for a single movement.
 522     function! s:TemporaryNostartofline(movement)
 523         let l:startofline = &startofline
 524         set nostartofline
 525         execute 'normal! ' . a:movement
 526         let &startofline = l:startofline
 527     endfunction
 528
 529     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 530     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 531     nnoremap <silent> <C-F>
 532         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 533     nnoremap <silent> <C-B>
 534         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 535     nnoremap <silent> <C-D>
 536         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 537     nnoremap <silent> <C-U>
 538         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 539 endif
 540
 541 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 542 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 543 " Only the current buffer is written, thus switching to another buffer works
 544 " too.
 545 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 546
 547 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 548 " in #vim on Freenode (2011-08-15 00:17 CEST).
 549 nnoremap <C-G> 2<C-G>
 550
 551 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 552 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 553 nmap <Space> <C-F>
 554 nmap - <C-B>
 555
 556 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 557 " (2010-05-16 18:38 CEST) for this idea.
 558 nnoremap <silent> gb :bnext<CR>
 559 nnoremap <silent> gB :bprevious<CR>
 560 if has('eval')
 561     " But when starting again at the first buffer, print a warning which
 562     " reminds me that I've already seen that buffer.
 563     function! s:NextBuffer()
 564         " Are we currently on the last buffer and moving to the first?
 565         let l:last_buffer = 0
 566         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 567             let l:last_buffer = 1
 568         endif
 569
 570         " Go to the next buffer.
 571         if !l:last_buffer
 572             bnext
 573
 574         " Go to the first buffer, silent is necessary or the following message
 575         " won't be displayed because it's overwritten by the status message
 576         " displayed when entering a buffer.
 577         else
 578             silent bnext
 579
 580             echohl WarningMsg
 581             echo 'Starting again at first buffer.'
 582             echohl None
 583         endif
 584     endfunction
 585     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 586 endif
 587
 588 " Fast access to buffers.
 589 nnoremap <silent> <Leader>1 :1buffer<CR>
 590 nnoremap <silent> <Leader>2 :2buffer<CR>
 591 nnoremap <silent> <Leader>3 :3buffer<CR>
 592 nnoremap <silent> <Leader>4 :4buffer<CR>
 593 nnoremap <silent> <Leader>5 :5buffer<CR>
 594 nnoremap <silent> <Leader>6 :6buffer<CR>
 595 nnoremap <silent> <Leader>7 :7buffer<CR>
 596 nnoremap <silent> <Leader>8 :8buffer<CR>
 597 nnoremap <silent> <Leader>9 :9buffer<CR>
 598 nnoremap <silent> <Leader>0 :10buffer<CR>
 599
 600 " Make last active window the only window. Similar to <C-W> o.
 601 nnoremap <C-W>O <C-W>p<C-W>o
 602
 603 " Maps to change spell language between English and German and disable spell
 604 " checking.
 605 if exists('+spell')
 606     nnoremap <silent> <Leader>sn :set nospell<CR>
 607     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 608     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 609 " If no spell support is available, these mappings do nothing.
 610 else
 611     nmap <Leader>sn <Nop>
 612     nmap <Leader>se <Nop>
 613     nmap <Leader>sd <Nop>
 614 endif
 615
 616 " Add semicolon to the end of the line. Thanks to
 617 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 618 " on Freenode for an improved version which doesn't clobber any marks.
 619 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 620
 621 if has('eval')
 622 " * and # for selections in visual mode. Thanks to
 623 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 624 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 625     function! s:VSetSearch()
 626         let l:temp = @@ " unnamed register
 627         normal! gvy
 628         " Added \C to force 'noignorecase' while searching the current visual
 629         " selection. I want to search for the exact string in this case.
 630         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 631         let @@ = l:temp
 632     endfunction
 633     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 634     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 635
 636 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 637 " Thanks to the writers of s:VSetSearch(), see above.
 638     function! s:NSetSearch()
 639         let l:cword = expand('<cword>')
 640         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 641         let @/ = '\C\V'. '\<' . l:regex . '\>'
 642     endfunction
 643     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 644     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 645 endif
 646
 647 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 648 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 649 " mailing list for the commands.
 650 if v:version < 700
 651     cnoreabbrev W w
 652     cnoreabbrev Wa wa
 653     cnoreabbrev Wq wq
 654     cnoreabbrev Wqa wqa
 655 else
 656     cnoreabbrev <expr> W
 657         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 658     cnoreabbrev <expr> Wa
 659         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 660     cnoreabbrev <expr> Wq
 661         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 662     cnoreabbrev <expr> Wqa
 663         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 664 endif
 665 " Also fix my typo with "Q".
 666 if v:version < 700
 667     cnoreabbrev Q q
 668     cnoreabbrev Qa qa
 669 else
 670     cnoreabbrev <expr> Q
 671         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 672     cnoreabbrev <expr> Qa
 673         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 674 endif
 675
 676 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 677 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 678 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 679
 680 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 681 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 682 " Vim's source.
 683 inoremap <C-U> <C-G>u<C-U>
 684 " Same for <C-@> (insert previously inserted text and leave insert mode).
 685 inoremap <C-@> <C-G>u<C-@>
 686 " And for <C-A> (insert previously inserted text).
 687 inoremap <C-A> <C-G>u<C-A>
 688 " And for <C-W> (delete word before cursor).
 689 inoremap <C-W> <C-G>u<C-W>
 690
 691 if has('eval')
 692 " New text-objects ii and ai to work on text with the same indentation. Thanks
 693 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 694 " (visited on 2011-11-19).
 695     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 696     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 697     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 698     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 699
 700     function! s:IndTxtObj(inner)
 701         let curline = line(".")
 702         let lastline = line("$")
 703         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 704         let i = i < 0 ? 0 : i
 705         if getline(".") !~ "^\\s*$"
 706             let p = line(".") - 1
 707             let nextblank = getline(p) =~ "^\\s*$"
 708             while p > 0
 709                     \ && ((i == 0 && !nextblank)
 710                         \ || (i > 0 && ((indent(p) >= i
 711                             \ && !(nextblank && a:inner))
 712                             \ || (nextblank && !a:inner))))
 713                 -
 714                 let p = line(".") - 1
 715                 let nextblank = getline(p) =~ "^\\s*$"
 716             endwhile
 717             normal! 0V
 718             call cursor(curline, 0)
 719             let p = line(".") + 1
 720             let nextblank = getline(p) =~ "^\\s*$"
 721             while p <= lastline
 722                     \ && ((i == 0 && !nextblank)
 723                         \ || (i > 0 && ((indent(p) >= i
 724                             \ && !(nextblank && a:inner))
 725                             \ || (nextblank && !a:inner))))
 726                 +
 727                 let p = line(".") + 1
 728                 let nextblank = getline(p) =~ "^\\s*$"
 729             endwhile
 730             normal! $
 731         endif
 732     endfunction
 733 endif
 734
 735
 736 " ABBREVIATIONS
 737
 738 " Fix some of my spelling mistakes (German).
 739 inoreabbrev relle reelle
 740 inoreabbrev reele reelle
 741 " Fix some of my spelling mistakes (English).
 742 inoreabbrev completly completely
 743
 744
 745 " SYNTAX SETTINGS
 746
 747 " Activate syntax coloring.
 748 if has('syntax')
 749     syntax enable
 750
 751 " Don't highlight more than 500 columns as I normally don't have that long
 752 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 753 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 754     if exists('+synmaxcol')
 755         set synmaxcol=500
 756     endif
 757
 758 " Use (limited) syntax based omni completion if no other omni completion is
 759 " available. Taken from :help ft-syntax-omni.
 760     if has('autocmd') && exists('+omnifunc')
 761         augroup vimrc
 762             autocmd FileType *
 763                 \ if &omnifunc == '' |
 764                 \     setlocal omnifunc=syntaxcomplete#Complete |
 765                 \ endif
 766         augroup END
 767     endif
 768
 769 " Function to enable all custom highlights. Necessary as highlights are
 770 " window-local and thus must be set for each new window.
 771     function! s:CustomSyntaxHighlights()
 772         " Not the first time called, nothing to do.
 773         if exists('w:vimrc_syntax_run')
 774             return
 775         endif
 776         let w:vimrc_syntax_run = 1
 777
 778 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 779 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 780 " disabled when necessary with :2match (in Vim >= 700).
 781         if !&diff && exists(':2match')
 782             " Use ColorColumn for overlong lines if available and my color
 783             " scheme is used.
 784             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 785                 2match ColorColumn /\%>78v./
 786             else
 787                 2match Todo /\%>78v./
 788             endif
 789         elseif !&diff
 790             match Todo /\%>78v./
 791         endif
 792
 793         if exists('*matchadd')
 794 " Highlight some important keywords in all documents.
 795             let l:todos = ['TODO', 'XXX', 'FIXME',
 796                          \ 'CHANGED', 'REMOVED', 'DELETED']
 797             " Compatibility fix for Vim 6.4 which can't handle for in function
 798             " (without function it's ignored).
 799             execute '  for l:x in l:todos'
 800                   \ '|     call matchadd("Todo", l:x)'
 801                   \ '| endfor'
 802
 803 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 804             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 805                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 806                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 807                           \ '205f', '2060', '3000', 'feff']
 808             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 809             " it won't work!
 810             execute '  for l:x in l:spaces'
 811                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 812                   \ '| endfor'
 813
 814 " Special highlight for tabs to reduce their visibility in contrast to other
 815 " SpecialKey characters (e.g. ^L).
 816             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 817                 call matchadd('specialKeyTab', '\t')
 818             endif
 819         endif
 820     endfunction
 821 " Enable highlights for the current and all new windows. Thanks to bairui in
 822 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 823     call s:CustomSyntaxHighlights()
 824     if has('autocmd')
 825         augroup vimrc
 826             autocmd WinEnter * call s:CustomSyntaxHighlights()
 827         augroup END
 828     endif
 829
 830 " Settings for specific filetypes.
 831
 832     " C
 833     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 834     " Haskell.
 835     let g:hs_highlight_delimiters = 1
 836     let g:hs_highlight_boolean = 1
 837     let g:hs_highlight_types = 1
 838     let g:hs_highlight_more_types = 1
 839     " Java.
 840     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 841     " Perl.
 842     let g:perl_fold = 1
 843     let g:perl_fold_blocks = 1
 844     let g:perl_nofold_packages = 1
 845     let g:perl_include_pod = 1 " syntax coloring for PODs
 846     " PHP.
 847     let g:php_folding = 3    " fold functions
 848     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 849     let g:php_sql_query = 1  " highlight SQL queries in strings
 850     " Python.
 851     let g:python_highlight_all = 1
 852     " Shell.
 853     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 854     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 855     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 856     " Vim.
 857     let g:vimsyn_embed = 0      " don't highlight embedded languages
 858     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 859     " XML.
 860     let g:xml_syntax_folding = 1
 861 endif
 862
 863
 864 " PLUGIN SETTINGS
 865
 866 if has('eval')
 867 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 868 " installing/removing/updating plugins simple. (Used for plugins with more
 869 " than one file.) Ignore errors in case pathogen is not installed.
 870     if v:version >= 700
 871         silent! execute 'call pathogen#infect()'
 872     endif
 873
 874 " Settings for securemodelines.
 875     " Only allow items I need (also includes spl which is not enabled by
 876     " default).
 877     if v:version >= 700 " need lists
 878         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 879                                               \ 'sw', 'sts', 'noet']
 880     endif
 881
 882 " Settings for the NERD commenter.
 883     " Don't create any mappings I don't want to use.
 884     let g:NERDCreateDefaultMappings = 0
 885     " Map toggle comment.
 886     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 887
 888 " XPTemplate settings.
 889     " Try to maintain snippet rendering even after editing outside of a
 890     " snippet.
 891     let g:xptemplate_strict = 0
 892     " Don't complete any braces automatically.
 893     let g:xptemplate_brace_complete = 0
 894     " Only highlight the current placeholder.
 895     let g:xptemplate_highlight = 'current'
 896
 897 " CtrlP settings.
 898     " Don't manage the working directory (the default setting is too slow for
 899     " me).
 900     let g:ctrlp_working_path_mode = 0
 901
 902     " Path to cache directory. I prefer to keep generated files as local as
 903     " possible.
 904     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 905     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 906     " cache manually.
 907     let g:ctrlp_clear_cache_on_exit = 0
 908
 909     " Don't switch the window if the selected buffer is already open. I want
 910     " to open another view on this buffer in most cases.
 911     let g:ctrlp_switch_buffer = 0
 912
 913 " FSWitch settings.
 914     " Defaults don't work well for my projects.
 915     augroup vimrc
 916         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 917                           \ | let b:fswitchlocs = './'
 918         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 919                           \ | let b:fswitchlocs = './'
 920     augroup END
 921
 922     " Switch to corresponding header/source file.
 923     nnoremap <silent> <Leader>h :FSHere<CR>
 924
 925 " netrw settings.
 926     " Don't create ~/.vim/.netrwhist history file.
 927     let g:netrw_dirhistmax = 0
 928 endif
 929
 930
 931 " AUTO COMMANDS
 932
 933 " Use a custom auto group to prevent problems when the vimrc files is sourced
 934 " twice.
 935 if has('autocmd')
 936     augroup vimrc
 937
 938 " Go to last position of opened files. Taken from :help last-position-jump.
 939         autocmd BufReadPost *
 940             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 941             \     execute "normal! g'\"" |
 942             \ endif
 943 " But not for Git commits, go to beginning of the file.
 944         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 945
 946 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 947 " when switching to a help buffer which is in the background with :buffer as
 948 " these options are local to windows (and not only to buffers). This happens
 949 " because I often want to use only one window and thus the help buffer is in
 950 " the background.
 951         autocmd BufWinEnter *.txt
 952             \ if &filetype == 'help' |
 953             \     setlocal nolist |
 954             \     setlocal nonumber |
 955             \ endif
 956
 957 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 958 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 959 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 960 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
 961 " 'paste' in this case.
 962         if exists('##InsertLeave')
 963             autocmd InsertLeave * set nopaste
 964         endif
 965
 966 " Write all files when running :mak[e] before 'makeprg' is called.
 967 " QuickFixCmdPre doesn't exist in older Vims.
 968         if exists('##QuickFixCmdPre')
 969             autocmd QuickFixCmdPre * wall
 970         endif
 971
 972 " Don't ignore case while in insert mode, but ignore case in all other modes.
 973 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 974 " capitalization. But while searching (/) 'ignorecase' is used.
 975 " InsertEnter/InsertLeave doesn't exist in older Vims.
 976         if exists('##InsertEnter') && exists('##InsertLeave')
 977             autocmd InsertEnter * set noignorecase
 978             autocmd InsertLeave * set   ignorecase
 979         endif
 980
 981 " Display a warning when editing a file which contains "do not edit" (ignoring
 982 " the case) in the first lines of the file, for example template files which
 983 " were preprocessed or auto-generated files. Especially useful when the header
 984 " is not displayed on the first screen, e.g. when the old position is
 985 " restored.
 986         function! s:SearchForDoNotEditHeader()
 987             " Only search the first 20 lines to prevent false positives, e.g.
 988             " in scripts which write files containing this warning and ignore
 989             " the case (\c). (Can't use search()'s {stopline} as we might not
 990             " start searching from the top.)
 991             let l:match = search('\cdo not edit', 'n')
 992             if l:match == 0 || l:match > 20
 993                 return
 994             endif
 995
 996             echoerr 'Do not edit this file! (Maybe a template file.)'
 997         endfunction
 998         autocmd BufRead * call s:SearchForDoNotEditHeader()
 999
1000 " AFTER/FTPLUGIN AUTO COMMANDS
1001
1002 " Disable spell checking for files which don't need it.
1003         autocmd FileType deb  setlocal nospell
1004         autocmd FileType diff setlocal nospell
1005         autocmd FileType tar  setlocal nospell
1006 " Fix to allow Vim edit crontab files as crontab doesn't work with
1007 " backupcopy=auto.
1008         autocmd FileType crontab setlocal backupcopy=yes
1009 " Don't use the modeline in git commits as the diff created by `git commit -v`
1010 " may contain one which could change the filetype or other settings of the
1011 " commit buffer. Also make sure we use only 72 characters per line which is
1012 " the recommendation for git commit messages (http://tpope.net/node/106).
1013         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1014                                  \ setlocal textwidth=72
1015 " Fix 'include' setting for shell files to recognize '.' and 'source'
1016 " commands. Use &l:include instead of setlocal which requires excessive
1017 " escaping of \.
1018         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1019 " Use the same comment string as for Vim files in Vimperator files.
1020         autocmd FileType vimperator setlocal commentstring=\"%s
1021 " Use TeX compiler for (La)TeX files.
1022         autocmd FileType tex compiler tex
1023
1024 " FTDETECT AUTO COMMANDS
1025
1026 " Recognize .md as markdown files (Vim default is .mkd).
1027         autocmd BufRead,BufNewFile *.md set filetype=mkd
1028 " Recognize .test as Tcl files.
1029         autocmd BufRead,BufNewFile *.test set filetype=tcl
1030
1031 " OTHER AUTO COMMANDS
1032
1033 " Disable spell checking, displaying of list characters and long lines when
1034 " viewing documentation.
1035         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1036
1037 " Use diff filetype for mercurial patches in patch queue.
1038         autocmd BufReadPost */.hg/patches/* set filetype=diff
1039
1040     augroup END
1041 endif
1042
1043
1044 " CUSTOM FUNCTIONS AND COMMANDS
1045
1046 if has('eval')
1047 " Convenient command to see the difference between the current buffer and the
1048 " file it was loaded from, thus the changes you made. Thanks to the
1049 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1050 " for the diffed file as the filetype for the original file.
1051     if !exists(':DiffOrig')
1052         command DiffOrig
1053             \ let s:diff_orig_filetype = &filetype
1054             \ | vertical new
1055             \ | let &filetype = s:diff_orig_filetype
1056             \ | unlet s:diff_orig_filetype
1057             \ | set buftype=nofile
1058             \ | read ++edit #
1059             \ | 0d_
1060             \ | diffthis
1061             \ | wincmd p
1062             \ | diffthis
1063     endif
1064 endif