zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 149 # doesn't need any space, necessary for correct prompt draw.
 150 local red="%{${fg[red]}%}"
 151 local blue="%{${fg[blue]}%}"
 152 local green="%{${fg[green]}%}"
 153 local yellow="%{${fg[yellow]}%}"
 154 local default="%{${fg[default]}%}"
 155
 156 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 157 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 158 # symbolic link to current checkout of Zsh's sources).
 159 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 160       -d ~/.zsh/functions/vcs_info ]]; then
 161     # Update fpath to allow loading the vcs_info functions.
 162     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 163        fpath=(~/.zsh/functions/vcs_info/
 164               ~/.zsh/functions/vcs_info/Backends
 165               $fpath)
 166     fi
 167
 168     # Load vcs_info to display information about version control repositories.
 169     autoload -Uz vcs_info
 170     # Only look for git and mercurial repositories; the only I use.
 171     zstyle ':vcs_info:*' enable git hg
 172     # Check the repository for changes so they can be used in %u/%c (see
 173     # below). This comes with a speed penalty for bigger repositories.
 174     zstyle ':vcs_info:*' check-for-changes true
 175
 176     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 177     # is displayed. If there is an special action going on (merge, rebase)
 178     # it's also displayed (red). Also display if there are unstaged or staged
 179     # (%u/%c) changes.
 180     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 181           -d ~/.zsh/functions/vcs_info ]]; then
 182         zstyle ':vcs_info:*' formats \
 183             "($green%b%u%c$default:$blue%s$default)"
 184         zstyle ':vcs_info:*' actionformats \
 185             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 186     else
 187         # In older versions %u and %c are not defined yet and are not
 188         # correctly expanded.
 189         zstyle ':vcs_info:*' formats \
 190             "($green%b$default:$blue%s$default)"
 191         zstyle ':vcs_info:*' actionformats \
 192             "($green%b$default/$red%a$default:$blue%s$default)"
 193     fi
 194     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 195     # changes are detected in the repository; check-for-changes must be set to
 196     # true for this to work. Thanks to Bart Trojanowski
 197     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 198     # (2010-03-11 00:20).
 199     zstyle ':vcs_info:*' unstagedstr '¹'
 200     zstyle ':vcs_info:*' stagedstr   '²'
 201
 202     # Default to running vcs_info. If possible we prevent running it later for
 203     # speed reasons. If set to a non empty value vcs_info is run.
 204     FORCE_RUN_VCS_INFO=1
 205
 206     # Cache system inspired by Bart Trojanowski
 207     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 208     #zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 209     +vi-pre-get-data() {
 210         # Only Git and Mercurial support and need caching. Abort if any other
 211         # VCS is used.
 212         [[ "$vcs" != git && "$vcs" != hg ]] && return
 213
 214         # If the shell just started up or we changed directories (or for other
 215         # custom reasons) we must run vcs_info.
 216         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 217             FORCE_RUN_VCS_INFO=
 218             return
 219         fi
 220
 221         # Don't run vcs_info by default to speed up the shell.
 222         ret=1
 223         # If a git/hg command was run then run vcs_info as the status might
 224         # need to be updated.
 225         case "$(fc -ln $(($HISTCMD-1)))" in
 226             git* | g\ *)
 227                 ret=0
 228                 ;;
 229             hg*)
 230                 ret=0
 231                 ;;
 232         esac
 233     }
 234
 235     # Must run vcs_info when changing directories.
 236     prompt_chpwd() {
 237         FORCE_RUN_VCS_INFO=1
 238     }
 239     add-zsh-hook chpwd prompt_chpwd
 240
 241     # Used by prompt code below to determine if vcs_info should be run.
 242     RUN_VCS_INFO=1
 243 else
 244     RUN_VCS_INFO=
 245 fi
 246
 247 # Set the prompt. A two line prompt is used. On the top left the current
 248 # working directory is displayed, on the right vcs_info (if available). On the
 249 # bottom left current user name and host is shown, the exit code of the last
 250 # command if it wasn't 0, the number of running jobs if not 0.
 251 #
 252 # The prompt is in green and blue to make easily detectable, the error exit
 253 # code in red and bold and the job count in yellow.
 254 #
 255 # Thanks to Adam's prompt for the basic idea of this prompt.
 256 prompt_precmd() {
 257     # Regex to remove elements which take no space. Used to calculate the
 258     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 259     # Functions/Prompts/prompt_*_setup.
 260     local zero='%([BSUbfksu]|([FB]|){*})'
 261
 262     # Call vcs_info before every prompt.
 263     if [[ -n $RUN_VCS_INFO ]]; then
 264         vcs_info
 265     else
 266         vcs_info_msg_0_=
 267     fi
 268
 269     local width width_left width_right
 270     local top_left top_right
 271
 272     # Display vcs_info (if used) on the right in the top prompt.
 273     top_right="${vcs_info_msg_0_}"
 274     width_right=${#${(S%%)top_right//$~zero/}}
 275     # Remove vcs_info if it would get too long.
 276     if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
 277         top_right=
 278         width_right=0
 279     fi
 280
 281     # Display current directory on the left in the top prompt. Truncate the
 282     # directory if necessary.
 283     width=$(( COLUMNS - 4 - 1 - width_right ))
 284     top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
 285
 286     # Calculate the width of the top prompt to fill the middle with "-".
 287     width_left=${#${(S%%)top_left//$~zero/}}
 288     width_right=${#${(S%%)top_right//$~zero/}}
 289     width=$(( COLUMNS - width_left - width_right ))
 290
 291     PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
 292 $blue%B'%b$default\
 293 $green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
 294 %(?..($red%B%?%b$default%) )"
 295
 296 }
 297 add-zsh-hook precmd prompt_precmd
 298
 299
 300 # When screen, xterm or rxvt is used set the name of the window to the
 301 # currently running program.
 302 #
 303 # When a program is started preexec() sets the window's name to it; when it
 304 # stops precmd() resets the window's name to 'zsh'.
 305 #
 306 # It works with screen, xterm and rxvt.
 307 #
 308 # If a command is run with sudo or if the shell is running as root then a ! is
 309 # added at the beginning of the command to make this clear. If a command is
 310 # running on a different computer with ssh a @ is added at the beginning. If
 311 # screen is running on the remote machine instead of @screen @:hostname
 312 # (hostname replaced by the machine's hostname) is displayed. This only works
 313 # if the .zshrc on the server also uses this command.
 314 #
 315 # screen* is necessary as `screen` uses screen.linux for example for a linux
 316 # console.
 317 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 318     # Is set to a non empty value to reset the window name in the next
 319     # precmd() call.
 320     window_reset=yes
 321     # Is set to a non empty value when the shell is running as root.
 322     if [[ $(id -u) -eq 0 ]]; then
 323         window_root=yes
 324     fi
 325
 326     window_preexec() {
 327         # Get the program name with its arguments.
 328         local program_name=$1
 329
 330         # When sudo is used use real program name instead, but with an
 331         # exclamation mark at the beginning (handled below).
 332         local program_sudo=
 333         if [[ $program_name == sudo* ]]; then
 334             program_name=${program_name#sudo }
 335             program_sudo=yes
 336         fi
 337         # Remove all arguments from the program name.
 338         program_name=${program_name%% *}
 339
 340         # Ignore often used commands which are only running for a very short
 341         # time. This prevents a "blinking" name when it's changed to "cd" for
 342         # example and then some milliseconds later back to "zsh".
 343         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 344
 345         # Change my shortcuts so the real name of the program is displayed.
 346         case $program_name in
 347             e)
 348                 program_name=elinks
 349                 ;;
 350             g)
 351                 program_name=git
 352                 ;;
 353             m)
 354                 program_name=mutt
 355                 ;;
 356             v)
 357                 program_name=vim
 358                 ;;
 359         esac
 360
 361         # Add an exclamation mark at the beginning if running with sudo or if
 362         # running zsh as root.
 363         if [[ -n $program_sudo || -n $window_root ]]; then
 364             program_name=!$program_name
 365         fi
 366
 367         # Add an at mark at the beginning if running through ssh on a
 368         # different computer.
 369         if [[ -n $SSH_CONNECTION ]]; then
 370             program_name="@$program_name"
 371
 372             # If screen is running in SSH then display "@:hostname" as title
 373             # in the term/outer screen.
 374             if [[ $program_name == @screen ]]; then
 375                 program_name="@:${$(hostname)//.*/}"
 376             # Use "@:!hostname" for root screens.
 377             elif [[ $program_name == @!screen ]]; then
 378                 program_name="@:!${$(hostname)//.*/}"
 379             fi
 380         fi
 381
 382         # Set the window name to the currently running program.
 383         window_title "$program_name"
 384
 385         # Tell precmd() to reset the window name when the program stops.
 386         window_reset=yes
 387     }
 388
 389     window_precmd() {
 390         # Abort if no window name reset is necessary.
 391         [[ -z $window_reset ]] && return
 392
 393         # Reset the window name to 'zsh'.
 394         local name=zsh
 395         # If the function was called with an argument then reset the window
 396         # name to '.zsh' (used by clear alias).
 397         if [[ -n $1 ]]; then
 398             name=.zsh
 399         fi
 400
 401         # Prepend prefixes like in window_preexec().
 402         if [[ -n $window_root ]]; then
 403             name="!$name"
 404         fi
 405         if [[ -n $SSH_CONNECTION ]]; then
 406             name="@$name"
 407         fi
 408         window_title $name
 409
 410         # Just reset the name, so no screen reset necessary for the moment.
 411         window_reset=
 412     }
 413
 414     # Sets the window title. Works with screen, xterm and rxvt. (V) escapes
 415     # all non-printable characters. Thanks to Mikachu in #zsh on Freenode
 416     # (2010-08-07 17:09 CEST).
 417     if [[ $TERM == screen* ]]; then
 418         window_title() {
 419             print -n "\ek${(V)1}\e\\"
 420         }
 421     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 422         window_title() {
 423             print -n "\e]2;${(V)1}\e\\"
 424         }
 425     else
 426         # Fallback if another TERM is used.
 427         window_title() { }
 428     fi
 429
 430     # Add the preexec() and precmd() hooks.
 431     add-zsh-hook preexec window_preexec
 432     add-zsh-hook precmd window_precmd
 433 else
 434     # Fallback if another TERM is used, necessary to run screen (see below in
 435     # "RUN COMMANDS").
 436     window_preexec() { }
 437 fi
 438
 439
 440 # COMPLETION SETTINGS
 441
 442 # Load the complist module which provides additions to completion lists
 443 # (coloring, scrollable).
 444 zmodload zsh/complist
 445 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 446 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 447 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 448 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 449
 450 # Use cache to speed up completions.
 451 zstyle ':completion:*' use-cache on
 452 zstyle ':completion:*' cache-path ~/.zsh/cache
 453
 454 # Complete arguments and fix spelling mistakes when possible.
 455 zstyle ':completion:*' completer _complete _match _correct _approximate
 456
 457 # Make sure the list of possible completions is displayed after pressing <TAB>
 458 # the first time.
 459 setopt nolistambiguous
 460 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 461 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 462 bindkey '^I' expand-or-complete-prefix
 463 # Try uppercase if the currently typed string doesn't match. This allows
 464 # typing in lowercase most of the time and completion fixes the case.
 465 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 466
 467 # Use ls like colors for completions.
 468 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 469
 470 # Make completion lists scrollable so "do you wish to see all n possibilities"
 471 # is no longer displayed.
 472 zstyle ':completion:*' list-prompt '%p'
 473 # Display group name (like 'external command', 'alias', etc.) when there are
 474 # multiple matches in bold.
 475 zstyle ':completion:*' format '    %B%d%b:'
 476 # Display different types of matches separately.
 477 zstyle ':completion:*' group-name ''
 478
 479 # Ignore completion functions.
 480 zstyle ':completion:*:functions' ignored-patterns '_*'
 481 # Ignore parent directory.
 482 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 483 # Always complete one value (file name) only once in the current line. This
 484 # makes it easy to complete multiple values because I can just press tab to
 485 # get all possible values. Otherwise I would have to skip the first value
 486 # again and again.
 487 zstyle ':completion:*' ignore-line yes
 488 # Except for mv and cp, because I often want to use to similar names, so I
 489 # complete to the same and change it.
 490 zstyle ':completion:*:(mv|cp):*' ignore-line no
 491 # Don't complete ./config.* files, this makes running ./configure much
 492 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54)
 493 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 494
 495 # Provide a fallback completer which always completes files. Useful when Zsh's
 496 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 497 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 498 zle -C complete-files complete-word _generic
 499 zstyle ':completion:complete-files:*' completer _files
 500 bindkey '^F' complete-files
 501
 502
 503 # CUSTOM ALIASES AND FUNCTIONS
 504
 505 # If ^C is pressed while typing a command, add it to the history so it can be
 506 # easily retrieved later and then abort like ^C normally does. This is useful
 507 # when I want to abort an command to do something in between and then finish
 508 # typing the command.
 509 #
 510 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 511 # starting with - don't cause errors; and to Nadav Har'El
 512 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 513 # correctly, both on the Zsh mailing list.
 514 TRAPINT() {
 515     # Store the current buffer in the history.
 516     zle && print -s -r -- $BUFFER
 517
 518     # Return the default exit code so Zsh aborts the current command.
 519     return $1
 520 }
 521
 522 # Colorize stderr in red. Very useful when looking for errors. Thanks to
 523 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 524 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 525 # perfect and doesn't work with su and git for example, but it can handle most
 526 # interactive output quite well (even with no trailing new line) and in cases
 527 # it doesn't work, the E alias can be used as workaround.
 528 exec 2>>(while read -r -k -u 0 line; do
 529     printf '\e[91m%s\e[0m' "$line";
 530     print -n $'\0';
 531 done &)
 532
 533 # Load aliases and similar functions also used by other shells.
 534 if [[ -f ~/.shell/aliases ]]; then
 535     . ~/.shell/aliases
 536 fi
 537
 538 # Make sure aliases are expanded when using sudo.
 539 alias sudo='sudo '
 540
 541 # Global aliases for often used commands in the command line.
 542 alias -g E='2>&1'
 543 alias -g L='E | less'
 544 alias -g D='E | colordiff L'
 545 alias -g G='| grep'
 546 alias -g S='| sort'
 547 alias -g U='| uniq'
 548 alias -g H='| head'
 549 alias -g T='| tail'
 550
 551 # Make going up directories simple.
 552 alias -g ...='../..'
 553 alias -g ....='../../..'
 554 alias -g .....='../../../..'
 555
 556 # If the window naming feature is used (see above) then use ".zsh" (leading
 557 # dot) as title name after running clear so it's clear to me that the window
 558 # is empty. I open so much windows that I don't know in which I have something
 559 # important. This helps me to remember which windows are empty (I run clear
 560 # after I finished my work in a window).
 561 if [[ -n $window_reset ]]; then
 562     alias clear='clear; window_reset=yes; window_precmd reset'
 563 fi
 564
 565 # Display all branches (except stash) in gitk but only 200 commits as this is
 566 # much faster. Also put in the background and disown. Thanks to sitaram in
 567 # #git on Freenode (2009-04-20 15:51).
 568 gitk() {
 569     command gitk \
 570         --max-count=200 \
 571         $(git rev-parse --symbolic-full-name --remotes --branches) \
 572         $@ &
 573     disown %command
 574 }
 575 # Same for tig (except the disown part as it's no GUI program).
 576 tig() {
 577     command tig \
 578         --max-count=200 \
 579         $(git rev-parse --symbolic-full-name --remotes --branches) \
 580         $@
 581 }
 582
 583
 584 # OS SPECIFIC SETTINGS
 585
 586 local uname=$(uname)
 587
 588 if [[ $uname == Linux ]]; then
 589     # Settings when creating Debian packages.
 590     DEBEMAIL=simon@ruderich.org
 591     export DEBEMAIL
 592     DEBFULLNAME='Simon Ruderich'
 593     export DEBFULLNAME
 594
 595 elif [[ $uname == Darwin ]]; then # Mac OS X
 596     # Store the current clipboard in CLIPBOARD before every command so it can
 597     # be used in commands.
 598     os_darwin_preexec() {
 599         export CLIPBOARD="$(pbpaste)"
 600     }
 601     # Add the function as preexec hook.
 602     add-zsh-hook preexec os_darwin_preexec
 603
 604     # Initialize CLIPBOARD so it's available for completion directly after
 605     # startup.
 606     CLIPBOARD=""
 607     export CLIPBOARD
 608
 609     # Fetch current URL in clipboard with wget.
 610     alias wnc='wget --no-proxy $CLIPBOARD'
 611 fi
 612
 613
 614 # LOAD ADDITIONAL CONFIGURATION FILES
 615
 616 # Load rc file for current hostname (first part before a dot) or rc.local.
 617 source_config ~/.zsh host rc ${$(hostname)//.*/}
 618
 619
 620 # RUN COMMANDS
 621
 622 # If not already in screen reattach to a running session or create a new one.
 623 # This also starts screen one a remote server when connecting through ssh.
 624 if [[ $TERM != dumb && -z $STY ]]; then
 625     # Get running detached sessions.
 626     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 627
 628     # As we exec later we have to set the title here.
 629     window_preexec "screen"
 630
 631     # Create a new session if none is running.
 632     if [[ -z $session ]]; then
 633         exec screen
 634     # Reattach to a running session.
 635     else
 636         exec screen -r $session
 637     fi
 638 fi
 639
 640
 641 source_debug "finished sourcing ~/.zsh/rc"
 642
 643 # vim: ft=zsh