x11/xmonad/xmonad.hs

   1 -- xmonad configuration file.
   2
   3 -- Copyright (C) 2011-2015  Simon Ruderich
   4 --
   5 -- This file is free software: you can redistribute it and/or modify
   6 -- it under the terms of the GNU General Public License as published by
   7 -- the Free Software Foundation, either version 3 of the License, or
   8 -- (at your option) any later version.
   9 --
  10 -- This file is distributed in the hope that it will be useful,
  11 -- but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 -- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 -- GNU General Public License for more details.
  14 --
  15 -- You should have received a copy of the GNU General Public License
  16 -- along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 import XMonad hiding ( (|||) )
  20 import XMonad.Actions.CycleWS (toggleWS)
  21 import XMonad.Hooks.ManageHelpers ((-?>), composeOne)
  22 import XMonad.Hooks.SetWMName (setWMName)
  23 import XMonad.Layout.LayoutCombinators ((|||), JumpToLayout(..))
  24 import XMonad.Layout.Named (named)
  25 import XMonad.Layout.NoBorders (smartBorders)
  26 import XMonad.Layout.TwoPane (TwoPane(..))
  27 import XMonad.Util.EZConfig (additionalKeys)
  28 import qualified XMonad.StackSet as W
  29
  30
  31 -- Prevent new windows from spawning in the master pane. Taken from
  32 -- http://haskell.org/haskellwiki/Xmonad/Frequently_asked_questions on
  33 -- 2009-06-30. Thanks. Modified to not steal focus from the master pane when a
  34 -- new window is created, thanks to vav in #xmonad on Freenode (2010-04-15
  35 -- 21:59 CEST).
  36 avoidMaster :: W.StackSet i l a s sd -> W.StackSet i l a s sd
  37 avoidMaster = W.modify' $ \c -> case c of
  38     W.Stack t [] (r:rs) -> W.Stack r [] (t:rs)
  39     _                   -> c
  40
  41 -- Create my custom layout.
  42 --
  43 -- Only use horizontal (Mirror tiled) and fullscreen layouts, but allow
  44 -- switching to other layouts with bindings.
  45 --
  46 -- The master pane is at the top of the screen. To make sure new windows don't
  47 -- spawn in the master pane avoidMaster (see below) is used. Borders are only
  48 -- drawn when the screen has more then one window (smartBorders).
  49 --
  50 -- Thanks to jrick in #xmonad on Freenode (2009-06-29 22:19 CEST) for telling
  51 -- me how to remove the vertical tiled layout.
  52 --
  53 -- JumpToLayout (from LayoutCombinators) is used to jump to specific layouts,
  54 -- thanks to aavogt in #xmonad on Freenode (2011-06-12 22:13 CEST).
  55 --
  56 -- named is used to name layouts which allows switching to a specific layout
  57 -- (see below), thanks to vav in #xmonad on Freenode (2011-06-12 22:28 CEST).
  58 --
  59 -- The limit layout displays only one window in the lower pane, thanks to to
  60 -- Qantourisc (2010-06-12 15:15 CEST) for the hint to use TwoPane.
  61 myLayoutHook =
  62     named "Default" (smartBorders $ Mirror tiled)
  63         ||| named "Full" (smartBorders Full)
  64         ||| named "Vertical" (smartBorders tiled)
  65         ||| named "Limit" (smartBorders $ Mirror $ TwoPane delta ratio)
  66   where
  67     -- Default tiling algorithm partitions the screen into two panes.
  68     tiled   = Tall nmaster delta ratio
  69     -- The default number of windows in the master pane.
  70     nmaster = 1
  71     -- Percent of screen to increment by when resizing panes.
  72     delta   = 3/100
  73     -- Default proportion of screen occupied by master pane.
  74     ratio   = 1/2
  75
  76 -- Don't spawn new windows in the master pane (which is at the top of the
  77 -- screen). Thanks to dschoepe, aavogt and especially vav in #xmonad on
  78 -- Freenode (2009-06-30 02:10f CEST).
  79 --
  80 -- Also some applications are spawned on specific workspaces. Thanks to
  81 -- dschoepe and ivanm in #xmonad on Freenode (2009-07-12 14:50 CEST).
  82 myManageHook :: ManageHook
  83 myManageHook = composeOne
  84     -- Browser on "2".
  85     [ className =? "Iceweasel"          -?> doF (W.shift "2")
  86     -- Miscellaneous on "3".
  87     , className =? "Wireshark"          -?> doF (W.shift "3")
  88     , title     =? "OpenOffice.org"     -?> doF (W.shift "3") -- splash screen
  89     , className =? "OpenOffice.org 2.4" -?> doF (W.shift "3")
  90     , className =? "Vncviewer"          -?> doF (W.shift "3")
  91     -- Wine on "4".
  92     , className =? "Wine"               -?> doF (W.shift "4")
  93     -- Gimp on "5".
  94     , className =? "Gimp"               -?> doF (W.shift "5")
  95
  96     -- Don't spawn new windows in the master pane.
  97     , return True -?> doF avoidMaster
  98     -- Prevent windows which get moved to other workspaces from removing the
  99     -- focus of the currently selected window. Thanks to vav in #xmonad on
 100     -- Freenode (2010-04-15 21:04 CEST).
 101     , return True -?> doF W.focusDown
 102     ]
 103
 104 -- Switch to next layout, but skip all layouts not in layouts argument. This
 105 -- allows switching to some layouts with mappings but excluding them from
 106 -- meta-space (which gets mapped to this function). Thanks to aavogt in
 107 -- #xmonad on Freenode for this function (2011-06-13 12:45 CEST) and
 108 -- rootzlevel in #xmonad on Freenode for fixes (2011-06-13 15:20 CEST),
 109 -- modified to take list of layouts to switch to, not layouts to exclude.
 110 nextLayoutIncluding :: [String] -> X ()
 111 nextLayoutIncluding layouts = do
 112     cws <- gets (W.workspace . W.current . windowset)
 113     sendMessageWithNoRefresh NextLayout cws
 114     nextLayoutIncluding' layouts 1000 -- nobody has more than 1000 layouts
 115
 116 nextLayoutIncluding' :: [String] -> Int -> X ()
 117 nextLayoutIncluding' layouts iterations = do
 118     cws <- gets (W.workspace . W.current . windowset)
 119     -- iterations prevents an endless loop if no valid layout can be found.
 120     if not ((description $ W.layout cws) `elem` layouts) && iterations > 0
 121         -- Skip over excluded layouts.
 122         then do
 123             sendMessageWithNoRefresh NextLayout cws
 124             nextLayoutIncluding' layouts (iterations - 1)
 125         -- Found allowed layout, show it.
 126         else refresh
 127
 128 -- Use additional workspaces. Access with meta 1,2,..,9,0 for the first ten,
 129 -- meta f1,f2,..,f10 for the second ten workspaces (see mappings below).
 130 myWorkspaces :: [String]
 131 myWorkspaces = map show [1 .. 20 :: Int]
 132
 133 -- Use Windows (= Super) key as main key as it doesn't conflict with any other
 134 -- key bindings.
 135 myModMask :: KeyMask
 136 myModMask = mod4Mask
 137
 138 myKeys :: [((KeyMask, KeySym), X ())]
 139 myKeys = [
 140         -- Switch to next layout, but only use the listed layouts.
 141         ((myModMask, xK_space), nextLayoutIncluding ["Default", "Full"])
 142         -- Switch to vertical tiled layout.
 143       , ((myModMask, xK_v), sendMessage $ JumpToLayout "Vertical")
 144         -- Switch to limit layout which displays only one window in the lower
 145         -- pane.
 146       , ((myModMask, xK_b), sendMessage $ JumpToLayout "Limit")
 147
 148         -- Switch to last active workspace, thanks to moljac024 in #xmonad on
 149         -- Freenode (2010-12-18 14:45 CET).
 150       , ((myModMask, xK_b), toggleWS)
 151
 152       -- Lock the screen.
 153       , ((myModMask, xK_z), spawn "$HOME/.xlockscreen lock")
 154     ]
 155     ++
 156     -- When using multiple screens, switching to another workspace causes
 157     -- xmonad to pull the workspace to the current screen if it was also
 158     -- displayed on another one. This is confusing for me so the following
 159     -- code changes it to just switch to the screen where the workspace is
 160     -- already displayed.
 161     --
 162     -- Thanks to the xmonad FAQ, read on 2010-06-16 13:42 CEST
 163     -- (http://www.haskell.org/haskellwiki/Xmonad/Frequently_asked_questions).
 164     -- Thanks to MrElendig in #xmonad on Freenode (2010-06-17 17:16 CEST) how
 165     -- to use the default xmonad workspaces. Thanks to geekosaur and OODavo in
 166     -- #xmonad on Freenode (2012-12-23 01:14 CET) how to use more workspaces.
 167     [((m .|. myModMask, k), windows $ f i)
 168         | (i, k) <- zip myWorkspaces ([xK_1 .. xK_9] ++ [xK_0] -- 1..9,0
 169                                       ++ [xK_F1 .. xK_F10])    -- f1..f10
 170         , (f, m) <- [(W.view, 0), (W.shift, shiftMask)]]
 171
 172 main :: IO ()
 173 main = xmonad $ defaultConfig
 174     -- Change main key.
 175     { modMask = myModMask
 176     -- Inactive borders are black - invisible on my black screen.
 177     , normalBorderColor = "#000000"
 178     -- Active borders are dark red.
 179     , focusedBorderColor = "#990000"
 180     -- Use my layout and manage hooks (see above).
 181     , layoutHook = myLayoutHook
 182     , manageHook = myManageHook
 183     -- Use unicode rxvt as my terminal.
 184     , terminal = "urxvt"
 185     -- Necessary for Java so it recognizes xmonad as tiling window manager.
 186     , startupHook = setWMName "LG3D"
 187     -- Use more workspaces than the default.
 188     , workspaces = myWorkspaces
 189     }
 190     `additionalKeys` myKeys
 191
 192 -- vim: nospell