vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2008-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " HELPER FUNCTIONS
  92
  93 " Check if the given syntax group is available. Thanks to bairui in #vim on
  94 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
  95 if has('eval')
  96     function! s:HasSyntaxGroup(group)
  97         try
  98             execute 'silent highlight ' . a:group
  99         " \a = [A-Za-z]
 100         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
 101             return 0
 102         endtry
 103         return 1
 104     endfunction
 105 endif
 106
 107
 108 " EDIT SETTINGS
 109
 110 " Enable automatic file detection, plugin and indention support.
 111 if has('autocmd')
 112     filetype off " necessary for pathogen to force a reload of ftplugins
 113     filetype plugin indent on
 114 endif
 115
 116 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 117 " existing files.
 118 set fileencodings=utf-8,latin1
 119
 120 " Wrap text after 78 characters.
 121 set textwidth=78
 122
 123 " Set tabs to 4 spaces, use softtabs.
 124 set shiftwidth=4
 125 set softtabstop=4
 126 set expandtab
 127 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 128 set shiftround
 129 " Use the default value for real tabs.
 130 set tabstop=8
 131
 132 " Enable auto indention.
 133 set autoindent
 134
 135 " When joining lines only add one space after a sentence.
 136 set nojoinspaces
 137
 138 " Allow backspacing over autoindent and line breaks.
 139 set backspace=indent,eol
 140
 141 " Start a comment when hitting enter after a commented line (r) and when using
 142 " o or O around a commented line (o).
 143 set formatoptions+=ro
 144 " Don't break a line if was already longer then 'textwidth' when insert mode
 145 " started.
 146 set formatoptions+=l
 147
 148 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 149 " no character) in visual block mode.
 150 set virtualedit=block
 151
 152 " Already display matches while typing the search command. This makes spotting
 153 " errors easy.
 154 set incsearch
 155
 156 " Activate syntax folding.
 157 if has('folding')
 158     set foldmethod=syntax
 159     " Only use fold column if we have enough space (for example in a (virtual)
 160     " terminals).
 161     if &columns > 80
 162         set foldcolumn=2
 163     endif
 164     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 165                      " folding which is not what I want
 166 endif
 167
 168 " Only check case if the searched word contains a capital character.
 169 set ignorecase
 170 set smartcase
 171
 172 " Activate spell checking, use English as default.
 173 if exists('+spell') && has('syntax')
 174     " But not when diffing because spell checking is distracting in this case.
 175     if !&diff
 176         set spell
 177     endif
 178     set spelllang=en_us
 179 endif
 180
 181 " Allow buffers with changes to be hidden. Very important for effective
 182 " editing with multiple buffers. Prevents the "E37: No write since last change
 183 " (add ! to override)" warning.
 184 set hidden
 185
 186
 187 " DISPLAY SETTINGS
 188
 189 " Use a dark background. Doesn't change the background color, only sets text
 190 " colors for a dark terminal.
 191 set background=dark
 192
 193 " Use my color scheme if 256 colors are available.
 194 if &t_Co == 256
 195     colorscheme simon
 196 endif
 197
 198 " Display line numbers.
 199 set number
 200 " But use as little space as possible for the numbers column. Thanks to James
 201 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 202 if exists('+numberwidth')
 203     set numberwidth=1
 204 endif
 205 " Display the ruler with current line/file position. If 'statusline' is used
 206 " then this only affects <C-G>.
 207 set ruler
 208 " Display partial commands in the status line.
 209 set showcmd
 210
 211 " Don't redraw screen when executing macros; increases speed. Thanks to James
 212 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 213 set lazyredraw
 214
 215 " Visualize the line the cursor is currently in.
 216 if exists('+cursorline')
 217     set cursorline
 218 endif
 219
 220 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 221 " remove the highlighting until the next search.
 222 set hlsearch
 223
 224 " Display some special characters.
 225 set list
 226 set listchars=
 227 " Display tabs as ">--------".
 228 set listchars+=tab:>-
 229 " Display trailing whitespace as "-".
 230 set listchars+=trail:-
 231 " Display markers for long lines when wrapping is disabled.
 232 set listchars+=extends:>,precedes:<
 233 " Display non-breakable space as "!".
 234 if v:version >= 700
 235     set listchars+=nbsp:!
 236 endif
 237
 238 " Don't draw the vertical split separator by using space as character. Thanks
 239 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
 240 " non-breakable space. But a simple space works as well, as long as the
 241 " current color scheme is not reset.
 242 if has('windows') && has('folding')
 243     set fillchars+=vert:\  " comment to prevent trailing whitespace
 244 endif
 245
 246 if has('statusline')
 247     " Always display the status line even if there is only one window.
 248     set laststatus=2
 249
 250     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 251     " is the highest buffer number, otherwise return nothing. Used in
 252     " 'statusline' to get an overview of available buffer numbers.
 253     function! StatuslineBufferCount()
 254         let l:bufnr = bufnr('$')
 255         if l:bufnr > 1
 256             let l:result = '/'
 257             if exists('*printf')
 258                 let l:result .= printf('%02d', l:bufnr)
 259             else
 260                 " Older Vims don't have printf() (and no .= either). Emulate
 261                 " "%02d".
 262                 if l:bufnr < 10
 263                     let l:result = l:result . '0'
 264                 endif
 265                 let l:result = l:result . l:bufnr
 266             endif
 267             return l:result
 268         else
 269             return ''
 270         endif
 271     endfunction
 272
 273     set statusline=
 274     " on the left
 275     set statusline+=%02n  " buffer number
 276     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 277     set statusline+=:
 278     set statusline+=%f\   " path to current file in buffer
 279     set statusline+=%h    " [help] if buffer is help file
 280     set statusline+=%w    " [Preview] if buffer is preview buffer
 281     set statusline+=%m    " [+] if buffer was modified,
 282                           " [-] if 'modifiable' is off
 283     set statusline+=%r    " [RO] if buffer is read only
 284
 285     " on the right
 286     set statusline+=%=                " right align
 287     set statusline+=0x%-8B\           " current character under cursor as hex
 288     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 289                                       " column number (%c),
 290                                       " virtual column number if different
 291                                       "                       than %c (%V)
 292     set statusline+=%P                " position in file in percent
 293 endif
 294
 295
 296 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 297
 298 " noremap is used to make sure the right side is executed as is and can't be
 299 " modified by a plugin or other settings. Except for <Nop> which isn't
 300 " affected by mappings.
 301
 302 " Easy way to exit insert mode.
 303 inoremap jj <Esc>
 304 inoremap jk <Esc>
 305 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 306 " (2010-10-15).
 307 cnoremap jj <C-C>
 308 cnoremap jk <C-C>
 309
 310 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 311 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 312 map <Right>  <Nop>
 313 map <Left>   <Nop>
 314 map <Up>     <Nop>
 315 map <Down>   <Nop>
 316 imap <Right> <Nop>
 317 imap <Left>  <Nop>
 318 imap <Up>    <Nop>
 319 imap <Down>  <Nop>
 320 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 321 " below).
 322 cmap <Up>    <Nop>
 323 cmap <Down>  <Nop>
 324 cmap <Right> <Nop>
 325 cmap <Left>  <Nop>
 326
 327 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 328 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 329 cnoremap <C-P> <Up>
 330 cnoremap <C-N> <Down>
 331
 332 if has('eval')
 333 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 334 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 335 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 336 " directly because it also enables that feature for other commands which I
 337 " don't want.
 338
 339     " Set 'nostartofline' for a single movement.
 340     function! s:TemporaryNostartofline(movement)
 341         let l:startofline = &startofline
 342         set nostartofline
 343         execute 'normal! ' . a:movement
 344         let &startofline = l:startofline
 345     endfunction
 346
 347     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 348     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 349     nnoremap <silent> <C-F>
 350         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 351     nnoremap <silent> <C-B>
 352         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 353     nnoremap <silent> <C-D>
 354         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 355     nnoremap <silent> <C-U>
 356         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 357 endif
 358
 359 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 360 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 361 " Only the current buffer is written.
 362 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 363
 364 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 365 " in #vim on Freenode (2011-08-15 00:17 CEST).
 366 nnoremap <C-G> 2<C-G>
 367
 368 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 369 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 370 nmap <Space> <C-F>
 371 nmap - <C-B>
 372
 373 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 374 " (2010-05-16 18:38 CEST) for this idea.
 375 nnoremap <silent> gb :bnext<CR>
 376 nnoremap <silent> gB :bprevious<CR>
 377
 378 " Fast access to buffers.
 379 nnoremap <silent> <Leader>1 :1buffer<CR>
 380 nnoremap <silent> <Leader>2 :2buffer<CR>
 381 nnoremap <silent> <Leader>3 :3buffer<CR>
 382 nnoremap <silent> <Leader>4 :4buffer<CR>
 383 nnoremap <silent> <Leader>5 :5buffer<CR>
 384 nnoremap <silent> <Leader>6 :6buffer<CR>
 385 nnoremap <silent> <Leader>7 :7buffer<CR>
 386 nnoremap <silent> <Leader>8 :8buffer<CR>
 387 nnoremap <silent> <Leader>9 :9buffer<CR>
 388 nnoremap <silent> <Leader>0 :10buffer<CR>
 389
 390 " Make last active window the only window. Similar to <C-W> o.
 391 nnoremap <C-W>O <C-W>p<C-W>o
 392
 393 " Maps to change spell language between English and German and disable spell
 394 " checking.
 395 if exists('+spell')
 396     nnoremap <silent> <Leader>sn :set nospell<CR>
 397     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 398     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 399 endif
 400
 401 " Add semicolon to the end of the line. Thanks to
 402 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 403 " on Freenode for an improved version which doesn't clobber any marks.
 404 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 405
 406 " * and # for selections in visual mode. Thanks to
 407 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 408 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 409 if has('eval')
 410     function! s:VSetSearch()
 411         let l:temp = @@
 412         normal! gvy
 413         " Added \C to force 'noignorecase' while searching the current visual
 414         " selection. I want to search for the exact string in this case.
 415         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 416         let @@ = l:temp
 417     endfunction
 418     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 419     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 420 endif
 421
 422 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 423 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 424 " mailing list for the commands.
 425 if v:version < 700
 426     cnoreabbrev W w
 427     cnoreabbrev Wa wa
 428     cnoreabbrev Wq wq
 429     cnoreabbrev Wqa wqa
 430 else
 431     cnoreabbrev <expr> W
 432         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 433     cnoreabbrev <expr> Wa
 434         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 435     cnoreabbrev <expr> Wq
 436         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 437     cnoreabbrev <expr> Wqa
 438         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 439 endif
 440 " Also fix my typo with "Q".
 441 if v:version < 700
 442     cnoreabbrev Q q
 443     cnoreabbrev Qa qa
 444 else
 445     cnoreabbrev <expr> Q
 446         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 447     cnoreabbrev <expr> Qa
 448         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 449 endif
 450
 451 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 452 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 453 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 454
 455 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 456 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 457 " Vim's source.
 458 inoremap <C-U> <C-G>u<C-U>
 459 " Same for <C-@> (insert previously inserted text and leave insert mode).
 460 inoremap <C-@> <C-G>u<C-@>
 461 " And for <C-A> (insert previously inserted text).
 462 inoremap <C-A> <C-G>u<C-A>
 463 " And for <C-W> (delete word before cursor).
 464 inoremap <C-W> <C-G>u<C-W>
 465
 466 if has('eval')
 467 " New text-objects ii and ai to work on text with the same indentation. Thanks
 468 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 469 " (visited on 2011-11-19).
 470     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 471     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 472     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 473     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 474
 475     function! s:IndTxtObj(inner)
 476         let curline = line(".")
 477         let lastline = line("$")
 478         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 479         let i = i < 0 ? 0 : i
 480         if getline(".") !~ "^\\s*$"
 481             let p = line(".") - 1
 482             let nextblank = getline(p) =~ "^\\s*$"
 483             while p > 0
 484                     \ && ((i == 0 && !nextblank)
 485                         \ || (i > 0 && ((indent(p) >= i
 486                             \ && !(nextblank && a:inner))
 487                             \ || (nextblank && !a:inner))))
 488                 -
 489                 let p = line(".") - 1
 490                 let nextblank = getline(p) =~ "^\\s*$"
 491             endwhile
 492             normal! 0V
 493             call cursor(curline, 0)
 494             let p = line(".") + 1
 495             let nextblank = getline(p) =~ "^\\s*$"
 496             while p <= lastline
 497                     \ && ((i == 0 && !nextblank)
 498                         \ || (i > 0 && ((indent(p) >= i
 499                             \ && !(nextblank && a:inner))
 500                             \ || (nextblank && !a:inner))))
 501                 +
 502                 let p = line(".") + 1
 503                 let nextblank = getline(p) =~ "^\\s*$"
 504             endwhile
 505             normal! $
 506         endif
 507     endfunction
 508 endif
 509
 510
 511 " ABBREVIATIONS
 512
 513 " Fix some of my spelling mistakes.
 514 inoreabbrev relle reelle
 515 inoreabbrev reele reelle
 516
 517
 518 " SYNTAX SETTINGS
 519
 520 " Activate syntax coloring.
 521 if has('syntax')
 522     syntax enable
 523
 524 " Don't highlight more than 500 columns as I normally don't have that long
 525 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 526 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 527     if exists('+synmaxcol')
 528         set synmaxcol=500
 529     endif
 530
 531 " Use (limited) syntax based omni completion if no other omni completion is
 532 " available. Taken from :help ft-syntax-omni.
 533     if has('autocmd') && exists('+omnifunc')
 534         augroup vimrc
 535             autocmd FileType *
 536                 \ if &omnifunc == '' |
 537                 \     setlocal omnifunc=syntaxcomplete#Complete |
 538                 \ endif
 539         augroup END
 540     endif
 541
 542 " Function to enable all custom highlights. Necessary as highlights are
 543 " window-local and thus must be set for each new window.
 544     function! s:CustomSyntaxHighlights()
 545         " Not the first time called, nothing to do.
 546         if exists('w:vimrc_syntax_run')
 547             return
 548         endif
 549         let w:vimrc_syntax_run = 1
 550
 551 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 552 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 553 " disabled when necessary with :2match (in Vim >= 700).
 554         if !&diff && exists(':2match')
 555             " Use ColorColumn for overlong lines if available and my color
 556             " scheme is used.
 557             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
 558                 2match ColorColumn /\%>78v./
 559             else
 560                 2match Todo /\%>78v./
 561             endif
 562         elseif !&diff
 563             match Todo /\%>78v./
 564         endif
 565
 566         if exists('*matchadd')
 567 " Highlight some important keywords in all documents.
 568             let l:todos = ['TODO', 'XXX', 'FIXME',
 569                          \ 'CHANGED', 'REMOVED', 'DELETED']
 570             " Compatibility fix for Vim 6.4 which can't handle for in function
 571             " (without function it's ignored).
 572             execute '  for l:x in l:todos'
 573                   \ '|     call matchadd("Todo", l:x)'
 574                   \ '| endfor'
 575
 576 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 577             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 578                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 579                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 580                           \ '205f', '2060', '3000', 'feff']
 581             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
 582             " it won't work!
 583             execute '  for l:x in l:spaces'
 584                   \ '|     call matchadd("Error", "\\%u" . l:x)'
 585                   \ '| endfor'
 586
 587 " Reduce visibility of tabs in contrast to normal SpecialKeys.
 588             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
 589                 call matchadd('specialKeyTab', '\t')
 590             endif
 591         endif
 592     endfunction
 593 " Enable highlights for the current and all new windows. Thanks to bairui in
 594 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 595     call <SID>CustomSyntaxHighlights()
 596     if has('autocmd')
 597         augroup vimrc
 598             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 599         augroup END
 600     endif
 601
 602 " Settings for specific filetypes.
 603
 604     " C
 605     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
 606     " Haskell.
 607     let g:hs_highlight_delimiters = 1
 608     let g:hs_highlight_boolean = 1
 609     let g:hs_highlight_types = 1
 610     let g:hs_highlight_more_types = 1
 611     " Perl.
 612     let g:perl_fold = 1
 613     let g:perl_fold_blocks = 1
 614     let g:perl_nofold_packages = 1
 615     let g:perl_include_pod = 1 " syntax coloring for PODs
 616     " Python.
 617     let g:python_highlight_all = 1
 618     " Shell.
 619     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 620     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 621     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 622     " Vim.
 623     let g:vimsyn_embed = 0      " don't highlight embedded languages
 624     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 625     " XML.
 626     let g:xml_syntax_folding = 1
 627 endif
 628
 629
 630 " PLUGIN SETTINGS
 631
 632 if has('eval')
 633 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 634 " installing/removing/updating plugins simple. (Used for plugins with more
 635 " than one file.) Ignore errors in case pathogen is not installed.
 636     if v:version >= 700
 637         silent! execute 'call pathogen#runtime_append_all_bundles()'
 638     endif
 639
 640 " Settings for the NERD commenter.
 641     " Don't create any mappings I don't want to use.
 642     let g:NERDCreateDefaultMappings = 0
 643     " Map toggle comment.
 644     map <Leader><Leader> <Plug>NERDCommenterToggle
 645
 646 " XPTemplate settings.
 647     " Try to maintain snippet rendering even after editing outside of a
 648     " snippet.
 649     let g:xptemplate_strict = 0
 650     " Don't complete any braces automatically.
 651     let g:xptemplate_brace_complete = 0
 652     " Only highlight the current placeholder.
 653     let g:xptemplate_highlight = 'current'
 654 endif
 655
 656
 657 " AUTO COMMANDS
 658
 659 " Use a custom auto group to prevent problems when the vimrc files is sourced
 660 " twice.
 661 if has('autocmd')
 662     augroup vimrc
 663
 664 " Go to last position of opened files. Taken from :help last-position-jump.
 665         autocmd BufReadPost *
 666             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 667             \     execute "normal! g'\"" |
 668             \ endif
 669 " But not for Git commits, go to beginning of the file.
 670         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 671
 672 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 673 " when switching to a help buffer which is in the background with :buffer as
 674 " these options are local to windows (and not only to buffers). This happens
 675 " because I often want to use only one window and thus the help buffer is in
 676 " the background.
 677         autocmd BufWinEnter *.txt
 678             \ if &filetype == 'help' |
 679             \     setlocal nolist |
 680             \     setlocal nonumber |
 681             \ endif
 682
 683 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 684 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 685 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 686 " doesn't exist in older Vims.
 687         if exists('##InsertLeave')
 688             autocmd InsertLeave * set nopaste
 689         endif
 690
 691 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 692 " doesn't exist in older Vims.
 693         if exists('##QuickFixCmdPre')
 694             autocmd QuickFixCmdPre * write
 695         endif
 696
 697 " Don't ignore case while in insert mode, but ignore case in all other modes.
 698 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 699 " capitalization. But while searching (/) 'ignorecase' is used.
 700 " InsertEnter/InsertLeave doesn't exist in older Vims.
 701         if exists('##InsertEnter') && exists('##InsertLeave')
 702             autocmd InsertEnter * set noignorecase
 703             autocmd InsertLeave * set   ignorecase
 704         endif
 705
 706 " AFTER/FTPLUGIN AUTO COMMANDS
 707
 708 " Disable spell checking for files which don't need it.
 709         autocmd FileType deb  setlocal nospell
 710         autocmd FileType diff setlocal nospell
 711         autocmd FileType tar  setlocal nospell
 712 " Fix to allow Vim edit crontab files as crontab doesn't work with
 713 " backupcopy=auto.
 714         autocmd FileType crontab setlocal backupcopy=yes
 715 " Don't use the modeline in git commits as the diff created by `git commit -v`
 716 " may contain one which could change the filetype or other settings of the
 717 " commit buffer. Also make sure we use only 72 characters per line which is
 718 " the recommendation for git commit messages (http://tpope.net/node/106).
 719         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 720                                  \ setlocal textwidth=72
 721 " Use the same comment string as for Vim files in Vimperator files.
 722         autocmd FileType vimperator setlocal commentstring=\"%s
 723 " Use tex compiler for (La)TeX files.
 724         autocmd FileType tex compiler tex
 725
 726 " FTDETECT AUTO COMMANDS
 727
 728 " Recognize .md as markdown files (Vim default is .mkd).
 729         autocmd BufRead,BufNewFile *.md set filetype=mkd
 730 " Recognize .test as Tcl files.
 731         autocmd BufRead,BufNewFile *.test set filetype=tcl
 732
 733 " OTHER AUTO COMMANDS
 734
 735 " Disable spell checking, displaying of list characters and long lines when
 736 " viewing documentation.
 737         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 738
 739 " Use diff filetype for mercurial patches in patch queue.
 740         autocmd BufReadPost */.hg/patches/* set filetype=diff
 741
 742     augroup END
 743 endif
 744
 745
 746 " CUSTOM FUNCTIONS AND COMMANDS
 747
 748 if has('eval')
 749 " Convenient command to see the difference between the current buffer and the
 750 " file it was loaded from, thus the changes you made. Thanks to the
 751 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 752 " for the diffed file than the filetype for the original file.
 753     if !exists(':DiffOrig')
 754         command DiffOrig
 755             \ let s:diff_orig_filetype = &filetype
 756             \ | vertical new
 757             \ | let &filetype = s:diff_orig_filetype
 758             \ | unlet s:diff_orig_filetype
 759             \ | set buftype=nofile
 760             \ | read ++edit #
 761             \ | 0d_
 762             \ | diffthis
 763             \ | wincmd p
 764             \ | diffthis
 765     endif
 766 endif