vimrc

   1 " Vim main configuration file.
   2
   3
   4 " EDITOR SETTINGS
   5
   6 " Prevent editing as root as it may cause security problems. Use sudoedit
   7 " instead. Thanks to godlygeek in #vim on Freenode (2009-06-19 22:21 CEST).
   8 if $HOME == '/root' || exists('$SUDO_USER')
   9     echomsg 'Running as root is forbidden! Use sudoedit.'
  10     qall
  11 endif
  12
  13
  14 " Save 'runtimepath' in case it was changed by the system's configuration
  15 " files.
  16 if has('eval')
  17     let s:save_runtimepath = &runtimepath
  18 endif
  19 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
  20 " system wide configuration file doesn't change default values.
  21 set all&
  22 " And restore it after all other options were reset.
  23 if has('eval')
  24     let &runtimepath = s:save_runtimepath
  25 endif
  26
  27 " Make sure Vim (and not Vi) settings are used.
  28 set nocompatible
  29
  30 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
  31 " runtime files).
  32 set runtimepath-=~/.vim
  33 set runtimepath^=~/.vim,~/.vim/runtime
  34
  35 " Don't store swap files in the same directory as the edited file.
  36 set directory-=.
  37 " But store them in ~/.tmp if available.
  38 set directory^=~/.tmp
  39
  40 " Disable modelines as they may cause security problems. Instead use
  41 " securemodelines (Vim script #1876).
  42 set nomodeline
  43
  44 " Complete to longest common string (list:longest) and then complete all full
  45 " matches after another (full). Thanks to pbrisbin
  46 " (http://pbrisbin.com:8080/dotfiles/vimrc).
  47 set wildmode=list:longest,full
  48
  49 " Increase history of executed commands (:).
  50 set history=1000
  51
  52 " Increase number of possible undos.
  53 set undolevels=1000
  54
  55 " Use strong encryption if possible, also used for swap/undo files.
  56 if v:version >= 703
  57     set cryptmethod=blowfish
  58 endif
  59
  60
  61 " EDIT SETTINGS
  62
  63 " Enable automatic file detection, plugin and indention support.
  64 if has('autocmd')
  65     filetype off " necessary for pathogen to force a reload of ftplugins
  66     filetype plugin indent on
  67 endif
  68
  69 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
  70 " existing files.
  71 set fileencodings=utf-8,latin1
  72
  73 " Wrap text after 78 characters.
  74 set textwidth=78
  75
  76 " Set tabs to 4 spaces, use softtabs.
  77 set shiftwidth=4
  78 set softtabstop=4
  79 set expandtab
  80 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
  81 set shiftround
  82 " Use the default value for real tabs.
  83 set tabstop=8
  84
  85 " Enable auto indention.
  86 set autoindent
  87
  88 " When joining lines only add one space after a sentence.
  89 set nojoinspaces
  90
  91 " Allow backspacing over autoindent and line breaks.
  92 set backspace=indent,eol
  93
  94 " Start a comment when hitting enter after a commented line (r) and when using
  95 " o or O around a commented line (o).
  96 set formatoptions+=ro
  97 " Don't break a line if was already longer then 'textwidth' when insert mode
  98 " started.
  99 set formatoptions+=l
 100
 101 " Allow virtual editing (cursor can be positioned anywhere, even when there is
 102 " no character) in visual block mode.
 103 set virtualedit=block
 104
 105 " Already display matches while typing the search command. This makes spotting
 106 " errors easy.
 107 set incsearch
 108
 109 " Activate syntax folding.
 110 if has('folding')
 111     set foldmethod=syntax
 112     set foldcolumn=2
 113     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
 114                      " folding which is not what I want
 115 endif
 116
 117 " Only check for case if the searched word contains a capital character.
 118 set ignorecase
 119 set smartcase
 120
 121 " Activate spell checking, use English as default. Don't use spell checking
 122 " when diffing.
 123 if v:version >= 700 && has('syntax') && !&diff
 124     set spell
 125     set spelllang=en_us
 126 endif
 127
 128 " Allow buffers with changes to be hidden. Very important for effective
 129 " editing with multiple buffers.
 130 set hidden
 131
 132
 133 " DISPLAY SETTINGS
 134
 135 " Use a dark background. Doesn't change the background color, only sets text
 136 " colors for a dark terminal.
 137 set background=dark
 138
 139 " Display line numbers.
 140 set number
 141 " But use as little space as necessary for the numbers column. Thanks to James
 142 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 143 if v:version >= 700
 144     set numberwidth=1
 145 endif
 146 " Display the ruler with current line/file position. If 'statusline' is used
 147 " then this only affects <C-G>.
 148 set ruler
 149 " Display partial commands in the status line.
 150 set showcmd
 151
 152 " Don't redraw screen when executing macros; increases speed. Thanks to James
 153 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 154 set lazyredraw
 155
 156 " Visualize the line the cursor is currently in.
 157 if v:version >= 700
 158     set cursorline
 159 endif
 160
 161 " Display tabs, trailing space, non breakable spaces and long lines (when
 162 " wrapping is disabled).
 163 set list
 164 set listchars=trail:-,extends:>
 165 if v:version >= 700
 166     set listchars+=nbsp:!
 167 endif
 168
 169 if has('statusline')
 170     " Always display the status line even if there is only one window.
 171     set laststatus=2
 172
 173     set statusline=
 174     " on the left
 175     set statusline+=%02n: " buffer number
 176     set statusline+=%f\   " path to current file in buffer
 177     set statusline+=%h    " [help] if buffer is help file
 178     set statusline+=%w    " [Preview] if buffer is preview buffer
 179     set statusline+=%m    " [+] if buffer was modified,
 180                           " [-] if 'modifiable' is off
 181     set statusline+=%r    " [RO] if buffer is read only
 182
 183     " on the right
 184     set statusline+=%=                " right align
 185     set statusline+=0x%-8B\           " current character under cursor as hex
 186     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
 187                                       " column number (%c),
 188                                       " virtual column number if different
 189                                       "                       than %c (%V)
 190     set statusline+=%P                " position in file in percent
 191 endif
 192
 193
 194 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
 195
 196 " Easy way to exit insert mode.
 197 inoremap jj <Esc>
 198 inoremap jk <Esc>
 199 " Also for command mode, thanks to http://github.com/mitechie/pyvim
 200 " (2010-10-15).
 201 cnoremap jj <C-C>
 202 cnoremap jk <C-C>
 203
 204 " Disable arrow keys for all modes except command modes. Thanks to James Vega
 205 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
 206 map <Right>  <Nop>
 207 map <Left>   <Nop>
 208 map <Up>     <Nop>
 209 map <Down>   <Nop>
 210 imap <Right> <Nop>
 211 imap <Left>  <Nop>
 212 imap <Up>    <Nop>
 213 imap <Down>  <Nop>
 214 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
 215 " below).
 216 cmap <Up>    <Nop>
 217 cmap <Down>  <Nop>
 218 cmap <Right> <Nop>
 219 cmap <Left>  <Nop>
 220
 221 " Use Ctrl-P/Ctrl-N as replacement for <Up>/<Down> in command mode. Thanks to
 222 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
 223 cnoremap <C-P> <Up>
 224 cnoremap <C-N> <Down>
 225
 226 " Use <Space> to move down a page and - to move up one like in mutt.
 227 nnoremap <Space> <C-F>
 228 nnoremap - <C-B>
 229
 230 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
 231 " (2010-05-16 18:38 CEST) for this idea.
 232 nnoremap <silent> gb :bnext<CR>
 233 nnoremap <silent> gB :bprev<CR>
 234
 235 " Fast access to buffers.
 236 nnoremap <Leader>1 :1b<CR>
 237 nnoremap <Leader>2 :2b<CR>
 238 nnoremap <Leader>3 :3b<CR>
 239 nnoremap <Leader>4 :4b<CR>
 240 nnoremap <Leader>5 :5b<CR>
 241 nnoremap <Leader>6 :6b<CR>
 242 nnoremap <Leader>7 :7b<CR>
 243 nnoremap <Leader>8 :8b<CR>
 244 nnoremap <Leader>9 :9b<CR>
 245 nnoremap <Leader>0 :10b<CR>
 246
 247 " Make last active window the only window. Similar to <C-w> o.
 248 nnoremap <C-W>O <C-W>p<C-W>o
 249
 250 " Maps to change spell language between English and German and disable spell
 251 " checking.
 252 if v:version >= 700
 253     noremap <Leader>sn :set nospell<CR>
 254     noremap <Leader>se :set spell spelllang=en_us<CR>
 255     noremap <Leader>sd :set spell spelllang=de_de<CR>
 256 endif
 257
 258 " Add semicolon to the end of the line. Thanks to
 259 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
 260 " on Freenode for an improved version which doesn't clobber any marks.
 261 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
 262
 263 " * and # for selections in visual mode. Thanks to
 264 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
 265 " and all nerds involved (godlygeek, strull in #vim on Freenode).
 266 if has('eval')
 267     function! s:VSetSearch()
 268         let temp = @@
 269         normal! gvy
 270         let @/ = '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
 271         let @@ = temp
 272     endfunction
 273     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
 274     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
 275 endif
 276
 277 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
 278 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
 279 " mailing list for the commands.
 280 if v:version < 700
 281     cnoreabbrev W w
 282     cnoreabbrev Wa wa
 283     cnoreabbrev Wq wq
 284     cnoreabbrev Wqa wqa
 285 else
 286     cnoreabbrev <expr> W
 287         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
 288     cnoreabbrev <expr> Wa
 289         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
 290     cnoreabbrev <expr> Wq
 291         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
 292     cnoreabbrev <expr> Wqa
 293         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
 294 endif
 295 " Also fix my typo with "Q".
 296 if v:version < 700
 297     cnoreabbrev Q q
 298     cnoreabbrev Qa qa
 299 else
 300     cnoreabbrev <expr> Q
 301         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
 302     cnoreabbrev <expr> Qa
 303         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
 304 endif
 305
 306 " Make sure xa0 (alt + space) is automatically changed to a normal whitespace
 307 " if pressed accidentally while in insert mode (happens on Mac when alt
 308 " doesn't send escape). filereadable() is necessary for Leopard were 'mac' is
 309 " no longer set on the console.
 310 if has('mac') || filereadable('/Users/.localized')
 311     inoremap <Char-0xa0> <Space>
 312 endif
 313
 314 " Disable Apple style movements in MacVim.
 315 if has('gui_macvim') && has('eval')
 316     let macvim_skip_cmd_opt_movement = 1
 317 endif
 318
 319 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
 320 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
 321 noremap <silent> <C-L> :nohlsearch<CR><C-L>
 322
 323
 324 " ABBREVIATIONS
 325
 326 " Fix some of my spelling mistakes.
 327 iabbrev relle reelle
 328 iabbrev reele reelle
 329
 330
 331 " SYNTAX SETTINGS
 332
 333 " Activate syntax coloring.
 334 if has('syntax')
 335     syntax enable
 336
 337 " Don't highlight more than 500 columns as I normally don't have that long
 338 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
 339 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
 340     set synmaxcol=500
 341
 342 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
 343 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
 344 " disabled when necessary with :2match (in Vim >= 700).
 345     if v:version >= 700
 346         2match Todo /\%>78v./
 347     else
 348         match Todo /\%>78v./
 349     endif
 350
 351 " Highlight TODO, FIXME, CHANGED and XXX in all documents.
 352     if v:version > 701 || (v:version == 701 && has('patch42'))
 353         call matchadd('Todo', '\(TODO\|FIXME\|CHANGED\|XXX\)')
 354     endif
 355 endif
 356
 357
 358 " PLUGIN SETTINGS
 359
 360 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
 361 " installing/removing/updating plugins simple. (Used for plugins with more
 362 " than one file.)
 363 if has('eval')
 364     call pathogen#runtime_append_all_bundles()
 365 endif
 366
 367 " Settings for the NERD commenter.
 368 " Don't create any mappings I don't want to use.
 369 if has('eval')
 370     let NERDCreateDefaultMappings = 0
 371 endif
 372 " Map toggle comment.
 373 map <Leader><Leader> <Plug>NERDCommenterToggle
 374
 375 " XPTemplate settings.
 376 if has('eval')
 377     " Try to maintain snippet rendering even after editing outside of a
 378     " snippet.
 379     let g:xptemplate_strict = 0
 380     " Don't complete any braces automatically.
 381     let g:xptemplate_brace_complete = 0
 382     " Only highlight the current placeholder.
 383     let g:xptemplate_highlight = 'current'
 384 endif
 385
 386
 387 " AUTO COMMANDS
 388
 389 " Use a custom auto group to prevent problems when the vimrc files is sourced
 390 " twice.
 391 if has('autocmd')
 392     augroup vimrc
 393         autocmd!
 394
 395 " Go to last position of opened files. Taken from :help last-position-jump.
 396         autocmd BufReadPost *
 397             \ if line("'\"") > 1 && line("'\"") <= line("$") |
 398             \     execute "normal! g'\"" |
 399             \ endif
 400 " But not for Git commits, go to beginning of the file.
 401         autocmd BufReadPost COMMIT_EDITMSG normal! gg
 402
 403 " Make sure 'list' and 'number' is disabled in help files. This is necessary
 404 " when switching to a help buffer which is in the background with :buffer as
 405 " these options are local to windows (and not only to buffers). This happens
 406 " because I often want to use only one window and thus the help buffer is in
 407 " the background.
 408         autocmd BufWinEnter *.txt
 409             \ if &filetype == 'help' |
 410             \     setlocal nolist |
 411             \     setlocal nonumber |
 412             \ endif
 413
 414 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
 415 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
 416 " want to paste once and then 'paste' gets automatically unset.
 417         autocmd InsertLeave * set nopaste
 418
 419 " AFTER/FTPLUGIN AUTO COMMANDS
 420
 421 " Disable spell checking for files which don't need it.
 422         autocmd FileType deb  setlocal nospell
 423         autocmd FileType diff setlocal nospell
 424         autocmd FileType tar  setlocal nospell
 425 " Fix to allow Vim edit crontab files as crontab doesn't work with
 426 " backupcopy=auto.
 427         autocmd FileType crontab setlocal backupcopy=yes
 428 " Don't use the modeline in git commits as the diff created by `git commit -v`
 429 " may contain one which could change the filetype or other settings of the
 430 " commit buffer. Also make sure we use only 72 characters per line which is
 431 " the recommendation for git commit messages (http://tpope.net/node/106).
 432         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
 433                                  \ setlocal textwidth=72
 434 " Allow folding in perl.
 435         autocmd FileType perl let perl_fold = 1 |
 436                             \ let perl_fold_blocks = 1
 437 " Use the same comment string as for Vim files in Vimperator files.
 438         autocmd FileType vimperator setlocal commentstring=\"%s
 439
 440 " FTDETECT AUTO COMMANDS
 441
 442 " Recognize .md as markdown files (Vim default is .mkd).
 443         autocmd BufRead,BufNewFile *.md set filetype=mkd
 444 " Recognize .test as Tcl files.
 445         autocmd BufRead,BufNewFile *.test set filetype=tcl
 446
 447 " OTHER AUTO COMMANDS
 448
 449 " Disable spell checking, displaying of list characters and long lines when
 450 " viewing documentation.
 451         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
 452
 453 " Use diff filetype for mercurial patches in patch queue.
 454         autocmd BufReadPost */.hg/patches/* set filetype=diff
 455
 456     augroup END
 457 endif