vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Increase history of executed commands (:).
  74 set history=1000
  75
  76 " Increase number of possible undos.
  77 set undolevels=1000
  78
  79 " Remember marks (including the last cursor position) for more files.
  80 if has('viminfo')
  81     set viminfo^='1000
  82 endif
  83
  84 " Use strong encryption if possible, also used for swap/undo files.
  85 if exists('+cryptmethod')
  86     set cryptmethod=blowfish
  87 endif
  88
  89 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  90 " is used multiple times.
  91 if has('autocmd')
  92     augroup vimrc
  93         autocmd!
  94     augroup END
  95 endif
  96
  97
  98 " HELPER FUNCTIONS
  99
 100 if has('eval')
 101 " Check if the given syntax group is available. Thanks to bairui in #vim on
 102 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 103     function! s:HasSyntaxGroup(group)
 104         try
 105             execute 'silent highlight ' . a:group
 106         " \a = [A-Za-z]
 107         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 108             return 0
 109         endtry
 110         return 1
 111     endfunction
 112
 113 " Check if the given Vim version and patch is available.
 114     function! s:HasVersionAndPatch(version, patch)
 115         return v:version > a:version
 116             \ || (v:version == a:version && has('patch' . a:patch))
 117     endfunction
 118 endif
 119
 120
 121 " EDIT SETTINGS
 122
 123 " Enable automatic file detection, plugin and indention support.
 124 if has('autocmd')
 125     filetype off " necessary for pathogen to force a reload of ftplugins
 126     filetype plugin indent on
 127 endif
 128
 129 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 130 " existing files.
 131 set fileencodings=utf-8,latin1
 132
 133 " Always use unix line-endings for new files.
 134 set fileformats=unix,dos
 135
 136 " Wrap text after 78 characters.
 137 set textwidth=78
 138
 139 " Set tabs to 4 spaces, use softtabs.
 140 set shiftwidth=4
 141 set softtabstop=4
 142 set expandtab
 143 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 144 set shiftround
 145 " Use the default value for real tabs.
 146 set tabstop=8
 147
 148 " Enable auto indention.
 149 set autoindent
 150
 151 " When joining lines only add one space after a sentence.
 152 set nojoinspaces
 153
 154 " Allow backspacing over autoindent and line breaks.
 155 set backspace=indent,eol
 156
 157 " Start a comment when hitting enter after a commented line (r) and when using
 158 " o or O around a commented line (o).
 159 set formatoptions+=ro
 160 " Don't break a line if was already longer then 'textwidth' when insert mode
 161 " started.
 162 set formatoptions+=l
 163 " Remove comment leader when joining lines where it makes sense.
 164 if <SID>HasVersionAndPatch(703, 541)
 165     set formatoptions+=j
 166 endif
 167
 168 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 169 " no character) in visual block mode.
 170 set virtualedit=block
 171
 172 " Already display matches while typing the search command. This makes spotting
 173 " errors easy.
 174 set incsearch
 175
 176 " Activate syntax folding.
 177 if has('folding')
 178     set foldmethod=syntax
 179     " Only use fold column if we have enough space (for example not in a
 180     " (virtual) terminal which has only 80 columns).
 181     if &columns > 80
 182         set foldcolumn=2
 183     endif
 184     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 185                      " folding which is not what I want
 186 endif
 187
 188 " Only check case if the searched word contains a capital character.
 189 set ignorecase
 190 set smartcase
 191
 192 " Activate spell checking, use English as default.
 193 if exists('+spell') && has('syntax')
 194     " But not when diffing because spell checking is distracting in this case.
 195     if !&diff
 196         set spell
 197     endif
 198     set spelllang=en_us
 199 endif
 200
 201 " Allow buffers with changes to be hidden. Very important for effective
 202 " editing with multiple buffers. Prevents the "E37: No write since last change
 203 " (add ! to override)" warning.
 204 set hidden
 205
 206
 207 " DISPLAY SETTINGS
 208
 209 " Use a dark background. Doesn't change the background color, only sets text
 210 " colors for a dark terminal.
 211 set background=dark
 212
 213 " Use my color scheme if 256 colors are available.
 214 if &t_Co == 256 || has('gui_running')
 215     colorscheme simon
 216 endif
 217
 218 " Display line numbers.
 219 set number
 220 " But use as little space as possible for the numbers column. Thanks to James
 221 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 222 if exists('+numberwidth')
 223     set numberwidth=1
 224 endif
 225 " Display the ruler with current line/file position. If 'statusline' is used
 226 " then this only affects <C-G>.
 227 set ruler
 228 " Display partial commands in the status line.
 229 set showcmd
 230
 231 " Don't redraw screen when executing macros; increases speed. Thanks to James
 232 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 233 set lazyredraw
 234
 235 " Visualize the line the cursor is currently in.
 236 if exists('+cursorline')
 237     set cursorline
 238 endif
 239
 240 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 241 " remove the highlighting until the next search.
 242 set hlsearch
 243
 244 " Display some special characters.
 245 set list
 246 set listchars=
 247 " Display tabs as ">--------".
 248 set listchars+=tab:>-
 249 " Display trailing whitespace as "-".
 250 set listchars+=trail:-
 251 " Display markers for long lines when wrapping is disabled.
 252 set listchars+=extends:>,precedes:<
 253 " Display non-breakable space as "!".
 254 if v:version >= 700
 255     set listchars+=nbsp:!
 256 endif
 257
 258 " Don't draw the vertical split separator by using space as character. Thanks
 259 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 260 " non-breakable space. But a simple space works as well, as long as the
 261 " current color scheme is not reset.
 262 if has('windows') && has('folding')
 263     set fillchars+=vert:\  " comment to prevent trailing whitespace
 264 endif
 265
 266 if has('statusline')
 267     " Always display the status line even if there is only one window.
 268     set laststatus=2
 269
 270     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 271     " is the highest buffer number, otherwise return nothing. Used in
 272     " 'statusline' to get an overview of available buffer numbers.
 273     function! StatuslineBufferCount()
 274         let l:bufnr = bufnr('$')
 275         if l:bufnr > 1
 276             let l:result = '/'
 277             if exists('*printf')
 278                 let l:result .= printf('%02d', l:bufnr)
 279             else
 280                 " Older Vims don't have printf() (and no .= either). Emulate
 281                 " "%02d".
 282                 if l:bufnr < 10
 283                     let l:result = l:result . '0'
 284                 endif
 285                 let l:result = l:result . l:bufnr
 286             endif
 287             return l:result
 288         else
 289             return ''
 290         endif
 291     endfunction
 292
 293     " Like %f but use relative filename if it's shorter than the absolute path
 294     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 295     " not enough because it doesn't create '../'s.
 296     function! StatuslineRelativeFilename()
 297         " Display only filename for help files.
 298         if &buftype == 'help'
 299             return expand('%:t')
 300         endif
 301         " Special case for scratch files.
 302         if &buftype == 'nofile'
 303             return '[Scratch]'
 304         endif
 305
 306         let l:path = expand('%')
 307         " No file.
 308         if l:path == ''
 309             return '[No Name]'
 310         endif
 311         " Path is already relative, nothing to do.
 312         if stridx(l:path, '/') != 0
 313             return l:path
 314         endif
 315
 316         " Absolute path to this file.
 317         let l:path = expand('%:p')
 318         " Shortened path to this file, thanks to bairui in #vim on Freenode
 319         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 320         " Vim normally uses as %f (minus some exceptions).
 321         let l:original_path = fnamemodify(l:path, ':~')
 322         " Absolute path to the current working directory.
 323         let l:cwd = getcwd()
 324
 325         " Working directory completely contained in path, replace it with a
 326         " relative path. Happens for example when opening a file with netrw.
 327         " %f displays this as absolute path, but we want a relative path of
 328         " course.
 329         if stridx(l:path, l:cwd) == 0
 330             return strpart(l:path, strlen(l:cwd) + 1)
 331         endif
 332
 333         let l:path_list = split(l:path, '/')
 334         let l:cwd_list  = split(l:cwd,  '/')
 335
 336         " Remove the common path.
 337         while l:path_list[0] == l:cwd_list[0]
 338             call remove(l:path_list, 0)
 339             call remove(l:cwd_list,  0)
 340         endwhile
 341
 342         " Add as many '..' as necessary for the relative path and join the
 343         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 344         " the hint to use repeat() instead of a loop.
 345         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 346
 347         " Use the shorter path, either relative or absolute.
 348         if strlen(l:path) < strlen(l:original_path)
 349             return l:path
 350         else
 351             return l:original_path
 352         endif
 353     endfunction
 354
 355     set statusline=
 356     " on the left
 357     set statusline+=%02n  " buffer number
 358     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 359     set statusline+=:
 360     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 361         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 362         set statusline+=\     " space after path
 363     else
 364         set statusline+=%f\   " path to current file in buffer
 365     endif
 366     set statusline+=%h    " [help] if buffer is help file
 367     set statusline+=%w    " [Preview] if buffer is preview buffer
 368     set statusline+=%m    " [+] if buffer was modified,
 369                           " [-] if 'modifiable' is off
 370     set statusline+=%r    " [RO] if buffer is read only
 371
 372     " on the right
 373     set statusline+=%=                " right align
 374     set statusline+=0x%-8B\           " current character under cursor as hex
 375     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 376                                       " column number (%c),
 377                                       " virtual column number if different
 378                                       "                       than %c (%V)
 379     set statusline+=%P                " position in file in percent
 380 endif
 381
 382
 383 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 384
 385 " noremap is used to make sure the right side is executed as is and can't be
 386 " modified by a plugin or other settings. Except for <Nop> which isn't
 387 " affected by mappings.
 388
 389 " Easy way to exit insert mode. jk is preferred because it's faster.
 390 inoremap jj <Esc>
 391 inoremap jk <Esc>
 392 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 393 " (2010-10-15).
 394 cnoremap jj <C-C>
 395 cnoremap jk <C-C>
 396
 397 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 398 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 399 map <Right>  <Nop>
 400 map <Left>   <Nop>
 401 map <Up>     <Nop>
 402 map <Down>   <Nop>
 403 imap <Right> <Nop>
 404 imap <Left>  <Nop>
 405 imap <Up>    <Nop>
 406 imap <Down>  <Nop>
 407 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 408 " below).
 409 cmap <Up>    <Nop>
 410 cmap <Down>  <Nop>
 411 cmap <Right> <Nop>
 412 cmap <Left>  <Nop>
 413
 414 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 415 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 416 cnoremap <C-P> <Up>
 417 cnoremap <C-N> <Down>
 418
 419 if has('eval')
 420 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 421 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 422 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 423 " directly because it also enables that feature for other commands which I
 424 " don't want.
 425
 426     " Set 'nostartofline' for a single movement.
 427     function! s:TemporaryNostartofline(movement)
 428         let l:startofline = &startofline
 429         set nostartofline
 430         execute 'normal! ' . a:movement
 431         let &startofline = l:startofline
 432     endfunction
 433
 434     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 435     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 436     nnoremap <silent> <C-F>
 437         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 438     nnoremap <silent> <C-B>
 439         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 440     nnoremap <silent> <C-D>
 441         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 442     nnoremap <silent> <C-U>
 443         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 444 endif
 445
 446 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 447 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 448 " Only the current buffer is written, thus switching to another buffer works
 449 " too.
 450 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 451
 452 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 453 " in #vim on Freenode (2011-08-15 00:17 CEST).
 454 nnoremap <C-G> 2<C-G>
 455
 456 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 457 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 458 nmap <Space> <C-F>
 459 nmap - <C-B>
 460
 461 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 462 " (2010-05-16 18:38 CEST) for this idea.
 463 nnoremap <silent> gb :bnext<CR>
 464 nnoremap <silent> gB :bprevious<CR>
 465 if has('eval')
 466     " But when starting again at the first buffer, print a warning which
 467     " reminds me that I've already seen that buffer.
 468     function! s:NextBuffer()
 469         " Are we currently on the last buffer and moving to the first?
 470         let l:last_buffer = 0
 471         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 472             let l:last_buffer = 1
 473         endif
 474
 475         " Go to the next buffer.
 476         if !l:last_buffer
 477             bnext
 478
 479         " Go to the first buffer, silent is necessary or the following message
 480         " won't be displayed because it's overwritten by the status message
 481         " displayed when entering a buffer.
 482         else
 483             silent bnext
 484
 485             echohl WarningMsg
 486             echo 'Starting again at first buffer.'
 487             echohl None
 488         endif
 489     endfunction
 490     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 491 endif
 492
 493 " Fast access to buffers.
 494 nnoremap <silent> <Leader>1 :1buffer<CR>
 495 nnoremap <silent> <Leader>2 :2buffer<CR>
 496 nnoremap <silent> <Leader>3 :3buffer<CR>
 497 nnoremap <silent> <Leader>4 :4buffer<CR>
 498 nnoremap <silent> <Leader>5 :5buffer<CR>
 499 nnoremap <silent> <Leader>6 :6buffer<CR>
 500 nnoremap <silent> <Leader>7 :7buffer<CR>
 501 nnoremap <silent> <Leader>8 :8buffer<CR>
 502 nnoremap <silent> <Leader>9 :9buffer<CR>
 503 nnoremap <silent> <Leader>0 :10buffer<CR>
 504
 505 " Make last active window the only window. Similar to <C-W> o.
 506 nnoremap <C-W>O <C-W>p<C-W>o
 507
 508 " Maps to change spell language between English and German and disable spell
 509 " checking.
 510 if exists('+spell')
 511     nnoremap <silent> <Leader>sn :set nospell<CR>
 512     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 513     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 514 endif
 515
 516 " Add semicolon to the end of the line. Thanks to
 517 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 518 " on Freenode for an improved version which doesn't clobber any marks.
 519 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 520
 521 " * and # for selections in visual mode. Thanks to
 522 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 523 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 524 if has('eval')
 525     function! s:VSetSearch()
 526         let l:temp = @@
 527         normal! gvy
 528         " Added \C to force 'noignorecase' while searching the current visual
 529         " selection. I want to search for the exact string in this case.
 530         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 531         let @@ = l:temp
 532     endfunction
 533     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 534     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 535 endif
 536
 537 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 538 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 539 " mailing list for the commands.
 540 if v:version < 700
 541     cnoreabbrev W w
 542     cnoreabbrev Wa wa
 543     cnoreabbrev Wq wq
 544     cnoreabbrev Wqa wqa
 545 else
 546     cnoreabbrev <expr> W
 547         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 548     cnoreabbrev <expr> Wa
 549         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 550     cnoreabbrev <expr> Wq
 551         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 552     cnoreabbrev <expr> Wqa
 553         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 554 endif
 555 " Also fix my typo with "Q".
 556 if v:version < 700
 557     cnoreabbrev Q q
 558     cnoreabbrev Qa qa
 559 else
 560     cnoreabbrev <expr> Q
 561         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 562     cnoreabbrev <expr> Qa
 563         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 564 endif
 565
 566 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 567 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 568 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 569
 570 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 571 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 572 " Vim's source.
 573 inoremap <C-U> <C-G>u<C-U>
 574 " Same for <C-@> (insert previously inserted text and leave insert mode).
 575 inoremap <C-@> <C-G>u<C-@>
 576 " And for <C-A> (insert previously inserted text).
 577 inoremap <C-A> <C-G>u<C-A>
 578 " And for <C-W> (delete word before cursor).
 579 inoremap <C-W> <C-G>u<C-W>
 580
 581 if has('eval')
 582 " New text-objects ii and ai to work on text with the same indentation. Thanks
 583 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 584 " (visited on 2011-11-19).
 585     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 586     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 587     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 588     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 589
 590     function! s:IndTxtObj(inner)
 591         let curline = line(".")
 592         let lastline = line("$")
 593         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 594         let i = i < 0 ? 0 : i
 595         if getline(".") !~ "^\\s*$"
 596             let p = line(".") - 1
 597             let nextblank = getline(p) =~ "^\\s*$"
 598             while p > 0
 599                     \ && ((i == 0 && !nextblank)
 600                         \ || (i > 0 && ((indent(p) >= i
 601                             \ && !(nextblank && a:inner))
 602                             \ || (nextblank && !a:inner))))
 603                 -
 604                 let p = line(".") - 1
 605                 let nextblank = getline(p) =~ "^\\s*$"
 606             endwhile
 607             normal! 0V
 608             call cursor(curline, 0)
 609             let p = line(".") + 1
 610             let nextblank = getline(p) =~ "^\\s*$"
 611             while p <= lastline
 612                     \ && ((i == 0 && !nextblank)
 613                         \ || (i > 0 && ((indent(p) >= i
 614                             \ && !(nextblank && a:inner))
 615                             \ || (nextblank && !a:inner))))
 616                 +
 617                 let p = line(".") + 1
 618                 let nextblank = getline(p) =~ "^\\s*$"
 619             endwhile
 620             normal! $
 621         endif
 622     endfunction
 623 endif
 624
 625
 626 " ABBREVIATIONS
 627
 628 " Fix some of my spelling mistakes (German).
 629 inoreabbrev relle reelle
 630 inoreabbrev reele reelle
 631 " Fix some of my spelling mistakes (English).
 632 inoreabbrev completly completely
 633
 634
 635 " SYNTAX SETTINGS
 636
 637 " Activate syntax coloring.
 638 if has('syntax')
 639     syntax enable
 640
 641 " Don't highlight more than 500 columns as I normally don't have that long
 642 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 643 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 644     if exists('+synmaxcol')
 645         set synmaxcol=500
 646     endif
 647
 648 " Use (limited) syntax based omni completion if no other omni completion is
 649 " available. Taken from :help ft-syntax-omni.
 650     if has('autocmd') && exists('+omnifunc')
 651         augroup vimrc
 652             autocmd FileType *
 653                 \ if &omnifunc == '' |
 654                 \     setlocal omnifunc=syntaxcomplete#Complete |
 655                 \ endif
 656         augroup END
 657     endif
 658
 659 " Function to enable all custom highlights. Necessary as highlights are
 660 " window-local and thus must be set for each new window.
 661     function! s:CustomSyntaxHighlights()
 662         " Not the first time called, nothing to do.
 663         if exists('w:vimrc_syntax_run')
 664             return
 665         endif
 666         let w:vimrc_syntax_run = 1
 667
 668 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 669 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 670 " disabled when necessary with :2match (in Vim >= 700).
 671         if !&diff && exists(':2match')
 672             " Use ColorColumn for overlong lines if available and my color
 673             " scheme is used.
 674             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 675                 2match ColorColumn /\%>78v./
 676             else
 677                 2match Todo /\%>78v./
 678             endif
 679         elseif !&diff
 680             match Todo /\%>78v./
 681         endif
 682
 683         if exists('*matchadd')
 684 " Highlight some important keywords in all documents.
 685             let l:todos = ['TODO', 'XXX', 'FIXME',
 686                          \ 'CHANGED', 'REMOVED', 'DELETED']
 687             " Compatibility fix for Vim 6.4 which can't handle for in function
 688             " (without function it's ignored).
 689             execute '  for l:x in l:todos'
 690                   \ '|     call matchadd("Todo", l:x)'
 691                   \ '| endfor'
 692
 693 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 694             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 695                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 696                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 697                           \ '205f', '2060', '3000', 'feff']
 698             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 699             " it won't work!
 700             execute '  for l:x in l:spaces'
 701                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 702                   \ '| endfor'
 703
 704 " Special highlight for tabs to reduce their visibility in contrast to other
 705 " SpecialKey characters (e.g. ^L).
 706             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 707                 call matchadd('specialKeyTab', '\t')
 708             endif
 709         endif
 710     endfunction
 711 " Enable highlights for the current and all new windows. Thanks to bairui in
 712 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 713     call <SID>CustomSyntaxHighlights()
 714     if has('autocmd')
 715         augroup vimrc
 716             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 717         augroup END
 718     endif
 719
 720 " Settings for specific filetypes.
 721
 722     " C
 723     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 724     " Haskell.
 725     let g:hs_highlight_delimiters = 1
 726     let g:hs_highlight_boolean = 1
 727     let g:hs_highlight_types = 1
 728     let g:hs_highlight_more_types = 1
 729     " Perl.
 730     let g:perl_fold = 1
 731     let g:perl_fold_blocks = 1
 732     let g:perl_nofold_packages = 1
 733     let g:perl_include_pod = 1 " syntax coloring for PODs
 734     " Python.
 735     let g:python_highlight_all = 1
 736     " Shell.
 737     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 738     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 739     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 740     " Vim.
 741     let g:vimsyn_embed = 0      " don't highlight embedded languages
 742     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 743     " XML.
 744     let g:xml_syntax_folding = 1
 745 endif
 746
 747
 748 " PLUGIN SETTINGS
 749
 750 if has('eval')
 751 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 752 " installing/removing/updating plugins simple. (Used for plugins with more
 753 " than one file.) Ignore errors in case pathogen is not installed.
 754     if v:version >= 700
 755         silent! execute 'call pathogen#infect()'
 756     endif
 757
 758 " Settings for securemodelines.
 759     " Only allow items I need (also includes spl which is not enabled by
 760     " default).
 761     if v:version >= 700 " need lists
 762         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 763                                               \ 'sw', 'sts', 'noet']
 764     endif
 765
 766 " Settings for the NERD commenter.
 767     " Don't create any mappings I don't want to use.
 768     let g:NERDCreateDefaultMappings = 0
 769     " Map toggle comment.
 770     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 771
 772 " XPTemplate settings.
 773     " Try to maintain snippet rendering even after editing outside of a
 774     " snippet.
 775     let g:xptemplate_strict = 0
 776     " Don't complete any braces automatically.
 777     let g:xptemplate_brace_complete = 0
 778     " Only highlight the current placeholder.
 779     let g:xptemplate_highlight = 'current'
 780 endif
 781
 782
 783 " AUTO COMMANDS
 784
 785 " Use a custom auto group to prevent problems when the vimrc files is sourced
 786 " twice.
 787 if has('autocmd')
 788     augroup vimrc
 789
 790 " Go to last position of opened files. Taken from :help last-position-jump.
 791         autocmd BufReadPost *
 792             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 793             \     execute "normal! g'\"" |
 794             \ endif
 795 " But not for Git commits, go to beginning of the file.
 796         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 797
 798 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 799 " when switching to a help buffer which is in the background with :buffer as
 800 " these options are local to windows (and not only to buffers). This happens
 801 " because I often want to use only one window and thus the help buffer is in
 802 " the background.
 803         autocmd BufWinEnter *.txt
 804             \ if &filetype == 'help' |
 805             \     setlocal nolist |
 806             \     setlocal nonumber |
 807             \ endif
 808
 809 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 810 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 811 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 812 " doesn't exist in older Vims.
 813         if exists('##InsertLeave')
 814             autocmd InsertLeave * set nopaste
 815         endif
 816
 817 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 818 " doesn't exist in older Vims.
 819         if exists('##QuickFixCmdPre')
 820             autocmd QuickFixCmdPre * write
 821         endif
 822
 823 " Don't ignore case while in insert mode, but ignore case in all other modes.
 824 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 825 " capitalization. But while searching (/) 'ignorecase' is used.
 826 " InsertEnter/InsertLeave doesn't exist in older Vims.
 827         if exists('##InsertEnter') && exists('##InsertLeave')
 828             autocmd InsertEnter * set noignorecase
 829             autocmd InsertLeave * set   ignorecase
 830         endif
 831
 832 " AFTER/FTPLUGIN AUTO COMMANDS
 833
 834 " Disable spell checking for files which don't need it.
 835         autocmd FileType deb  setlocal nospell
 836         autocmd FileType diff setlocal nospell
 837         autocmd FileType tar  setlocal nospell
 838 " Fix to allow Vim edit crontab files as crontab doesn't work with
 839 " backupcopy=auto.
 840         autocmd FileType crontab setlocal backupcopy=yes
 841 " Don't use the modeline in git commits as the diff created by `git commit -v`
 842 " may contain one which could change the filetype or other settings of the
 843 " commit buffer. Also make sure we use only 72 characters per line which is
 844 " the recommendation for git commit messages (http://tpope.net/node/106).
 845         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 846                                  \ setlocal textwidth=72
 847 " Use the same comment string as for Vim files in Vimperator files.
 848         autocmd FileType vimperator setlocal commentstring=\"%s
 849 " Use TeX compiler for (La)TeX files.
 850         autocmd FileType tex compiler tex
 851
 852 " FTDETECT AUTO COMMANDS
 853
 854 " Recognize .md as markdown files (Vim default is .mkd).
 855         autocmd BufRead,BufNewFile *.md set filetype=mkd
 856 " Recognize .test as Tcl files.
 857         autocmd BufRead,BufNewFile *.test set filetype=tcl
 858
 859 " OTHER AUTO COMMANDS
 860
 861 " Disable spell checking, displaying of list characters and long lines when
 862 " viewing documentation.
 863         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 864
 865 " Use diff filetype for mercurial patches in patch queue.
 866         autocmd BufReadPost */.hg/patches/* set filetype=diff
 867
 868     augroup END
 869 endif
 870
 871
 872 " CUSTOM FUNCTIONS AND COMMANDS
 873
 874 if has('eval')
 875 " Convenient command to see the difference between the current buffer and the
 876 " file it was loaded from, thus the changes you made. Thanks to the
 877 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 878 " for the diffed file than the filetype for the original file.
 879     if !exists(':DiffOrig')
 880         command DiffOrig
 881             \ let s:diff_orig_filetype = &filetype
 882             \ | vertical new
 883             \ | let &filetype = s:diff_orig_filetype
 884             \ | unlet s:diff_orig_filetype
 885             \ | set buftype=nofile
 886             \ | read ++edit #
 887             \ | 0d_
 888             \ | diffthis
 889             \ | wincmd p
 890             \ | diffthis
 891     endif
 892 endif