vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Save 'runtimepath' in case it was changed by the system's configuration
   7 " files. Also save 'diff' as set all& resets it; but somehow later (after
   8 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
   9 " automagically restored to the correct value.
  10 if has('eval')
  11     let s:save_runtimepath = &runtimepath
  12     let s:save_diff = &diff
  13 endif
  14 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  15 " system wide configuration file doesn't change default values.
  16 set all&
  17 " And restore it after all other options were reset.
  18 if has('eval')
  19     let &runtimepath = s:save_runtimepath
  20     let &diff = s:save_diff
  21     unlet s:save_runtimepath
  22     unlet s:save_diff
  23 endif
  24
  25 " Make sure Vim (and not Vi) settings are used.
  26 set nocompatible
  27
  28 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  29 " affect reading files in different encodings, see 'fileencodings' for that.
  30 set encoding=utf-8
  31
  32 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  33 " runtime files) if available.
  34 set runtimepath-=~/.vim
  35 set runtimepath^=~/.vim,~/.vim/runtime
  36
  37 " Don't store swap files in the same directory as the edited file.
  38 set directory-=.
  39 " But store them in ~/.tmp if available.
  40 set directory^=~/.tmp
  41
  42 " Disable modelines as they may cause security problems. Instead use
  43 " securemodelines (Vim script #1876).
  44 set nomodeline
  45
  46 " Complete to longest common string (list:longest) and then complete all full
  47 " matches after another (full). Thanks to pbrisbin
  48 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  49 set wildmode=list:longest,full
  50
  51 " Increase history of executed commands (:).
  52 set history=1000
  53
  54 " Increase number of possible undos.
  55 set undolevels=1000
  56
  57 if has('viminfo')
  58     " Remember marks (including the last cursor position) for more files.
  59     set viminfo^='1000
  60 endif
  61
  62 " Use strong encryption if possible, also used for swap/undo files.
  63 if exists('+cryptmethod')
  64     set cryptmethod=blowfish
  65 endif
  66
  67
  68 " EDIT SETTINGS
  69
  70 " Enable automatic file detection, plugin and indention support.
  71 if has('autocmd')
  72     filetype off " necessary for pathogen to force a reload of ftplugins
  73     filetype plugin indent on
  74 endif
  75
  76 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  77 " existing files.
  78 set fileencodings=utf-8,latin1
  79
  80 " Wrap text after 78 characters.
  81 set textwidth=78
  82
  83 " Set tabs to 4 spaces, use softtabs.
  84 set shiftwidth=4
  85 set softtabstop=4
  86 set expandtab
  87 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  88 set shiftround
  89 " Use the default value for real tabs.
  90 set tabstop=8
  91
  92 " Enable auto indention.
  93 set autoindent
  94
  95 " When joining lines only add one space after a sentence.
  96 set nojoinspaces
  97
  98 " Allow backspacing over autoindent and line breaks.
  99 set backspace=indent,eol
 100
 101 " Start a comment when hitting enter after a commented line (r) and when using
 102 " o or O around a commented line (o).
 103 set formatoptions+=ro
 104 " Don't break a line if was already longer then 'textwidth' when insert mode
 105 " started.
 106 set formatoptions+=l
 107
 108 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 109 " no character) in visual block mode.
 110 set virtualedit=block
 111
 112 " Already display matches while typing the search command. This makes spotting
 113 " errors easy.
 114 set incsearch
 115
 116 " Activate syntax folding.
 117 if has('folding')
 118     set foldmethod=syntax
 119     set foldcolumn=2
 120     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 121                      " folding which is not what I want
 122 endif
 123
 124 " Only check for case if the searched word contains a capital character.
 125 set ignorecase
 126 set smartcase
 127
 128 " Activate spell checking, use English as default.
 129 if exists('+spell') && has('syntax')
 130     " But not when diffing as spell checking is distracting in this case.
 131     if !&diff
 132         set spell
 133     endif
 134     set spelllang=en_us
 135 endif
 136
 137 " Allow buffers with changes to be hidden. Very important for effective
 138 " editing with multiple buffers.
 139 set hidden
 140
 141
 142 " DISPLAY SETTINGS
 143
 144 " Use a dark background. Doesn't change the background color, only sets text
 145 " colors for a dark terminal.
 146 set background=dark
 147
 148 " Display line numbers.
 149 set number
 150 " But use as little space as necessary for the numbers column. Thanks to James
 151 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 152 if exists('+numberwidth')
 153     set numberwidth=1
 154 endif
 155 " Display the ruler with current line/file position. If 'statusline' is used
 156 " then this only affects <C-G>.
 157 set ruler
 158 " Display partial commands in the status line.
 159 set showcmd
 160
 161 " Don't redraw screen when executing macros; increases speed. Thanks to James
 162 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 163 set lazyredraw
 164
 165 " Visualize the line the cursor is currently in.
 166 if exists('+cursorline')
 167     set cursorline
 168 endif
 169
 170 " Display tabs, trailing space, non breakable spaces and long lines (when
 171 " wrapping is disabled).
 172 set list
 173 set listchars=trail:-,extends:>
 174 if v:version >= 700
 175     set listchars+=nbsp:!
 176 endif
 177
 178 if has('statusline')
 179     " Always display the status line even if there is only one window.
 180     set laststatus=2
 181
 182     set statusline=
 183     " on the left
 184     set statusline+=%02n: " buffer number
 185     set statusline+=%f\   " path to current file in buffer
 186     set statusline+=%h    " [help] if buffer is help file
 187     set statusline+=%w    " [Preview] if buffer is preview buffer
 188     set statusline+=%m    " [+] if buffer was modified,
 189                           " [-] if 'modifiable' is off
 190     set statusline+=%r    " [RO] if buffer is read only
 191
 192     " on the right
 193     set statusline+=%=                " right align
 194     set statusline+=0x%-8B\           " current character under cursor as hex
 195     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 196                                       " column number (%c),
 197                                       " virtual column number if different
 198                                       "                       than %c (%V)
 199     set statusline+=%P                " position in file in percent
 200 endif
 201
 202
 203 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 204
 205 " Easy way to exit insert mode.
 206 inoremap jj <Esc>
 207 inoremap jk <Esc>
 208 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 209 " (2010-10-15).
 210 cnoremap jj <C-C>
 211 cnoremap jk <C-C>
 212
 213 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 214 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 215 map <Right>  <Nop>
 216 map <Left>   <Nop>
 217 map <Up>     <Nop>
 218 map <Down>   <Nop>
 219 imap <Right> <Nop>
 220 imap <Left>  <Nop>
 221 imap <Up>    <Nop>
 222 imap <Down>  <Nop>
 223 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 224 " below).
 225 cmap <Up>    <Nop>
 226 cmap <Down>  <Nop>
 227 cmap <Right> <Nop>
 228 cmap <Left>  <Nop>
 229
 230 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 231 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 232 cnoremap <C-P> <Up>
 233 cnoremap <C-N> <Down>
 234
 235 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 236 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 237 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 238
 239 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 240 " in #vim on Freenode (2011-08-15 00:17 CEST).
 241 nnoremap <C-G> 2<C-G>
 242
 243 " Use <Space> to move down a page and - to move up one like in mutt.
 244 nnoremap <Space> <C-F>
 245 nnoremap - <C-B>
 246
 247 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 248 " (2010-05-16 18:38 CEST) for this idea.
 249 nnoremap <silent> gb :bnext<CR>
 250 nnoremap <silent> gB :bprev<CR>
 251
 252 " Fast access to buffers.
 253 nnoremap <silent> <Leader>1 :1buffer<CR>
 254 nnoremap <silent> <Leader>2 :2buffer<CR>
 255 nnoremap <silent> <Leader>3 :3buffer<CR>
 256 nnoremap <silent> <Leader>4 :4buffer<CR>
 257 nnoremap <silent> <Leader>5 :5buffer<CR>
 258 nnoremap <silent> <Leader>6 :6buffer<CR>
 259 nnoremap <silent> <Leader>7 :7buffer<CR>
 260 nnoremap <silent> <Leader>8 :8buffer<CR>
 261 nnoremap <silent> <Leader>9 :9buffer<CR>
 262 nnoremap <silent> <Leader>0 :10buffer<CR>
 263
 264 " Make last active window the only window. Similar to <C-W> o.
 265 nnoremap <C-W>O <C-W>p<C-W>o
 266
 267 " Maps to change spell language between English and German and disable spell
 268 " checking.
 269 if exists('+spell')
 270     noremap <silent> <Leader>sn :set nospell<CR>
 271     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 272     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 273 endif
 274
 275 " Add semicolon to the end of the line. Thanks to
 276 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 277 " on Freenode for an improved version which doesn't clobber any marks.
 278 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 279
 280 " * and # for selections in visual mode. Thanks to
 281 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 282 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 283 if has('eval')
 284     function! s:VSetSearch()
 285         let l:temp = @@
 286         normal! gvy
 287         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 288         let @@ = l:temp
 289     endfunction
 290     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 291     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 292 endif
 293
 294 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 295 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 296 " mailing list for the commands.
 297 if v:version < 700
 298     cnoreabbrev W w
 299     cnoreabbrev Wa wa
 300     cnoreabbrev Wq wq
 301     cnoreabbrev Wqa wqa
 302 else
 303     cnoreabbrev <expr> W
 304         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 305     cnoreabbrev <expr> Wa
 306         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 307     cnoreabbrev <expr> Wq
 308         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 309     cnoreabbrev <expr> Wqa
 310         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 311 endif
 312 " Also fix my typo with "Q".
 313 if v:version < 700
 314     cnoreabbrev Q q
 315     cnoreabbrev Qa qa
 316 else
 317     cnoreabbrev <expr> Q
 318         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 319     cnoreabbrev <expr> Qa
 320         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 321 endif
 322
 323 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 324 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 325 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 326
 327 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 328 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 329 " Vim's source.
 330 inoremap <C-U> <C-G>u<C-U>
 331 " Same for <C-@> (insert previously inserted text and leave insert mode).
 332 inoremap <C-@> <C-G>u<C-@>
 333 " And for <C-A> (insert previously inserted text).
 334 inoremap <C-A> <C-G>u<C-A>
 335 " And for <C-W> (delete word before cursor).
 336 inoremap <C-W> <C-G>u<C-W>
 337
 338 if has('eval')
 339 " New text-objects ii and ai to work on text with the same indentation. Thanks
 340 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 341 " (visited on 2011-11-19).
 342     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 343     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 344     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 345     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 346
 347     function! s:IndTxtObj(inner)
 348         let curline = line(".")
 349         let lastline = line("$")
 350         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 351         let i = i < 0 ? 0 : i
 352         if getline(".") !~ "^\\s*$"
 353             let p = line(".") - 1
 354             let nextblank = getline(p) =~ "^\\s*$"
 355             while p > 0
 356                     \ && ((i == 0 && !nextblank)
 357                         \ || (i > 0 && ((indent(p) >= i
 358                             \ && !(nextblank && a:inner))
 359                             \ || (nextblank && !a:inner))))
 360                 -
 361                 let p = line(".") - 1
 362                 let nextblank = getline(p) =~ "^\\s*$"
 363             endwhile
 364             normal! 0V
 365             call cursor(curline, 0)
 366             let p = line(".") + 1
 367             let nextblank = getline(p) =~ "^\\s*$"
 368             while p <= lastline
 369                     \ && ((i == 0 && !nextblank)
 370                         \ || (i > 0 && ((indent(p) >= i
 371                             \ && !(nextblank && a:inner))
 372                             \ || (nextblank && !a:inner))))
 373                 +
 374                 let p = line(".") + 1
 375                 let nextblank = getline(p) =~ "^\\s*$"
 376             endwhile
 377             normal! $
 378         endif
 379     endfunction
 380 endif
 381
 382
 383 " ABBREVIATIONS
 384
 385 " Fix some of my spelling mistakes.
 386 iabbrev relle reelle
 387 iabbrev reele reelle
 388
 389
 390 " SYNTAX SETTINGS
 391
 392 " Activate syntax coloring.
 393 if has('syntax')
 394     syntax enable
 395
 396 " Don't highlight more than 500 columns as I normally don't have that long
 397 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 398 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 399     if exists('+synmaxcol')
 400         set synmaxcol=500
 401     endif
 402
 403 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 404 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 405 " disabled when necessary with :2match (in Vim >= 700).
 406     if exists(':2match')
 407         2match Todo /\%>78v./
 408     else
 409         match Todo /\%>78v./
 410     endif
 411
 412     if exists('*matchadd')
 413 " Highlight some important keywords in all documents.
 414         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 415             call matchadd('Todo', s:x)
 416         endfor
 417
 418 " Highlight unicode whitespace which is no normal whitespace (0x20).
 419         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 420                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 421                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 422                 \ 'feff']
 423             call matchadd('Error', '\%u' . s:x)
 424         endfor
 425     endif
 426
 427 " Settings for specific filetypes.
 428
 429     " Haskell.
 430     let g:hs_highlight_boolean = 1
 431     let g:hs_highlight_types = 1
 432     let g:hs_highlight_more_types = 1
 433
 434     " Perl.
 435     let g:perl_fold = 1
 436     let g:perl_fold_blocks = 1
 437     let g:perl_nofold_packages = 1
 438     let g:perl_include_pod = 1 " syntax coloring for PODs
 439 endif
 440
 441
 442 " PLUGIN SETTINGS
 443
 444 if has('eval')
 445 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 446 " installing/removing/updating plugins simple. (Used for plugins with more
 447 " than one file.)
 448     if v:version >= 700
 449         execute 'call pathogen#runtime_append_all_bundles()'
 450     endif
 451
 452 " Settings for the NERD commenter.
 453     " Don't create any mappings I don't want to use.
 454     let g:NERDCreateDefaultMappings = 0
 455     " Map toggle comment.
 456     map <Leader><Leader> <Plug>NERDCommenterToggle
 457
 458 " XPTemplate settings.
 459     " Try to maintain snippet rendering even after editing outside of a
 460     " snippet.
 461     let g:xptemplate_strict = 0
 462     " Don't complete any braces automatically.
 463     let g:xptemplate_brace_complete = 0
 464     " Only highlight the current placeholder.
 465     let g:xptemplate_highlight = 'current'
 466 endif
 467
 468
 469 " AUTO COMMANDS
 470
 471 " Use a custom auto group to prevent problems when the vimrc files is sourced
 472 " twice.
 473 if has('autocmd')
 474     augroup vimrc
 475 " Remove all autocmds from the current group.
 476         autocmd!
 477
 478 " Go to last position of opened files. Taken from :help last-position-jump.
 479         autocmd BufReadPost *
 480             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 481             \     execute "normal! g'\"" |
 482             \ endif
 483 " But not for Git commits, go to beginning of the file.
 484         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 485
 486 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 487 " when switching to a help buffer which is in the background with :buffer as
 488 " these options are local to windows (and not only to buffers). This happens
 489 " because I often want to use only one window and thus the help buffer is in
 490 " the background.
 491         autocmd BufWinEnter *.txt
 492             \ if &filetype == 'help' |
 493             \     setlocal nolist |
 494             \     setlocal nonumber |
 495             \ endif
 496
 497 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 498 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 499 " want to paste once and then 'paste' gets automatically unset.
 500         if exists('##InsertLeave')
 501             autocmd InsertLeave * set nopaste
 502         endif
 503
 504 " Write file when running :mak[e] before 'makeprg' is called.
 505         autocmd QuickFixCmdPre * write
 506
 507 " AFTER/FTPLUGIN AUTO COMMANDS
 508
 509 " Disable spell checking for files which don't need it.
 510         autocmd FileType deb  setlocal nospell
 511         autocmd FileType diff setlocal nospell
 512         autocmd FileType tar  setlocal nospell
 513 " Fix to allow Vim edit crontab files as crontab doesn't work with
 514 " backupcopy=auto.
 515         autocmd FileType crontab setlocal backupcopy=yes
 516 " Don't use the modeline in git commits as the diff created by `git commit -v`
 517 " may contain one which could change the filetype or other settings of the
 518 " commit buffer. Also make sure we use only 72 characters per line which is
 519 " the recommendation for git commit messages (http://tpope.net/node/106).
 520         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 521                                  \ setlocal textwidth=72
 522 " Use the same comment string as for Vim files in Vimperator files.
 523         autocmd FileType vimperator setlocal commentstring=\"%s
 524 " Use tex compiler for (La)TeX files.
 525         autocmd FileType tex compiler tex
 526
 527 " FTDETECT AUTO COMMANDS
 528
 529 " Recognize .md as markdown files (Vim default is .mkd).
 530         autocmd BufRead,BufNewFile *.md set filetype=mkd
 531 " Recognize .test as Tcl files.
 532         autocmd BufRead,BufNewFile *.test set filetype=tcl
 533
 534 " OTHER AUTO COMMANDS
 535
 536 " Disable spell checking, displaying of list characters and long lines when
 537 " viewing documentation.
 538         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 539
 540 " Use diff filetype for mercurial patches in patch queue.
 541         autocmd BufReadPost */.hg/patches/* set filetype=diff
 542
 543     augroup END
 544 endif
 545
 546
 547 " CUSTOM FUNCTIONS AND COMMANDS
 548
 549 if has('eval')
 550 " Convenient command to see the difference between the current buffer and the
 551 " file it was loaded from, thus the changes you made. Thanks to the
 552 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 553 " for the diffed file than the filetype for the original file.
 554     if !exists(":DiffOrig")
 555         command DiffOrig
 556             \ let s:diff_orig_filetype = &filetype
 557             \ | vertical new
 558             \ | let &filetype = s:diff_orig_filetype
 559             \ | unlet s:diff_orig_filetype
 560             \ | set buftype=nofile
 561             \ | read ++edit #
 562             \ | 0d_
 563             \ | diffthis
 564             \ | wincmd p
 565             \ | diffthis
 566     endif
 567 endif