vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Save 'runtimepath' in case it was changed by the system's configuration
   7 " files. Also save 'diff' as set all& resets it; but somehow later (after
   8 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
   9 " automagically restored to the correct value.
  10 if has('eval')
  11     let s:save_runtimepath = &runtimepath
  12     let s:save_diff = &diff
  13 endif
  14 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  15 " system wide configuration file doesn't change default values.
  16 set all&
  17 " And restore it after all other options were reset.
  18 if has('eval')
  19     let &runtimepath = s:save_runtimepath
  20     let &diff = s:save_diff
  21     unlet s:save_runtimepath
  22     unlet s:save_diff
  23 endif
  24
  25 " Make sure Vim (and not Vi) settings are used.
  26 set nocompatible
  27
  28 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  29 " affect reading files in different encodings, see 'fileencodings' for that.
  30 set encoding=utf-8
  31
  32 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  33 " runtime files) if available.
  34 set runtimepath-=~/.vim
  35 set runtimepath^=~/.vim,~/.vim/runtime
  36
  37 " Don't store swap files in the same directory as the edited file.
  38 set directory-=.
  39 " But store them in ~/.tmp if available.
  40 set directory^=~/.tmp
  41
  42 " Disable modelines as they may cause security problems. Instead use
  43 " securemodelines (Vim script #1876).
  44 set nomodeline
  45
  46 " Complete to longest common string (list:longest) and then complete all full
  47 " matches after another (full). Thanks to pbrisbin
  48 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  49 set wildmode=list:longest,full
  50
  51 " Increase history of executed commands (:).
  52 set history=1000
  53
  54 " Increase number of possible undos.
  55 set undolevels=1000
  56
  57 if has('viminfo')
  58     " Remember marks (including the last cursor position) for more files.
  59     set viminfo^='1000
  60 endif
  61
  62 " Use strong encryption if possible, also used for swap/undo files.
  63 if exists('+cryptmethod')
  64     set cryptmethod=blowfish
  65 endif
  66
  67
  68 " EDIT SETTINGS
  69
  70 " Enable automatic file detection, plugin and indention support.
  71 if has('autocmd')
  72     filetype off " necessary for pathogen to force a reload of ftplugins
  73     filetype plugin indent on
  74 endif
  75
  76 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  77 " existing files.
  78 set fileencodings=utf-8,latin1
  79
  80 " Wrap text after 78 characters.
  81 set textwidth=78
  82
  83 " Set tabs to 4 spaces, use softtabs.
  84 set shiftwidth=4
  85 set softtabstop=4
  86 set expandtab
  87 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  88 set shiftround
  89 " Use the default value for real tabs.
  90 set tabstop=8
  91
  92 " Enable auto indention.
  93 set autoindent
  94
  95 " When joining lines only add one space after a sentence.
  96 set nojoinspaces
  97
  98 " Allow backspacing over autoindent and line breaks.
  99 set backspace=indent,eol
 100
 101 " Start a comment when hitting enter after a commented line (r) and when using
 102 " o or O around a commented line (o).
 103 set formatoptions+=ro
 104 " Don't break a line if was already longer then 'textwidth' when insert mode
 105 " started.
 106 set formatoptions+=l
 107
 108 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 109 " no character) in visual block mode.
 110 set virtualedit=block
 111
 112 " Already display matches while typing the search command. This makes spotting
 113 " errors easy.
 114 set incsearch
 115
 116 " Activate syntax folding.
 117 if has('folding')
 118     set foldmethod=syntax
 119     set foldcolumn=2
 120     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 121                      " folding which is not what I want
 122 endif
 123
 124 " Only check for case if the searched word contains a capital character.
 125 set ignorecase
 126 set smartcase
 127
 128 " Activate spell checking, use English as default.
 129 if exists('+spell') && has('syntax')
 130     " But not when diffing as spell checking is distracting in this case.
 131     if !&diff
 132         set spell
 133     endif
 134     set spelllang=en_us
 135 endif
 136
 137 " Allow buffers with changes to be hidden. Very important for effective
 138 " editing with multiple buffers.
 139 set hidden
 140
 141
 142 " DISPLAY SETTINGS
 143
 144 " Use a dark background. Doesn't change the background color, only sets text
 145 " colors for a dark terminal.
 146 set background=dark
 147
 148 " Display line numbers.
 149 set number
 150 " But use as little space as necessary for the numbers column. Thanks to James
 151 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 152 if exists('+numberwidth')
 153     set numberwidth=1
 154 endif
 155 " Display the ruler with current line/file position. If 'statusline' is used
 156 " then this only affects <C-G>.
 157 set ruler
 158 " Display partial commands in the status line.
 159 set showcmd
 160
 161 " Don't redraw screen when executing macros; increases speed. Thanks to James
 162 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 163 set lazyredraw
 164
 165 " Visualize the line the cursor is currently in.
 166 if exists('+cursorline')
 167     set cursorline
 168 endif
 169
 170 " Display tabs, trailing space, non breakable spaces and long lines (when
 171 " wrapping is disabled).
 172 set list
 173 set listchars=trail:-,extends:>
 174 if v:version >= 700
 175     set listchars+=nbsp:!
 176 endif
 177
 178 if has('statusline')
 179     " Always display the status line even if there is only one window.
 180     set laststatus=2
 181
 182     set statusline=
 183     " on the left
 184     set statusline+=%02n: " buffer number
 185     set statusline+=%f\   " path to current file in buffer
 186     set statusline+=%h    " [help] if buffer is help file
 187     set statusline+=%w    " [Preview] if buffer is preview buffer
 188     set statusline+=%m    " [+] if buffer was modified,
 189                           " [-] if 'modifiable' is off
 190     set statusline+=%r    " [RO] if buffer is read only
 191
 192     " on the right
 193     set statusline+=%=                " right align
 194     set statusline+=0x%-8B\           " current character under cursor as hex
 195     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 196                                       " column number (%c),
 197                                       " virtual column number if different
 198                                       "                       than %c (%V)
 199     set statusline+=%P                " position in file in percent
 200 endif
 201
 202
 203 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 204
 205 " noremap is used to make sure the right side is executed as is and can't be
 206 " modified by a plugin or other settings. Except for <Nop> which isn't
 207 " affected by mappings.
 208
 209 " Easy way to exit insert mode.
 210 inoremap jj <Esc>
 211 inoremap jk <Esc>
 212 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 213 " (2010-10-15).
 214 cnoremap jj <C-C>
 215 cnoremap jk <C-C>
 216
 217 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 218 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 219 map <Right>  <Nop>
 220 map <Left>   <Nop>
 221 map <Up>     <Nop>
 222 map <Down>   <Nop>
 223 imap <Right> <Nop>
 224 imap <Left>  <Nop>
 225 imap <Up>    <Nop>
 226 imap <Down>  <Nop>
 227 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 228 " below).
 229 cmap <Up>    <Nop>
 230 cmap <Down>  <Nop>
 231 cmap <Right> <Nop>
 232 cmap <Left>  <Nop>
 233
 234 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 235 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 236 cnoremap <C-P> <Up>
 237 cnoremap <C-N> <Down>
 238
 239 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 240 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 241 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 242
 243 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 244 " in #vim on Freenode (2011-08-15 00:17 CEST).
 245 nnoremap <C-G> 2<C-G>
 246
 247 " Use <Space> to move down a page and - to move up one like in mutt.
 248 nnoremap <Space> <C-F>
 249 nnoremap - <C-B>
 250
 251 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 252 " (2010-05-16 18:38 CEST) for this idea.
 253 nnoremap <silent> gb :bnext<CR>
 254 nnoremap <silent> gB :bprev<CR>
 255
 256 " Fast access to buffers.
 257 nnoremap <silent> <Leader>1 :1buffer<CR>
 258 nnoremap <silent> <Leader>2 :2buffer<CR>
 259 nnoremap <silent> <Leader>3 :3buffer<CR>
 260 nnoremap <silent> <Leader>4 :4buffer<CR>
 261 nnoremap <silent> <Leader>5 :5buffer<CR>
 262 nnoremap <silent> <Leader>6 :6buffer<CR>
 263 nnoremap <silent> <Leader>7 :7buffer<CR>
 264 nnoremap <silent> <Leader>8 :8buffer<CR>
 265 nnoremap <silent> <Leader>9 :9buffer<CR>
 266 nnoremap <silent> <Leader>0 :10buffer<CR>
 267
 268 " Make last active window the only window. Similar to <C-W> o.
 269 nnoremap <C-W>O <C-W>p<C-W>o
 270
 271 " Maps to change spell language between English and German and disable spell
 272 " checking.
 273 if exists('+spell')
 274     noremap <silent> <Leader>sn :set nospell<CR>
 275     noremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 276     noremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 277 endif
 278
 279 " Add semicolon to the end of the line. Thanks to
 280 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 281 " on Freenode for an improved version which doesn't clobber any marks.
 282 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 283
 284 " * and # for selections in visual mode. Thanks to
 285 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 286 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 287 if has('eval')
 288     function! s:VSetSearch()
 289         let l:temp = @@
 290         normal! gvy
 291         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 292         let @@ = l:temp
 293     endfunction
 294     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 295     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 296 endif
 297
 298 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 299 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 300 " mailing list for the commands.
 301 if v:version < 700
 302     cnoreabbrev W w
 303     cnoreabbrev Wa wa
 304     cnoreabbrev Wq wq
 305     cnoreabbrev Wqa wqa
 306 else
 307     cnoreabbrev <expr> W
 308         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 309     cnoreabbrev <expr> Wa
 310         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 311     cnoreabbrev <expr> Wq
 312         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 313     cnoreabbrev <expr> Wqa
 314         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 315 endif
 316 " Also fix my typo with "Q".
 317 if v:version < 700
 318     cnoreabbrev Q q
 319     cnoreabbrev Qa qa
 320 else
 321     cnoreabbrev <expr> Q
 322         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 323     cnoreabbrev <expr> Qa
 324         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 325 endif
 326
 327 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 328 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 329 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 330
 331 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 332 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 333 " Vim's source.
 334 inoremap <C-U> <C-G>u<C-U>
 335 " Same for <C-@> (insert previously inserted text and leave insert mode).
 336 inoremap <C-@> <C-G>u<C-@>
 337 " And for <C-A> (insert previously inserted text).
 338 inoremap <C-A> <C-G>u<C-A>
 339 " And for <C-W> (delete word before cursor).
 340 inoremap <C-W> <C-G>u<C-W>
 341
 342 if has('eval')
 343 " New text-objects ii and ai to work on text with the same indentation. Thanks
 344 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 345 " (visited on 2011-11-19).
 346     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 347     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 348     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 349     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 350
 351     function! s:IndTxtObj(inner)
 352         let curline = line(".")
 353         let lastline = line("$")
 354         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 355         let i = i < 0 ? 0 : i
 356         if getline(".") !~ "^\\s*$"
 357             let p = line(".") - 1
 358             let nextblank = getline(p) =~ "^\\s*$"
 359             while p > 0
 360                     \ && ((i == 0 && !nextblank)
 361                         \ || (i > 0 && ((indent(p) >= i
 362                             \ && !(nextblank && a:inner))
 363                             \ || (nextblank && !a:inner))))
 364                 -
 365                 let p = line(".") - 1
 366                 let nextblank = getline(p) =~ "^\\s*$"
 367             endwhile
 368             normal! 0V
 369             call cursor(curline, 0)
 370             let p = line(".") + 1
 371             let nextblank = getline(p) =~ "^\\s*$"
 372             while p <= lastline
 373                     \ && ((i == 0 && !nextblank)
 374                         \ || (i > 0 && ((indent(p) >= i
 375                             \ && !(nextblank && a:inner))
 376                             \ || (nextblank && !a:inner))))
 377                 +
 378                 let p = line(".") + 1
 379                 let nextblank = getline(p) =~ "^\\s*$"
 380             endwhile
 381             normal! $
 382         endif
 383     endfunction
 384 endif
 385
 386
 387 " ABBREVIATIONS
 388
 389 " Fix some of my spelling mistakes.
 390 iabbrev relle reelle
 391 iabbrev reele reelle
 392
 393
 394 " SYNTAX SETTINGS
 395
 396 " Activate syntax coloring.
 397 if has('syntax')
 398     syntax enable
 399
 400 " Don't highlight more than 500 columns as I normally don't have that long
 401 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 402 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 403     if exists('+synmaxcol')
 404         set synmaxcol=500
 405     endif
 406
 407 " Use (limited) syntax based omni completion if no other omni completion is
 408 " available. Taken from :help ft-syntax-omni.
 409     if has('autocmd') && exists('+omnifunc')
 410         autocmd FileType *
 411             \ if &omnifunc == '' |
 412             \     setlocal omnifunc=syntaxcomplete#Complete |
 413             \ endif
 414     endif
 415
 416 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 417 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 418 " disabled when necessary with :2match (in Vim >= 700).
 419     if exists(':2match')
 420         2match Todo /\%>78v./
 421     else
 422         match Todo /\%>78v./
 423     endif
 424
 425     if exists('*matchadd')
 426 " Highlight some important keywords in all documents.
 427         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 428             call matchadd('Todo', s:x)
 429         endfor
 430
 431 " Highlight unicode whitespace which is no normal whitespace (0x20).
 432         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 433                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 434                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 435                 \ 'feff']
 436             call matchadd('Error', '\%u' . s:x)
 437         endfor
 438     endif
 439
 440 " Settings for specific filetypes.
 441
 442     " Haskell.
 443     let g:hs_highlight_boolean = 1
 444     let g:hs_highlight_types = 1
 445     let g:hs_highlight_more_types = 1
 446
 447     " Perl.
 448     let g:perl_fold = 1
 449     let g:perl_fold_blocks = 1
 450     let g:perl_nofold_packages = 1
 451     let g:perl_include_pod = 1 " syntax coloring for PODs
 452 endif
 453
 454
 455 " PLUGIN SETTINGS
 456
 457 if has('eval')
 458 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 459 " installing/removing/updating plugins simple. (Used for plugins with more
 460 " than one file.)
 461     if v:version >= 700
 462         execute 'call pathogen#runtime_append_all_bundles()'
 463     endif
 464
 465 " Settings for the NERD commenter.
 466     " Don't create any mappings I don't want to use.
 467     let g:NERDCreateDefaultMappings = 0
 468     " Map toggle comment.
 469     map <Leader><Leader> <Plug>NERDCommenterToggle
 470
 471 " XPTemplate settings.
 472     " Try to maintain snippet rendering even after editing outside of a
 473     " snippet.
 474     let g:xptemplate_strict = 0
 475     " Don't complete any braces automatically.
 476     let g:xptemplate_brace_complete = 0
 477     " Only highlight the current placeholder.
 478     let g:xptemplate_highlight = 'current'
 479 endif
 480
 481
 482 " AUTO COMMANDS
 483
 484 " Use a custom auto group to prevent problems when the vimrc files is sourced
 485 " twice.
 486 if has('autocmd')
 487     augroup vimrc
 488 " Remove all autocmds from the current group.
 489         autocmd!
 490
 491 " Go to last position of opened files. Taken from :help last-position-jump.
 492         autocmd BufReadPost *
 493             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 494             \     execute "normal! g'\"" |
 495             \ endif
 496 " But not for Git commits, go to beginning of the file.
 497         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 498
 499 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 500 " when switching to a help buffer which is in the background with :buffer as
 501 " these options are local to windows (and not only to buffers). This happens
 502 " because I often want to use only one window and thus the help buffer is in
 503 " the background.
 504         autocmd BufWinEnter *.txt
 505             \ if &filetype == 'help' |
 506             \     setlocal nolist |
 507             \     setlocal nonumber |
 508             \ endif
 509
 510 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 511 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 512 " want to paste once and then 'paste' gets automatically unset.
 513         if exists('##InsertLeave')
 514             autocmd InsertLeave * set nopaste
 515         endif
 516
 517 " Write file when running :mak[e] before 'makeprg' is called.
 518         autocmd QuickFixCmdPre * write
 519
 520 " AFTER/FTPLUGIN AUTO COMMANDS
 521
 522 " Disable spell checking for files which don't need it.
 523         autocmd FileType deb  setlocal nospell
 524         autocmd FileType diff setlocal nospell
 525         autocmd FileType tar  setlocal nospell
 526 " Fix to allow Vim edit crontab files as crontab doesn't work with
 527 " backupcopy=auto.
 528         autocmd FileType crontab setlocal backupcopy=yes
 529 " Don't use the modeline in git commits as the diff created by `git commit -v`
 530 " may contain one which could change the filetype or other settings of the
 531 " commit buffer. Also make sure we use only 72 characters per line which is
 532 " the recommendation for git commit messages (http://tpope.net/node/106).
 533         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 534                                  \ setlocal textwidth=72
 535 " Use the same comment string as for Vim files in Vimperator files.
 536         autocmd FileType vimperator setlocal commentstring=\"%s
 537 " Use tex compiler for (La)TeX files.
 538         autocmd FileType tex compiler tex
 539
 540 " FTDETECT AUTO COMMANDS
 541
 542 " Recognize .md as markdown files (Vim default is .mkd).
 543         autocmd BufRead,BufNewFile *.md set filetype=mkd
 544 " Recognize .test as Tcl files.
 545         autocmd BufRead,BufNewFile *.test set filetype=tcl
 546
 547 " OTHER AUTO COMMANDS
 548
 549 " Disable spell checking, displaying of list characters and long lines when
 550 " viewing documentation.
 551         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 552
 553 " Use diff filetype for mercurial patches in patch queue.
 554         autocmd BufReadPost */.hg/patches/* set filetype=diff
 555
 556     augroup END
 557 endif
 558
 559
 560 " CUSTOM FUNCTIONS AND COMMANDS
 561
 562 if has('eval')
 563 " Convenient command to see the difference between the current buffer and the
 564 " file it was loaded from, thus the changes you made. Thanks to the
 565 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 566 " for the diffed file than the filetype for the original file.
 567     if !exists(":DiffOrig")
 568         command DiffOrig
 569             \ let s:diff_orig_filetype = &filetype
 570             \ | vertical new
 571             \ | let &filetype = s:diff_orig_filetype
 572             \ | unlet s:diff_orig_filetype
 573             \ | set buftype=nofile
 574             \ | read ++edit #
 575             \ | 0d_
 576             \ | diffthis
 577             \ | wincmd p
 578             \ | diffthis
 579     endif
 580 endif