vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 " Remember marks (including the last cursor position) for more files.
  73 if has('viminfo')
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " HELPER FUNCTIONS
  92
  93 " Check if the given syntax group is available. Thanks to bairui in #vim on
  94 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  95 if has('eval')
  96     function! s:HasSyntaxGroup(group)
  97         try
  98             execute 'silent highlight ' . a:group
  99         " \a = [A-Za-z]
 100         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 101             return 0
 102         endtry
 103         return 1
 104     endfunction
 105 endif
 106
 107
 108 " EDIT SETTINGS
 109
 110 " Enable automatic file detection, plugin and indention support.
 111 if has('autocmd')
 112     filetype off " necessary for pathogen to force a reload of ftplugins
 113     filetype plugin indent on
 114 endif
 115
 116 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 117 " existing files.
 118 set fileencodings=utf-8,latin1
 119
 120 " Wrap text after 78 characters.
 121 set textwidth=78
 122
 123 " Set tabs to 4 spaces, use softtabs.
 124 set shiftwidth=4
 125 set softtabstop=4
 126 set expandtab
 127 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 128 set shiftround
 129 " Use the default value for real tabs.
 130 set tabstop=8
 131
 132 " Enable auto indention.
 133 set autoindent
 134
 135 " When joining lines only add one space after a sentence.
 136 set nojoinspaces
 137
 138 " Allow backspacing over autoindent and line breaks.
 139 set backspace=indent,eol
 140
 141 " Start a comment when hitting enter after a commented line (r) and when using
 142 " o or O around a commented line (o).
 143 set formatoptions+=ro
 144 " Don't break a line if was already longer then 'textwidth' when insert mode
 145 " started.
 146 set formatoptions+=l
 147
 148 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 149 " no character) in visual block mode.
 150 set virtualedit=block
 151
 152 " Already display matches while typing the search command. This makes spotting
 153 " errors easy.
 154 set incsearch
 155
 156 " Activate syntax folding.
 157 if has('folding')
 158     set foldmethod=syntax
 159     " Only use fold column if we have enough space (for example in a (virtual)
 160     " terminals).
 161     if &columns > 80
 162         set foldcolumn=2
 163     endif
 164     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 165                      " folding which is not what I want
 166 endif
 167
 168 " Only check case if the searched word contains a capital character.
 169 set ignorecase
 170 set smartcase
 171
 172 " Activate spell checking, use English as default.
 173 if exists('+spell') && has('syntax')
 174     " But not when diffing because spell checking is distracting in this case.
 175     if !&diff
 176         set spell
 177     endif
 178     set spelllang=en_us
 179 endif
 180
 181 " Allow buffers with changes to be hidden. Very important for effective
 182 " editing with multiple buffers. Prevents the "E37: No write since last change
 183 " (add ! to override)" warning.
 184 set hidden
 185
 186
 187 " DISPLAY SETTINGS
 188
 189 " Use a dark background. Doesn't change the background color, only sets text
 190 " colors for a dark terminal.
 191 set background=dark
 192
 193 " Use my color scheme if 256 colors are available.
 194 if &t_Co == 256
 195     colorscheme simon
 196 endif
 197
 198 " Display line numbers.
 199 set number
 200 " But use as little space as possible for the numbers column. Thanks to James
 201 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 202 if exists('+numberwidth')
 203     set numberwidth=1
 204 endif
 205 " Display the ruler with current line/file position. If 'statusline' is used
 206 " then this only affects <C-G>.
 207 set ruler
 208 " Display partial commands in the status line.
 209 set showcmd
 210
 211 " Don't redraw screen when executing macros; increases speed. Thanks to James
 212 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 213 set lazyredraw
 214
 215 " Visualize the line the cursor is currently in.
 216 if exists('+cursorline')
 217     set cursorline
 218 endif
 219
 220 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 221 " remove the highlighting until the next search.
 222 set hlsearch
 223
 224 " Display some special characters.
 225 set list
 226 set listchars=
 227 " Display tabs as ">--------".
 228 set listchars+=tab:>-
 229 " Display trailing whitespace as "-".
 230 set listchars+=trail:-
 231 " Display markers for long lines when wrapping is disabled.
 232 set listchars+=extends:>,precedes:<
 233 " Display non-breakable space as "!".
 234 if v:version >= 700
 235     set listchars+=nbsp:!
 236 endif
 237
 238 " Don't draw the vertical split separator by using space as character. Thanks
 239 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 240 " non-breakable space. But a simple space works as well, as long as the
 241 " current color scheme is not reset.
 242 if has('windows') && has('folding')
 243     set fillchars+=vert:\  " comment to prevent trailing whitespace
 244 endif
 245
 246 if has('statusline')
 247     " Always display the status line even if there is only one window.
 248     set laststatus=2
 249
 250     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 251     " is the highest buffer number, otherwise return nothing. Used in
 252     " 'statusline' to get an overview of available buffer numbers.
 253     function! StatuslineBufferCount()
 254         let l:bufnr = bufnr('$')
 255         if l:bufnr > 1
 256             let l:result = '/'
 257             if exists('*printf')
 258                 let l:result .= printf('%02d', l:bufnr)
 259             else
 260                 " Older Vims don't have printf() (and no .= either). Emulate
 261                 " "%02d".
 262                 if l:bufnr < 10
 263                     let l:result = l:result . '0'
 264                 endif
 265                 let l:result = l:result . l:bufnr
 266             endif
 267             return l:result
 268         else
 269             return ''
 270         endif
 271     endfunction
 272
 273     " Like %f but use relative filename if it's shorter than the absolute path
 274     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 275     " not enough because it doesn't create '../'s.
 276     function! StatuslineRelativeFilename()
 277         " Display only filename for help files.
 278         if &buftype == 'help'
 279             return expand('%:t')
 280         endif
 281         " Special case for scratch files.
 282         if &buftype == 'nofile'
 283             return '[Scratch]'
 284         endif
 285
 286         let l:path = expand('%')
 287         " No file.
 288         if l:path == ''
 289             return '[No Name]'
 290         endif
 291         " Path is already relative, nothing to do.
 292         if stridx(l:path, '/') != 0
 293             return l:path
 294         endif
 295
 296         " Absolute path to this file.
 297         let l:path = expand('%:p')
 298         " Shortened path to this file, thanks to bairui in #vim on Freenode
 299         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 300         " Vim normally uses as %f (minus some exceptions).
 301         let l:original_path = fnamemodify(l:path, ':~')
 302         " Absolute path to the current working directory.
 303         let l:cwd = getcwd()
 304
 305         " Working directory completely contained in path, replace it with a
 306         " relative path. Happens for example when opening a file with netrw.
 307         " %f displays this as absolute path, but we want a relative path of
 308         " course.
 309         if stridx(l:path, l:cwd) == 0
 310             return strpart(l:path, strlen(l:cwd) + 1)
 311         endif
 312
 313         let l:path_list = split(l:path, '/')
 314         let l:cwd_list  = split(l:cwd,  '/')
 315
 316         " Remove the common path.
 317         while l:path_list[0] == l:cwd_list[0]
 318             call remove(l:path_list, 0)
 319             call remove(l:cwd_list,  0)
 320         endwhile
 321
 322         " Add as many '..' as necessary for the relative path and join the
 323         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 324         " the hint to use repeat() instead of a loop.
 325         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 326
 327         " Use the shorter path, either relative or absolute.
 328         if strlen(l:path) < strlen(l:original_path)
 329             return l:path
 330         else
 331             return l:original_path
 332         endif
 333     endfunction
 334
 335     set statusline=
 336     " on the left
 337     set statusline+=%02n  " buffer number
 338     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 339     set statusline+=:
 340     if has('modify_fname')
 341         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 342         set statusline+=\     " space after path
 343     else
 344         set statusline+=%f\   " path to current file in buffer
 345     endif
 346     set statusline+=%h    " [help] if buffer is help file
 347     set statusline+=%w    " [Preview] if buffer is preview buffer
 348     set statusline+=%m    " [+] if buffer was modified,
 349                           " [-] if 'modifiable' is off
 350     set statusline+=%r    " [RO] if buffer is read only
 351
 352     " on the right
 353     set statusline+=%=                " right align
 354     set statusline+=0x%-8B\           " current character under cursor as hex
 355     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 356                                       " column number (%c),
 357                                       " virtual column number if different
 358                                       "                       than %c (%V)
 359     set statusline+=%P                " position in file in percent
 360 endif
 361
 362
 363 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 364
 365 " noremap is used to make sure the right side is executed as is and can't be
 366 " modified by a plugin or other settings. Except for <Nop> which isn't
 367 " affected by mappings.
 368
 369 " Easy way to exit insert mode.
 370 inoremap jj <Esc>
 371 inoremap jk <Esc>
 372 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 373 " (2010-10-15).
 374 cnoremap jj <C-C>
 375 cnoremap jk <C-C>
 376
 377 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 378 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 379 map <Right>  <Nop>
 380 map <Left>   <Nop>
 381 map <Up>     <Nop>
 382 map <Down>   <Nop>
 383 imap <Right> <Nop>
 384 imap <Left>  <Nop>
 385 imap <Up>    <Nop>
 386 imap <Down>  <Nop>
 387 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 388 " below).
 389 cmap <Up>    <Nop>
 390 cmap <Down>  <Nop>
 391 cmap <Right> <Nop>
 392 cmap <Left>  <Nop>
 393
 394 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 395 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 396 cnoremap <C-P> <Up>
 397 cnoremap <C-N> <Down>
 398
 399 if has('eval')
 400 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 401 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 402 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 403 " directly because it also enables that feature for other commands which I
 404 " don't want.
 405
 406     " Set 'nostartofline' for a single movement.
 407     function! s:TemporaryNostartofline(movement)
 408         let l:startofline = &startofline
 409         set nostartofline
 410         execute 'normal! ' . a:movement
 411         let &startofline = l:startofline
 412     endfunction
 413
 414     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 415     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 416     nnoremap <silent> <C-F>
 417         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 418     nnoremap <silent> <C-B>
 419         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 420     nnoremap <silent> <C-D>
 421         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 422     nnoremap <silent> <C-U>
 423         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 424 endif
 425
 426 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 427 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 428 " Only the current buffer is written.
 429 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 430
 431 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 432 " in #vim on Freenode (2011-08-15 00:17 CEST).
 433 nnoremap <C-G> 2<C-G>
 434
 435 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 436 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 437 nmap <Space> <C-F>
 438 nmap - <C-B>
 439
 440 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 441 " (2010-05-16 18:38 CEST) for this idea.
 442 nnoremap <silent> gb :bnext<CR>
 443 nnoremap <silent> gB :bprevious<CR>
 444
 445 " Fast access to buffers.
 446 nnoremap <silent> <Leader>1 :1buffer<CR>
 447 nnoremap <silent> <Leader>2 :2buffer<CR>
 448 nnoremap <silent> <Leader>3 :3buffer<CR>
 449 nnoremap <silent> <Leader>4 :4buffer<CR>
 450 nnoremap <silent> <Leader>5 :5buffer<CR>
 451 nnoremap <silent> <Leader>6 :6buffer<CR>
 452 nnoremap <silent> <Leader>7 :7buffer<CR>
 453 nnoremap <silent> <Leader>8 :8buffer<CR>
 454 nnoremap <silent> <Leader>9 :9buffer<CR>
 455 nnoremap <silent> <Leader>0 :10buffer<CR>
 456
 457 " Make last active window the only window. Similar to <C-W> o.
 458 nnoremap <C-W>O <C-W>p<C-W>o
 459
 460 " Maps to change spell language between English and German and disable spell
 461 " checking.
 462 if exists('+spell')
 463     nnoremap <silent> <Leader>sn :set nospell<CR>
 464     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 465     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 466 endif
 467
 468 " Add semicolon to the end of the line. Thanks to
 469 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 470 " on Freenode for an improved version which doesn't clobber any marks.
 471 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 472
 473 " * and # for selections in visual mode. Thanks to
 474 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 475 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 476 if has('eval')
 477     function! s:VSetSearch()
 478         let l:temp = @@
 479         normal! gvy
 480         " Added \C to force 'noignorecase' while searching the current visual
 481         " selection. I want to search for the exact string in this case.
 482         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 483         let @@ = l:temp
 484     endfunction
 485     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 486     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 487 endif
 488
 489 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 490 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 491 " mailing list for the commands.
 492 if v:version < 700
 493     cnoreabbrev W w
 494     cnoreabbrev Wa wa
 495     cnoreabbrev Wq wq
 496     cnoreabbrev Wqa wqa
 497 else
 498     cnoreabbrev <expr> W
 499         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 500     cnoreabbrev <expr> Wa
 501         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 502     cnoreabbrev <expr> Wq
 503         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 504     cnoreabbrev <expr> Wqa
 505         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 506 endif
 507 " Also fix my typo with "Q".
 508 if v:version < 700
 509     cnoreabbrev Q q
 510     cnoreabbrev Qa qa
 511 else
 512     cnoreabbrev <expr> Q
 513         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 514     cnoreabbrev <expr> Qa
 515         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 516 endif
 517
 518 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 519 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 520 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 521
 522 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 523 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 524 " Vim's source.
 525 inoremap <C-U> <C-G>u<C-U>
 526 " Same for <C-@> (insert previously inserted text and leave insert mode).
 527 inoremap <C-@> <C-G>u<C-@>
 528 " And for <C-A> (insert previously inserted text).
 529 inoremap <C-A> <C-G>u<C-A>
 530 " And for <C-W> (delete word before cursor).
 531 inoremap <C-W> <C-G>u<C-W>
 532
 533 if has('eval')
 534 " New text-objects ii and ai to work on text with the same indentation. Thanks
 535 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 536 " (visited on 2011-11-19).
 537     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 538     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 539     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 540     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 541
 542     function! s:IndTxtObj(inner)
 543         let curline = line(".")
 544         let lastline = line("$")
 545         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 546         let i = i < 0 ? 0 : i
 547         if getline(".") !~ "^\\s*$"
 548             let p = line(".") - 1
 549             let nextblank = getline(p) =~ "^\\s*$"
 550             while p > 0
 551                     \ && ((i == 0 && !nextblank)
 552                         \ || (i > 0 && ((indent(p) >= i
 553                             \ && !(nextblank && a:inner))
 554                             \ || (nextblank && !a:inner))))
 555                 -
 556                 let p = line(".") - 1
 557                 let nextblank = getline(p) =~ "^\\s*$"
 558             endwhile
 559             normal! 0V
 560             call cursor(curline, 0)
 561             let p = line(".") + 1
 562             let nextblank = getline(p) =~ "^\\s*$"
 563             while p <= lastline
 564                     \ && ((i == 0 && !nextblank)
 565                         \ || (i > 0 && ((indent(p) >= i
 566                             \ && !(nextblank && a:inner))
 567                             \ || (nextblank && !a:inner))))
 568                 +
 569                 let p = line(".") + 1
 570                 let nextblank = getline(p) =~ "^\\s*$"
 571             endwhile
 572             normal! $
 573         endif
 574     endfunction
 575 endif
 576
 577
 578 " ABBREVIATIONS
 579
 580 " Fix some of my spelling mistakes (German).
 581 inoreabbrev relle reelle
 582 inoreabbrev reele reelle
 583 " Fix some of my spelling mistakes (English).
 584 inoreabbrev completly completely
 585
 586
 587 " SYNTAX SETTINGS
 588
 589 " Activate syntax coloring.
 590 if has('syntax')
 591     syntax enable
 592
 593 " Don't highlight more than 500 columns as I normally don't have that long
 594 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 595 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 596     if exists('+synmaxcol')
 597         set synmaxcol=500
 598     endif
 599
 600 " Use (limited) syntax based omni completion if no other omni completion is
 601 " available. Taken from :help ft-syntax-omni.
 602     if has('autocmd') && exists('+omnifunc')
 603         augroup vimrc
 604             autocmd FileType *
 605                 \ if &omnifunc == '' |
 606                 \     setlocal omnifunc=syntaxcomplete#Complete |
 607                 \ endif
 608         augroup END
 609     endif
 610
 611 " Function to enable all custom highlights. Necessary as highlights are
 612 " window-local and thus must be set for each new window.
 613     function! s:CustomSyntaxHighlights()
 614         " Not the first time called, nothing to do.
 615         if exists('w:vimrc_syntax_run')
 616             return
 617         endif
 618         let w:vimrc_syntax_run = 1
 619
 620 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 621 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 622 " disabled when necessary with :2match (in Vim >= 700).
 623         if !&diff && exists(':2match')
 624             " Use ColorColumn for overlong lines if available and my color
 625             " scheme is used.
 626             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 627                 2match ColorColumn /\%>78v./
 628             else
 629                 2match Todo /\%>78v./
 630             endif
 631         elseif !&diff
 632             match Todo /\%>78v./
 633         endif
 634
 635         if exists('*matchadd')
 636 " Highlight some important keywords in all documents.
 637             let l:todos = ['TODO', 'XXX', 'FIXME',
 638                          \ 'CHANGED', 'REMOVED', 'DELETED']
 639             " Compatibility fix for Vim 6.4 which can't handle for in function
 640             " (without function it's ignored).
 641             execute '  for l:x in l:todos'
 642                   \ '|     call matchadd("Todo", l:x)'
 643                   \ '| endfor'
 644
 645 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 646             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 647                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 648                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 649                           \ '205f', '2060', '3000', 'feff']
 650             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 651             " it won't work!
 652             execute '  for l:x in l:spaces'
 653                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 654                   \ '| endfor'
 655
 656 " Special highlight for tabs to reduce their visibility in contrast to other
 657 " SpecialKey characters (e.g. ^L).
 658             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 659                 call matchadd('specialKeyTab', '\t')
 660             endif
 661         endif
 662     endfunction
 663 " Enable highlights for the current and all new windows. Thanks to bairui in
 664 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 665     call <SID>CustomSyntaxHighlights()
 666     if has('autocmd')
 667         augroup vimrc
 668             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 669         augroup END
 670     endif
 671
 672 " Settings for specific filetypes.
 673
 674     " C
 675     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 676     " Haskell.
 677     let g:hs_highlight_delimiters = 1
 678     let g:hs_highlight_boolean = 1
 679     let g:hs_highlight_types = 1
 680     let g:hs_highlight_more_types = 1
 681     " Perl.
 682     let g:perl_fold = 1
 683     let g:perl_fold_blocks = 1
 684     let g:perl_nofold_packages = 1
 685     let g:perl_include_pod = 1 " syntax coloring for PODs
 686     " Python.
 687     let g:python_highlight_all = 1
 688     " Shell.
 689     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 690     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 691     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 692     " Vim.
 693     let g:vimsyn_embed = 0      " don't highlight embedded languages
 694     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 695     " XML.
 696     let g:xml_syntax_folding = 1
 697 endif
 698
 699
 700 " PLUGIN SETTINGS
 701
 702 if has('eval')
 703 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 704 " installing/removing/updating plugins simple. (Used for plugins with more
 705 " than one file.) Ignore errors in case pathogen is not installed.
 706     if v:version >= 700
 707         silent! execute 'call pathogen#runtime_append_all_bundles()'
 708     endif
 709
 710 " Settings for securemodelines.
 711     " Only allow items I need (also includes spl which is not enabled by
 712     " default).
 713     let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 714                                           \ 'sw', 'sts', 'noet']
 715
 716 " Settings for the NERD commenter.
 717     " Don't create any mappings I don't want to use.
 718     let g:NERDCreateDefaultMappings = 0
 719     " Map toggle comment.
 720     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 721
 722 " XPTemplate settings.
 723     " Try to maintain snippet rendering even after editing outside of a
 724     " snippet.
 725     let g:xptemplate_strict = 0
 726     " Don't complete any braces automatically.
 727     let g:xptemplate_brace_complete = 0
 728     " Only highlight the current placeholder.
 729     let g:xptemplate_highlight = 'current'
 730 endif
 731
 732
 733 " AUTO COMMANDS
 734
 735 " Use a custom auto group to prevent problems when the vimrc files is sourced
 736 " twice.
 737 if has('autocmd')
 738     augroup vimrc
 739
 740 " Go to last position of opened files. Taken from :help last-position-jump.
 741         autocmd BufReadPost *
 742             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 743             \     execute "normal! g'\"" |
 744             \ endif
 745 " But not for Git commits, go to beginning of the file.
 746         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 747
 748 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 749 " when switching to a help buffer which is in the background with :buffer as
 750 " these options are local to windows (and not only to buffers). This happens
 751 " because I often want to use only one window and thus the help buffer is in
 752 " the background.
 753         autocmd BufWinEnter *.txt
 754             \ if &filetype == 'help' |
 755             \     setlocal nolist |
 756             \     setlocal nonumber |
 757             \ endif
 758
 759 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 760 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 761 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 762 " doesn't exist in older Vims.
 763         if exists('##InsertLeave')
 764             autocmd InsertLeave * set nopaste
 765         endif
 766
 767 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 768 " doesn't exist in older Vims.
 769         if exists('##QuickFixCmdPre')
 770             autocmd QuickFixCmdPre * write
 771         endif
 772
 773 " Don't ignore case while in insert mode, but ignore case in all other modes.
 774 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 775 " capitalization. But while searching (/) 'ignorecase' is used.
 776 " InsertEnter/InsertLeave doesn't exist in older Vims.
 777         if exists('##InsertEnter') && exists('##InsertLeave')
 778             autocmd InsertEnter * set noignorecase
 779             autocmd InsertLeave * set   ignorecase
 780         endif
 781
 782 " AFTER/FTPLUGIN AUTO COMMANDS
 783
 784 " Disable spell checking for files which don't need it.
 785         autocmd FileType deb  setlocal nospell
 786         autocmd FileType diff setlocal nospell
 787         autocmd FileType tar  setlocal nospell
 788 " Fix to allow Vim edit crontab files as crontab doesn't work with
 789 " backupcopy=auto.
 790         autocmd FileType crontab setlocal backupcopy=yes
 791 " Don't use the modeline in git commits as the diff created by `git commit -v`
 792 " may contain one which could change the filetype or other settings of the
 793 " commit buffer. Also make sure we use only 72 characters per line which is
 794 " the recommendation for git commit messages (http://tpope.net/node/106).
 795         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 796                                  \ setlocal textwidth=72
 797 " Use the same comment string as for Vim files in Vimperator files.
 798         autocmd FileType vimperator setlocal commentstring=\"%s
 799 " Use TeX compiler for (La)TeX files.
 800         autocmd FileType tex compiler tex
 801
 802 " FTDETECT AUTO COMMANDS
 803
 804 " Recognize .md as markdown files (Vim default is .mkd).
 805         autocmd BufRead,BufNewFile *.md set filetype=mkd
 806 " Recognize .test as Tcl files.
 807         autocmd BufRead,BufNewFile *.test set filetype=tcl
 808
 809 " OTHER AUTO COMMANDS
 810
 811 " Disable spell checking, displaying of list characters and long lines when
 812 " viewing documentation.
 813         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 814
 815 " Use diff filetype for mercurial patches in patch queue.
 816         autocmd BufReadPost */.hg/patches/* set filetype=diff
 817
 818     augroup END
 819 endif
 820
 821
 822 " CUSTOM FUNCTIONS AND COMMANDS
 823
 824 if has('eval')
 825 " Convenient command to see the difference between the current buffer and the
 826 " file it was loaded from, thus the changes you made. Thanks to the
 827 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 828 " for the diffed file than the filetype for the original file.
 829     if !exists(':DiffOrig')
 830         command DiffOrig
 831             \ let s:diff_orig_filetype = &filetype
 832             \ | vertical new
 833             \ | let &filetype = s:diff_orig_filetype
 834             \ | unlet s:diff_orig_filetype
 835             \ | set buftype=nofile
 836             \ | read ++edit #
 837             \ | 0d_
 838             \ | diffthis
 839             \ | wincmd p
 840             \ | diffthis
 841     endif
 842 endif