vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file. But only if
  53 " we have a "safe" writable directory available.
  54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  55     set directory-=.
  56 endif
  57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  58 set directory^=~/.tmp
  59
  60 " Disable modelines as they may cause security problems. Instead use
  61 " securemodelines (Vim script #1876).
  62 set nomodeline
  63
  64 " Complete to longest common string (list:longest) and then complete all full
  65 " matches after another (full). Thanks to pbrisbin
  66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  67 set wildmode=list:longest,full
  68 " Ignore case when completing files/directories.
  69 if exists('+wildignorecase')
  70     set wildignorecase
  71 endif
  72
  73 " Ignore files with the following extensions because I almost never want to
  74 " edit them in Vim (specifying them manually still works of course).
  75 set wildignore=
  76 " C
  77 set wildignore+=*.o,*.d,*.so
  78 " Java
  79 set wildignore+=*.class
  80 " LaTeX
  81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  82 " Python
  83 set wildignore+=*.pyc
  84
  85 " Show completion menu even if only one entry matches.
  86 if exists('+completeopt')
  87     set completeopt+=menuone
  88 endif
  89
  90 " Increase history of executed commands (:) and search patterns (/).
  91 set history=1000
  92
  93 " Increase number of possible undos.
  94 set undolevels=1000
  95
  96 " Remember marks (including the last cursor position) for more files. ^= is
  97 " necessary because 'viminfo' is parsed from the beginning and the first match
  98 " is used.
  99 if has('viminfo')
 100     set viminfo^='1000
 101 endif
 102
 103 " Use strong encryption if possible, also used for swap/undo files.
 104 if exists('+cryptmethod')
 105     set cryptmethod=blowfish
 106 endif
 107
 108 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 109 " is used multiple times. Necessary to support reloading the vimrc.
 110 if has('autocmd')
 111     augroup vimrc
 112         autocmd!
 113     augroup END
 114 endif
 115
 116
 117 " HELPER FUNCTIONS
 118
 119 if has('eval')
 120 " Check if the given syntax group is available. Thanks to bairui in #vim on
 121 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 122     function! s:HasSyntaxGroup(group)
 123         try
 124             execute 'silent highlight ' . a:group
 125         " \a = [A-Za-z]
 126         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 127             return 0
 128         endtry
 129         return 1
 130     endfunction
 131
 132 " Check if the given Vim version and patch is available.
 133     function! s:HasVersionAndPatch(version, patch)
 134         return v:version > a:version
 135             \ || (v:version == a:version && has('patch' . a:patch))
 136     endfunction
 137 endif
 138
 139
 140 " TERMINAL SETTINGS
 141
 142 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 143 " connections.
 144 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 145     set ttyfast
 146 endif
 147
 148
 149 " EDIT SETTINGS
 150
 151 " Enable automatic file detection, plugin and indention support.
 152 if has('autocmd')
 153     filetype off " necessary for pathogen to force a reload of ftplugins
 154     filetype plugin indent on
 155 endif
 156
 157 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 158 " existing files.
 159 set fileencodings=utf-8,latin1
 160
 161 " Always use unix line-endings for new files.
 162 set fileformats=unix,dos
 163
 164 " Wrap text after 78 characters.
 165 set textwidth=78
 166
 167 " Set tabs to 4 spaces, use softtabs.
 168 set shiftwidth=4
 169 set softtabstop=4
 170 set expandtab
 171 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 172 set shiftround
 173 " Use the default value for real tabs.
 174 set tabstop=8
 175
 176 " Enable auto indention.
 177 set autoindent
 178
 179 " When joining lines only add one space after a sentence.
 180 set nojoinspaces
 181
 182 " Allow backspacing over autoindent and line breaks.
 183 set backspace=indent,eol
 184
 185 " Start a comment when hitting enter after a commented line (r) and when using
 186 " o or O around a commented line (o).
 187 set formatoptions+=ro
 188 " Don't break a line if was already longer then 'textwidth' when insert mode
 189 " started.
 190 set formatoptions+=l
 191 " Remove comment leader when joining lines where it makes sense.
 192 if <SID>HasVersionAndPatch(703, 541)
 193     set formatoptions+=j
 194 endif
 195
 196 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 197 " no character) in visual block mode.
 198 set virtualedit=block
 199
 200 " Already display matches while typing the search command. This makes spotting
 201 " typos easy and searching faster.
 202 set incsearch
 203
 204 " Activate syntax folding.
 205 if has('folding')
 206     set foldmethod=syntax
 207     " Only use fold column if we have enough space (for example not in a
 208     " (virtual) terminal which has only 80 columns).
 209     if &columns > 80
 210         set foldcolumn=2
 211     endif
 212     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 213                      " folding which is not what I want
 214     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 215     set foldopen-=block
 216 endif
 217
 218 " Only check case if the searched word contains a capital character.
 219 set ignorecase
 220 set smartcase
 221
 222 " Activate spell checking, use English as default.
 223 if exists('+spell') && has('syntax')
 224     " But not when diffing because spell checking is distracting in this case.
 225     if !&diff
 226         set spell
 227     endif
 228     set spelllang=en_us
 229 endif
 230
 231 " Allow buffers with changes to be hidden. Very important for effective
 232 " editing with multiple buffers. Prevents the "E37: No write since last change
 233 " (add ! to override)" warning when switching buffers.
 234 set hidden
 235
 236 " When splitting vertically put the new window right of the current one.
 237 if has('vertsplit')
 238     set splitright
 239 endif
 240
 241
 242 " DISPLAY SETTINGS
 243
 244 " Use a dark background. Doesn't change the background color, only sets text
 245 " colors for a dark terminal.
 246 set background=dark
 247
 248 " Use my color scheme if 256 colors are available.
 249 if &t_Co == 256 || has('gui_running')
 250     colorscheme simon
 251 endif
 252
 253 " Display line numbers.
 254 set number
 255 " But use as little space as possible for the numbers column. Thanks to James
 256 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 257 if exists('+numberwidth')
 258     set numberwidth=1
 259 endif
 260 " Display the ruler with current line/file position. If 'statusline' is used
 261 " then this only affects <C-G>.
 262 set ruler
 263 " Display partial commands in the status line.
 264 set showcmd
 265
 266 " Don't redraw screen when executing macros; increases speed. Thanks to James
 267 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 268 set lazyredraw
 269
 270 " Visualize the line the cursor is currently in.
 271 if exists('+cursorline')
 272     set cursorline
 273 endif
 274
 275 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 276 " remove the highlighting until the next search.
 277 set hlsearch
 278
 279 " Display some special characters.
 280 set list
 281 set listchars=
 282 " Display tabs as ">--------".
 283 set listchars+=tab:>-
 284 " Display trailing whitespace as "-".
 285 set listchars+=trail:-
 286 " Display markers for long lines when wrapping is disabled.
 287 set listchars+=extends:>,precedes:<
 288 " Display non-breakable space as "!".
 289 if v:version >= 700
 290     set listchars+=nbsp:!
 291 endif
 292
 293 " Don't draw the vertical split separator by using space as character. Thanks
 294 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 295 " non-breakable space. But a simple space works as well, as long as the
 296 " current color scheme is not reset.
 297 if has('windows') && has('folding')
 298     set fillchars+=vert:\  " comment to prevent trailing whitespace
 299 endif
 300
 301 if has('statusline')
 302     " Always display the status line even if there is only one window.
 303     set laststatus=2
 304
 305     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 306     " is the highest buffer number, otherwise return nothing. Used in
 307     " 'statusline' to get an overview of available buffer numbers.
 308     function! s:StatuslineBufferCount()
 309         let l:bufnr = bufnr('$')
 310         if l:bufnr > 1
 311             let l:result = '/'
 312             if exists('*printf')
 313                 let l:result .= printf('%02d', l:bufnr)
 314             else
 315                 " Older Vims don't have printf() (and no .= either). Emulate
 316                 " "%02d".
 317                 if l:bufnr < 10
 318                     let l:result = l:result . '0'
 319                 endif
 320                 let l:result = l:result . l:bufnr
 321             endif
 322             return l:result
 323         else
 324             return ''
 325         endif
 326     endfunction
 327
 328     " Like %f but use relative filename if it's shorter than the absolute path
 329     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 330     " not enough because it doesn't create '../'s.
 331     function! s:StatuslineRelativeFilename()
 332         " Display only filename for help files.
 333         if &buftype == 'help'
 334             return expand('%:t')
 335         endif
 336         " Special case for scratch files.
 337         if &buftype == 'nofile'
 338             return '[Scratch]'
 339         endif
 340
 341         let l:path = expand('%')
 342         " No file.
 343         if l:path == ''
 344             return '[No Name]'
 345         endif
 346         " Path is already relative, nothing to do.
 347         if stridx(l:path, '/') != 0
 348             return l:path
 349         endif
 350
 351         " Absolute path to this file.
 352         let l:path = expand('%:p')
 353         " Shortened path to this file, thanks to bairui in #vim on Freenode
 354         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 355         " Vim normally uses as %f (minus some exceptions).
 356         let l:original_path = fnamemodify(l:path, ':~')
 357         " Absolute path to the current working directory.
 358         let l:cwd = getcwd()
 359
 360         " Working directory completely contained in path, replace it with a
 361         " relative path. Happens for example when opening a file with netrw.
 362         " %f displays this as absolute path, but we want a relative path of
 363         " course.
 364         if stridx(l:path, l:cwd) == 0
 365             return strpart(l:path, strlen(l:cwd) + 1)
 366         endif
 367
 368         let l:path_list = split(l:path, '/')
 369         let l:cwd_list  = split(l:cwd,  '/')
 370
 371         " Remove the common path.
 372         while l:path_list[0] == l:cwd_list[0]
 373             call remove(l:path_list, 0)
 374             call remove(l:cwd_list,  0)
 375         endwhile
 376
 377         " Add as many '..' as necessary for the relative path and join the
 378         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 379         " the hint to use repeat() instead of a loop.
 380         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 381
 382         " Use the shorter path, either relative or absolute.
 383         if strlen(l:path) < strlen(l:original_path)
 384             return l:path
 385         else
 386             return l:original_path
 387         endif
 388     endfunction
 389
 390     " Display unexpected 'fileformat' and 'fileencoding' settings.
 391     function! s:StatuslineFileFormat()
 392         if &fileformat != 'unix'
 393             return '[' . &fileformat . ']'
 394         else
 395             return ''
 396         endif
 397     endfunction
 398     function! s:StatuslineFileEncoding()
 399         if &fileencoding != '' && &fileencoding != 'utf-8'
 400             return '[' . &fileencoding . ']'
 401         else
 402             return ''
 403         endif
 404     endfunction
 405
 406     " Return current syntax group in brackets or nothing if there's none.
 407     function! s:StatuslineSyntaxGroup()
 408         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 409         if l:group != ''
 410             return '[' . l:group . '] '
 411         else
 412             return ''
 413         endif
 414     endfunction
 415
 416     " Short function names to make 'statusline' more readable.
 417     function! SBC()
 418         return <SID>StatuslineBufferCount()
 419     endfunction
 420     function! SRF()
 421         return <SID>StatuslineRelativeFilename()
 422     endfunction
 423     function! SFF()
 424         return <SID>StatuslineFileFormat()
 425     endfunction
 426     function! SFE()
 427         return <SID>StatuslineFileEncoding()
 428     endfunction
 429     function! SSG()
 430         return <SID>StatuslineSyntaxGroup()
 431     endfunction
 432
 433     set statusline=
 434     " on the left
 435     set statusline+=%02n              " buffer number
 436     set statusline+=%{SBC()}          " highest buffer number
 437     set statusline+=:
 438     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 439         set statusline+=%{SRF()}      " path to current file
 440         set statusline+=\             " space after path
 441     else
 442         set statusline+=%f\           " path to current file in buffer
 443     endif
 444     set statusline+=%h                " [help] if buffer is help file
 445     set statusline+=%w                " [Preview] if buffer is preview buffer
 446     set statusline+=%m                " [+] if buffer was modified,
 447                                       " [-] if 'modifiable' is off
 448     set statusline+=%r                " [RO] if buffer is read only
 449     set statusline+=%#Error#          " display warnings
 450     set statusline+=%{SFF()}          "   - unexpected file format
 451     set statusline+=%{SFE()}          "   - unexpected file encoding
 452     set statusline+=%##               " continue with normal colors
 453
 454     " on the right
 455     set statusline+=%=                " right align
 456     set statusline+=0x%-8B\           " current character under cursor as hex
 457     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 458                                       " column number (%c),
 459                                       " virtual column number if different
 460                                       "                       than %c (%V)
 461     set statusline+=%P                " position in file in percent
 462 endif
 463
 464
 465 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 466
 467 " noremap is used to make sure the right side is executed as is and can't be
 468 " modified by a plugin or other settings. Except for <Nop> which isn't
 469 " affected by mappings.
 470
 471 " Easy way to exit insert mode. jk is preferred because it's faster.
 472 inoremap jj <Esc>
 473 inoremap jk <Esc>
 474 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 475 " (2010-10-15).
 476 cnoremap jj <C-C>
 477 cnoremap jk <C-C>
 478
 479 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 480 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 481 map <Right>  <Nop>
 482 map <Left>   <Nop>
 483 map <Up>     <Nop>
 484 map <Down>   <Nop>
 485 imap <Right> <Nop>
 486 imap <Left>  <Nop>
 487 imap <Up>    <Nop>
 488 imap <Down>  <Nop>
 489 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 490 " below).
 491 cmap <Up>    <Nop>
 492 cmap <Down>  <Nop>
 493 cmap <Right> <Nop>
 494 cmap <Left>  <Nop>
 495
 496 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 497 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 498 cnoremap <C-P> <Up>
 499 cnoremap <C-N> <Down>
 500
 501 if has('eval')
 502 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 503 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 504 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 505 " directly because it also enables that feature for other commands which I
 506 " don't want.
 507
 508     " Set 'nostartofline' for a single movement.
 509     function! s:TemporaryNostartofline(movement)
 510         let l:startofline = &startofline
 511         set nostartofline
 512         execute 'normal! ' . a:movement
 513         let &startofline = l:startofline
 514     endfunction
 515
 516     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 517     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 518     nnoremap <silent> <C-F>
 519         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 520     nnoremap <silent> <C-B>
 521         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 522     nnoremap <silent> <C-D>
 523         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 524     nnoremap <silent> <C-U>
 525         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 526 endif
 527
 528 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 529 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 530 " Only the current buffer is written, thus switching to another buffer works
 531 " too.
 532 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 533
 534 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 535 " in #vim on Freenode (2011-08-15 00:17 CEST).
 536 nnoremap <C-G> 2<C-G>
 537
 538 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 539 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 540 nmap <Space> <C-F>
 541 nmap - <C-B>
 542
 543 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 544 " (2010-05-16 18:38 CEST) for this idea.
 545 nnoremap <silent> gb :bnext<CR>
 546 nnoremap <silent> gB :bprevious<CR>
 547 if has('eval')
 548     " But when starting again at the first buffer, print a warning which
 549     " reminds me that I've already seen that buffer.
 550     function! s:NextBuffer()
 551         " Are we currently on the last buffer and moving to the first?
 552         let l:last_buffer = 0
 553         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 554             let l:last_buffer = 1
 555         endif
 556
 557         " Go to the next buffer.
 558         if !l:last_buffer
 559             bnext
 560
 561         " Go to the first buffer, silent is necessary or the following message
 562         " won't be displayed because it's overwritten by the status message
 563         " displayed when entering a buffer.
 564         else
 565             silent bnext
 566
 567             echohl WarningMsg
 568             echo 'Starting again at first buffer.'
 569             echohl None
 570         endif
 571     endfunction
 572     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 573 endif
 574
 575 " Fast access to buffers.
 576 nnoremap <silent> <Leader>1 :1buffer<CR>
 577 nnoremap <silent> <Leader>2 :2buffer<CR>
 578 nnoremap <silent> <Leader>3 :3buffer<CR>
 579 nnoremap <silent> <Leader>4 :4buffer<CR>
 580 nnoremap <silent> <Leader>5 :5buffer<CR>
 581 nnoremap <silent> <Leader>6 :6buffer<CR>
 582 nnoremap <silent> <Leader>7 :7buffer<CR>
 583 nnoremap <silent> <Leader>8 :8buffer<CR>
 584 nnoremap <silent> <Leader>9 :9buffer<CR>
 585 nnoremap <silent> <Leader>0 :10buffer<CR>
 586
 587 " Make last active window the only window. Similar to <C-W> o.
 588 nnoremap <C-W>O <C-W>p<C-W>o
 589
 590 " Maps to change spell language between English and German and disable spell
 591 " checking.
 592 if exists('+spell')
 593     nnoremap <silent> <Leader>sn :set nospell<CR>
 594     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 595     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 596 " If no spell support is available, these mappings do nothing.
 597 else
 598     nmap <Leader>sn <Nop>
 599     nmap <Leader>se <Nop>
 600     nmap <Leader>sd <Nop>
 601 endif
 602
 603 " Add semicolon to the end of the line. Thanks to
 604 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 605 " on Freenode for an improved version which doesn't clobber any marks.
 606 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 607
 608 " * and # for selections in visual mode. Thanks to
 609 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 610 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 611 if has('eval')
 612     function! s:VSetSearch()
 613         let l:temp = @@ " unnamed register
 614         normal! gvy
 615         " Added \C to force 'noignorecase' while searching the current visual
 616         " selection. I want to search for the exact string in this case.
 617         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 618         let @@ = l:temp
 619     endfunction
 620     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 621     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 622 endif
 623
 624 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 625 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 626 " mailing list for the commands.
 627 if v:version < 700
 628     cnoreabbrev W w
 629     cnoreabbrev Wa wa
 630     cnoreabbrev Wq wq
 631     cnoreabbrev Wqa wqa
 632 else
 633     cnoreabbrev <expr> W
 634         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 635     cnoreabbrev <expr> Wa
 636         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 637     cnoreabbrev <expr> Wq
 638         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 639     cnoreabbrev <expr> Wqa
 640         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 641 endif
 642 " Also fix my typo with "Q".
 643 if v:version < 700
 644     cnoreabbrev Q q
 645     cnoreabbrev Qa qa
 646 else
 647     cnoreabbrev <expr> Q
 648         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 649     cnoreabbrev <expr> Qa
 650         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 651 endif
 652
 653 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 654 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 655 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 656
 657 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 658 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 659 " Vim's source.
 660 inoremap <C-U> <C-G>u<C-U>
 661 " Same for <C-@> (insert previously inserted text and leave insert mode).
 662 inoremap <C-@> <C-G>u<C-@>
 663 " And for <C-A> (insert previously inserted text).
 664 inoremap <C-A> <C-G>u<C-A>
 665 " And for <C-W> (delete word before cursor).
 666 inoremap <C-W> <C-G>u<C-W>
 667
 668 if has('eval')
 669 " New text-objects ii and ai to work on text with the same indentation. Thanks
 670 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 671 " (visited on 2011-11-19).
 672     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 673     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 674     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 675     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 676
 677     function! s:IndTxtObj(inner)
 678         let curline = line(".")
 679         let lastline = line("$")
 680         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 681         let i = i < 0 ? 0 : i
 682         if getline(".") !~ "^\\s*$"
 683             let p = line(".") - 1
 684             let nextblank = getline(p) =~ "^\\s*$"
 685             while p > 0
 686                     \ && ((i == 0 && !nextblank)
 687                         \ || (i > 0 && ((indent(p) >= i
 688                             \ && !(nextblank && a:inner))
 689                             \ || (nextblank && !a:inner))))
 690                 -
 691                 let p = line(".") - 1
 692                 let nextblank = getline(p) =~ "^\\s*$"
 693             endwhile
 694             normal! 0V
 695             call cursor(curline, 0)
 696             let p = line(".") + 1
 697             let nextblank = getline(p) =~ "^\\s*$"
 698             while p <= lastline
 699                     \ && ((i == 0 && !nextblank)
 700                         \ || (i > 0 && ((indent(p) >= i
 701                             \ && !(nextblank && a:inner))
 702                             \ || (nextblank && !a:inner))))
 703                 +
 704                 let p = line(".") + 1
 705                 let nextblank = getline(p) =~ "^\\s*$"
 706             endwhile
 707             normal! $
 708         endif
 709     endfunction
 710 endif
 711
 712
 713 " ABBREVIATIONS
 714
 715 " Fix some of my spelling mistakes (German).
 716 inoreabbrev relle reelle
 717 inoreabbrev reele reelle
 718 " Fix some of my spelling mistakes (English).
 719 inoreabbrev completly completely
 720
 721
 722 " SYNTAX SETTINGS
 723
 724 " Activate syntax coloring.
 725 if has('syntax')
 726     syntax enable
 727
 728 " Don't highlight more than 500 columns as I normally don't have that long
 729 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 730 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 731     if exists('+synmaxcol')
 732         set synmaxcol=500
 733     endif
 734
 735 " Use (limited) syntax based omni completion if no other omni completion is
 736 " available. Taken from :help ft-syntax-omni.
 737     if has('autocmd') && exists('+omnifunc')
 738         augroup vimrc
 739             autocmd FileType *
 740                 \ if &omnifunc == '' |
 741                 \     setlocal omnifunc=syntaxcomplete#Complete |
 742                 \ endif
 743         augroup END
 744     endif
 745
 746 " Function to enable all custom highlights. Necessary as highlights are
 747 " window-local and thus must be set for each new window.
 748     function! s:CustomSyntaxHighlights()
 749         " Not the first time called, nothing to do.
 750         if exists('w:vimrc_syntax_run')
 751             return
 752         endif
 753         let w:vimrc_syntax_run = 1
 754
 755 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 756 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 757 " disabled when necessary with :2match (in Vim >= 700).
 758         if !&diff && exists(':2match')
 759             " Use ColorColumn for overlong lines if available and my color
 760             " scheme is used.
 761             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 762                 2match ColorColumn /\%>78v./
 763             else
 764                 2match Todo /\%>78v./
 765             endif
 766         elseif !&diff
 767             match Todo /\%>78v./
 768         endif
 769
 770         if exists('*matchadd')
 771 " Highlight some important keywords in all documents.
 772             let l:todos = ['TODO', 'XXX', 'FIXME',
 773                          \ 'CHANGED', 'REMOVED', 'DELETED']
 774             " Compatibility fix for Vim 6.4 which can't handle for in function
 775             " (without function it's ignored).
 776             execute '  for l:x in l:todos'
 777                   \ '|     call matchadd("Todo", l:x)'
 778                   \ '| endfor'
 779
 780 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 781             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 782                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 783                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 784                           \ '205f', '2060', '3000', 'feff']
 785             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 786             " it won't work!
 787             execute '  for l:x in l:spaces'
 788                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 789                   \ '| endfor'
 790
 791 " Special highlight for tabs to reduce their visibility in contrast to other
 792 " SpecialKey characters (e.g. ^L).
 793             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 794                 call matchadd('specialKeyTab', '\t')
 795             endif
 796         endif
 797     endfunction
 798 " Enable highlights for the current and all new windows. Thanks to bairui in
 799 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 800     call <SID>CustomSyntaxHighlights()
 801     if has('autocmd')
 802         augroup vimrc
 803             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 804         augroup END
 805     endif
 806
 807 " Settings for specific filetypes.
 808
 809     " C
 810     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 811     " Haskell.
 812     let g:hs_highlight_delimiters = 1
 813     let g:hs_highlight_boolean = 1
 814     let g:hs_highlight_types = 1
 815     let g:hs_highlight_more_types = 1
 816     " Java.
 817     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 818     " Perl.
 819     let g:perl_fold = 1
 820     let g:perl_fold_blocks = 1
 821     let g:perl_nofold_packages = 1
 822     let g:perl_include_pod = 1 " syntax coloring for PODs
 823     " PHP.
 824     let g:php_folding = 3    " fold functions
 825     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 826     let g:php_sql_query = 1  " highlight SQL queries in strings
 827     " Python.
 828     let g:python_highlight_all = 1
 829     " Shell.
 830     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 831     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 832     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 833     " Vim.
 834     let g:vimsyn_embed = 0      " don't highlight embedded languages
 835     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 836     " XML.
 837     let g:xml_syntax_folding = 1
 838 endif
 839
 840
 841 " PLUGIN SETTINGS
 842
 843 if has('eval')
 844 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 845 " installing/removing/updating plugins simple. (Used for plugins with more
 846 " than one file.) Ignore errors in case pathogen is not installed.
 847     if v:version >= 700
 848         silent! execute 'call pathogen#infect()'
 849     endif
 850
 851 " Settings for securemodelines.
 852     " Only allow items I need (also includes spl which is not enabled by
 853     " default).
 854     if v:version >= 700 " need lists
 855         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 856                                               \ 'sw', 'sts', 'noet']
 857     endif
 858
 859 " Settings for the NERD commenter.
 860     " Don't create any mappings I don't want to use.
 861     let g:NERDCreateDefaultMappings = 0
 862     " Map toggle comment.
 863     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 864
 865 " XPTemplate settings.
 866     " Try to maintain snippet rendering even after editing outside of a
 867     " snippet.
 868     let g:xptemplate_strict = 0
 869     " Don't complete any braces automatically.
 870     let g:xptemplate_brace_complete = 0
 871     " Only highlight the current placeholder.
 872     let g:xptemplate_highlight = 'current'
 873
 874 " CtrlP settings.
 875     " Don't manage the working directory (the default setting is too slow for
 876     " me).
 877     let g:ctrlp_working_path_mode = 0
 878     " Path to cache directory. I prefer to keep generated files as local as
 879     " possible.
 880     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 881     " Permanent cache, cleared by a crontab entry.
 882     let g:ctrlp_clear_cache_on_exit = 0
 883
 884 " FSWitch settings.
 885     " Default don't work well for my projects.
 886     augroup vimrc
 887         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 888                           \ | let b:fswitchlocs = './'
 889         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 890                           \ | let b:fswitchlocs = './'
 891     augroup END
 892
 893     " Switch to corresponding header/source file.
 894     nnoremap <silent> <Leader>h :FSHere<CR>
 895 endif
 896
 897
 898 " AUTO COMMANDS
 899
 900 " Use a custom auto group to prevent problems when the vimrc files is sourced
 901 " twice.
 902 if has('autocmd')
 903     augroup vimrc
 904
 905 " Go to last position of opened files. Taken from :help last-position-jump.
 906         autocmd BufReadPost *
 907             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 908             \     execute "normal! g'\"" |
 909             \ endif
 910 " But not for Git commits, go to beginning of the file.
 911         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 912
 913 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 914 " when switching to a help buffer which is in the background with :buffer as
 915 " these options are local to windows (and not only to buffers). This happens
 916 " because I often want to use only one window and thus the help buffer is in
 917 " the background.
 918         autocmd BufWinEnter *.txt
 919             \ if &filetype == 'help' |
 920             \     setlocal nolist |
 921             \     setlocal nonumber |
 922             \ endif
 923
 924 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 925 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 926 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 927 " doesn't exist in older Vims.
 928         if exists('##InsertLeave')
 929             autocmd InsertLeave * set nopaste
 930         endif
 931
 932 " Write all files when running :mak[e] before 'makeprg' is called.
 933 " QuickFixCmdPre doesn't exist in older Vims.
 934         if exists('##QuickFixCmdPre')
 935             autocmd QuickFixCmdPre * wall
 936         endif
 937
 938 " Don't ignore case while in insert mode, but ignore case in all other modes.
 939 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 940 " capitalization. But while searching (/) 'ignorecase' is used.
 941 " InsertEnter/InsertLeave doesn't exist in older Vims.
 942         if exists('##InsertEnter') && exists('##InsertLeave')
 943             autocmd InsertEnter * set noignorecase
 944             autocmd InsertLeave * set   ignorecase
 945         endif
 946
 947 " Display a warning when editing a file which contains "do not edit" (ignoring
 948 " the case, \c), for example template files which were preprocessed or
 949 " auto-generated files. Especially useful when the header is not displayed on
 950 " the first screen, e.g. when the old position is restored. Not for vimrc
 951 " though.
 952         function! s:SearchForDoNotEditHeader()
 953             if search('\cdo not edit', 'n') == 0
 954                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
 955                 return
 956             endif
 957
 958             echoerr 'Do not edit this file! (Maybe a template file.)'
 959         endfunction
 960         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
 961
 962 " AFTER/FTPLUGIN AUTO COMMANDS
 963
 964 " Disable spell checking for files which don't need it.
 965         autocmd FileType deb  setlocal nospell
 966         autocmd FileType diff setlocal nospell
 967         autocmd FileType tar  setlocal nospell
 968 " Fix to allow Vim edit crontab files as crontab doesn't work with
 969 " backupcopy=auto.
 970         autocmd FileType crontab setlocal backupcopy=yes
 971 " Don't use the modeline in git commits as the diff created by `git commit -v`
 972 " may contain one which could change the filetype or other settings of the
 973 " commit buffer. Also make sure we use only 72 characters per line which is
 974 " the recommendation for git commit messages (http://tpope.net/node/106).
 975         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 976                                  \ setlocal textwidth=72
 977 " Use the same comment string as for Vim files in Vimperator files.
 978         autocmd FileType vimperator setlocal commentstring=\"%s
 979 " Use TeX compiler for (La)TeX files.
 980         autocmd FileType tex compiler tex
 981
 982 " FTDETECT AUTO COMMANDS
 983
 984 " Recognize .md as markdown files (Vim default is .mkd).
 985         autocmd BufRead,BufNewFile *.md set filetype=mkd
 986 " Recognize .test as Tcl files.
 987         autocmd BufRead,BufNewFile *.test set filetype=tcl
 988
 989 " OTHER AUTO COMMANDS
 990
 991 " Disable spell checking, displaying of list characters and long lines when
 992 " viewing documentation.
 993         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 994
 995 " Use diff filetype for mercurial patches in patch queue.
 996         autocmd BufReadPost */.hg/patches/* set filetype=diff
 997
 998     augroup END
 999 endif
1000
1001
1002 " CUSTOM FUNCTIONS AND COMMANDS
1003
1004 if has('eval')
1005 " Convenient command to see the difference between the current buffer and the
1006 " file it was loaded from, thus the changes you made. Thanks to the
1007 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1008 " for the diffed file than the filetype for the original file.
1009     if !exists(':DiffOrig')
1010         command DiffOrig
1011             \ let s:diff_orig_filetype = &filetype
1012             \ | vertical new
1013             \ | let &filetype = s:diff_orig_filetype
1014             \ | unlet s:diff_orig_filetype
1015             \ | set buftype=nofile
1016             \ | read ++edit #
1017             \ | 0d_
1018             \ | diffthis
1019             \ | wincmd p
1020             \ | diffthis
1021     endif
1022 endif