vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     set foldcolumn=2
 143     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 144                      " folding which is not what I want
 145 endif
 146
 147 " Only check for case if the searched word contains a capital character.
 148 set ignorecase
 149 set smartcase
 150
 151 " Activate spell checking, use English as default.
 152 if exists('+spell') && has('syntax')
 153     " But not when diffing as spell checking is distracting in this case.
 154     if !&diff
 155         set spell
 156     endif
 157     set spelllang=en_us
 158 endif
 159
 160 " Allow buffers with changes to be hidden. Very important for effective
 161 " editing with multiple buffers.
 162 set hidden
 163
 164
 165 " DISPLAY SETTINGS
 166
 167 " Use a dark background. Doesn't change the background color, only sets text
 168 " colors for a dark terminal.
 169 set background=dark
 170
 171 " Display line numbers.
 172 set number
 173 " But use as little space as necessary for the numbers column. Thanks to James
 174 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 175 if exists('+numberwidth')
 176     set numberwidth=1
 177 endif
 178 " Display the ruler with current line/file position. If 'statusline' is used
 179 " then this only affects <C-G>.
 180 set ruler
 181 " Display partial commands in the status line.
 182 set showcmd
 183
 184 " Don't redraw screen when executing macros; increases speed. Thanks to James
 185 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 186 set lazyredraw
 187
 188 " Visualize the line the cursor is currently in.
 189 if exists('+cursorline')
 190     set cursorline
 191 endif
 192
 193 " Display tabs, trailing space, non breakable spaces and long lines (when
 194 " wrapping is disabled).
 195 set list
 196 set listchars=trail:-,extends:>
 197 if v:version >= 700
 198     set listchars+=nbsp:!
 199 endif
 200
 201 if has('statusline')
 202     " Always display the status line even if there is only one window.
 203     set laststatus=2
 204
 205     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 206     " is the highest buffer number, otherwise return nothing. Used in
 207     " 'statusline' to get an overview of available buffer numbers.
 208     function! StatuslineBufferCount()
 209         let l:bufnr = bufnr('$')
 210         if l:bufnr > 1
 211             let l:result = '/'
 212             if exists('*printf')
 213                 let l:result .= printf('%02d', l:bufnr)
 214             else
 215                 " Older Vims don't have printf() (and no .= either). Emulate
 216                 " "%02d".
 217                 if l:bufnr < 10
 218                     let l:result = l:result . '0'
 219                 endif
 220                 let l:result = l:result . l:bufnr
 221             endif
 222             return l:result
 223         else
 224             return ''
 225         endif
 226     endfunction
 227
 228     set statusline=
 229     " on the left
 230     set statusline+=%02n  " buffer number
 231     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 232     set statusline+=:
 233     set statusline+=%f\   " path to current file in buffer
 234     set statusline+=%h    " [help] if buffer is help file
 235     set statusline+=%w    " [Preview] if buffer is preview buffer
 236     set statusline+=%m    " [+] if buffer was modified,
 237                           " [-] if 'modifiable' is off
 238     set statusline+=%r    " [RO] if buffer is read only
 239
 240     " on the right
 241     set statusline+=%=                " right align
 242     set statusline+=0x%-8B\           " current character under cursor as hex
 243     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 244                                       " column number (%c),
 245                                       " virtual column number if different
 246                                       "                       than %c (%V)
 247     set statusline+=%P                " position in file in percent
 248 endif
 249
 250
 251 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 252
 253 " noremap is used to make sure the right side is executed as is and can't be
 254 " modified by a plugin or other settings. Except for <Nop> which isn't
 255 " affected by mappings.
 256
 257 " Easy way to exit insert mode.
 258 inoremap jj <Esc>
 259 inoremap jk <Esc>
 260 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 261 " (2010-10-15).
 262 cnoremap jj <C-C>
 263 cnoremap jk <C-C>
 264
 265 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 266 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 267 map <Right>  <Nop>
 268 map <Left>   <Nop>
 269 map <Up>     <Nop>
 270 map <Down>   <Nop>
 271 imap <Right> <Nop>
 272 imap <Left>  <Nop>
 273 imap <Up>    <Nop>
 274 imap <Down>  <Nop>
 275 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 276 " below).
 277 cmap <Up>    <Nop>
 278 cmap <Down>  <Nop>
 279 cmap <Right> <Nop>
 280 cmap <Left>  <Nop>
 281
 282 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 283 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 284 cnoremap <C-P> <Up>
 285 cnoremap <C-N> <Down>
 286
 287 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 288 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 289 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 290
 291 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 292 " in #vim on Freenode (2011-08-15 00:17 CEST).
 293 nnoremap <C-G> 2<C-G>
 294
 295 " Use <Space> to move down a page and - to move up one like in mutt.
 296 nnoremap <Space> <C-F>
 297 nnoremap - <C-B>
 298
 299 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 300 " (2010-05-16 18:38 CEST) for this idea.
 301 nnoremap <silent> gb :bnext<CR>
 302 nnoremap <silent> gB :bprev<CR>
 303
 304 " Fast access to buffers.
 305 nnoremap <silent> <Leader>1 :1buffer<CR>
 306 nnoremap <silent> <Leader>2 :2buffer<CR>
 307 nnoremap <silent> <Leader>3 :3buffer<CR>
 308 nnoremap <silent> <Leader>4 :4buffer<CR>
 309 nnoremap <silent> <Leader>5 :5buffer<CR>
 310 nnoremap <silent> <Leader>6 :6buffer<CR>
 311 nnoremap <silent> <Leader>7 :7buffer<CR>
 312 nnoremap <silent> <Leader>8 :8buffer<CR>
 313 nnoremap <silent> <Leader>9 :9buffer<CR>
 314 nnoremap <silent> <Leader>0 :10buffer<CR>
 315
 316 " Make last active window the only window. Similar to <C-W> o.
 317 nnoremap <C-W>O <C-W>p<C-W>o
 318
 319 " Maps to change spell language between English and German and disable spell
 320 " checking.
 321 if exists('+spell')
 322     nnoremap <silent> <Leader>sn :set nospell<CR>
 323     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 324     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 325 endif
 326
 327 " Add semicolon to the end of the line. Thanks to
 328 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 329 " on Freenode for an improved version which doesn't clobber any marks.
 330 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 331
 332 " * and # for selections in visual mode. Thanks to
 333 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 334 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 335 if has('eval')
 336     function! s:VSetSearch()
 337         let l:temp = @@
 338         normal! gvy
 339         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 340         let @@ = l:temp
 341     endfunction
 342     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 343     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 344 endif
 345
 346 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 347 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 348 " mailing list for the commands.
 349 if v:version < 700
 350     cnoreabbrev W w
 351     cnoreabbrev Wa wa
 352     cnoreabbrev Wq wq
 353     cnoreabbrev Wqa wqa
 354 else
 355     cnoreabbrev <expr> W
 356         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 357     cnoreabbrev <expr> Wa
 358         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 359     cnoreabbrev <expr> Wq
 360         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 361     cnoreabbrev <expr> Wqa
 362         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 363 endif
 364 " Also fix my typo with "Q".
 365 if v:version < 700
 366     cnoreabbrev Q q
 367     cnoreabbrev Qa qa
 368 else
 369     cnoreabbrev <expr> Q
 370         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 371     cnoreabbrev <expr> Qa
 372         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 373 endif
 374
 375 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 376 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 377 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 378
 379 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 380 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 381 " Vim's source.
 382 inoremap <C-U> <C-G>u<C-U>
 383 " Same for <C-@> (insert previously inserted text and leave insert mode).
 384 inoremap <C-@> <C-G>u<C-@>
 385 " And for <C-A> (insert previously inserted text).
 386 inoremap <C-A> <C-G>u<C-A>
 387 " And for <C-W> (delete word before cursor).
 388 inoremap <C-W> <C-G>u<C-W>
 389
 390 if has('eval')
 391 " New text-objects ii and ai to work on text with the same indentation. Thanks
 392 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 393 " (visited on 2011-11-19).
 394     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 395     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 396     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 397     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 398
 399     function! s:IndTxtObj(inner)
 400         let curline = line(".")
 401         let lastline = line("$")
 402         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 403         let i = i < 0 ? 0 : i
 404         if getline(".") !~ "^\\s*$"
 405             let p = line(".") - 1
 406             let nextblank = getline(p) =~ "^\\s*$"
 407             while p > 0
 408                     \ && ((i == 0 && !nextblank)
 409                         \ || (i > 0 && ((indent(p) >= i
 410                             \ && !(nextblank && a:inner))
 411                             \ || (nextblank && !a:inner))))
 412                 -
 413                 let p = line(".") - 1
 414                 let nextblank = getline(p) =~ "^\\s*$"
 415             endwhile
 416             normal! 0V
 417             call cursor(curline, 0)
 418             let p = line(".") + 1
 419             let nextblank = getline(p) =~ "^\\s*$"
 420             while p <= lastline
 421                     \ && ((i == 0 && !nextblank)
 422                         \ || (i > 0 && ((indent(p) >= i
 423                             \ && !(nextblank && a:inner))
 424                             \ || (nextblank && !a:inner))))
 425                 +
 426                 let p = line(".") + 1
 427                 let nextblank = getline(p) =~ "^\\s*$"
 428             endwhile
 429             normal! $
 430         endif
 431     endfunction
 432 endif
 433
 434
 435 " ABBREVIATIONS
 436
 437 " Fix some of my spelling mistakes.
 438 iabbrev relle reelle
 439 iabbrev reele reelle
 440
 441
 442 " SYNTAX SETTINGS
 443
 444 " Activate syntax coloring.
 445 if has('syntax')
 446     syntax enable
 447
 448 " Don't highlight more than 500 columns as I normally don't have that long
 449 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 450 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 451     if exists('+synmaxcol')
 452         set synmaxcol=500
 453     endif
 454
 455 " Use (limited) syntax based omni completion if no other omni completion is
 456 " available. Taken from :help ft-syntax-omni.
 457     if has('autocmd') && exists('+omnifunc')
 458         augroup vimrc
 459             autocmd FileType *
 460                 \ if &omnifunc == '' |
 461                 \     setlocal omnifunc=syntaxcomplete#Complete |
 462                 \ endif
 463         augroup END
 464     endif
 465
 466 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 467 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 468 " disabled when necessary with :2match (in Vim >= 700).
 469     if exists(':2match')
 470         2match Todo /\%>78v./
 471     else
 472         match Todo /\%>78v./
 473     endif
 474
 475     if exists('*matchadd')
 476 " Highlight some important keywords in all documents.
 477         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 478             call matchadd('Todo', s:x)
 479         endfor
 480
 481 " Highlight unicode whitespace which is no normal whitespace (0x20).
 482         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 483                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 484                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 485                 \ 'feff']
 486             call matchadd('Error', '\%u' . s:x)
 487         endfor
 488     endif
 489
 490 " Settings for specific filetypes.
 491
 492     " Haskell.
 493     let g:hs_highlight_delimiters = 1
 494     let g:hs_highlight_boolean = 1
 495     let g:hs_highlight_types = 1
 496     let g:hs_highlight_more_types = 1
 497     " Perl.
 498     let g:perl_fold = 1
 499     let g:perl_fold_blocks = 1
 500     let g:perl_nofold_packages = 1
 501     let g:perl_include_pod = 1 " syntax coloring for PODs
 502     " Python.
 503     let g:python_highlight_all = 1
 504     " Vim.
 505     let g:vimsyn_embed = 0      " don't highlight embedded languages
 506     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 507     " XML.
 508     let g:xml_syntax_folding = 1
 509 endif
 510
 511
 512 " PLUGIN SETTINGS
 513
 514 if has('eval')
 515 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 516 " installing/removing/updating plugins simple. (Used for plugins with more
 517 " than one file.)
 518     if v:version >= 700
 519         execute 'call pathogen#runtime_append_all_bundles()'
 520     endif
 521
 522 " Settings for the NERD commenter.
 523     " Don't create any mappings I don't want to use.
 524     let g:NERDCreateDefaultMappings = 0
 525     " Map toggle comment.
 526     map <Leader><Leader> <Plug>NERDCommenterToggle
 527
 528 " XPTemplate settings.
 529     " Try to maintain snippet rendering even after editing outside of a
 530     " snippet.
 531     let g:xptemplate_strict = 0
 532     " Don't complete any braces automatically.
 533     let g:xptemplate_brace_complete = 0
 534     " Only highlight the current placeholder.
 535     let g:xptemplate_highlight = 'current'
 536 endif
 537
 538
 539 " AUTO COMMANDS
 540
 541 " Use a custom auto group to prevent problems when the vimrc files is sourced
 542 " twice.
 543 if has('autocmd')
 544     augroup vimrc
 545
 546 " Go to last position of opened files. Taken from :help last-position-jump.
 547         autocmd BufReadPost *
 548             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 549             \     execute "normal! g'\"" |
 550             \ endif
 551 " But not for Git commits, go to beginning of the file.
 552         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 553
 554 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 555 " when switching to a help buffer which is in the background with :buffer as
 556 " these options are local to windows (and not only to buffers). This happens
 557 " because I often want to use only one window and thus the help buffer is in
 558 " the background.
 559         autocmd BufWinEnter *.txt
 560             \ if &filetype == 'help' |
 561             \     setlocal nolist |
 562             \     setlocal nonumber |
 563             \ endif
 564
 565 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 566 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 567 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 568 " doesn't exist in older Vims.
 569         if exists('##InsertLeave')
 570             autocmd InsertLeave * set nopaste
 571         endif
 572
 573 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 574 " doesn't exist in older Vims.
 575         if exists('##QuickFixCmdPre')
 576             autocmd QuickFixCmdPre * write
 577         endif
 578
 579 " AFTER/FTPLUGIN AUTO COMMANDS
 580
 581 " Disable spell checking for files which don't need it.
 582         autocmd FileType deb  setlocal nospell
 583         autocmd FileType diff setlocal nospell
 584         autocmd FileType tar  setlocal nospell
 585 " Fix to allow Vim edit crontab files as crontab doesn't work with
 586 " backupcopy=auto.
 587         autocmd FileType crontab setlocal backupcopy=yes
 588 " Don't use the modeline in git commits as the diff created by `git commit -v`
 589 " may contain one which could change the filetype or other settings of the
 590 " commit buffer. Also make sure we use only 72 characters per line which is
 591 " the recommendation for git commit messages (http://tpope.net/node/106).
 592         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 593                                  \ setlocal textwidth=72
 594 " Use the same comment string as for Vim files in Vimperator files.
 595         autocmd FileType vimperator setlocal commentstring=\"%s
 596 " Use tex compiler for (La)TeX files.
 597         autocmd FileType tex compiler tex
 598
 599 " FTDETECT AUTO COMMANDS
 600
 601 " Recognize .md as markdown files (Vim default is .mkd).
 602         autocmd BufRead,BufNewFile *.md set filetype=mkd
 603 " Recognize .test as Tcl files.
 604         autocmd BufRead,BufNewFile *.test set filetype=tcl
 605
 606 " OTHER AUTO COMMANDS
 607
 608 " Disable spell checking, displaying of list characters and long lines when
 609 " viewing documentation.
 610         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 611
 612 " Use diff filetype for mercurial patches in patch queue.
 613         autocmd BufReadPost */.hg/patches/* set filetype=diff
 614
 615     augroup END
 616 endif
 617
 618
 619 " CUSTOM FUNCTIONS AND COMMANDS
 620
 621 if has('eval')
 622 " Convenient command to see the difference between the current buffer and the
 623 " file it was loaded from, thus the changes you made. Thanks to the
 624 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 625 " for the diffed file than the filetype for the original file.
 626     if !exists(':DiffOrig')
 627         command DiffOrig
 628             \ let s:diff_orig_filetype = &filetype
 629             \ | vertical new
 630             \ | let &filetype = s:diff_orig_filetype
 631             \ | unlet s:diff_orig_filetype
 632             \ | set buftype=nofile
 633             \ | read ++edit #
 634             \ | 0d_
 635             \ | diffthis
 636             \ | wincmd p
 637             \ | diffthis
 638     endif
 639 endif