vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     " Only use fold column if we have enough space (for example in a (virtual)
 143     " terminals).
 144     if &columns > 80
 145         set foldcolumn=2
 146     endif
 147     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 148                      " folding which is not what I want
 149 endif
 150
 151 " Only check for case if the searched word contains a capital character.
 152 set ignorecase
 153 set smartcase
 154
 155 " Activate spell checking, use English as default.
 156 if exists('+spell') && has('syntax')
 157     " But not when diffing because spell checking is distracting in this case.
 158     if !&diff
 159         set spell
 160     endif
 161     set spelllang=en_us
 162 endif
 163
 164 " Allow buffers with changes to be hidden. Very important for effective
 165 " editing with multiple buffers.
 166 set hidden
 167
 168
 169 " DISPLAY SETTINGS
 170
 171 " Use a dark background. Doesn't change the background color, only sets text
 172 " colors for a dark terminal.
 173 set background=dark
 174
 175 " Display line numbers.
 176 set number
 177 " But use as little space as necessary for the numbers column. Thanks to James
 178 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 179 if exists('+numberwidth')
 180     set numberwidth=1
 181 endif
 182 " Display the ruler with current line/file position. If 'statusline' is used
 183 " then this only affects <C-G>.
 184 set ruler
 185 " Display partial commands in the status line.
 186 set showcmd
 187
 188 " Don't redraw screen when executing macros; increases speed. Thanks to James
 189 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 190 set lazyredraw
 191
 192 " Visualize the line the cursor is currently in.
 193 if exists('+cursorline')
 194     set cursorline
 195 endif
 196
 197 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 198 " remove the highlighting until the next search.
 199 set hlsearch
 200
 201 " Display some special characters.
 202 set list
 203 set listchars=
 204 " Display trailing whitespace as "-".
 205 set listchars+=trail:-
 206 " Display markers for long lines when wrapping is disabled.
 207 set listchars+=extends:>
 208 " Display non-breakable space as "!".
 209 if v:version >= 700
 210     set listchars+=nbsp:!
 211 endif
 212
 213 if has('statusline')
 214     " Always display the status line even if there is only one window.
 215     set laststatus=2
 216
 217     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 218     " is the highest buffer number, otherwise return nothing. Used in
 219     " 'statusline' to get an overview of available buffer numbers.
 220     function! StatuslineBufferCount()
 221         let l:bufnr = bufnr('$')
 222         if l:bufnr > 1
 223             let l:result = '/'
 224             if exists('*printf')
 225                 let l:result .= printf('%02d', l:bufnr)
 226             else
 227                 " Older Vims don't have printf() (and no .= either). Emulate
 228                 " "%02d".
 229                 if l:bufnr < 10
 230                     let l:result = l:result . '0'
 231                 endif
 232                 let l:result = l:result . l:bufnr
 233             endif
 234             return l:result
 235         else
 236             return ''
 237         endif
 238     endfunction
 239
 240     set statusline=
 241     " on the left
 242     set statusline+=%02n  " buffer number
 243     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 244     set statusline+=:
 245     set statusline+=%f\   " path to current file in buffer
 246     set statusline+=%h    " [help] if buffer is help file
 247     set statusline+=%w    " [Preview] if buffer is preview buffer
 248     set statusline+=%m    " [+] if buffer was modified,
 249                           " [-] if 'modifiable' is off
 250     set statusline+=%r    " [RO] if buffer is read only
 251
 252     " on the right
 253     set statusline+=%=                " right align
 254     set statusline+=0x%-8B\           " current character under cursor as hex
 255     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 256                                       " column number (%c),
 257                                       " virtual column number if different
 258                                       "                       than %c (%V)
 259     set statusline+=%P                " position in file in percent
 260 endif
 261
 262
 263 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 264
 265 " noremap is used to make sure the right side is executed as is and can't be
 266 " modified by a plugin or other settings. Except for <Nop> which isn't
 267 " affected by mappings.
 268
 269 " Easy way to exit insert mode.
 270 inoremap jj <Esc>
 271 inoremap jk <Esc>
 272 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 273 " (2010-10-15).
 274 cnoremap jj <C-C>
 275 cnoremap jk <C-C>
 276
 277 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 278 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 279 map <Right>  <Nop>
 280 map <Left>   <Nop>
 281 map <Up>     <Nop>
 282 map <Down>   <Nop>
 283 imap <Right> <Nop>
 284 imap <Left>  <Nop>
 285 imap <Up>    <Nop>
 286 imap <Down>  <Nop>
 287 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 288 " below).
 289 cmap <Up>    <Nop>
 290 cmap <Down>  <Nop>
 291 cmap <Right> <Nop>
 292 cmap <Left>  <Nop>
 293
 294 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 295 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 296 cnoremap <C-P> <Up>
 297 cnoremap <C-N> <Down>
 298
 299 if has('eval')
 300 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 301 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 302 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 303 " directly because it also enables that feature for other commands which I
 304 " don't want.
 305
 306     " Set 'nostartofline' for a single movement.
 307     function! s:TemporaryNostartofline(movement)
 308         let l:startofline = &startofline
 309         set nostartofline
 310         execute 'normal! ' . a:movement
 311         let &startofline = l:startofline
 312     endfunction
 313
 314     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 315     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 316     nnoremap <silent> <C-F>
 317         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 318     nnoremap <silent> <C-B>
 319         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 320     nnoremap <silent> <C-D>
 321         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 322     nnoremap <silent> <C-U>
 323         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 324 endif
 325
 326 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 327 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 328 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 329
 330 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 331 " in #vim on Freenode (2011-08-15 00:17 CEST).
 332 nnoremap <C-G> 2<C-G>
 333
 334 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 335 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 336 nmap <Space> <C-F>
 337 nmap - <C-B>
 338
 339 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 340 " (2010-05-16 18:38 CEST) for this idea.
 341 nnoremap <silent> gb :bnext<CR>
 342 nnoremap <silent> gB :bprev<CR>
 343
 344 " Fast access to buffers.
 345 nnoremap <silent> <Leader>1 :1buffer<CR>
 346 nnoremap <silent> <Leader>2 :2buffer<CR>
 347 nnoremap <silent> <Leader>3 :3buffer<CR>
 348 nnoremap <silent> <Leader>4 :4buffer<CR>
 349 nnoremap <silent> <Leader>5 :5buffer<CR>
 350 nnoremap <silent> <Leader>6 :6buffer<CR>
 351 nnoremap <silent> <Leader>7 :7buffer<CR>
 352 nnoremap <silent> <Leader>8 :8buffer<CR>
 353 nnoremap <silent> <Leader>9 :9buffer<CR>
 354 nnoremap <silent> <Leader>0 :10buffer<CR>
 355
 356 " Make last active window the only window. Similar to <C-W> o.
 357 nnoremap <C-W>O <C-W>p<C-W>o
 358
 359 " Maps to change spell language between English and German and disable spell
 360 " checking.
 361 if exists('+spell')
 362     nnoremap <silent> <Leader>sn :set nospell<CR>
 363     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 364     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 365 endif
 366
 367 " Add semicolon to the end of the line. Thanks to
 368 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 369 " on Freenode for an improved version which doesn't clobber any marks.
 370 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 371
 372 " * and # for selections in visual mode. Thanks to
 373 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 374 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 375 if has('eval')
 376     function! s:VSetSearch()
 377         let l:temp = @@
 378         normal! gvy
 379         " Added \C to force 'noignorecase' while searching the current visual
 380         " selection. I want to search for the exact string in this case.
 381         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 382         let @@ = l:temp
 383     endfunction
 384     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 385     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 386 endif
 387
 388 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 389 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 390 " mailing list for the commands.
 391 if v:version < 700
 392     cnoreabbrev W w
 393     cnoreabbrev Wa wa
 394     cnoreabbrev Wq wq
 395     cnoreabbrev Wqa wqa
 396 else
 397     cnoreabbrev <expr> W
 398         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 399     cnoreabbrev <expr> Wa
 400         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 401     cnoreabbrev <expr> Wq
 402         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 403     cnoreabbrev <expr> Wqa
 404         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 405 endif
 406 " Also fix my typo with "Q".
 407 if v:version < 700
 408     cnoreabbrev Q q
 409     cnoreabbrev Qa qa
 410 else
 411     cnoreabbrev <expr> Q
 412         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 413     cnoreabbrev <expr> Qa
 414         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 415 endif
 416
 417 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 418 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 419 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 420
 421 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 422 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 423 " Vim's source.
 424 inoremap <C-U> <C-G>u<C-U>
 425 " Same for <C-@> (insert previously inserted text and leave insert mode).
 426 inoremap <C-@> <C-G>u<C-@>
 427 " And for <C-A> (insert previously inserted text).
 428 inoremap <C-A> <C-G>u<C-A>
 429 " And for <C-W> (delete word before cursor).
 430 inoremap <C-W> <C-G>u<C-W>
 431
 432 if has('eval')
 433 " New text-objects ii and ai to work on text with the same indentation. Thanks
 434 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 435 " (visited on 2011-11-19).
 436     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 437     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 438     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 439     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 440
 441     function! s:IndTxtObj(inner)
 442         let curline = line(".")
 443         let lastline = line("$")
 444         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 445         let i = i < 0 ? 0 : i
 446         if getline(".") !~ "^\\s*$"
 447             let p = line(".") - 1
 448             let nextblank = getline(p) =~ "^\\s*$"
 449             while p > 0
 450                     \ && ((i == 0 && !nextblank)
 451                         \ || (i > 0 && ((indent(p) >= i
 452                             \ && !(nextblank && a:inner))
 453                             \ || (nextblank && !a:inner))))
 454                 -
 455                 let p = line(".") - 1
 456                 let nextblank = getline(p) =~ "^\\s*$"
 457             endwhile
 458             normal! 0V
 459             call cursor(curline, 0)
 460             let p = line(".") + 1
 461             let nextblank = getline(p) =~ "^\\s*$"
 462             while p <= lastline
 463                     \ && ((i == 0 && !nextblank)
 464                         \ || (i > 0 && ((indent(p) >= i
 465                             \ && !(nextblank && a:inner))
 466                             \ || (nextblank && !a:inner))))
 467                 +
 468                 let p = line(".") + 1
 469                 let nextblank = getline(p) =~ "^\\s*$"
 470             endwhile
 471             normal! $
 472         endif
 473     endfunction
 474 endif
 475
 476
 477 " ABBREVIATIONS
 478
 479 " Fix some of my spelling mistakes.
 480 iabbrev relle reelle
 481 iabbrev reele reelle
 482
 483
 484 " SYNTAX SETTINGS
 485
 486 " Activate syntax coloring.
 487 if has('syntax')
 488     syntax enable
 489
 490 " Don't highlight more than 500 columns as I normally don't have that long
 491 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 492 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 493     if exists('+synmaxcol')
 494         set synmaxcol=500
 495     endif
 496
 497 " Use (limited) syntax based omni completion if no other omni completion is
 498 " available. Taken from :help ft-syntax-omni.
 499     if has('autocmd') && exists('+omnifunc')
 500         augroup vimrc
 501             autocmd FileType *
 502                 \ if &omnifunc == '' |
 503                 \     setlocal omnifunc=syntaxcomplete#Complete |
 504                 \ endif
 505         augroup END
 506     endif
 507
 508 " Function to enable all custom highlights. Necessary as highlights are
 509 " window-local and thus must be set for each new window.
 510     function! s:CustomSyntaxHighlights()
 511         " Not the first time called, nothing to do.
 512         if exists('w:vimrc_syntax_run')
 513             return
 514         endif
 515         let w:vimrc_syntax_run = 1
 516
 517 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 518 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 519 " disabled when necessary with :2match (in Vim >= 700).
 520         if exists(':2match')
 521             2match Todo /\%>78v./
 522         else
 523             match Todo /\%>78v./
 524         endif
 525
 526         if exists('*matchadd')
 527 " Highlight some important keywords in all documents.
 528             let l:todos = ['TODO', 'XXX', 'FIXME',
 529                          \ 'CHANGED', 'REMOVED', 'DELETED']
 530             " Compatibility fix for Vim 6.4 which can't handle for in function
 531             " (without function it's ignored).
 532             execute '  for l:x in l:todos'
 533                   \ '|     call matchadd("Todo", l:x)'
 534                   \ '| endfor'
 535
 536 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 537             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 538                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 539                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 540                           \ '205f', '2060', '3000', 'feff']
 541             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 542             " it won't work!
 543             execute '  for l:x in l:spaces'
 544                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 545                   \ '| endfor'
 546         endif
 547     endfunction
 548 " Enable highlights for the current and all new windows. Thanks to bairui in
 549 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 550     call <SID>CustomSyntaxHighlights()
 551     if has('autocmd')
 552         augroup vimrc
 553             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 554         augroup END
 555     endif
 556
 557 " Settings for specific filetypes.
 558
 559     " Haskell.
 560     let g:hs_highlight_delimiters = 1
 561     let g:hs_highlight_boolean = 1
 562     let g:hs_highlight_types = 1
 563     let g:hs_highlight_more_types = 1
 564     " Perl.
 565     let g:perl_fold = 1
 566     let g:perl_fold_blocks = 1
 567     let g:perl_nofold_packages = 1
 568     let g:perl_include_pod = 1 " syntax coloring for PODs
 569     " Python.
 570     let g:python_highlight_all = 1
 571     " Shell.
 572     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 573     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 574     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 575     " Vim.
 576     let g:vimsyn_embed = 0      " don't highlight embedded languages
 577     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 578     " XML.
 579     let g:xml_syntax_folding = 1
 580 endif
 581
 582
 583 " PLUGIN SETTINGS
 584
 585 if has('eval')
 586 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 587 " installing/removing/updating plugins simple. (Used for plugins with more
 588 " than one file.) Ignore errors in case pathogen is not installed.
 589     if v:version >= 700
 590         silent! execute 'call pathogen#runtime_append_all_bundles()'
 591     endif
 592
 593 " Settings for the NERD commenter.
 594     " Don't create any mappings I don't want to use.
 595     let g:NERDCreateDefaultMappings = 0
 596     " Map toggle comment.
 597     map <Leader><Leader> <Plug>NERDCommenterToggle
 598
 599 " XPTemplate settings.
 600     " Try to maintain snippet rendering even after editing outside of a
 601     " snippet.
 602     let g:xptemplate_strict = 0
 603     " Don't complete any braces automatically.
 604     let g:xptemplate_brace_complete = 0
 605     " Only highlight the current placeholder.
 606     let g:xptemplate_highlight = 'current'
 607 endif
 608
 609
 610 " AUTO COMMANDS
 611
 612 " Use a custom auto group to prevent problems when the vimrc files is sourced
 613 " twice.
 614 if has('autocmd')
 615     augroup vimrc
 616
 617 " Go to last position of opened files. Taken from :help last-position-jump.
 618         autocmd BufReadPost *
 619             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 620             \     execute "normal! g'\"" |
 621             \ endif
 622 " But not for Git commits, go to beginning of the file.
 623         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 624
 625 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 626 " when switching to a help buffer which is in the background with :buffer as
 627 " these options are local to windows (and not only to buffers). This happens
 628 " because I often want to use only one window and thus the help buffer is in
 629 " the background.
 630         autocmd BufWinEnter *.txt
 631             \ if &filetype == 'help' |
 632             \     setlocal nolist |
 633             \     setlocal nonumber |
 634             \ endif
 635
 636 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 637 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 638 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 639 " doesn't exist in older Vims.
 640         if exists('##InsertLeave')
 641             autocmd InsertLeave * set nopaste
 642         endif
 643
 644 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 645 " doesn't exist in older Vims.
 646         if exists('##QuickFixCmdPre')
 647             autocmd QuickFixCmdPre * write
 648         endif
 649
 650 " Don't ignore case while in insert mode, but ignore case in all other modes.
 651 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 652 " capitalization. But while searching (/) 'ignorecase' is used.
 653 " InsertEnter/InsertLeave doesn't exist in older Vims.
 654         if exists('##InsertEnter') && exists('##InsertLeave')
 655             autocmd InsertEnter * set noignorecase
 656             autocmd InsertLeave * set   ignorecase
 657         endif
 658
 659 " AFTER/FTPLUGIN AUTO COMMANDS
 660
 661 " Disable spell checking for files which don't need it.
 662         autocmd FileType deb  setlocal nospell
 663         autocmd FileType diff setlocal nospell
 664         autocmd FileType tar  setlocal nospell
 665 " Fix to allow Vim edit crontab files as crontab doesn't work with
 666 " backupcopy=auto.
 667         autocmd FileType crontab setlocal backupcopy=yes
 668 " Don't use the modeline in git commits as the diff created by `git commit -v`
 669 " may contain one which could change the filetype or other settings of the
 670 " commit buffer. Also make sure we use only 72 characters per line which is
 671 " the recommendation for git commit messages (http://tpope.net/node/106).
 672         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 673                                  \ setlocal textwidth=72
 674 " Use the same comment string as for Vim files in Vimperator files.
 675         autocmd FileType vimperator setlocal commentstring=\"%s
 676 " Use tex compiler for (La)TeX files.
 677         autocmd FileType tex compiler tex
 678
 679 " FTDETECT AUTO COMMANDS
 680
 681 " Recognize .md as markdown files (Vim default is .mkd).
 682         autocmd BufRead,BufNewFile *.md set filetype=mkd
 683 " Recognize .test as Tcl files.
 684         autocmd BufRead,BufNewFile *.test set filetype=tcl
 685
 686 " OTHER AUTO COMMANDS
 687
 688 " Disable spell checking, displaying of list characters and long lines when
 689 " viewing documentation.
 690         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 691
 692 " Use diff filetype for mercurial patches in patch queue.
 693         autocmd BufReadPost */.hg/patches/* set filetype=diff
 694
 695     augroup END
 696 endif
 697
 698
 699 " CUSTOM FUNCTIONS AND COMMANDS
 700
 701 if has('eval')
 702 " Convenient command to see the difference between the current buffer and the
 703 " file it was loaded from, thus the changes you made. Thanks to the
 704 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 705 " for the diffed file than the filetype for the original file.
 706     if !exists(':DiffOrig')
 707         command DiffOrig
 708             \ let s:diff_orig_filetype = &filetype
 709             \ | vertical new
 710             \ | let &filetype = s:diff_orig_filetype
 711             \ | unlet s:diff_orig_filetype
 712             \ | set buftype=nofile
 713             \ | read ++edit #
 714             \ | 0d_
 715             \ | diffthis
 716             \ | wincmd p
 717             \ | diffthis
 718     endif
 719 endif