vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     set foldcolumn=2
 143     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 144                      " folding which is not what I want
 145 endif
 146
 147 " Only check for case if the searched word contains a capital character.
 148 set ignorecase
 149 set smartcase
 150
 151 " Activate spell checking, use English as default.
 152 if exists('+spell') && has('syntax')
 153     " But not when diffing because spell checking is distracting in this case.
 154     if !&diff
 155         set spell
 156     endif
 157     set spelllang=en_us
 158 endif
 159
 160 " Allow buffers with changes to be hidden. Very important for effective
 161 " editing with multiple buffers.
 162 set hidden
 163
 164
 165 " DISPLAY SETTINGS
 166
 167 " Use a dark background. Doesn't change the background color, only sets text
 168 " colors for a dark terminal.
 169 set background=dark
 170
 171 " Display line numbers.
 172 set number
 173 " But use as little space as necessary for the numbers column. Thanks to James
 174 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 175 if exists('+numberwidth')
 176     set numberwidth=1
 177 endif
 178 " Display the ruler with current line/file position. If 'statusline' is used
 179 " then this only affects <C-G>.
 180 set ruler
 181 " Display partial commands in the status line.
 182 set showcmd
 183
 184 " Don't redraw screen when executing macros; increases speed. Thanks to James
 185 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 186 set lazyredraw
 187
 188 " Visualize the line the cursor is currently in.
 189 if exists('+cursorline')
 190     set cursorline
 191 endif
 192
 193 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 194 " remove the highlighting until the next search.
 195 set hlsearch
 196
 197 " Display tabs, trailing space, non breakable spaces and long lines (when
 198 " wrapping is disabled).
 199 set list
 200 set listchars=trail:-,extends:>
 201 if v:version >= 700
 202     set listchars+=nbsp:!
 203 endif
 204
 205 if has('statusline')
 206     " Always display the status line even if there is only one window.
 207     set laststatus=2
 208
 209     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 210     " is the highest buffer number, otherwise return nothing. Used in
 211     " 'statusline' to get an overview of available buffer numbers.
 212     function! StatuslineBufferCount()
 213         let l:bufnr = bufnr('$')
 214         if l:bufnr > 1
 215             let l:result = '/'
 216             if exists('*printf')
 217                 let l:result .= printf('%02d', l:bufnr)
 218             else
 219                 " Older Vims don't have printf() (and no .= either). Emulate
 220                 " "%02d".
 221                 if l:bufnr < 10
 222                     let l:result = l:result . '0'
 223                 endif
 224                 let l:result = l:result . l:bufnr
 225             endif
 226             return l:result
 227         else
 228             return ''
 229         endif
 230     endfunction
 231
 232     set statusline=
 233     " on the left
 234     set statusline+=%02n  " buffer number
 235     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 236     set statusline+=:
 237     set statusline+=%f\   " path to current file in buffer
 238     set statusline+=%h    " [help] if buffer is help file
 239     set statusline+=%w    " [Preview] if buffer is preview buffer
 240     set statusline+=%m    " [+] if buffer was modified,
 241                           " [-] if 'modifiable' is off
 242     set statusline+=%r    " [RO] if buffer is read only
 243
 244     " on the right
 245     set statusline+=%=                " right align
 246     set statusline+=0x%-8B\           " current character under cursor as hex
 247     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 248                                       " column number (%c),
 249                                       " virtual column number if different
 250                                       "                       than %c (%V)
 251     set statusline+=%P                " position in file in percent
 252 endif
 253
 254
 255 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 256
 257 " noremap is used to make sure the right side is executed as is and can't be
 258 " modified by a plugin or other settings. Except for <Nop> which isn't
 259 " affected by mappings.
 260
 261 " Easy way to exit insert mode.
 262 inoremap jj <Esc>
 263 inoremap jk <Esc>
 264 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 265 " (2010-10-15).
 266 cnoremap jj <C-C>
 267 cnoremap jk <C-C>
 268
 269 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 270 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 271 map <Right>  <Nop>
 272 map <Left>   <Nop>
 273 map <Up>     <Nop>
 274 map <Down>   <Nop>
 275 imap <Right> <Nop>
 276 imap <Left>  <Nop>
 277 imap <Up>    <Nop>
 278 imap <Down>  <Nop>
 279 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 280 " below).
 281 cmap <Up>    <Nop>
 282 cmap <Down>  <Nop>
 283 cmap <Right> <Nop>
 284 cmap <Left>  <Nop>
 285
 286 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 287 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 288 cnoremap <C-P> <Up>
 289 cnoremap <C-N> <Down>
 290
 291 if has('eval')
 292 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 293 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 294 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 295 " directly because it also enables that feature for other commands which I
 296 " don't want.
 297
 298     " Set 'nostartofline' for a single movement.
 299     function! s:TemporaryNostartofline(movement)
 300         let l:startofline = &startofline
 301         set nostartofline
 302         execute 'normal! ' . a:movement
 303         let &startofline = l:startofline
 304     endfunction
 305
 306     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 307     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 308     nnoremap <silent> <C-F>
 309         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 310     nnoremap <silent> <C-B>
 311         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 312     nnoremap <silent> <C-D>
 313         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 314     nnoremap <silent> <C-U>
 315         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 316 endif
 317
 318 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 319 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 320 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 321
 322 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 323 " in #vim on Freenode (2011-08-15 00:17 CEST).
 324 nnoremap <C-G> 2<C-G>
 325
 326 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 327 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 328 nmap <Space> <C-F>
 329 nmap - <C-B>
 330
 331 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 332 " (2010-05-16 18:38 CEST) for this idea.
 333 nnoremap <silent> gb :bnext<CR>
 334 nnoremap <silent> gB :bprev<CR>
 335
 336 " Fast access to buffers.
 337 nnoremap <silent> <Leader>1 :1buffer<CR>
 338 nnoremap <silent> <Leader>2 :2buffer<CR>
 339 nnoremap <silent> <Leader>3 :3buffer<CR>
 340 nnoremap <silent> <Leader>4 :4buffer<CR>
 341 nnoremap <silent> <Leader>5 :5buffer<CR>
 342 nnoremap <silent> <Leader>6 :6buffer<CR>
 343 nnoremap <silent> <Leader>7 :7buffer<CR>
 344 nnoremap <silent> <Leader>8 :8buffer<CR>
 345 nnoremap <silent> <Leader>9 :9buffer<CR>
 346 nnoremap <silent> <Leader>0 :10buffer<CR>
 347
 348 " Make last active window the only window. Similar to <C-W> o.
 349 nnoremap <C-W>O <C-W>p<C-W>o
 350
 351 " Maps to change spell language between English and German and disable spell
 352 " checking.
 353 if exists('+spell')
 354     nnoremap <silent> <Leader>sn :set nospell<CR>
 355     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 356     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 357 endif
 358
 359 " Add semicolon to the end of the line. Thanks to
 360 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 361 " on Freenode for an improved version which doesn't clobber any marks.
 362 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 363
 364 " * and # for selections in visual mode. Thanks to
 365 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 366 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 367 if has('eval')
 368     function! s:VSetSearch()
 369         let l:temp = @@
 370         normal! gvy
 371         " Added \C to force 'noignorecase' while searching the current visual
 372         " selection. I want to search for the exact string in this case.
 373         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 374         let @@ = l:temp
 375     endfunction
 376     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 377     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 378 endif
 379
 380 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 381 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 382 " mailing list for the commands.
 383 if v:version < 700
 384     cnoreabbrev W w
 385     cnoreabbrev Wa wa
 386     cnoreabbrev Wq wq
 387     cnoreabbrev Wqa wqa
 388 else
 389     cnoreabbrev <expr> W
 390         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 391     cnoreabbrev <expr> Wa
 392         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 393     cnoreabbrev <expr> Wq
 394         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 395     cnoreabbrev <expr> Wqa
 396         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 397 endif
 398 " Also fix my typo with "Q".
 399 if v:version < 700
 400     cnoreabbrev Q q
 401     cnoreabbrev Qa qa
 402 else
 403     cnoreabbrev <expr> Q
 404         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 405     cnoreabbrev <expr> Qa
 406         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 407 endif
 408
 409 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 410 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 411 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 412
 413 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 414 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 415 " Vim's source.
 416 inoremap <C-U> <C-G>u<C-U>
 417 " Same for <C-@> (insert previously inserted text and leave insert mode).
 418 inoremap <C-@> <C-G>u<C-@>
 419 " And for <C-A> (insert previously inserted text).
 420 inoremap <C-A> <C-G>u<C-A>
 421 " And for <C-W> (delete word before cursor).
 422 inoremap <C-W> <C-G>u<C-W>
 423
 424 if has('eval')
 425 " New text-objects ii and ai to work on text with the same indentation. Thanks
 426 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 427 " (visited on 2011-11-19).
 428     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 429     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 430     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 431     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 432
 433     function! s:IndTxtObj(inner)
 434         let curline = line(".")
 435         let lastline = line("$")
 436         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 437         let i = i < 0 ? 0 : i
 438         if getline(".") !~ "^\\s*$"
 439             let p = line(".") - 1
 440             let nextblank = getline(p) =~ "^\\s*$"
 441             while p > 0
 442                     \ && ((i == 0 && !nextblank)
 443                         \ || (i > 0 && ((indent(p) >= i
 444                             \ && !(nextblank && a:inner))
 445                             \ || (nextblank && !a:inner))))
 446                 -
 447                 let p = line(".") - 1
 448                 let nextblank = getline(p) =~ "^\\s*$"
 449             endwhile
 450             normal! 0V
 451             call cursor(curline, 0)
 452             let p = line(".") + 1
 453             let nextblank = getline(p) =~ "^\\s*$"
 454             while p <= lastline
 455                     \ && ((i == 0 && !nextblank)
 456                         \ || (i > 0 && ((indent(p) >= i
 457                             \ && !(nextblank && a:inner))
 458                             \ || (nextblank && !a:inner))))
 459                 +
 460                 let p = line(".") + 1
 461                 let nextblank = getline(p) =~ "^\\s*$"
 462             endwhile
 463             normal! $
 464         endif
 465     endfunction
 466 endif
 467
 468
 469 " ABBREVIATIONS
 470
 471 " Fix some of my spelling mistakes.
 472 iabbrev relle reelle
 473 iabbrev reele reelle
 474
 475
 476 " SYNTAX SETTINGS
 477
 478 " Activate syntax coloring.
 479 if has('syntax')
 480     syntax enable
 481
 482 " Don't highlight more than 500 columns as I normally don't have that long
 483 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 484 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 485     if exists('+synmaxcol')
 486         set synmaxcol=500
 487     endif
 488
 489 " Use (limited) syntax based omni completion if no other omni completion is
 490 " available. Taken from :help ft-syntax-omni.
 491     if has('autocmd') && exists('+omnifunc')
 492         augroup vimrc
 493             autocmd FileType *
 494                 \ if &omnifunc == '' |
 495                 \     setlocal omnifunc=syntaxcomplete#Complete |
 496                 \ endif
 497         augroup END
 498     endif
 499
 500 " Function to enable all custom highlights. Necessary as highlights are
 501 " window-local and thus must be set for each new window.
 502     function! s:CustomSyntaxHighlights()
 503         " Not the first time called, nothing to do.
 504         if exists('w:vimrc_syntax_run')
 505             return
 506         endif
 507         let w:vimrc_syntax_run = 1
 508
 509 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 510 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 511 " disabled when necessary with :2match (in Vim >= 700).
 512         if exists(':2match')
 513             2match Todo /\%>78v./
 514         else
 515             match Todo /\%>78v./
 516         endif
 517
 518         if exists('*matchadd')
 519 " Highlight some important keywords in all documents.
 520             let l:todos = ['TODO', 'XXX', 'FIXME',
 521                          \ 'CHANGED', 'REMOVED', 'DELETED']
 522             " Compatibility fix for Vim 6.4 which can't handle for in function
 523             " (without function it's ignored).
 524             execute '  for l:x in l:todos'
 525                   \ '|     call matchadd("Todo", l:x)'
 526                   \ '| endfor'
 527
 528 " Highlight Unicode whitespace which is no normal whitespace (0x20).
 529             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
 530                           \ '2003', '2004', '2005', '2006', '2007', '2008',
 531                           \ '2009', '200a', '200b', '200c', '200d', '202f',
 532                           \ '205f', '2060', '3000', 'feff']
 533             " Compatibility fix for Vim 6.4.
 534             execute '  for l:x in l:spaces'
 535                   \ '|     call matchadd("Error", "\%u" . l:x)'
 536                   \ '| endfor'
 537         endif
 538     endfunction
 539 " Enable highlights for the current and all new windows. Thanks to bairui in
 540 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
 541     call <SID>CustomSyntaxHighlights()
 542     if has('autocmd')
 543         augroup vimrc
 544             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
 545         augroup END
 546     endif
 547
 548 " Settings for specific filetypes.
 549
 550     " Haskell.
 551     let g:hs_highlight_delimiters = 1
 552     let g:hs_highlight_boolean = 1
 553     let g:hs_highlight_types = 1
 554     let g:hs_highlight_more_types = 1
 555     " Perl.
 556     let g:perl_fold = 1
 557     let g:perl_fold_blocks = 1
 558     let g:perl_nofold_packages = 1
 559     let g:perl_include_pod = 1 " syntax coloring for PODs
 560     " Python.
 561     let g:python_highlight_all = 1
 562     " Shell.
 563     let g:sh_noisk = 1        " don't add . to 'iskeyword'
 564     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
 565     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
 566     " Vim.
 567     let g:vimsyn_embed = 0      " don't highlight embedded languages
 568     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 569     " XML.
 570     let g:xml_syntax_folding = 1
 571 endif
 572
 573
 574 " PLUGIN SETTINGS
 575
 576 if has('eval')
 577 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 578 " installing/removing/updating plugins simple. (Used for plugins with more
 579 " than one file.) Ignore errors in case pathogen is not installed.
 580     if v:version >= 700
 581         silent! execute 'call pathogen#runtime_append_all_bundles()'
 582     endif
 583
 584 " Settings for the NERD commenter.
 585     " Don't create any mappings I don't want to use.
 586     let g:NERDCreateDefaultMappings = 0
 587     " Map toggle comment.
 588     map <Leader><Leader> <Plug>NERDCommenterToggle
 589
 590 " XPTemplate settings.
 591     " Try to maintain snippet rendering even after editing outside of a
 592     " snippet.
 593     let g:xptemplate_strict = 0
 594     " Don't complete any braces automatically.
 595     let g:xptemplate_brace_complete = 0
 596     " Only highlight the current placeholder.
 597     let g:xptemplate_highlight = 'current'
 598 endif
 599
 600
 601 " AUTO COMMANDS
 602
 603 " Use a custom auto group to prevent problems when the vimrc files is sourced
 604 " twice.
 605 if has('autocmd')
 606     augroup vimrc
 607
 608 " Go to last position of opened files. Taken from :help last-position-jump.
 609         autocmd BufReadPost *
 610             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 611             \     execute "normal! g'\"" |
 612             \ endif
 613 " But not for Git commits, go to beginning of the file.
 614         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 615
 616 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 617 " when switching to a help buffer which is in the background with :buffer as
 618 " these options are local to windows (and not only to buffers). This happens
 619 " because I often want to use only one window and thus the help buffer is in
 620 " the background.
 621         autocmd BufWinEnter *.txt
 622             \ if &filetype == 'help' |
 623             \     setlocal nolist |
 624             \     setlocal nonumber |
 625             \ endif
 626
 627 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 628 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 629 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 630 " doesn't exist in older Vims.
 631         if exists('##InsertLeave')
 632             autocmd InsertLeave * set nopaste
 633         endif
 634
 635 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 636 " doesn't exist in older Vims.
 637         if exists('##QuickFixCmdPre')
 638             autocmd QuickFixCmdPre * write
 639         endif
 640
 641 " Don't ignore case while in insert mode, but ignore case in all other modes.
 642 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
 643 " capitalization. But while searching (/) 'ignorecase' is used.
 644         autocmd InsertEnter * set noignorecase
 645         autocmd InsertLeave * set   ignorecase
 646
 647 " AFTER/FTPLUGIN AUTO COMMANDS
 648
 649 " Disable spell checking for files which don't need it.
 650         autocmd FileType deb  setlocal nospell
 651         autocmd FileType diff setlocal nospell
 652         autocmd FileType tar  setlocal nospell
 653 " Fix to allow Vim edit crontab files as crontab doesn't work with
 654 " backupcopy=auto.
 655         autocmd FileType crontab setlocal backupcopy=yes
 656 " Don't use the modeline in git commits as the diff created by `git commit -v`
 657 " may contain one which could change the filetype or other settings of the
 658 " commit buffer. Also make sure we use only 72 characters per line which is
 659 " the recommendation for git commit messages (http://tpope.net/node/106).
 660         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 661                                  \ setlocal textwidth=72
 662 " Use the same comment string as for Vim files in Vimperator files.
 663         autocmd FileType vimperator setlocal commentstring=\"%s
 664 " Use tex compiler for (La)TeX files.
 665         autocmd FileType tex compiler tex
 666
 667 " FTDETECT AUTO COMMANDS
 668
 669 " Recognize .md as markdown files (Vim default is .mkd).
 670         autocmd BufRead,BufNewFile *.md set filetype=mkd
 671 " Recognize .test as Tcl files.
 672         autocmd BufRead,BufNewFile *.test set filetype=tcl
 673
 674 " OTHER AUTO COMMANDS
 675
 676 " Disable spell checking, displaying of list characters and long lines when
 677 " viewing documentation.
 678         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 679
 680 " Use diff filetype for mercurial patches in patch queue.
 681         autocmd BufReadPost */.hg/patches/* set filetype=diff
 682
 683     augroup END
 684 endif
 685
 686
 687 " CUSTOM FUNCTIONS AND COMMANDS
 688
 689 if has('eval')
 690 " Convenient command to see the difference between the current buffer and the
 691 " file it was loaded from, thus the changes you made. Thanks to the
 692 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 693 " for the diffed file than the filetype for the original file.
 694     if !exists(':DiffOrig')
 695         command DiffOrig
 696             \ let s:diff_orig_filetype = &filetype
 697             \ | vertical new
 698             \ | let &filetype = s:diff_orig_filetype
 699             \ | unlet s:diff_orig_filetype
 700             \ | set buftype=nofile
 701             \ | read ++edit #
 702             \ | 0d_
 703             \ | diffthis
 704             \ | wincmd p
 705             \ | diffthis
 706     endif
 707 endif