vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37 " But store them in ~/.tmp if available.
  38 set directory^=~/.tmp
  39
  40 " Disable modelines as they may cause security problems. Instead use
  41 " securemodelines (Vim script #1876).
  42 set nomodeline
  43
  44 " Complete to longest common string (list:longest) and then complete all full
  45 " matches after another (full). Thanks to pbrisbin
  46 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  47 set wildmode=list:longest,full
  48
  49 " Increase history of executed commands (:).
  50 set history=1000
  51
  52 " Increase number of possible undos.
  53 set undolevels=1000
  54
  55 " Use strong encryption if possible, also used for swap/undo files.
  56 if v:version >= 703
  57     set cryptmethod=blowfish
  58 endif
  59
  60
  61 " EDIT SETTINGS
  62
  63 " Enable automatic file detection, plugin and indention support.
  64 if has('autocmd')
  65     filetype off " necessary for pathogen to force a reload of ftplugins
  66     filetype plugin indent on
  67 endif
  68
  69 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  70 " existing files.
  71 set fileencodings=utf-8,latin1
  72
  73 " Wrap text after 78 characters.
  74 set textwidth=78
  75
  76 " Set tabs to 4 spaces, use softtabs.
  77 set shiftwidth=4
  78 set softtabstop=4
  79 set expandtab
  80 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  81 set shiftround
  82 " Use the default value for real tabs.
  83 set tabstop=8
  84
  85 " Enable auto indention.
  86 set autoindent
  87
  88 " When joining lines only add one space after a sentence.
  89 set nojoinspaces
  90
  91 " Allow backspacing over autoindent and line breaks.
  92 set backspace=indent,eol
  93
  94 " Start a comment when hitting enter after a commented line (r) and when using
  95 " o or O around a commented line (o).
  96 set formatoptions+=ro
  97 " Don't break a line if was already longer then 'textwidth' when insert mode
  98 " started.
  99 set formatoptions+=l
 100
 101 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 102 " no character) in visual block mode.
 103 set virtualedit=block
 104
 105 " Already display matches while typing the search command. This makes spotting
 106 " errors easy.
 107 set incsearch
 108
 109 " Activate syntax folding.
 110 if has('folding')
 111     set foldmethod=syntax
 112     set foldcolumn=2
 113     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 114                      " folding which is not what I want
 115 endif
 116
 117 " Only check for case if the searched word contains a capital character.
 118 set ignorecase
 119 set smartcase
 120
 121 " Activate spell checking, use English as default. Don't use spell checking
 122 " when diffing.
 123 if v:version >= 700 && has('syntax') && !&diff
 124     set spell
 125     set spelllang=en_us
 126 endif
 127
 128 " Allow buffers with changes to be hidden. Very important for effective
 129 " editing with multiple buffers.
 130 set hidden
 131
 132
 133 " DISPLAY SETTINGS
 134
 135 " Use a dark background. Doesn't change the background color, only sets text
 136 " colors for a dark terminal.
 137 set background=dark
 138
 139 " Display line numbers.
 140 set number
 141 " But use as little space as necessary for the numbers column. Thanks to James
 142 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 143 if v:version >= 700
 144     set numberwidth=1
 145 endif
 146 " Display the ruler with current line/file position. If 'statusline' is used
 147 " then this only affects <C-G>.
 148 set ruler
 149 " Display partial commands in the status line.
 150 set showcmd
 151
 152 " Don't redraw screen when executing macros; increases speed. Thanks to James
 153 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 154 set lazyredraw
 155
 156 " Visualize the line the cursor is currently in.
 157 if v:version >= 700
 158     set cursorline
 159 endif
 160
 161 " Display tabs, trailing space, non breakable spaces and long lines (when
 162 " wrapping is disabled).
 163 set list
 164 set listchars=trail:-,extends:>
 165 if v:version >= 700
 166     set listchars+=nbsp:!
 167 endif
 168
 169 if has('statusline')
 170     " Always display the status line even if there is only one window.
 171     set laststatus=2
 172
 173     set statusline=
 174     " on the left
 175     set statusline+=%02n: " buffer number
 176     set statusline+=%f\   " path to current file in buffer
 177     set statusline+=%h    " [help] if buffer is help file
 178     set statusline+=%w    " [Preview] if buffer is preview buffer
 179     set statusline+=%m    " [+] if buffer was modified,
 180                           " [-] if 'modifiable' is off
 181     set statusline+=%r    " [RO] if buffer is read only
 182
 183     " on the right
 184     set statusline+=%=                " right align
 185     set statusline+=0x%-8B\           " current character under cursor as hex
 186     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 187                                       " column number (%c),
 188                                       " virtual column number if different
 189                                       "                       than %c (%V)
 190     set statusline+=%P                " position in file in percent
 191 endif
 192
 193
 194 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 195
 196 " Easy way to exit insert mode.
 197 inoremap jj <Esc>
 198 inoremap jk <Esc>
 199 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 200 " (2010-10-15).
 201 cnoremap jj <C-C>
 202 cnoremap jk <C-C>
 203
 204 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 205 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 206 map <Right>  <Nop>
 207 map <Left>   <Nop>
 208 map <Up>     <Nop>
 209 map <Down>   <Nop>
 210 imap <Right> <Nop>
 211 imap <Left>  <Nop>
 212 imap <Up>    <Nop>
 213 imap <Down>  <Nop>
 214 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 215 " below).
 216 cmap <Up>    <Nop>
 217 cmap <Down>  <Nop>
 218 cmap <Right> <Nop>
 219 cmap <Left>  <Nop>
 220
 221 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 222 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 223 cnoremap <C-P> <Up>
 224 cnoremap <C-N> <Down>
 225
 226 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 227 " 20:02 CEST). To suspend without saving either unmap it or use :stop<CR>.
 228 nnoremap <C-Z> :update<CR>:stop<CR>
 229
 230 " Use <Space> to move down a page and - to move up one like in mutt.
 231 nnoremap <Space> <C-F>
 232 nnoremap - <C-B>
 233
 234 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 235 " (2010-05-16 18:38 CEST) for this idea.
 236 nnoremap <silent> gb :bnext<CR>
 237 nnoremap <silent> gB :bprev<CR>
 238
 239 " Fast access to buffers.
 240 nnoremap <Leader>1 :1b<CR>
 241 nnoremap <Leader>2 :2b<CR>
 242 nnoremap <Leader>3 :3b<CR>
 243 nnoremap <Leader>4 :4b<CR>
 244 nnoremap <Leader>5 :5b<CR>
 245 nnoremap <Leader>6 :6b<CR>
 246 nnoremap <Leader>7 :7b<CR>
 247 nnoremap <Leader>8 :8b<CR>
 248 nnoremap <Leader>9 :9b<CR>
 249 nnoremap <Leader>0 :10b<CR>
 250
 251 " Make last active window the only window. Similar to <C-w> o.
 252 nnoremap <C-W>O <C-W>p<C-W>o
 253
 254 " Maps to change spell language between English and German and disable spell
 255 " checking.
 256 if v:version >= 700
 257     noremap <Leader>sn :set nospell<CR>
 258     noremap <Leader>se :set spell spelllang=en_us<CR>
 259     noremap <Leader>sd :set spell spelllang=de_de<CR>
 260 endif
 261
 262 " Add semicolon to the end of the line. Thanks to
 263 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 264 " on Freenode for an improved version which doesn't clobber any marks.
 265 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 266
 267 " * and # for selections in visual mode. Thanks to
 268 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 269 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 270 if has('eval')
 271     function! s:VSetSearch()
 272         let temp = @@
 273         normal! gvy
 274         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 275         let @@ = temp
 276     endfunction
 277     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 278     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 279 endif
 280
 281 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 282 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 283 " mailing list for the commands.
 284 if v:version < 700
 285     cnoreabbrev W w
 286     cnoreabbrev Wa wa
 287     cnoreabbrev Wq wq
 288     cnoreabbrev Wqa wqa
 289 else
 290     cnoreabbrev <expr> W
 291         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 292     cnoreabbrev <expr> Wa
 293         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 294     cnoreabbrev <expr> Wq
 295         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 296     cnoreabbrev <expr> Wqa
 297         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 298 endif
 299 " Also fix my typo with "Q".
 300 if v:version < 700
 301     cnoreabbrev Q q
 302     cnoreabbrev Qa qa
 303 else
 304     cnoreabbrev <expr> Q
 305         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 306     cnoreabbrev <expr> Qa
 307         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 308 endif
 309
 310 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 311 " if pressed accidentally while in insert mode (happens on Mac when alt
 312 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 313 " no longer set on the console.
 314 if has('mac') || filereadable('/Users/.localized')
 315     inoremap <Char-0xa0> <Space>
 316 endif
 317
 318 " Disable Apple style movements in MacVim.
 319 if has('gui_macvim') && has('eval')
 320     let macvim_skip_cmd_opt_movement = 1
 321 endif
 322
 323 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 324 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 325 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 326
 327
 328 " ABBREVIATIONS
 329
 330 " Fix some of my spelling mistakes.
 331 iabbrev relle reelle
 332 iabbrev reele reelle
 333
 334
 335 " SYNTAX SETTINGS
 336
 337 " Activate syntax coloring.
 338 if has('syntax')
 339     syntax enable
 340
 341 " Don't highlight more than 500 columns as I normally don't have that long
 342 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 343 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 344     set synmaxcol=500
 345
 346 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 347 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 348 " disabled when necessary with :2match (in Vim >= 700).
 349     if v:version >= 700
 350         2match Todo /\%>78v./
 351     else
 352         match Todo /\%>78v./
 353     endif
 354
 355 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 356     if v:version > 701 || (v:version == 701 && has('patch42'))
 357         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 358     endif
 359 endif
 360
 361
 362 " PLUGIN SETTINGS
 363
 364 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 365 " installing/removing/updating plugins simple. (Used for plugins with more
 366 " than one file.)
 367 if has('eval')
 368     call pathogen#runtime_append_all_bundles()
 369 endif
 370
 371 " Settings for the NERD commenter.
 372 " Don't create any mappings I don't want to use.
 373 if has('eval')
 374     let NERDCreateDefaultMappings = 0
 375 endif
 376 " Map toggle comment.
 377 map <Leader><Leader> <Plug>NERDCommenterToggle
 378
 379 " XPTemplate settings.
 380 if has('eval')
 381     " Try to maintain snippet rendering even after editing outside of a
 382     " snippet.
 383     let g:xptemplate_strict = 0
 384     " Don't complete any braces automatically.
 385     let g:xptemplate_brace_complete = 0
 386     " Only highlight the current placeholder.
 387     let g:xptemplate_highlight = 'current'
 388 endif
 389
 390
 391 " AUTO COMMANDS
 392
 393 " Use a custom auto group to prevent problems when the vimrc files is sourced
 394 " twice.
 395 if has('autocmd')
 396     augroup vimrc
 397         autocmd!
 398
 399 " Go to last position of opened files. Taken from :help last-position-jump.
 400         autocmd BufReadPost *
 401             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 402             \     execute "normal! g'\"" |
 403             \ endif
 404 " But not for Git commits, go to beginning of the file.
 405         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 406
 407 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 408 " when switching to a help buffer which is in the background with :buffer as
 409 " these options are local to windows (and not only to buffers). This happens
 410 " because I often want to use only one window and thus the help buffer is in
 411 " the background.
 412         autocmd BufWinEnter *.txt
 413             \ if &filetype == 'help' |
 414             \     setlocal nolist |
 415             \     setlocal nonumber |
 416             \ endif
 417
 418 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 419 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 420 " want to paste once and then 'paste' gets automatically unset.
 421         autocmd InsertLeave * set nopaste
 422
 423 " AFTER/FTPLUGIN AUTO COMMANDS
 424
 425 " Disable spell checking for files which don't need it.
 426         autocmd FileType deb  setlocal nospell
 427         autocmd FileType diff setlocal nospell
 428         autocmd FileType tar  setlocal nospell
 429 " Fix to allow Vim edit crontab files as crontab doesn't work with
 430 " backupcopy=auto.
 431         autocmd FileType crontab setlocal backupcopy=yes
 432 " Don't use the modeline in git commits as the diff created by `git commit -v`
 433 " may contain one which could change the filetype or other settings of the
 434 " commit buffer. Also make sure we use only 72 characters per line which is
 435 " the recommendation for git commit messages (http://tpope.net/node/106).
 436         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 437                                  \ setlocal textwidth=72
 438 " Allow folding in perl.
 439         autocmd FileType perl let perl_fold = 1 |
 440                             \ let perl_fold_blocks = 1
 441 " Use the same comment string as for Vim files in Vimperator files.
 442         autocmd FileType vimperator setlocal commentstring=\"%s
 443
 444 " FTDETECT AUTO COMMANDS
 445
 446 " Recognize .md as markdown files (Vim default is .mkd).
 447         autocmd BufRead,BufNewFile *.md set filetype=mkd
 448 " Recognize .test as Tcl files.
 449         autocmd BufRead,BufNewFile *.test set filetype=tcl
 450
 451 " OTHER AUTO COMMANDS
 452
 453 " Disable spell checking, displaying of list characters and long lines when
 454 " viewing documentation.
 455         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 456
 457 " Use diff filetype for mercurial patches in patch queue.
 458         autocmd BufReadPost */.hg/patches/* set filetype=diff
 459
 460     augroup END
 461 endif