vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Save 'runtimepath' in case it was changed by the system's configuration
   7 " files. Also save 'diff' as set all& resets it; but somehow later (after
   8 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
   9 " automagically restored to the correct value.
  10 if has('eval')
  11     let s:save_runtimepath = &runtimepath
  12     let s:save_diff = &diff
  13 endif
  14 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  15 " system wide configuration file doesn't change default values.
  16 set all&
  17 " And restore it after all other options were reset.
  18 if has('eval')
  19     let &runtimepath = s:save_runtimepath
  20     let &diff = s:save_diff
  21     unlet s:save_runtimepath
  22     unlet s:save_diff
  23 endif
  24
  25 " Make sure Vim (and not Vi) settings are used.
  26 set nocompatible
  27
  28 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  29 " affect reading files in different encodings, see 'fileencodings' for that.
  30 set encoding=utf-8
  31
  32 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  33 " runtime files) if available.
  34 set runtimepath-=~/.vim
  35 set runtimepath^=~/.vim,~/.vim/runtime
  36
  37 " Don't store swap files in the same directory as the edited file.
  38 set directory-=.
  39 " But store them in ~/.tmp if available.
  40 set directory^=~/.tmp
  41
  42 " Disable modelines as they may cause security problems. Instead use
  43 " securemodelines (Vim script #1876).
  44 set nomodeline
  45
  46 " Complete to longest common string (list:longest) and then complete all full
  47 " matches after another (full). Thanks to pbrisbin
  48 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  49 set wildmode=list:longest,full
  50
  51 " Increase history of executed commands (:).
  52 set history=1000
  53
  54 " Increase number of possible undos.
  55 set undolevels=1000
  56
  57 " Use strong encryption if possible, also used for swap/undo files.
  58 if exists('+cryptmethod')
  59     set cryptmethod=blowfish
  60 endif
  61
  62
  63 " EDIT SETTINGS
  64
  65 " Enable automatic file detection, plugin and indention support.
  66 if has('autocmd')
  67     filetype off " necessary for pathogen to force a reload of ftplugins
  68     filetype plugin indent on
  69 endif
  70
  71 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  72 " existing files.
  73 set fileencodings=utf-8,latin1
  74
  75 " Wrap text after 78 characters.
  76 set textwidth=78
  77
  78 " Set tabs to 4 spaces, use softtabs.
  79 set shiftwidth=4
  80 set softtabstop=4
  81 set expandtab
  82 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  83 set shiftround
  84 " Use the default value for real tabs.
  85 set tabstop=8
  86
  87 " Enable auto indention.
  88 set autoindent
  89
  90 " When joining lines only add one space after a sentence.
  91 set nojoinspaces
  92
  93 " Allow backspacing over autoindent and line breaks.
  94 set backspace=indent,eol
  95
  96 " Start a comment when hitting enter after a commented line (r) and when using
  97 " o or O around a commented line (o).
  98 set formatoptions+=ro
  99 " Don't break a line if was already longer then 'textwidth' when insert mode
 100 " started.
 101 set formatoptions+=l
 102
 103 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 104 " no character) in visual block mode.
 105 set virtualedit=block
 106
 107 " Already display matches while typing the search command. This makes spotting
 108 " errors easy.
 109 set incsearch
 110
 111 " Activate syntax folding.
 112 if has('folding')
 113     set foldmethod=syntax
 114     set foldcolumn=2
 115     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 116                      " folding which is not what I want
 117 endif
 118
 119 " Only check for case if the searched word contains a capital character.
 120 set ignorecase
 121 set smartcase
 122
 123 " Activate spell checking, use English as default.
 124 if exists('+spell') && has('syntax')
 125     " But not when diffing as spell checking is distracting in this case.
 126     if !&diff
 127         set spell
 128     endif
 129     set spelllang=en_us
 130 endif
 131
 132 " Allow buffers with changes to be hidden. Very important for effective
 133 " editing with multiple buffers.
 134 set hidden
 135
 136
 137 " DISPLAY SETTINGS
 138
 139 " Use a dark background. Doesn't change the background color, only sets text
 140 " colors for a dark terminal.
 141 set background=dark
 142
 143 " Display line numbers.
 144 set number
 145 " But use as little space as necessary for the numbers column. Thanks to James
 146 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 147 if exists('+numberwidth')
 148     set numberwidth=1
 149 endif
 150 " Display the ruler with current line/file position. If 'statusline' is used
 151 " then this only affects <C-G>.
 152 set ruler
 153 " Display partial commands in the status line.
 154 set showcmd
 155
 156 " Don't redraw screen when executing macros; increases speed. Thanks to James
 157 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 158 set lazyredraw
 159
 160 " Visualize the line the cursor is currently in.
 161 if exists('+cursorline')
 162     set cursorline
 163 endif
 164
 165 " Display tabs, trailing space, non breakable spaces and long lines (when
 166 " wrapping is disabled).
 167 set list
 168 set listchars=trail:-,extends:>
 169 if v:version >= 700
 170     set listchars+=nbsp:!
 171 endif
 172
 173 if has('statusline')
 174     " Always display the status line even if there is only one window.
 175     set laststatus=2
 176
 177     set statusline=
 178     " on the left
 179     set statusline+=%02n: " buffer number
 180     set statusline+=%f\   " path to current file in buffer
 181     set statusline+=%h    " [help] if buffer is help file
 182     set statusline+=%w    " [Preview] if buffer is preview buffer
 183     set statusline+=%m    " [+] if buffer was modified,
 184                           " [-] if 'modifiable' is off
 185     set statusline+=%r    " [RO] if buffer is read only
 186
 187     " on the right
 188     set statusline+=%=                " right align
 189     set statusline+=0x%-8B\           " current character under cursor as hex
 190     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 191                                       " column number (%c),
 192                                       " virtual column number if different
 193                                       "                       than %c (%V)
 194     set statusline+=%P                " position in file in percent
 195 endif
 196
 197
 198 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 199
 200 " Easy way to exit insert mode.
 201 inoremap jj <Esc>
 202 inoremap jk <Esc>
 203 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 204 " (2010-10-15).
 205 cnoremap jj <C-C>
 206 cnoremap jk <C-C>
 207
 208 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 209 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 210 map <Right>  <Nop>
 211 map <Left>   <Nop>
 212 map <Up>     <Nop>
 213 map <Down>   <Nop>
 214 imap <Right> <Nop>
 215 imap <Left>  <Nop>
 216 imap <Up>    <Nop>
 217 imap <Down>  <Nop>
 218 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 219 " below).
 220 cmap <Up>    <Nop>
 221 cmap <Down>  <Nop>
 222 cmap <Right> <Nop>
 223 cmap <Left>  <Nop>
 224
 225 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 226 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 227 cnoremap <C-P> <Up>
 228 cnoremap <C-N> <Down>
 229
 230 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 231 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 232 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 233
 234 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 235 " in #vim on Freenode (2011-08-15 00:17 CEST).
 236 nnoremap <C-G> 2<C-G>
 237
 238 " Use <Space> to move down a page and - to move up one like in mutt.
 239 nnoremap <Space> <C-F>
 240 nnoremap - <C-B>
 241
 242 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 243 " (2010-05-16 18:38 CEST) for this idea.
 244 nnoremap <silent> gb :bnext<CR>
 245 nnoremap <silent> gB :bprev<CR>
 246
 247 " Fast access to buffers.
 248 nnoremap <silent> <Leader>1 :1b<CR>
 249 nnoremap <silent> <Leader>2 :2b<CR>
 250 nnoremap <silent> <Leader>3 :3b<CR>
 251 nnoremap <silent> <Leader>4 :4b<CR>
 252 nnoremap <silent> <Leader>5 :5b<CR>
 253 nnoremap <silent> <Leader>6 :6b<CR>
 254 nnoremap <silent> <Leader>7 :7b<CR>
 255 nnoremap <silent> <Leader>8 :8b<CR>
 256 nnoremap <silent> <Leader>9 :9b<CR>
 257 nnoremap <silent> <Leader>0 :10b<CR>
 258
 259 " Make last active window the only window. Similar to <C-W> o.
 260 nnoremap <C-W>O <C-W>p<C-W>o
 261
 262 " Maps to change spell language between English and German and disable spell
 263 " checking.
 264 if exists('+spell')
 265     noremap <silent> <Leader>sn :set nospell<CR>
 266     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 267     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 268 endif
 269
 270 " Add semicolon to the end of the line. Thanks to
 271 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 272 " on Freenode for an improved version which doesn't clobber any marks.
 273 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 274
 275 " * and # for selections in visual mode. Thanks to
 276 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 277 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 278 if has('eval')
 279     function! s:VSetSearch()
 280         let temp = @@
 281         normal! gvy
 282         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 283         let @@ = temp
 284     endfunction
 285     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 286     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 287 endif
 288
 289 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 290 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 291 " mailing list for the commands.
 292 if v:version < 700
 293     cnoreabbrev W w
 294     cnoreabbrev Wa wa
 295     cnoreabbrev Wq wq
 296     cnoreabbrev Wqa wqa
 297 else
 298     cnoreabbrev <expr> W
 299         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 300     cnoreabbrev <expr> Wa
 301         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 302     cnoreabbrev <expr> Wq
 303         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 304     cnoreabbrev <expr> Wqa
 305         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 306 endif
 307 " Also fix my typo with "Q".
 308 if v:version < 700
 309     cnoreabbrev Q q
 310     cnoreabbrev Qa qa
 311 else
 312     cnoreabbrev <expr> Q
 313         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 314     cnoreabbrev <expr> Qa
 315         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 316 endif
 317
 318 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 319 " if pressed accidentally while in insert mode (happens on Mac when alt
 320 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 321 " no longer set on the console.
 322 if has('mac') || filereadable('/Users/.localized')
 323     inoremap <Char-0xa0> <Space>
 324 endif
 325
 326 " Disable Apple style movements in MacVim.
 327 if has('gui_macvim')
 328     let g:macvim_skip_cmd_opt_movement = 1
 329 endif
 330
 331 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 332 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 333 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 334
 335 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 336 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 337 " Vim's source.
 338 inoremap <C-U> <C-G>u<C-U>
 339 " Same for <C-@> (insert previously inserted text and leave insert mode).
 340 inoremap <C-@> <C-G>u<C-@>
 341 " And for <C-A> (insert previously inserted text).
 342 inoremap <C-A> <C-G>u<C-A>
 343 " And for <C-W> (delete word before cursor).
 344 inoremap <C-W> <C-G>u<C-W>
 345
 346 if has('eval')
 347 " New text-objects ii and ai to work on text with the same indentation. Thanks
 348 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 349 " (visited on 2011-11-19).
 350     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 351     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 352     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 353     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 354
 355     function! s:IndTxtObj(inner)
 356         let curline = line(".")
 357         let lastline = line("$")
 358         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 359         let i = i < 0 ? 0 : i
 360         if getline(".") !~ "^\\s*$"
 361             let p = line(".") - 1
 362             let nextblank = getline(p) =~ "^\\s*$"
 363             while p > 0
 364                     \ && ((i == 0 && !nextblank)
 365                         \ || (i > 0 && ((indent(p) >= i
 366                             \ && !(nextblank && a:inner))
 367                             \ || (nextblank && !a:inner))))
 368                 -
 369                 let p = line(".") - 1
 370                 let nextblank = getline(p) =~ "^\\s*$"
 371             endwhile
 372             normal! 0V
 373             call cursor(curline, 0)
 374             let p = line(".") + 1
 375             let nextblank = getline(p) =~ "^\\s*$"
 376             while p <= lastline
 377                     \ && ((i == 0 && !nextblank)
 378                         \ || (i > 0 && ((indent(p) >= i
 379                             \ && !(nextblank && a:inner))
 380                             \ || (nextblank && !a:inner))))
 381                 +
 382                 let p = line(".") + 1
 383                 let nextblank = getline(p) =~ "^\\s*$"
 384             endwhile
 385             normal! $
 386         endif
 387     endfunction
 388 endif
 389
 390
 391 " ABBREVIATIONS
 392
 393 " Fix some of my spelling mistakes.
 394 iabbrev relle reelle
 395 iabbrev reele reelle
 396
 397
 398 " SYNTAX SETTINGS
 399
 400 " Activate syntax coloring.
 401 if has('syntax')
 402     syntax enable
 403
 404 " Don't highlight more than 500 columns as I normally don't have that long
 405 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 406 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 407     if exists('+synmaxcol')
 408         set synmaxcol=500
 409     endif
 410
 411 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 412 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 413 " disabled when necessary with :2match (in Vim >= 700).
 414     if exists(':2match')
 415         2match Todo /\%>78v./
 416     else
 417         match Todo /\%>78v./
 418     endif
 419
 420     if exists('*matchadd')
 421 " Highlight some important keywords in all documents.
 422         for x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 423             call matchadd('Todo', x)
 424         endfor
 425
 426 " Highlight unicode whitespace which is no normal whitespace (0x20).
 427         for x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 428                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 429                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 430                 \ 'feff']
 431             call matchadd('Error', '\%u' . x)
 432         endfor
 433     endif
 434
 435 " Settings for specific filetypes.
 436
 437     " Haskell.
 438     let g:hs_highlight_boolean = 1
 439     let g:hs_highlight_types = 1
 440     let g:hs_highlight_more_types = 1
 441
 442     " Perl.
 443     let g:perl_fold = 1
 444     let g:perl_fold_blocks = 1
 445     let g:perl_nofold_packages = 1
 446     let g:perl_include_pod = 1 " syntax coloring for PODs
 447 endif
 448
 449
 450 " PLUGIN SETTINGS
 451
 452 if has('eval')
 453 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 454 " installing/removing/updating plugins simple. (Used for plugins with more
 455 " than one file.)
 456     if v:version >= 700
 457         execute 'call pathogen#runtime_append_all_bundles()'
 458     endif
 459
 460 " Settings for the NERD commenter.
 461     " Don't create any mappings I don't want to use.
 462     let NERDCreateDefaultMappings = 0
 463     " Map toggle comment.
 464     map <Leader><Leader> <Plug>NERDCommenterToggle
 465
 466 " XPTemplate settings.
 467     " Try to maintain snippet rendering even after editing outside of a
 468     " snippet.
 469     let g:xptemplate_strict = 0
 470     " Don't complete any braces automatically.
 471     let g:xptemplate_brace_complete = 0
 472     " Only highlight the current placeholder.
 473     let g:xptemplate_highlight = 'current'
 474 endif
 475
 476
 477 " AUTO COMMANDS
 478
 479 " Use a custom auto group to prevent problems when the vimrc files is sourced
 480 " twice.
 481 if has('autocmd')
 482     augroup vimrc
 483 " Remove all autocmds from the current group.
 484         autocmd!
 485
 486 " Go to last position of opened files. Taken from :help last-position-jump.
 487         autocmd BufReadPost *
 488             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 489             \     execute "normal! g'\"" |
 490             \ endif
 491 " But not for Git commits, go to beginning of the file.
 492         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 493
 494 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 495 " when switching to a help buffer which is in the background with :buffer as
 496 " these options are local to windows (and not only to buffers). This happens
 497 " because I often want to use only one window and thus the help buffer is in
 498 " the background.
 499         autocmd BufWinEnter *.txt
 500             \ if &filetype == 'help' |
 501             \     setlocal nolist |
 502             \     setlocal nonumber |
 503             \ endif
 504
 505 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 506 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 507 " want to paste once and then 'paste' gets automatically unset.
 508         if exists('##InsertLeave')
 509             autocmd InsertLeave * set nopaste
 510         endif
 511
 512 " Write file when running :mak[e] before 'makeprg' is called.
 513         autocmd QuickFixCmdPre * write
 514
 515 " AFTER/FTPLUGIN AUTO COMMANDS
 516
 517 " Disable spell checking for files which don't need it.
 518         autocmd FileType deb  setlocal nospell
 519         autocmd FileType diff setlocal nospell
 520         autocmd FileType tar  setlocal nospell
 521 " Fix to allow Vim edit crontab files as crontab doesn't work with
 522 " backupcopy=auto.
 523         autocmd FileType crontab setlocal backupcopy=yes
 524 " Don't use the modeline in git commits as the diff created by `git commit -v`
 525 " may contain one which could change the filetype or other settings of the
 526 " commit buffer. Also make sure we use only 72 characters per line which is
 527 " the recommendation for git commit messages (http://tpope.net/node/106).
 528         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 529                                  \ setlocal textwidth=72
 530 " Use the same comment string as for Vim files in Vimperator files.
 531         autocmd FileType vimperator setlocal commentstring=\"%s
 532 " Use tex compiler for (La)TeX files.
 533         autocmd FileType tex compiler tex
 534
 535 " FTDETECT AUTO COMMANDS
 536
 537 " Recognize .md as markdown files (Vim default is .mkd).
 538         autocmd BufRead,BufNewFile *.md set filetype=mkd
 539 " Recognize .test as Tcl files.
 540         autocmd BufRead,BufNewFile *.test set filetype=tcl
 541
 542 " OTHER AUTO COMMANDS
 543
 544 " Disable spell checking, displaying of list characters and long lines when
 545 " viewing documentation.
 546         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 547
 548 " Use diff filetype for mercurial patches in patch queue.
 549         autocmd BufReadPost */.hg/patches/* set filetype=diff
 550
 551     augroup END
 552 endif
 553
 554
 555 " CUSTOM FUNCTIONS AND COMMANDS
 556
 557 if has('eval')
 558 " Convenient command to see the difference between the current buffer and the
 559 " file it was loaded from, thus the changes you made. Thanks to the
 560 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 561 " for the diffed file than the filetype for the original file.
 562     if !exists(":DiffOrig")
 563         command DiffOrig
 564             \ let s:diff_orig_filetype = &filetype
 565             \ | vertical new
 566             \ | let &filetype = s:diff_orig_filetype
 567             \ | unlet s:diff_orig_filetype
 568             \ | set buftype=nofile
 569             \ | read ++edit #
 570             \ | 0d_
 571             \ | diffthis
 572             \ | wincmd p
 573             \ | diffthis
 574     endif
 575 endif