vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 109 " is used multiple times. Necessary to support reloading the vimrc.
 110 if has('autocmd')
 111     augroup vimrc
 112         autocmd!
 113     augroup END
 114 endif
 115
 116
 117 " HELPER FUNCTIONS
 118
 119 if has('eval')
 120 " Check if the given syntax group is available. Thanks to bairui in #vim on
 121 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 122     function! s:HasSyntaxGroup(group)
 123         try
 124             execute 'silent highlight ' . a:group
 125         " \a = [A-Za-z]
 126         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 127             return 0
 128         endtry
 129         return 1
 130     endfunction
 131
 132 " Check if the given Vim version and patch is available.
 133     function! s:HasVersionAndPatch(version, patch)
 134         return v:version > a:version
 135             \ || (v:version == a:version && has('patch' . a:patch))
 136     endfunction
 137 endif
 138
 139
 140 " EDIT SETTINGS
 141
 142 " Enable automatic file detection, plugin and indention support.
 143 if has('autocmd')
 144     filetype off " necessary for pathogen to force a reload of ftplugins
 145     filetype plugin indent on
 146 endif
 147
 148 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 149 " existing files.
 150 set fileencodings=utf-8,latin1
 151
 152 " Always use unix line-endings for new files.
 153 set fileformats=unix,dos
 154
 155 " Wrap text after 78 characters.
 156 set textwidth=78
 157
 158 " Set tabs to 4 spaces, use softtabs.
 159 set shiftwidth=4
 160 set softtabstop=4
 161 set expandtab
 162 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 163 set shiftround
 164 " Use the default value for real tabs.
 165 set tabstop=8
 166
 167 " Enable auto indention.
 168 set autoindent
 169
 170 " When joining lines only add one space after a sentence.
 171 set nojoinspaces
 172
 173 " Allow backspacing over autoindent and line breaks.
 174 set backspace=indent,eol
 175
 176 " Start a comment when hitting enter after a commented line (r) and when using
 177 " o or O around a commented line (o).
 178 set formatoptions+=ro
 179 " Don't break a line if was already longer then 'textwidth' when insert mode
 180 " started.
 181 set formatoptions+=l
 182 " Remove comment leader when joining lines where it makes sense.
 183 if <SID>HasVersionAndPatch(703, 541)
 184     set formatoptions+=j
 185 endif
 186
 187 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 188 " no character) in visual block mode.
 189 set virtualedit=block
 190
 191 " Already display matches while typing the search command. This makes spotting
 192 " typos easy and searching faster.
 193 set incsearch
 194
 195 " Activate syntax folding.
 196 if has('folding')
 197     set foldmethod=syntax
 198     " Only use fold column if we have enough space (for example not in a
 199     " (virtual) terminal which has only 80 columns).
 200     if &columns > 80
 201         set foldcolumn=2
 202     endif
 203     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 204                      " folding which is not what I want
 205     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 206     set foldopen-=block
 207 endif
 208
 209 " Only check case if the searched word contains a capital character.
 210 set ignorecase
 211 set smartcase
 212
 213 " Activate spell checking, use English as default.
 214 if exists('+spell') && has('syntax')
 215     " But not when diffing because spell checking is distracting in this case.
 216     if !&diff
 217         set spell
 218     endif
 219     set spelllang=en_us
 220 endif
 221
 222 " Allow buffers with changes to be hidden. Very important for effective
 223 " editing with multiple buffers. Prevents the "E37: No write since last change
 224 " (add ! to override)" warning when switching buffers.
 225 set hidden
 226
 227
 228 " DISPLAY SETTINGS
 229
 230 " Use a dark background. Doesn't change the background color, only sets text
 231 " colors for a dark terminal.
 232 set background=dark
 233
 234 " Use my color scheme if 256 colors are available.
 235 if &t_Co == 256 || has('gui_running')
 236     colorscheme simon
 237 endif
 238
 239 " Display line numbers.
 240 set number
 241 " But use as little space as possible for the numbers column. Thanks to James
 242 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 243 if exists('+numberwidth')
 244     set numberwidth=1
 245 endif
 246 " Display the ruler with current line/file position. If 'statusline' is used
 247 " then this only affects <C-G>.
 248 set ruler
 249 " Display partial commands in the status line.
 250 set showcmd
 251
 252 " Don't redraw screen when executing macros; increases speed. Thanks to James
 253 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 254 set lazyredraw
 255
 256 " Visualize the line the cursor is currently in.
 257 if exists('+cursorline')
 258     set cursorline
 259 endif
 260
 261 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 262 " remove the highlighting until the next search.
 263 set hlsearch
 264
 265 " Display some special characters.
 266 set list
 267 set listchars=
 268 " Display tabs as ">--------".
 269 set listchars+=tab:>-
 270 " Display trailing whitespace as "-".
 271 set listchars+=trail:-
 272 " Display markers for long lines when wrapping is disabled.
 273 set listchars+=extends:>,precedes:<
 274 " Display non-breakable space as "!".
 275 if v:version >= 700
 276     set listchars+=nbsp:!
 277 endif
 278
 279 " Don't draw the vertical split separator by using space as character. Thanks
 280 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 281 " non-breakable space. But a simple space works as well, as long as the
 282 " current color scheme is not reset.
 283 if has('windows') && has('folding')
 284     set fillchars+=vert:\  " comment to prevent trailing whitespace
 285 endif
 286
 287 if has('statusline')
 288     " Always display the status line even if there is only one window.
 289     set laststatus=2
 290
 291     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 292     " is the highest buffer number, otherwise return nothing. Used in
 293     " 'statusline' to get an overview of available buffer numbers.
 294     function! StatuslineBufferCount()
 295         let l:bufnr = bufnr('$')
 296         if l:bufnr > 1
 297             let l:result = '/'
 298             if exists('*printf')
 299                 let l:result .= printf('%02d', l:bufnr)
 300             else
 301                 " Older Vims don't have printf() (and no .= either). Emulate
 302                 " "%02d".
 303                 if l:bufnr < 10
 304                     let l:result = l:result . '0'
 305                 endif
 306                 let l:result = l:result . l:bufnr
 307             endif
 308             return l:result
 309         else
 310             return ''
 311         endif
 312     endfunction
 313
 314     " Like %f but use relative filename if it's shorter than the absolute path
 315     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 316     " not enough because it doesn't create '../'s.
 317     function! StatuslineRelativeFilename()
 318         " Display only filename for help files.
 319         if &buftype == 'help'
 320             return expand('%:t')
 321         endif
 322         " Special case for scratch files.
 323         if &buftype == 'nofile'
 324             return '[Scratch]'
 325         endif
 326
 327         let l:path = expand('%')
 328         " No file.
 329         if l:path == ''
 330             return '[No Name]'
 331         endif
 332         " Path is already relative, nothing to do.
 333         if stridx(l:path, '/') != 0
 334             return l:path
 335         endif
 336
 337         " Absolute path to this file.
 338         let l:path = expand('%:p')
 339         " Shortened path to this file, thanks to bairui in #vim on Freenode
 340         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 341         " Vim normally uses as %f (minus some exceptions).
 342         let l:original_path = fnamemodify(l:path, ':~')
 343         " Absolute path to the current working directory.
 344         let l:cwd = getcwd()
 345
 346         " Working directory completely contained in path, replace it with a
 347         " relative path. Happens for example when opening a file with netrw.
 348         " %f displays this as absolute path, but we want a relative path of
 349         " course.
 350         if stridx(l:path, l:cwd) == 0
 351             return strpart(l:path, strlen(l:cwd) + 1)
 352         endif
 353
 354         let l:path_list = split(l:path, '/')
 355         let l:cwd_list  = split(l:cwd,  '/')
 356
 357         " Remove the common path.
 358         while l:path_list[0] == l:cwd_list[0]
 359             call remove(l:path_list, 0)
 360             call remove(l:cwd_list,  0)
 361         endwhile
 362
 363         " Add as many '..' as necessary for the relative path and join the
 364         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 365         " the hint to use repeat() instead of a loop.
 366         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 367
 368         " Use the shorter path, either relative or absolute.
 369         if strlen(l:path) < strlen(l:original_path)
 370             return l:path
 371         else
 372             return l:original_path
 373         endif
 374     endfunction
 375
 376     " Return current syntax group in brackets or nothing if there's none.
 377     function! StatuslineSyntaxGroup()
 378         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 379         if l:group != ''
 380             return '[' . l:group . '] '
 381         else
 382             return ''
 383         endif
 384     endfunction
 385
 386     set statusline=
 387     " on the left
 388     set statusline+=%02n  " buffer number
 389     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 390     set statusline+=:
 391     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 392         set statusline+=%{StatuslineRelativeFilename()} " path to current file
 393         set statusline+=\     " space after path
 394     else
 395         set statusline+=%f\   " path to current file in buffer
 396     endif
 397     set statusline+=%h    " [help] if buffer is help file
 398     set statusline+=%w    " [Preview] if buffer is preview buffer
 399     set statusline+=%m    " [+] if buffer was modified,
 400                           " [-] if 'modifiable' is off
 401     set statusline+=%r    " [RO] if buffer is read only
 402
 403     " on the right
 404     set statusline+=%=                " right align
 405     set statusline+=0x%-8B\           " current character under cursor as hex
 406     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 407                                       " column number (%c),
 408                                       " virtual column number if different
 409                                       "                       than %c (%V)
 410     set statusline+=%P                " position in file in percent
 411 endif
 412
 413
 414 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 415
 416 " noremap is used to make sure the right side is executed as is and can't be
 417 " modified by a plugin or other settings. Except for <Nop> which isn't
 418 " affected by mappings.
 419
 420 " Easy way to exit insert mode. jk is preferred because it's faster.
 421 inoremap jj <Esc>
 422 inoremap jk <Esc>
 423 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 424 " (2010-10-15).
 425 cnoremap jj <C-C>
 426 cnoremap jk <C-C>
 427
 428 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 429 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 430 map <Right>  <Nop>
 431 map <Left>   <Nop>
 432 map <Up>     <Nop>
 433 map <Down>   <Nop>
 434 imap <Right> <Nop>
 435 imap <Left>  <Nop>
 436 imap <Up>    <Nop>
 437 imap <Down>  <Nop>
 438 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 439 " below).
 440 cmap <Up>    <Nop>
 441 cmap <Down>  <Nop>
 442 cmap <Right> <Nop>
 443 cmap <Left>  <Nop>
 444
 445 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 446 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 447 cnoremap <C-P> <Up>
 448 cnoremap <C-N> <Down>
 449
 450 if has('eval')
 451 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 452 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 453 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 454 " directly because it also enables that feature for other commands which I
 455 " don't want.
 456
 457     " Set 'nostartofline' for a single movement.
 458     function! s:TemporaryNostartofline(movement)
 459         let l:startofline = &startofline
 460         set nostartofline
 461         execute 'normal! ' . a:movement
 462         let &startofline = l:startofline
 463     endfunction
 464
 465     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 466     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 467     nnoremap <silent> <C-F>
 468         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 469     nnoremap <silent> <C-B>
 470         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 471     nnoremap <silent> <C-D>
 472         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 473     nnoremap <silent> <C-U>
 474         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 475 endif
 476
 477 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 478 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 479 " Only the current buffer is written, thus switching to another buffer works
 480 " too.
 481 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 482
 483 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 484 " in #vim on Freenode (2011-08-15 00:17 CEST).
 485 nnoremap <C-G> 2<C-G>
 486
 487 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 488 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 489 nmap <Space> <C-F>
 490 nmap - <C-B>
 491
 492 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 493 " (2010-05-16 18:38 CEST) for this idea.
 494 nnoremap <silent> gb :bnext<CR>
 495 nnoremap <silent> gB :bprevious<CR>
 496 if has('eval')
 497     " But when starting again at the first buffer, print a warning which
 498     " reminds me that I've already seen that buffer.
 499     function! s:NextBuffer()
 500         " Are we currently on the last buffer and moving to the first?
 501         let l:last_buffer = 0
 502         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 503             let l:last_buffer = 1
 504         endif
 505
 506         " Go to the next buffer.
 507         if !l:last_buffer
 508             bnext
 509
 510         " Go to the first buffer, silent is necessary or the following message
 511         " won't be displayed because it's overwritten by the status message
 512         " displayed when entering a buffer.
 513         else
 514             silent bnext
 515
 516             echohl WarningMsg
 517             echo 'Starting again at first buffer.'
 518             echohl None
 519         endif
 520     endfunction
 521     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 522 endif
 523
 524 " Fast access to buffers.
 525 nnoremap <silent> <Leader>1 :1buffer<CR>
 526 nnoremap <silent> <Leader>2 :2buffer<CR>
 527 nnoremap <silent> <Leader>3 :3buffer<CR>
 528 nnoremap <silent> <Leader>4 :4buffer<CR>
 529 nnoremap <silent> <Leader>5 :5buffer<CR>
 530 nnoremap <silent> <Leader>6 :6buffer<CR>
 531 nnoremap <silent> <Leader>7 :7buffer<CR>
 532 nnoremap <silent> <Leader>8 :8buffer<CR>
 533 nnoremap <silent> <Leader>9 :9buffer<CR>
 534 nnoremap <silent> <Leader>0 :10buffer<CR>
 535
 536 " Make last active window the only window. Similar to <C-W> o.
 537 nnoremap <C-W>O <C-W>p<C-W>o
 538
 539 " Maps to change spell language between English and German and disable spell
 540 " checking.
 541 if exists('+spell')
 542     nnoremap <silent> <Leader>sn :set nospell<CR>
 543     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 544     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 545 " If no spell support is available, these mappings do nothing.
 546 else
 547     nmap <Leader>sn <Nop>
 548     nmap <Leader>se <Nop>
 549     nmap <Leader>sd <Nop>
 550 endif
 551
 552 " Add semicolon to the end of the line. Thanks to
 553 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 554 " on Freenode for an improved version which doesn't clobber any marks.
 555 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 556
 557 " * and # for selections in visual mode. Thanks to
 558 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 559 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 560 if has('eval')
 561     function! s:VSetSearch()
 562         let l:temp = @@
 563         normal! gvy
 564         " Added \C to force 'noignorecase' while searching the current visual
 565         " selection. I want to search for the exact string in this case.
 566         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 567         let @@ = l:temp
 568     endfunction
 569     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 570     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 571 endif
 572
 573 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 574 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 575 " mailing list for the commands.
 576 if v:version < 700
 577     cnoreabbrev W w
 578     cnoreabbrev Wa wa
 579     cnoreabbrev Wq wq
 580     cnoreabbrev Wqa wqa
 581 else
 582     cnoreabbrev <expr> W
 583         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 584     cnoreabbrev <expr> Wa
 585         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 586     cnoreabbrev <expr> Wq
 587         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 588     cnoreabbrev <expr> Wqa
 589         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 590 endif
 591 " Also fix my typo with "Q".
 592 if v:version < 700
 593     cnoreabbrev Q q
 594     cnoreabbrev Qa qa
 595 else
 596     cnoreabbrev <expr> Q
 597         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 598     cnoreabbrev <expr> Qa
 599         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 600 endif
 601
 602 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 603 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 604 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 605
 606 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 607 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 608 " Vim's source.
 609 inoremap <C-U> <C-G>u<C-U>
 610 " Same for <C-@> (insert previously inserted text and leave insert mode).
 611 inoremap <C-@> <C-G>u<C-@>
 612 " And for <C-A> (insert previously inserted text).
 613 inoremap <C-A> <C-G>u<C-A>
 614 " And for <C-W> (delete word before cursor).
 615 inoremap <C-W> <C-G>u<C-W>
 616
 617 if has('eval')
 618 " New text-objects ii and ai to work on text with the same indentation. Thanks
 619 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 620 " (visited on 2011-11-19).
 621     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 622     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 623     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 624     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 625
 626     function! s:IndTxtObj(inner)
 627         let curline = line(".")
 628         let lastline = line("$")
 629         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 630         let i = i < 0 ? 0 : i
 631         if getline(".") !~ "^\\s*$"
 632             let p = line(".") - 1
 633             let nextblank = getline(p) =~ "^\\s*$"
 634             while p > 0
 635                     \ && ((i == 0 && !nextblank)
 636                         \ || (i > 0 && ((indent(p) >= i
 637                             \ && !(nextblank && a:inner))
 638                             \ || (nextblank && !a:inner))))
 639                 -
 640                 let p = line(".") - 1
 641                 let nextblank = getline(p) =~ "^\\s*$"
 642             endwhile
 643             normal! 0V
 644             call cursor(curline, 0)
 645             let p = line(".") + 1
 646             let nextblank = getline(p) =~ "^\\s*$"
 647             while p <= lastline
 648                     \ && ((i == 0 && !nextblank)
 649                         \ || (i > 0 && ((indent(p) >= i
 650                             \ && !(nextblank && a:inner))
 651                             \ || (nextblank && !a:inner))))
 652                 +
 653                 let p = line(".") + 1
 654                 let nextblank = getline(p) =~ "^\\s*$"
 655             endwhile
 656             normal! $
 657         endif
 658     endfunction
 659 endif
 660
 661
 662 " ABBREVIATIONS
 663
 664 " Fix some of my spelling mistakes (German).
 665 inoreabbrev relle reelle
 666 inoreabbrev reele reelle
 667 " Fix some of my spelling mistakes (English).
 668 inoreabbrev completly completely
 669
 670
 671 " SYNTAX SETTINGS
 672
 673 " Activate syntax coloring.
 674 if has('syntax')
 675     syntax enable
 676
 677 " Don't highlight more than 500 columns as I normally don't have that long
 678 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 679 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 680     if exists('+synmaxcol')
 681         set synmaxcol=500
 682     endif
 683
 684 " Use (limited) syntax based omni completion if no other omni completion is
 685 " available. Taken from :help ft-syntax-omni.
 686     if has('autocmd') && exists('+omnifunc')
 687         augroup vimrc
 688             autocmd FileType *
 689                 \ if &omnifunc == '' |
 690                 \     setlocal omnifunc=syntaxcomplete#Complete |
 691                 \ endif
 692         augroup END
 693     endif
 694
 695 " Function to enable all custom highlights. Necessary as highlights are
 696 " window-local and thus must be set for each new window.
 697     function! s:CustomSyntaxHighlights()
 698         " Not the first time called, nothing to do.
 699         if exists('w:vimrc_syntax_run')
 700             return
 701         endif
 702         let w:vimrc_syntax_run = 1
 703
 704 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 705 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 706 " disabled when necessary with :2match (in Vim >= 700).
 707         if !&diff && exists(':2match')
 708             " Use ColorColumn for overlong lines if available and my color
 709             " scheme is used.
 710             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 711                 2match ColorColumn /\%>78v./
 712             else
 713                 2match Todo /\%>78v./
 714             endif
 715         elseif !&diff
 716             match Todo /\%>78v./
 717         endif
 718
 719         if exists('*matchadd')
 720 " Highlight some important keywords in all documents.
 721             let l:todos = ['TODO', 'XXX', 'FIXME',
 722                          \ 'CHANGED', 'REMOVED', 'DELETED']
 723             " Compatibility fix for Vim 6.4 which can't handle for in function
 724             " (without function it's ignored).
 725             execute '  for l:x in l:todos'
 726                   \ '|     call matchadd("Todo", l:x)'
 727                   \ '| endfor'
 728
 729 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 730             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 731                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 732                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 733                           \ '205f', '2060', '3000', 'feff']
 734             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 735             " it won't work!
 736             execute '  for l:x in l:spaces'
 737                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 738                   \ '| endfor'
 739
 740 " Special highlight for tabs to reduce their visibility in contrast to other
 741 " SpecialKey characters (e.g. ^L).
 742             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 743                 call matchadd('specialKeyTab', '\t')
 744             endif
 745         endif
 746     endfunction
 747 " Enable highlights for the current and all new windows. Thanks to bairui in
 748 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 749     call <SID>CustomSyntaxHighlights()
 750     if has('autocmd')
 751         augroup vimrc
 752             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 753         augroup END
 754     endif
 755
 756 " Settings for specific filetypes.
 757
 758     " C
 759     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 760     " Haskell.
 761     let g:hs_highlight_delimiters = 1
 762     let g:hs_highlight_boolean = 1
 763     let g:hs_highlight_types = 1
 764     let g:hs_highlight_more_types = 1
 765     " Java.
 766     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 767     " Perl.
 768     let g:perl_fold = 1
 769     let g:perl_fold_blocks = 1
 770     let g:perl_nofold_packages = 1
 771     let g:perl_include_pod = 1 " syntax coloring for PODs
 772     " Python.
 773     let g:python_highlight_all = 1
 774     " Shell.
 775     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 776     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 777     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 778     " Vim.
 779     let g:vimsyn_embed = 0      " don't highlight embedded languages
 780     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 781     " XML.
 782     let g:xml_syntax_folding = 1
 783 endif
 784
 785
 786 " PLUGIN SETTINGS
 787
 788 if has('eval')
 789 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 790 " installing/removing/updating plugins simple. (Used for plugins with more
 791 " than one file.) Ignore errors in case pathogen is not installed.
 792     if v:version >= 700
 793         silent! execute 'call pathogen#infect()'
 794     endif
 795
 796 " Settings for securemodelines.
 797     " Only allow items I need (also includes spl which is not enabled by
 798     " default).
 799     if v:version >= 700 " need lists
 800         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 801                                               \ 'sw', 'sts', 'noet']
 802     endif
 803
 804 " Settings for the NERD commenter.
 805     " Don't create any mappings I don't want to use.
 806     let g:NERDCreateDefaultMappings = 0
 807     " Map toggle comment.
 808     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 809
 810 " XPTemplate settings.
 811     " Try to maintain snippet rendering even after editing outside of a
 812     " snippet.
 813     let g:xptemplate_strict = 0
 814     " Don't complete any braces automatically.
 815     let g:xptemplate_brace_complete = 0
 816     " Only highlight the current placeholder.
 817     let g:xptemplate_highlight = 'current'
 818
 819 " CtrlP settings.
 820     " Don't manage the working directory (the default setting is too slow for
 821     " me).
 822     let g:ctrlp_working_path_mode = 0
 823     " Path to cache directory. I prefer to keep generated files as local as
 824     " possible.
 825     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 826     " Permanent cache, cleared by a crontab entry.
 827     let g:ctrlp_clear_cache_on_exit = 0
 828
 829 " FSWitch settings.
 830     " Default don't work well for my projects.
 831     augroup vimrc
 832         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 833                           \ | let b:fswitchlocs = './'
 834         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 835                           \ | let b:fswitchlocs = './'
 836     augroup END
 837
 838     " Switch to corresponding header/source file.
 839     nnoremap <silent> <Leader>h :FSHere<CR>
 840 endif
 841
 842
 843 " AUTO COMMANDS
 844
 845 " Use a custom auto group to prevent problems when the vimrc files is sourced
 846 " twice.
 847 if has('autocmd')
 848     augroup vimrc
 849
 850 " Go to last position of opened files. Taken from :help last-position-jump.
 851         autocmd BufReadPost *
 852             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 853             \     execute "normal! g'\"" |
 854             \ endif
 855 " But not for Git commits, go to beginning of the file.
 856         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 857
 858 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 859 " when switching to a help buffer which is in the background with :buffer as
 860 " these options are local to windows (and not only to buffers). This happens
 861 " because I often want to use only one window and thus the help buffer is in
 862 " the background.
 863         autocmd BufWinEnter *.txt
 864             \ if &filetype == 'help' |
 865             \     setlocal nolist |
 866             \     setlocal nonumber |
 867             \ endif
 868
 869 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 870 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 871 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 872 " doesn't exist in older Vims.
 873         if exists('##InsertLeave')
 874             autocmd InsertLeave * set nopaste
 875         endif
 876
 877 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 878 " doesn't exist in older Vims.
 879         if exists('##QuickFixCmdPre')
 880             autocmd QuickFixCmdPre * write
 881         endif
 882
 883 " Don't ignore case while in insert mode, but ignore case in all other modes.
 884 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 885 " capitalization. But while searching (/) 'ignorecase' is used.
 886 " InsertEnter/InsertLeave doesn't exist in older Vims.
 887         if exists('##InsertEnter') && exists('##InsertLeave')
 888             autocmd InsertEnter * set noignorecase
 889             autocmd InsertLeave * set   ignorecase
 890         endif
 891
 892 " Display a warning when editing a file which contains "do not edit" (ignoring
 893 " the case, \c), for example template files which were preprocessed or
 894 " auto-generated files. Especially useful when the header is not displayed on
 895 " the first screen, e.g. when the old position is restored. Not for vimrc
 896 " though.
 897         function! s:SearchForDoNotEditHeader()
 898             if search('\cdo not edit', 'n') == 0
 899                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 900                 return
 901             endif
 902
 903             echohl WarningMsg
 904             echo 'Do not edit this file! (Maybe a template file.)'
 905             echohl None
 906         endfunction
 907         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 908
 909 " AFTER/FTPLUGIN AUTO COMMANDS
 910
 911 " Disable spell checking for files which don't need it.
 912         autocmd FileType deb  setlocal nospell
 913         autocmd FileType diff setlocal nospell
 914         autocmd FileType tar  setlocal nospell
 915 " Fix to allow Vim edit crontab files as crontab doesn't work with
 916 " backupcopy=auto.
 917         autocmd FileType crontab setlocal backupcopy=yes
 918 " Don't use the modeline in git commits as the diff created by `git commit -v`
 919 " may contain one which could change the filetype or other settings of the
 920 " commit buffer. Also make sure we use only 72 characters per line which is
 921 " the recommendation for git commit messages (http://tpope.net/node/106).
 922         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 923                                  \ setlocal textwidth=72
 924 " Use the same comment string as for Vim files in Vimperator files.
 925         autocmd FileType vimperator setlocal commentstring=\"%s
 926 " Use TeX compiler for (La)TeX files.
 927         autocmd FileType tex compiler tex
 928
 929 " FTDETECT AUTO COMMANDS
 930
 931 " Recognize .md as markdown files (Vim default is .mkd).
 932         autocmd BufRead,BufNewFile *.md set filetype=mkd
 933 " Recognize .test as Tcl files.
 934         autocmd BufRead,BufNewFile *.test set filetype=tcl
 935
 936 " OTHER AUTO COMMANDS
 937
 938 " Disable spell checking, displaying of list characters and long lines when
 939 " viewing documentation.
 940         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 941
 942 " Use diff filetype for mercurial patches in patch queue.
 943         autocmd BufReadPost */.hg/patches/* set filetype=diff
 944
 945     augroup END
 946 endif
 947
 948
 949 " CUSTOM FUNCTIONS AND COMMANDS
 950
 951 if has('eval')
 952 " Convenient command to see the difference between the current buffer and the
 953 " file it was loaded from, thus the changes you made. Thanks to the
 954 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 955 " for the diffed file than the filetype for the original file.
 956     if !exists(':DiffOrig')
 957         command DiffOrig
 958             \ let s:diff_orig_filetype = &filetype
 959             \ | vertical new
 960             \ | let &filetype = s:diff_orig_filetype
 961             \ | unlet s:diff_orig_filetype
 962             \ | set buftype=nofile
 963             \ | read ++edit #
 964             \ | 0d_
 965             \ | diffthis
 966             \ | wincmd p
 967             \ | diffthis
 968     endif
 969 endif