vimrc

   1 " Vim main configuration file.
   2
   3 " Copyright (C) 2011-2012  Simon Ruderich
   4 "
   5 " This file is free software: you can redistribute it and/or modify
   6 " it under the terms of the GNU General Public License as published by
   7 " the Free Software Foundation, either version 3 of the License, or
   8 " (at your option) any later version.
   9 "
  10 " This file is distributed in the hope that it will be useful,
  11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 " GNU General Public License for more details.
  14 "
  15 " You should have received a copy of the GNU General Public License
  16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 " EDITOR SETTINGS
  20
  21 " Save 'runtimepath' in case it was changed by the system's configuration
  22 " files. Also save 'diff' as set all& resets it; but somehow later (after
  23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
  24 " automagically restored to the correct value.
  25 if has('eval')
  26     let s:save_runtimepath = &runtimepath
  27     let s:save_diff = &diff
  28 endif
  29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  30 " system wide configuration file doesn't change default values.
  31 set all&
  32 " And restore it after all other options were reset.
  33 if has('eval')
  34     let &runtimepath = s:save_runtimepath
  35     let &diff = s:save_diff
  36     unlet s:save_runtimepath
  37     unlet s:save_diff
  38 endif
  39
  40 " Make sure Vim (and not Vi) settings are used.
  41 set nocompatible
  42
  43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
  44 " affect reading files in different encodings, see 'fileencodings' for that.
  45 set encoding=utf-8
  46
  47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  48 " runtime files) if available.
  49 set runtimepath-=~/.vim
  50 set runtimepath^=~/.vim,~/.vim/runtime
  51
  52 " Don't store swap files in the same directory as the edited file.
  53 set directory-=.
  54 " But store them in ~/.tmp if available.
  55 set directory^=~/.tmp
  56
  57 " Disable modelines as they may cause security problems. Instead use
  58 " securemodelines (Vim script #1876).
  59 set nomodeline
  60
  61 " Complete to longest common string (list:longest) and then complete all full
  62 " matches after another (full). Thanks to pbrisbin
  63 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  64 set wildmode=list:longest,full
  65
  66 " Increase history of executed commands (:).
  67 set history=1000
  68
  69 " Increase number of possible undos.
  70 set undolevels=1000
  71
  72 if has('viminfo')
  73     " Remember marks (including the last cursor position) for more files.
  74     set viminfo^='1000
  75 endif
  76
  77 " Use strong encryption if possible, also used for swap/undo files.
  78 if exists('+cryptmethod')
  79     set cryptmethod=blowfish
  80 endif
  81
  82 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
  83 " is used multiple times.
  84 if has('autocmd')
  85     augroup vimrc
  86         autocmd!
  87     augroup END
  88 endif
  89
  90
  91 " EDIT SETTINGS
  92
  93 " Enable automatic file detection, plugin and indention support.
  94 if has('autocmd')
  95     filetype off " necessary for pathogen to force a reload of ftplugins
  96     filetype plugin indent on
  97 endif
  98
  99 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
 100 " existing files.
 101 set fileencodings=utf-8,latin1
 102
 103 " Wrap text after 78 characters.
 104 set textwidth=78
 105
 106 " Set tabs to 4 spaces, use softtabs.
 107 set shiftwidth=4
 108 set softtabstop=4
 109 set expandtab
 110 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
 111 set shiftround
 112 " Use the default value for real tabs.
 113 set tabstop=8
 114
 115 " Enable auto indention.
 116 set autoindent
 117
 118 " When joining lines only add one space after a sentence.
 119 set nojoinspaces
 120
 121 " Allow backspacing over autoindent and line breaks.
 122 set backspace=indent,eol
 123
 124 " Start a comment when hitting enter after a commented line (r) and when using
 125 " o or O around a commented line (o).
 126 set formatoptions+=ro
 127 " Don't break a line if was already longer then 'textwidth' when insert mode
 128 " started.
 129 set formatoptions+=l
 130
 131 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 132 " no character) in visual block mode.
 133 set virtualedit=block
 134
 135 " Already display matches while typing the search command. This makes spotting
 136 " errors easy.
 137 set incsearch
 138
 139 " Activate syntax folding.
 140 if has('folding')
 141     set foldmethod=syntax
 142     set foldcolumn=2
 143     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 144                      " folding which is not what I want
 145 endif
 146
 147 " Only check for case if the searched word contains a capital character.
 148 set ignorecase
 149 set smartcase
 150
 151 " Activate spell checking, use English as default.
 152 if exists('+spell') && has('syntax')
 153     " But not when diffing as spell checking is distracting in this case.
 154     if !&diff
 155         set spell
 156     endif
 157     set spelllang=en_us
 158 endif
 159
 160 " Allow buffers with changes to be hidden. Very important for effective
 161 " editing with multiple buffers.
 162 set hidden
 163
 164
 165 " DISPLAY SETTINGS
 166
 167 " Use a dark background. Doesn't change the background color, only sets text
 168 " colors for a dark terminal.
 169 set background=dark
 170
 171 " Display line numbers.
 172 set number
 173 " But use as little space as necessary for the numbers column. Thanks to James
 174 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 175 if exists('+numberwidth')
 176     set numberwidth=1
 177 endif
 178 " Display the ruler with current line/file position. If 'statusline' is used
 179 " then this only affects <C-G>.
 180 set ruler
 181 " Display partial commands in the status line.
 182 set showcmd
 183
 184 " Don't redraw screen when executing macros; increases speed. Thanks to James
 185 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 186 set lazyredraw
 187
 188 " Visualize the line the cursor is currently in.
 189 if exists('+cursorline')
 190     set cursorline
 191 endif
 192
 193 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
 194 " remove the highlighting until the next search.
 195 set hlsearch
 196
 197 " Display tabs, trailing space, non breakable spaces and long lines (when
 198 " wrapping is disabled).
 199 set list
 200 set listchars=trail:-,extends:>
 201 if v:version >= 700
 202     set listchars+=nbsp:!
 203 endif
 204
 205 if has('statusline')
 206     " Always display the status line even if there is only one window.
 207     set laststatus=2
 208
 209     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
 210     " is the highest buffer number, otherwise return nothing. Used in
 211     " 'statusline' to get an overview of available buffer numbers.
 212     function! StatuslineBufferCount()
 213         let l:bufnr = bufnr('$')
 214         if l:bufnr > 1
 215             let l:result = '/'
 216             if exists('*printf')
 217                 let l:result .= printf('%02d', l:bufnr)
 218             else
 219                 " Older Vims don't have printf() (and no .= either). Emulate
 220                 " "%02d".
 221                 if l:bufnr < 10
 222                     let l:result = l:result . '0'
 223                 endif
 224                 let l:result = l:result . l:bufnr
 225             endif
 226             return l:result
 227         else
 228             return ''
 229         endif
 230     endfunction
 231
 232     set statusline=
 233     " on the left
 234     set statusline+=%02n  " buffer number
 235     set statusline+=%{StatuslineBufferCount()} " highest buffer number
 236     set statusline+=:
 237     set statusline+=%f\   " path to current file in buffer
 238     set statusline+=%h    " [help] if buffer is help file
 239     set statusline+=%w    " [Preview] if buffer is preview buffer
 240     set statusline+=%m    " [+] if buffer was modified,
 241                           " [-] if 'modifiable' is off
 242     set statusline+=%r    " [RO] if buffer is read only
 243
 244     " on the right
 245     set statusline+=%=                " right align
 246     set statusline+=0x%-8B\           " current character under cursor as hex
 247     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 248                                       " column number (%c),
 249                                       " virtual column number if different
 250                                       "                       than %c (%V)
 251     set statusline+=%P                " position in file in percent
 252 endif
 253
 254
 255 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 256
 257 " noremap is used to make sure the right side is executed as is and can't be
 258 " modified by a plugin or other settings. Except for <Nop> which isn't
 259 " affected by mappings.
 260
 261 " Easy way to exit insert mode.
 262 inoremap jj <Esc>
 263 inoremap jk <Esc>
 264 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 265 " (2010-10-15).
 266 cnoremap jj <C-C>
 267 cnoremap jk <C-C>
 268
 269 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 270 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 271 map <Right>  <Nop>
 272 map <Left>   <Nop>
 273 map <Up>     <Nop>
 274 map <Down>   <Nop>
 275 imap <Right> <Nop>
 276 imap <Left>  <Nop>
 277 imap <Up>    <Nop>
 278 imap <Down>  <Nop>
 279 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 280 " below).
 281 cmap <Up>    <Nop>
 282 cmap <Down>  <Nop>
 283 cmap <Right> <Nop>
 284 cmap <Left>  <Nop>
 285
 286 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
 287 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 288 cnoremap <C-P> <Up>
 289 cnoremap <C-N> <Down>
 290
 291 if has('eval')
 292 " Don't move the cursor to the first column for certain scroll commands (<C-F,
 293 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
 294 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
 295 " directly because it also enables that feature for other commands which I
 296 " don't want.
 297
 298     " Set 'nostartofline' for a single movement.
 299     function! s:TemporaryNostartofline(movement)
 300         let l:startofline = &startofline
 301         set nostartofline
 302         execute 'normal! ' . a:movement
 303         let &startofline = l:startofline
 304     endfunction
 305
 306     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
 307     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
 308     nnoremap <silent> <C-F>
 309         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
 310     nnoremap <silent> <C-B>
 311         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
 312     nnoremap <silent> <C-D>
 313         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
 314     nnoremap <silent> <C-U>
 315         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
 316 endif
 317
 318 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
 319 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
 320 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
 321
 322 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
 323 " in #vim on Freenode (2011-08-15 00:17 CEST).
 324 nnoremap <C-G> 2<C-G>
 325
 326 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
 327 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
 328 nmap <Space> <C-F>
 329 nmap - <C-B>
 330
 331 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 332 " (2010-05-16 18:38 CEST) for this idea.
 333 nnoremap <silent> gb :bnext<CR>
 334 nnoremap <silent> gB :bprev<CR>
 335
 336 " Fast access to buffers.
 337 nnoremap <silent> <Leader>1 :1buffer<CR>
 338 nnoremap <silent> <Leader>2 :2buffer<CR>
 339 nnoremap <silent> <Leader>3 :3buffer<CR>
 340 nnoremap <silent> <Leader>4 :4buffer<CR>
 341 nnoremap <silent> <Leader>5 :5buffer<CR>
 342 nnoremap <silent> <Leader>6 :6buffer<CR>
 343 nnoremap <silent> <Leader>7 :7buffer<CR>
 344 nnoremap <silent> <Leader>8 :8buffer<CR>
 345 nnoremap <silent> <Leader>9 :9buffer<CR>
 346 nnoremap <silent> <Leader>0 :10buffer<CR>
 347
 348 " Make last active window the only window. Similar to <C-W> o.
 349 nnoremap <C-W>O <C-W>p<C-W>o
 350
 351 " Maps to change spell language between English and German and disable spell
 352 " checking.
 353 if exists('+spell')
 354     nnoremap <silent> <Leader>sn :set nospell<CR>
 355     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
 356     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
 357 endif
 358
 359 " Add semicolon to the end of the line. Thanks to
 360 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 361 " on Freenode for an improved version which doesn't clobber any marks.
 362 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 363
 364 " * and # for selections in visual mode. Thanks to
 365 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 366 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 367 if has('eval')
 368     function! s:VSetSearch()
 369         let l:temp = @@
 370         normal! gvy
 371         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 372         let @@ = l:temp
 373     endfunction
 374     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 375     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 376 endif
 377
 378 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 379 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 380 " mailing list for the commands.
 381 if v:version < 700
 382     cnoreabbrev W w
 383     cnoreabbrev Wa wa
 384     cnoreabbrev Wq wq
 385     cnoreabbrev Wqa wqa
 386 else
 387     cnoreabbrev <expr> W
 388         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 389     cnoreabbrev <expr> Wa
 390         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 391     cnoreabbrev <expr> Wq
 392         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 393     cnoreabbrev <expr> Wqa
 394         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 395 endif
 396 " Also fix my typo with "Q".
 397 if v:version < 700
 398     cnoreabbrev Q q
 399     cnoreabbrev Qa qa
 400 else
 401     cnoreabbrev <expr> Q
 402         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 403     cnoreabbrev <expr> Qa
 404         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 405 endif
 406
 407 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 408 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 409 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 410
 411 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
 412 " line so the change can be undone. Thanks to the vimrc_example.vim file in
 413 " Vim's source.
 414 inoremap <C-U> <C-G>u<C-U>
 415 " Same for <C-@> (insert previously inserted text and leave insert mode).
 416 inoremap <C-@> <C-G>u<C-@>
 417 " And for <C-A> (insert previously inserted text).
 418 inoremap <C-A> <C-G>u<C-A>
 419 " And for <C-W> (delete word before cursor).
 420 inoremap <C-W> <C-G>u<C-W>
 421
 422 if has('eval')
 423 " New text-objects ii and ai to work on text with the same indentation. Thanks
 424 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
 425 " (visited on 2011-11-19).
 426     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
 427     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
 428     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
 429     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
 430
 431     function! s:IndTxtObj(inner)
 432         let curline = line(".")
 433         let lastline = line("$")
 434         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
 435         let i = i < 0 ? 0 : i
 436         if getline(".") !~ "^\\s*$"
 437             let p = line(".") - 1
 438             let nextblank = getline(p) =~ "^\\s*$"
 439             while p > 0
 440                     \ && ((i == 0 && !nextblank)
 441                         \ || (i > 0 && ((indent(p) >= i
 442                             \ && !(nextblank && a:inner))
 443                             \ || (nextblank && !a:inner))))
 444                 -
 445                 let p = line(".") - 1
 446                 let nextblank = getline(p) =~ "^\\s*$"
 447             endwhile
 448             normal! 0V
 449             call cursor(curline, 0)
 450             let p = line(".") + 1
 451             let nextblank = getline(p) =~ "^\\s*$"
 452             while p <= lastline
 453                     \ && ((i == 0 && !nextblank)
 454                         \ || (i > 0 && ((indent(p) >= i
 455                             \ && !(nextblank && a:inner))
 456                             \ || (nextblank && !a:inner))))
 457                 +
 458                 let p = line(".") + 1
 459                 let nextblank = getline(p) =~ "^\\s*$"
 460             endwhile
 461             normal! $
 462         endif
 463     endfunction
 464 endif
 465
 466
 467 " ABBREVIATIONS
 468
 469 " Fix some of my spelling mistakes.
 470 iabbrev relle reelle
 471 iabbrev reele reelle
 472
 473
 474 " SYNTAX SETTINGS
 475
 476 " Activate syntax coloring.
 477 if has('syntax')
 478     syntax enable
 479
 480 " Don't highlight more than 500 columns as I normally don't have that long
 481 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 482 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 483     if exists('+synmaxcol')
 484         set synmaxcol=500
 485     endif
 486
 487 " Use (limited) syntax based omni completion if no other omni completion is
 488 " available. Taken from :help ft-syntax-omni.
 489     if has('autocmd') && exists('+omnifunc')
 490         augroup vimrc
 491             autocmd FileType *
 492                 \ if &omnifunc == '' |
 493                 \     setlocal omnifunc=syntaxcomplete#Complete |
 494                 \ endif
 495         augroup END
 496     endif
 497
 498 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 499 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 500 " disabled when necessary with :2match (in Vim >= 700).
 501     if exists(':2match')
 502         2match Todo /\%>78v./
 503     else
 504         match Todo /\%>78v./
 505     endif
 506
 507     if exists('*matchadd')
 508 " Highlight some important keywords in all documents.
 509         for s:x in ['TODO', 'XXX', 'FIXME', 'CHANGED', 'REMOVED', 'DELETED']
 510             call matchadd('Todo', s:x)
 511         endfor
 512
 513 " Highlight unicode whitespace which is no normal whitespace (0x20).
 514         for s:x in ['00a0', '1680', '180e', '2000', '2001', '2002', '2003',
 515                 \ '2004', '2005', '2006', '2007', '2008', '2009', '200a',
 516                 \ '200b', '200c', '200d', '202f', '205f', '2060', '3000',
 517                 \ 'feff']
 518             call matchadd('Error', '\%u' . s:x)
 519         endfor
 520     endif
 521
 522 " Settings for specific filetypes.
 523
 524     " Haskell.
 525     let g:hs_highlight_delimiters = 1
 526     let g:hs_highlight_boolean = 1
 527     let g:hs_highlight_types = 1
 528     let g:hs_highlight_more_types = 1
 529     " Perl.
 530     let g:perl_fold = 1
 531     let g:perl_fold_blocks = 1
 532     let g:perl_nofold_packages = 1
 533     let g:perl_include_pod = 1 " syntax coloring for PODs
 534     " Python.
 535     let g:python_highlight_all = 1
 536     " Vim.
 537     let g:vimsyn_embed = 0      " don't highlight embedded languages
 538     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
 539     " XML.
 540     let g:xml_syntax_folding = 1
 541 endif
 542
 543
 544 " PLUGIN SETTINGS
 545
 546 if has('eval')
 547 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 548 " installing/removing/updating plugins simple. (Used for plugins with more
 549 " than one file.)
 550     if v:version >= 700
 551         execute 'call pathogen#runtime_append_all_bundles()'
 552     endif
 553
 554 " Settings for the NERD commenter.
 555     " Don't create any mappings I don't want to use.
 556     let g:NERDCreateDefaultMappings = 0
 557     " Map toggle comment.
 558     map <Leader><Leader> <Plug>NERDCommenterToggle
 559
 560 " XPTemplate settings.
 561     " Try to maintain snippet rendering even after editing outside of a
 562     " snippet.
 563     let g:xptemplate_strict = 0
 564     " Don't complete any braces automatically.
 565     let g:xptemplate_brace_complete = 0
 566     " Only highlight the current placeholder.
 567     let g:xptemplate_highlight = 'current'
 568 endif
 569
 570
 571 " AUTO COMMANDS
 572
 573 " Use a custom auto group to prevent problems when the vimrc files is sourced
 574 " twice.
 575 if has('autocmd')
 576     augroup vimrc
 577
 578 " Go to last position of opened files. Taken from :help last-position-jump.
 579         autocmd BufReadPost *
 580             \ if line("'\"") > 1 && line("'\"") <= line('$') |
 581             \     execute "normal! g'\"" |
 582             \ endif
 583 " But not for Git commits, go to beginning of the file.
 584         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 585
 586 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 587 " when switching to a help buffer which is in the background with :buffer as
 588 " these options are local to windows (and not only to buffers). This happens
 589 " because I often want to use only one window and thus the help buffer is in
 590 " the background.
 591         autocmd BufWinEnter *.txt
 592             \ if &filetype == 'help' |
 593             \     setlocal nolist |
 594             \     setlocal nonumber |
 595             \ endif
 596
 597 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 598 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 599 " want to paste once and then 'paste' gets automatically unset. InsertLeave
 600 " doesn't exist in older Vims.
 601         if exists('##InsertLeave')
 602             autocmd InsertLeave * set nopaste
 603         endif
 604
 605 " Write file when running :mak[e] before 'makeprg' is called. QuickFixCmdPre
 606 " doesn't exist in older Vims.
 607         if exists('##QuickFixCmdPre')
 608             autocmd QuickFixCmdPre * write
 609         endif
 610
 611 " AFTER/FTPLUGIN AUTO COMMANDS
 612
 613 " Disable spell checking for files which don't need it.
 614         autocmd FileType deb  setlocal nospell
 615         autocmd FileType diff setlocal nospell
 616         autocmd FileType tar  setlocal nospell
 617 " Fix to allow Vim edit crontab files as crontab doesn't work with
 618 " backupcopy=auto.
 619         autocmd FileType crontab setlocal backupcopy=yes
 620 " Don't use the modeline in git commits as the diff created by `git commit -v`
 621 " may contain one which could change the filetype or other settings of the
 622 " commit buffer. Also make sure we use only 72 characters per line which is
 623 " the recommendation for git commit messages (http://tpope.net/node/106).
 624         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 625                                  \ setlocal textwidth=72
 626 " Use the same comment string as for Vim files in Vimperator files.
 627         autocmd FileType vimperator setlocal commentstring=\"%s
 628 " Use tex compiler for (La)TeX files.
 629         autocmd FileType tex compiler tex
 630
 631 " FTDETECT AUTO COMMANDS
 632
 633 " Recognize .md as markdown files (Vim default is .mkd).
 634         autocmd BufRead,BufNewFile *.md set filetype=mkd
 635 " Recognize .test as Tcl files.
 636         autocmd BufRead,BufNewFile *.test set filetype=tcl
 637
 638 " OTHER AUTO COMMANDS
 639
 640 " Disable spell checking, displaying of list characters and long lines when
 641 " viewing documentation.
 642         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 643
 644 " Use diff filetype for mercurial patches in patch queue.
 645         autocmd BufReadPost */.hg/patches/* set filetype=diff
 646
 647     augroup END
 648 endif
 649
 650
 651 " CUSTOM FUNCTIONS AND COMMANDS
 652
 653 if has('eval')
 654 " Convenient command to see the difference between the current buffer and the
 655 " file it was loaded from, thus the changes you made. Thanks to the
 656 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
 657 " for the diffed file than the filetype for the original file.
 658     if !exists(':DiffOrig')
 659         command DiffOrig
 660             \ let s:diff_orig_filetype = &filetype
 661             \ | vertical new
 662             \ | let &filetype = s:diff_orig_filetype
 663             \ | unlet s:diff_orig_filetype
 664             \ | set buftype=nofile
 665             \ | read ++edit #
 666             \ | 0d_
 667             \ | diffthis
 668             \ | wincmd p
 669             \ | diffthis
 670     endif
 671 endif