vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2013  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value. Not sure what exactly Vim is
  25 " doing there.
  26 if has('eval')
  27     let s:save_runtimepath = &runtimepath
  28     let s:save_diff = &diff
  29 endif
  30 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  31 " system wide configuration file doesn't change default values.
  32 set all&
  33 " And restore it after all other options were reset.
  34 if has('eval')
  35     let &runtimepath = s:save_runtimepath
  36     let &diff = s:save_diff
  37     unlet s:save_runtimepath
  38     unlet s:save_diff
  39 endif
  40
  41 " Make sure Vim (and not Vi) settings are used.
  42 set nocompatible
  43
  44 " Disallow :autocmd, shell and write commands in .vimrc and .exrc files in the
  45 " current directory. Only used if 'exrc' is enabled (off by default),
  46 " precaution just in case somebody enables 'exrc'.
  47 set secure
  48
  49 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  50 " affect reading files in different encodings, see 'fileencodings' for that.
  51 set encoding=utf-8
  52
  53 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  54 " runtime files) if available.
  55 set runtimepath-=~/.vim
  56 set runtimepath^=~/.vim,~/.vim/runtime
  57
  58 " Don't store swap files in the same directory as the edited file, but only if
  59 " we have a "safe" writable directory available.
  60 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
  61     set directory-=.
  62 endif
  63 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  64 set directory^=~/.tmp
  65
  66 " Disable modelines as they may cause security problems. Instead use
  67 " securemodelines (Vim script #1876).
  68 set nomodeline
  69
  70 " Complete to longest common string (list:longest) and then complete all full
  71 " matches after another (full). Thanks to pbrisbin
  72 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  73 set wildmode=list:longest,full
  74 " Ignore case when completing files/directories.
  75 if exists('+wildignorecase')
  76     set wildignorecase
  77 endif
  78
  79 " Ignore files with the following extensions because I almost never want to
  80 " edit them in Vim (specifying them manually still works of course).
  81 set wildignore=
  82 " C
  83 set wildignore+=*.o,*.d,*.so
  84 " Java
  85 set wildignore+=*.class
  86 " LaTeX
  87 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
  88 " Python
  89 set wildignore+=*.pyc
  90
  91 " Show completion menu even if only one entry matches.
  92 if exists('+completeopt')
  93     set completeopt+=menuone
  94 endif
  95
  96 " Increase history of executed commands (:) and search patterns (/).
  97 set history=1000
  98
  99 " Increase number of possible undos.
 100 set undolevels=1000
 101
 102 " Remember marks (including the last cursor position) for more files. ^= is
 103 " necessary because 'viminfo' is parsed from the beginning and the first match
 104 " is used.
 105 if has('viminfo')
 106     set viminfo^='1000
 107 endif
 108
 109 " Use strong encryption if possible, also used for swap/undo files.
 110 if exists('+cryptmethod')
 111     set cryptmethod=blowfish
 112 endif
 113
 114 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
 115 " is used multiple times. Necessary to support reloading the vimrc.
 116 if has('autocmd')
 117     augroup vimrc
 118         autocmd!
 119     augroup END
 120 endif
 121
 122
 123 " HELPER FUNCTIONS
 124
 125 if has('eval')
 126 " Check if the given syntax group is available. Thanks to bairui in #vim on
 127 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
 128     function! s:HasSyntaxGroup(group)
 129         try
 130             execute 'silent highlight ' . a:group
 131         " \a = [A-Za-z]
 132         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 133             return 0
 134         endtry
 135         return 1
 136     endfunction
 137
 138 " Check if the given Vim version and patch is available.
 139     function! s:HasVersionAndPatch(version, patch)
 140         return v:version > a:version
 141             \ || (v:version == a:version && has('patch' . a:patch))
 142     endfunction
 143 endif
 144
 145
 146 " TERMINAL SETTINGS
 147
 148 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
 149 " connections.
 150 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
 151     set ttyfast
 152 endif
 153
 154
 155 " EDIT SETTINGS
 156
 157 " Enable automatic file detection, plugin and indention support.
 158 if has('autocmd')
 159     filetype off " necessary for pathogen to force a reload of ftplugins
 160     filetype plugin indent on
 161 endif
 162
 163 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 164 " existing files.
 165 set fileencodings=utf-8,latin1
 166
 167 " Always use unix line-endings for new files.
 168 set fileformats=unix,dos
 169
 170 " Wrap text after 78 characters.
 171 set textwidth=78
 172
 173 " Set tabs to 4 spaces, use softtabs.
 174 set shiftwidth=4
 175 set softtabstop=4
 176 set expandtab
 177 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 178 set shiftround
 179 " Use the default value for real tabs.
 180 set tabstop=8
 181
 182 " Enable auto indention.
 183 set autoindent
 184
 185 " When joining lines only add one space after a sentence.
 186 set nojoinspaces
 187
 188 " Allow backspacing over autoindent and line breaks.
 189 set backspace=indent,eol
 190
 191 " Start a comment when hitting enter after a commented line (r) and when using
 192 " o or O around a commented line (o).
 193 set formatoptions+=ro
 194 " Don't break a line if was already longer then 'textwidth' when insert mode
 195 " started.
 196 set formatoptions+=l
 197 " Remove comment leader when joining lines where it makes sense.
 198 if s:HasVersionAndPatch(703, 541)
 199     set formatoptions+=j
 200 endif
 201
 202 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 203 " no character) in visual block mode.
 204 set virtualedit=block
 205
 206 " Already display matches while typing the search command. This makes spotting
 207 " typos easy and searching faster.
 208 set incsearch
 209
 210 " Activate syntax folding.
 211 if has('folding')
 212     set foldmethod=syntax
 213     " Only use fold column if we have enough space (for example not in a
 214     " (virtual) terminal which has only 80 columns).
 215     if &columns > 80
 216         set foldcolumn=2
 217     endif
 218     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 219                      " folding which is not what I want
 220     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
 221     set foldopen-=block
 222 endif
 223
 224 " Only check case if the searched word contains a capital character.
 225 set ignorecase
 226 set smartcase
 227
 228 " Activate spell checking, use English as default.
 229 if exists('+spell') && has('syntax')
 230     " But not when diffing because spell checking is distracting in this case.
 231     if !&diff
 232         set spell
 233     endif
 234     set spelllang=en_us
 235 endif
 236
 237 " Allow buffers with changes to be hidden. Very important for efficient
 238 " editing with multiple buffers. Prevents the "E37: No write since last change
 239 " (add ! to override)" warning when switching modified buffers.
 240 set hidden
 241
 242 " When splitting vertically put the new window right of the current one.
 243 if has('vertsplit')
 244     set splitright
 245 endif
 246
 247
 248 " DISPLAY SETTINGS
 249
 250 " Use a dark background. Doesn't change the background color, only sets text
 251 " colors for a dark terminal.
 252 set background=dark
 253
 254 " Use my color scheme if 256 colors are available.
 255 if &t_Co == 256 || has('gui_running')
 256     colorscheme simon
 257 endif
 258
 259 " Display line numbers.
 260 set number
 261 " But use as little space as possible for the numbers column. Thanks to James
 262 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 263 if exists('+numberwidth')
 264     set numberwidth=1
 265 endif
 266 " Display the ruler with current line/file position. If 'statusline' is used
 267 " then this only affects <C-G>.
 268 set ruler
 269 " Display partial commands in the status line.
 270 set showcmd
 271
 272 " Don't redraw screen when executing macros; increases speed. Thanks to James
 273 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 274 set lazyredraw
 275
 276 " Visualize the line the cursor is currently in.
 277 if exists('+cursorline')
 278     set cursorline
 279 endif
 280
 281 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 282 " remove the highlighting until the next search.
 283 set hlsearch
 284
 285 " Display some special characters.
 286 set list
 287 set listchars=
 288 " Display tabs as ">--------".
 289 set listchars+=tab:>-
 290 " Display trailing whitespace as "-".
 291 set listchars+=trail:-
 292 " Display markers for long lines when wrapping is disabled.
 293 set listchars+=extends:>,precedes:<
 294 " Display non-breakable space as "!".
 295 if v:version >= 700
 296     set listchars+=nbsp:!
 297 endif
 298
 299 " Don't draw the vertical split separator by using space as character. Thanks
 300 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 301 " non-breakable space. But a simple space works as well, as long as the
 302 " current color scheme is not reset.
 303 if has('windows') && has('folding')
 304     set fillchars+=vert:\  " comment to prevent trailing whitespace
 305 endif
 306
 307 if has('statusline')
 308     " Always display the status line even if there is only one window.
 309     set laststatus=2
 310
 311     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 312     " is the highest buffer number, otherwise return nothing. Used in
 313     " 'statusline' to get an overview of available buffer numbers.
 314     function! s:StatuslineBufferCount()
 315         let l:bufnr = bufnr('$')
 316         if l:bufnr > 1
 317             let l:result = '/'
 318             if exists('*printf')
 319                 let l:result .= printf('%02d', l:bufnr)
 320             else
 321                 " Older Vims don't have printf() (and no .= either). Emulate
 322                 " "%02d".
 323                 if l:bufnr < 10
 324                     let l:result = l:result . '0'
 325                 endif
 326                 let l:result = l:result . l:bufnr
 327             endif
 328             return l:result
 329         else
 330             return ''
 331         endif
 332     endfunction
 333
 334     " Like %f but use relative filename if it's shorter than the absolute path
 335     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
 336     " not enough because it doesn't create '../'s.
 337     function! s:StatuslineRelativeFilename()
 338         " Display only filename for help files.
 339         if &buftype == 'help'
 340             return expand('%:t')
 341         endif
 342         " Special case for scratch files.
 343         if &buftype == 'nofile'
 344             return '[Scratch]'
 345         endif
 346
 347         let l:path = expand('%')
 348         " No file.
 349         if l:path == ''
 350             return '[No Name]'
 351         endif
 352         " Path is already relative, nothing to do.
 353         if stridx(l:path, '/') != 0
 354             return l:path
 355         endif
 356
 357         " Absolute path to this file.
 358         let l:path = expand('%:p')
 359         " Shortened path to this file, thanks to bairui in #vim on Freenode
 360         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
 361         " Vim normally uses as %f (minus some exceptions).
 362         let l:original_path = fnamemodify(l:path, ':~')
 363         " Absolute path to the current working directory.
 364         let l:cwd = getcwd()
 365
 366         " Working directory completely contained in path, replace it with a
 367         " relative path. Happens for example when opening a file with netrw.
 368         " %f displays this as absolute path, but we want a relative path of
 369         " course.
 370         if stridx(l:path, l:cwd) == 0
 371             return strpart(l:path, strlen(l:cwd) + 1)
 372         endif
 373
 374         let l:path_list = split(l:path, '/')
 375         let l:cwd_list  = split(l:cwd,  '/')
 376
 377         " Remove the common path.
 378         while l:path_list[0] == l:cwd_list[0]
 379             call remove(l:path_list, 0)
 380             call remove(l:cwd_list,  0)
 381         endwhile
 382
 383         " Add as many '..' as necessary for the relative path and join the
 384         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
 385         " the hint to use repeat() instead of a loop.
 386         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
 387
 388         " Use the shorter path, either relative or absolute.
 389         if strlen(l:path) < strlen(l:original_path)
 390             return l:path
 391         else
 392             return l:original_path
 393         endif
 394     endfunction
 395
 396     " Display unexpected 'fileformat', 'fileencoding' and 'bomb' settings.
 397     function! s:StatuslineFileFormat()
 398         if &fileformat != 'unix'
 399             return '[' . &fileformat . ']'
 400         else
 401             return ''
 402         endif
 403     endfunction
 404     function! s:StatuslineFileEncoding()
 405         if &fileencoding != '' && &fileencoding != 'utf-8'
 406                 \ && &filetype != 'help'
 407             return '[' . &fileencoding . ']'
 408         else
 409             return ''
 410         endif
 411     endfunction
 412     function! s:StatuslineFileBOMB()
 413         if exists('+bomb') && &bomb
 414             return '[BOM]'
 415         else
 416             return ''
 417         endif
 418     endfunction
 419
 420     " Return current syntax group in brackets or nothing if there's none.
 421     function! s:StatuslineSyntaxGroup()
 422         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
 423         if l:group != ''
 424             return '[' . l:group . '] '
 425         else
 426             return ''
 427         endif
 428     endfunction
 429
 430     " Short function names to make 'statusline' more readable.
 431     function! SBC()
 432         return s:StatuslineBufferCount()
 433     endfunction
 434     function! SRF()
 435         return s:StatuslineRelativeFilename()
 436     endfunction
 437     function! SFF()
 438         return s:StatuslineFileFormat()
 439     endfunction
 440     function! SFE()
 441         return s:StatuslineFileEncoding()
 442     endfunction
 443     function! SFB()
 444         return s:StatuslineFileBOMB()
 445     endfunction
 446     function! SSG()
 447         return s:StatuslineSyntaxGroup()
 448     endfunction
 449
 450     set statusline=
 451     " on the left
 452     set statusline+=%02n              " buffer number
 453     set statusline+=%{SBC()}          " highest buffer number
 454     set statusline+=:
 455     if has('modify_fname') && v:version >= 700 " some functions need 7.0
 456         set statusline+=%{SRF()}      " path to current file
 457     else
 458         set statusline+=%f            " path to current file in buffer
 459     endif
 460     set statusline+=\                 " space after path
 461     set statusline+=%h                " [help] if buffer is help file
 462     set statusline+=%w                " [Preview] if buffer is preview buffer
 463     set statusline+=%m                " [+] if buffer was modified,
 464                                       " [-] if 'modifiable' is off
 465     set statusline+=%r                " [RO] if buffer is read only
 466     if v:version >= 700               " %#..# needs 7.0
 467         set statusline+=%#Error#      " display warnings
 468         set statusline+=%{SFF()}      "   - unexpected file format
 469         set statusline+=%{SFE()}      "   - unexpected file encoding
 470         set statusline+=%{SFB()}      "   - unexpected file byte order mask
 471         set statusline+=%##           " continue with normal colors
 472     endif
 473
 474     " on the right
 475     set statusline+=%=                " right align
 476     set statusline+=0x%-8B\           " current character under cursor as hex
 477     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 478                                       " column number (%c),
 479                                       " virtual column number if different
 480                                       "                       than %c (%V)
 481     set statusline+=%P                " position in file in percent
 482 endif
 483
 484
 485 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 486
 487 " noremap is used to make sure the right side is executed as is and can't be
 488 " modified by a plugin or other settings. Except for <Nop> which isn't
 489 " affected by mappings.
 490
 491 " Easy way to exit insert mode (jj is too slow).
 492 inoremap jk <Esc>
 493 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 494 " (2010-10-15).
 495 cnoremap jk <C-C>
 496 " And fix my typos ...
 497 inoremap JK <Esc>
 498 inoremap Jk <Esc>
 499 inoremap jK <Esc>
 500 cnoremap JK <C-C>
 501 cnoremap Jk <C-C>
 502 cnoremap jK <C-C>
 503
 504 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 505 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 506 map <Right>  <Nop>
 507 map <Left>   <Nop>
 508 map <Up>     <Nop>
 509 map <Down>   <Nop>
 510 imap <Right> <Nop>
 511 imap <Left>  <Nop>
 512 imap <Up>    <Nop>
 513 imap <Down>  <Nop>
 514 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 515 " below).
 516 cmap <Up>    <Nop>
 517 cmap <Down>  <Nop>
 518 cmap <Right> <Nop>
 519 cmap <Left>  <Nop>
 520
 521 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 522 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 523 cnoremap <C-P> <Up>
 524 cnoremap <C-N> <Down>
 525
 526 if has('eval')
 527 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 528 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 529 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 530 " directly because it also enables that feature for other commands which I
 531 " don't want.
 532
 533     " Set 'nostartofline' for a single movement.
 534     function! s:TemporaryNostartofline(movement)
 535         let l:startofline = &startofline
 536         set nostartofline
 537         execute 'normal! ' . a:movement
 538         let &startofline = l:startofline
 539     endfunction
 540
 541     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 542     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 543     nnoremap <silent> <C-F>
 544         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 545     nnoremap <silent> <C-B>
 546         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 547     nnoremap <silent> <C-D>
 548         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 549     nnoremap <silent> <C-U>
 550         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 551 endif
 552
 553 " Let Y yank to the end of the line, similar to D and C. Use yy if you want to
 554 " yank a line. This fixes a weird inconsistency in Vi(m).
 555 nnoremap Y y$
 556
 557 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 558 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 559 " Only the current buffer is written, thus switching to another buffer works
 560 " too.
 561 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 562
 563 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 564 " in #vim on Freenode (2011-08-15 00:17 CEST).
 565 nnoremap <C-G> 2<C-G>
 566
 567 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 568 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 569 nmap <Space> <C-F>
 570 nmap - <C-B>
 571
 572 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 573 " (2010-05-16 18:38 CEST) for this idea.
 574 nnoremap <silent> gb :bnext<CR>
 575 nnoremap <silent> gB :bprevious<CR>
 576 if has('eval')
 577     " But when starting again at the first buffer, print a warning which
 578     " reminds me that I've already seen that buffer.
 579     function! s:NextBuffer()
 580         " Are we currently on the last buffer and moving to the first?
 581         let l:last_buffer = 0
 582         if bufnr('%') == bufnr('$') && bufnr('$') > 1
 583             let l:last_buffer = 1
 584         endif
 585
 586         " Go to the next buffer.
 587         if !l:last_buffer
 588             bnext
 589
 590         " Go to the first buffer, silent is necessary or the following message
 591         " won't be displayed because it's overwritten by the status message
 592         " displayed when entering a buffer.
 593         else
 594             silent bnext
 595
 596             echohl WarningMsg
 597             echo 'Starting again at first buffer.'
 598             echohl None
 599         endif
 600     endfunction
 601     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
 602 endif
 603
 604 " Fast access to buffers.
 605 nnoremap <silent> <Leader>1 :1buffer<CR>
 606 nnoremap <silent> <Leader>2 :2buffer<CR>
 607 nnoremap <silent> <Leader>3 :3buffer<CR>
 608 nnoremap <silent> <Leader>4 :4buffer<CR>
 609 nnoremap <silent> <Leader>5 :5buffer<CR>
 610 nnoremap <silent> <Leader>6 :6buffer<CR>
 611 nnoremap <silent> <Leader>7 :7buffer<CR>
 612 nnoremap <silent> <Leader>8 :8buffer<CR>
 613 nnoremap <silent> <Leader>9 :9buffer<CR>
 614 nnoremap <silent> <Leader>0 :10buffer<CR>
 615
 616 " Use real tabs instead of soft tabs.
 617 if has('eval')
 618 " Switch from soft tabs to real tabs.
 619     function! s:UseTabs()
 620         setlocal noexpandtab shiftwidth=8 softtabstop=8
 621     endfunction
 622     nnoremap <silent> <Leader>t :call <SID>UseTabs()<CR>
 623 endif
 624 " Enable "verbatim" mode. Used to view files with long lines or without syntax
 625 " coloring. 'list' is not changed, see next mapping.
 626 nnoremap <silent> <Leader>v :setlocal nowrap nospell synmaxcol=0<CR>
 627                           \ :2match<CR>
 628 " Toggle 'list'.
 629 nnoremap <silent> <Leader>l :set invlist<CR>
 630
 631 " Make last active window the only window. Similar to <C-W> o.
 632 nnoremap <C-W>O <C-W>p<C-W>o
 633
 634 " Maps to change spell language between English and German and disable spell
 635 " checking.
 636 if exists('+spell')
 637     nnoremap <silent> <Leader>sn :set nospell<CR>
 638     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 639     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 640 " If no spell support is available, these mappings do nothing.
 641 else
 642     nmap <Leader>sn <Nop>
 643     nmap <Leader>se <Nop>
 644     nmap <Leader>sd <Nop>
 645 endif
 646
 647 if has('eval')
 648 " * and # for selections in visual mode. Thanks to
 649 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 650 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 651     function! s:VSetSearch()
 652         let l:temp = @@ " unnamed register
 653         normal! gvy
 654         " Added \C to force 'noignorecase' while searching the current visual
 655         " selection. I want to search for the exact string in this case.
 656         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 657         let @@ = l:temp
 658     endfunction
 659     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 660     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 661
 662 " Use 'noignorecase' for * and #. See comment in s:VSetSearch() for details.
 663 " Thanks to the writers of s:VSetSearch(), see above.
 664     function! s:NSetSearch()
 665         let l:cword = expand('<cword>')
 666         let l:regex = substitute(escape(l:cword, '\'), '\n', '\\n', 'g')
 667         let @/ = '\C\V'. '\<' . l:regex . '\>'
 668     endfunction
 669     nnoremap * :call <SID>NSetSearch()<CR>//<CR>
 670     nnoremap # :call <SID>NSetSearch()<CR>??<CR>
 671 endif
 672
 673 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 674 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 675 " mailing list for the commands.
 676 if v:version < 700
 677     cnoreabbrev W w
 678     cnoreabbrev Wa wa
 679     cnoreabbrev Wq wq
 680     cnoreabbrev Wqa wqa
 681 else
 682     cnoreabbrev <expr> W
 683         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 684     cnoreabbrev <expr> Wa
 685         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 686     cnoreabbrev <expr> Wq
 687         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 688     cnoreabbrev <expr> Wqa
 689         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 690 endif
 691 " Also fix my typo with "Q".
 692 if v:version < 700
 693     cnoreabbrev Q q
 694     cnoreabbrev Qa qa
 695 else
 696     cnoreabbrev <expr> Q
 697         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 698     cnoreabbrev <expr> Qa
 699         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 700 endif
 701
 702 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 703 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 704 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
 705
 706 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 707 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 708 " Vim's source.
 709 inoremap <C-U> <C-G>u<C-U>
 710 " Same for <C-@> (insert previously inserted text and leave insert mode).
 711 inoremap <C-@> <C-G>u<C-@>
 712 " And for <C-A> (insert previously inserted text).
 713 inoremap <C-A> <C-G>u<C-A>
 714 " And for <C-W> (delete word before cursor).
 715 inoremap <C-W> <C-G>u<C-W>
 716
 717 if has('eval')
 718 " New text-objects ii and ai to work on text with the same indentation. Thanks
 719 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 720 " (visited on 2011-11-19).
 721     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 722     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 723     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 724     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 725
 726     function! s:IndTxtObj(inner)
 727         let curline = line(".")
 728         let lastline = line("$")
 729         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 730         let i = i < 0 ? 0 : i
 731         if getline(".") !~ "^\\s*$"
 732             let p = line(".") - 1
 733             let nextblank = getline(p) =~ "^\\s*$"
 734             while p > 0
 735                     \ && ((i == 0 && !nextblank)
 736                         \ || (i > 0 && ((indent(p) >= i
 737                             \ && !(nextblank && a:inner))
 738                             \ || (nextblank && !a:inner))))
 739                 -
 740                 let p = line(".") - 1
 741                 let nextblank = getline(p) =~ "^\\s*$"
 742             endwhile
 743             normal! 0V
 744             call cursor(curline, 0)
 745             let p = line(".") + 1
 746             let nextblank = getline(p) =~ "^\\s*$"
 747             while p <= lastline
 748                     \ && ((i == 0 && !nextblank)
 749                         \ || (i > 0 && ((indent(p) >= i
 750                             \ && !(nextblank && a:inner))
 751                             \ || (nextblank && !a:inner))))
 752                 +
 753                 let p = line(".") + 1
 754                 let nextblank = getline(p) =~ "^\\s*$"
 755             endwhile
 756             normal! $
 757         endif
 758     endfunction
 759 endif
 760
 761
 762 " ABBREVIATIONS
 763
 764 " Fix some of my spelling mistakes (German).
 765 inoreabbrev relle reelle
 766 inoreabbrev reele reelle
 767 " Fix some of my spelling mistakes (English).
 768 inoreabbrev completly completely
 769
 770
 771 " SYNTAX SETTINGS
 772
 773 " Activate syntax coloring.
 774 if has('syntax')
 775     " But only if it wasn't already active. Prevents breaking the syntax
 776     " coloring when reloading the vimrc. Thanks to johnLate for the idea.
 777     if !exists('g:syntax_on')
 778         syntax enable
 779     endif
 780
 781 " Don't highlight more than 500 columns as I normally don't have that long
 782 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 783 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 784     if exists('+synmaxcol')
 785         set synmaxcol=500
 786     endif
 787
 788 " Use (limited) syntax based omni completion if no other omni completion is
 789 " available. Taken from :help ft-syntax-omni.
 790     if has('autocmd') && exists('+omnifunc')
 791         augroup vimrc
 792             autocmd FileType *
 793                 \ if &omnifunc == '' |
 794                 \     setlocal omnifunc=syntaxcomplete#Complete |
 795                 \ endif
 796         augroup END
 797     endif
 798
 799 " Function to enable all custom highlights. Necessary as highlights are
 800 " window-local and thus must be set for each new window.
 801     function! s:CustomSyntaxHighlights()
 802         " Not the first time called, nothing to do.
 803         if exists('w:vimrc_syntax_run')
 804             return
 805         endif
 806         let w:vimrc_syntax_run = 1
 807
 808 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 809 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 810 " disabled when necessary with :2match (in Vim >= 700).
 811         if !&diff && exists(':2match')
 812             " Use ColorColumn for overlong lines if available and my color
 813             " scheme is used.
 814             if &t_Co == 256 && s:HasSyntaxGroup('ColorColumn')
 815                 2match ColorColumn /\%>78v./
 816             else
 817                 2match Todo /\%>78v./
 818             endif
 819         elseif !&diff
 820             match Todo /\%>78v./
 821         endif
 822
 823         if exists('*matchadd')
 824 " Highlight some important keywords in all documents.
 825             let l:todos = ['TODO', 'XXX', 'FIXME', 'NOTE',
 826                          \ 'CHANGED', 'REMOVED', 'DELETED']
 827             " Compatibility fix for Vim 6.4 which can't handle for in function
 828             " (without function it's ignored).
 829             execute '  for l:x in l:todos'
 830                   \ '|     call matchadd("Todo", l:x)'
 831                   \ '| endfor'
 832
 833 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 834             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 835                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 836                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 837                           \ '205f', '2060', '3000', 'feff']
 838             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 839             " it won't work!
 840             execute '  for l:x in l:spaces'
 841                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 842                   \ '| endfor'
 843
 844 " Special highlight for tabs to reduce their visibility in contrast to other
 845 " SpecialKey characters (e.g. ^L).
 846             if &t_Co == 256 && s:HasSyntaxGroup('specialKeyTab')
 847                 call matchadd('specialKeyTab', '\t')
 848             endif
 849         endif
 850     endfunction
 851 " Enable highlights for the current and all new windows. Thanks to bairui in
 852 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 853     call s:CustomSyntaxHighlights()
 854     if has('autocmd')
 855         augroup vimrc
 856             autocmd WinEnter * call s:CustomSyntaxHighlights()
 857         augroup END
 858     endif
 859
 860 " Settings for specific filetypes.
 861
 862     " C
 863     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 864     " Haskell.
 865     let g:hs_highlight_delimiters = 1
 866     let g:hs_highlight_boolean = 1
 867     let g:hs_highlight_types = 1
 868     let g:hs_highlight_more_types = 1
 869     " Java.
 870     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
 871     " Perl.
 872     let g:perl_fold = 1
 873     let g:perl_fold_blocks = 1
 874     let g:perl_nofold_packages = 1
 875     let g:perl_include_pod = 1 " syntax coloring for PODs
 876     " PHP.
 877     let g:php_folding = 3    " fold functions
 878     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
 879     let g:php_sql_query = 1  " highlight SQL queries in strings
 880     " Python.
 881     let g:python_highlight_all = 1
 882     " Shell.
 883     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 884     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 885     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 886     " Vim.
 887     let g:vimsyn_embed = 0      " don't highlight embedded languages
 888     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 889     " XML.
 890     let g:xml_syntax_folding = 1
 891 endif
 892
 893
 894 " PLUGIN SETTINGS
 895
 896 if has('eval')
 897 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 898 " installing/removing/updating plugins simple. (Used for plugins with more
 899 " than one file.) Ignore errors in case pathogen is not installed.
 900     if v:version >= 700
 901         silent! execute 'call pathogen#infect()'
 902     endif
 903
 904 " Settings for securemodelines.
 905     " Only allow items I need (also includes spl which is not enabled by
 906     " default).
 907     if v:version >= 700 " need lists
 908         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
 909                                               \ 'sw', 'sts', 'noet']
 910     endif
 911
 912 " Settings for the NERD commenter.
 913     " Don't create any mappings I don't want to use.
 914     let g:NERDCreateDefaultMappings = 0
 915     " Map toggle comment.
 916     nmap <Leader><Leader> <Plug>NERDCommenterToggle
 917
 918 " XPTemplate settings.
 919     " Try to maintain snippet rendering even after editing outside of a
 920     " snippet.
 921     let g:xptemplate_strict = 0
 922     " Don't complete any braces automatically.
 923     let g:xptemplate_brace_complete = 0
 924     " Only highlight the current placeholder.
 925     let g:xptemplate_highlight = 'current'
 926
 927 " CtrlP settings.
 928     " Don't manage the working directory (the default setting is too slow for
 929     " me).
 930     let g:ctrlp_working_path_mode = 0
 931
 932     " Path to cache directory. I prefer to keep generated files as local as
 933     " possible.
 934     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
 935     " Permanent cache, cleared by a crontab entry. Use <F5> to update the
 936     " cache manually.
 937     let g:ctrlp_clear_cache_on_exit = 0
 938
 939     " Don't switch the window if the selected buffer is already open. I want
 940     " to open another view on this buffer in most cases.
 941     let g:ctrlp_switch_buffer = 0
 942
 943 " FSWitch settings.
 944     " Defaults don't work well for my projects.
 945     augroup vimrc
 946         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
 947                           \ | let b:fswitchlocs = './'
 948         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
 949                           \ | let b:fswitchlocs = './'
 950     augroup END
 951
 952     " Switch to corresponding header/source file.
 953     nnoremap <silent> <Leader>h :FSHere<CR>
 954
 955 " netrw settings.
 956     " Don't create ~/.vim/.netrwhist history file.
 957     let g:netrw_dirhistmax = 0
 958 endif
 959
 960
 961 " AUTO COMMANDS
 962
 963 " Use a custom auto group to prevent problems when the vimrc files is sourced
 964 " twice.
 965 if has('autocmd')
 966     augroup vimrc
 967
 968 " Go to last position of opened files. Taken from :help last-position-jump.
 969         autocmd BufReadPost *
 970             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 971             \     execute "normal! g'\"" |
 972             \ endif
 973 " But not for Git commits, go to beginning of the file.
 974         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 975
 976 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 977 " when switching to a help buffer which is in the background with :buffer as
 978 " these options are local to windows (and not only to buffers). This happens
 979 " because I often want to use only one window and thus the help buffer is in
 980 " the background.
 981         autocmd BufWinEnter *.txt
 982             \ if &filetype == 'help' |
 983             \     setlocal nolist |
 984             \     setlocal nonumber |
 985             \ endif
 986
 987 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 988 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 989 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 990 " doesn't exist in older Vims. Use "*p to paste X11's selection, no need for
 991 " 'paste' in this case.
 992         if exists('##InsertLeave')
 993             autocmd InsertLeave * set nopaste
 994         endif
 995
 996 " Write all files when running :mak[e] before 'makeprg' is called.
 997 " QuickFixCmdPre doesn't exist in older Vims.
 998         if exists('##QuickFixCmdPre')
 999             autocmd QuickFixCmdPre * wall
1000         endif
1001
1002 " Don't ignore case while in insert mode, but ignore case in all other modes.
1003 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
1004 " capitalization. But while searching (/) 'ignorecase' is used.
1005 " InsertEnter/InsertLeave doesn't exist in older Vims.
1006         if exists('##InsertEnter') && exists('##InsertLeave')
1007             autocmd InsertEnter * set noignorecase
1008             autocmd InsertLeave * set   ignorecase
1009         endif
1010
1011 " Display a warning when editing a file which contains "do not edit" (ignoring
1012 " the case) and similar messages in the first lines of the file, for example
1013 " template files which were preprocessed or auto-generated files. Especially
1014 " useful when the header is not displayed on the first screen, e.g. when the
1015 " old position is restored.
1016         function! s:SearchForDoNotEditHeader()
1017             " Only search the first 20 lines to prevent false positives, e.g.
1018             " in scripts which write files containing this warning and ignore
1019             " the case (\c). (Can't use search()'s {stopline} as we might not
1020             " start searching from the top.)
1021             let l:search = '\c\(do not \(edit\|modify\)\|autogenerated by\)'
1022             let l:match = search(l:search, 'n')
1023             if l:match == 0 || l:match > 20
1024                 return
1025             endif
1026
1027             echoerr 'Do not edit this file! (Maybe a template file.)'
1028         endfunction
1029         autocmd BufRead * call s:SearchForDoNotEditHeader()
1030
1031 " AFTER/FTPLUGIN AUTO COMMANDS
1032
1033 " Disable spell checking for files which don't need it.
1034         autocmd FileType deb  setlocal nospell
1035         autocmd FileType diff setlocal nospell
1036         autocmd FileType tar  setlocal nospell
1037 " Fix to allow Vim edit crontab files as crontab doesn't work with
1038 " backupcopy=auto.
1039         autocmd FileType crontab setlocal backupcopy=yes
1040 " Don't use the modeline in git commits as the diff created by `git commit -v`
1041 " may contain one which could change the filetype or other settings of the
1042 " commit buffer. Also make sure we use only 72 characters per line which is
1043 " the recommendation for git commit messages (http://tpope.net/node/106).
1044         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
1045                                  \ setlocal textwidth=72
1046 " Fix 'include' setting for shell files to recognize '.' and 'source'
1047 " commands. Use &l:include instead of setlocal which requires excessive
1048 " escaping of \.
1049         autocmd FileType sh let &l:include = '^\s*\(\.\|source\)\s\+'
1050 " Use the same comment string as for Vim files in Vimperator files.
1051         autocmd FileType vimperator setlocal commentstring=\"%s
1052 " Use TeX compiler for (La)TeX files.
1053         autocmd FileType tex compiler tex
1054
1055 " FTDETECT AUTO COMMANDS
1056
1057 " Recognize .md as markdown files (Vim default is .mkd).
1058         autocmd BufRead,BufNewFile *.md set filetype=mkd
1059 " Recognize .test as Tcl files.
1060         autocmd BufRead,BufNewFile *.test set filetype=tcl
1061
1062 " OTHER AUTO COMMANDS
1063
1064 " Disable spell checking, displaying of list characters and long lines when
1065 " viewing documentation.
1066         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
1067
1068 " Use diff filetype for mercurial patches in patch queue.
1069         autocmd BufReadPost */.hg/patches/* set filetype=diff
1070
1071     augroup END
1072 endif
1073
1074
1075 " CUSTOM FUNCTIONS AND COMMANDS
1076
1077 if has('eval')
1078 " Convenient command to see the difference between the current buffer and the
1079 " file it was loaded from, thus the changes you made. Thanks to the
1080 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
1081 " for the diffed file as the filetype for the original file.
1082     if !exists(':DiffOrig')
1083         command DiffOrig
1084             \ let s:diff_orig_filetype = &filetype
1085             \ | vertical new
1086             \ | let &filetype = s:diff_orig_filetype
1087             \ | unlet s:diff_orig_filetype
1088             \ | set buftype=nofile
1089             \ | read ++edit #
1090             \ | 0d_
1091             \ | diffthis
1092             \ | wincmd p
1093             \ | diffthis
1094     endif
1095 endif