zsh/rc

   1 # Zsh configuration file.
   2
   3 # Copyright (C) 2011-2013  Simon Ruderich
   4 #
   5 # This file is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This file is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 source_debug '. ~/.zsh/rc'
  20
  21
  22 # Warn when creating global variables from inside a function. Needs to be set
  23 # before declaring a function.
  24 setopt warn_create_global
  25
  26
  27 # HELPER FUNCTIONS
  28
  29 # Return the name of the program which is called in the foreground with `fg`.
  30 # $1 is the name of the program (optional). If it's not 'fg' or 'fg *' it's
  31 # returned unchanged.
  32 zshrc_resolve_fg_to_resumed_job_name() {
  33     # $REPLY is used by convention for scalars ($reply for arrays) to return
  34     # values from functions. unset it here to prevent problems when REPLY is
  35     # bound to an integer or similar. Thanks to Mikachu in #zsh on Freenode
  36     # (2012-09-27 17:14 CEST) for this hint.
  37     unset REPLY
  38
  39     # Replace fg with the resumed job name.
  40     if [[ $1 == fg ]]; then
  41         REPLY="${jobtexts[%+]}"
  42     elif [[ $1 == fg\ * ]]; then
  43         REPLY="${jobtexts[${1#fg }]}"
  44     # Normal program, return as is.
  45     else
  46         REPLY="$1"
  47     fi
  48 }
  49
  50
  51 # MISCELLANEOUS SETTINGS
  52
  53 # Prevent warnings.
  54 typeset -g TMOUT
  55 # Load general shell setup commands. NOTE: Expand this when publishing the
  56 # config.
  57 source_config ~/.shell/rc
  58
  59 # Disable beeps.
  60 setopt nobeep
  61
  62 # Prevent overwriting existing files with '> filename', use '>| filename'
  63 # (or >!) instead.
  64 setopt noclobber
  65
  66 # Entering the name of a directory (if it's not a command) will automatically
  67 # cd to that directory.
  68 setopt autocd
  69
  70 # When entering a nonexistent command name automatically try to find a similar
  71 # one.
  72 setopt correct
  73
  74 # Enable zsh's extended glob abilities.
  75 setopt extendedglob
  76
  77 # Don't exit if <C-D> is pressed. Prevents exiting the shell by accident (e.g.
  78 # pressing <C-D> twice).
  79 setopt ignoreeof
  80
  81
  82 # KEY BINDINGS
  83
  84 # Not all bindings are done here, only those not specific to a given section.
  85
  86 # Use Vi(m) style key bindings.
  87 bindkey -v
  88
  89 # Use jk to exit insert mode (jj is too slow).
  90 bindkey 'jk' vi-cmd-mode
  91
  92 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  93 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  94 # Also not in Vi mode.
  95 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  96
  97
  98 # FUNCTION SETTINGS
  99
 100 # Make sure every entry in $fpath is unique.
 101 typeset -U fpath
 102 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
 103 # of a Zsh Git checkout. Use it to get the newest completions if available.
 104 if [[ -d ~/.zsh/functions/completion ]]; then
 105     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
 106 fi
 107 # Set correct fpath to allow loading my functions (including completion
 108 # functions).
 109 fpath=(~/.zsh/functions $fpath)
 110 # Autoload my functions (except completion functions and hidden files). Thanks
 111 # to caphuso from the Zsh example files for this idea.
 112 if [[ -d ~/.zsh/functions ]]; then
 113     autoload -Uz ${fpath[1]}/^_*(^/:t)
 114 fi
 115
 116 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
 117 # the moment only precmd(), preexec() and chpwd() are simulated.
 118 if [[ $ZSH_VERSION != (4.3.<4->*|4.<4->*|<5->*) ]]; then
 119     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
 120     # arrays.
 121     function precmd() {
 122         for function in $precmd_functions; do
 123             $function "$@"
 124         done
 125     }
 126     function preexec() {
 127         for function in $preexec_functions; do
 128             $function "$@"
 129         done
 130     }
 131     function chpwd() {
 132         for function in $chpwd_functions; do
 133             $function "$@"
 134         done
 135     }
 136 fi
 137
 138 # Load zmv (zsh move) which is a powerful file renamer.
 139 autoload -Uz zmv
 140
 141
 142 # HISTORY SETTINGS
 143
 144 # Use history and store it in ~/.zsh/history.
 145 HISTSIZE=50000
 146 SAVEHIST=50000
 147 HISTFILE=~/.zsh/history
 148 # Append to the history file instead of overwriting it and do it immediately
 149 # when a command is executed.
 150 setopt appendhistory
 151 setopt incappendhistory
 152 # If the same command is run multiple times store it only once in the history.
 153 setopt histignoredups
 154 # Don't add lines starting with a space to the history.
 155 setopt histignorespace
 156 # Vim like completions of previous executed commands (also enter Vi-mode). If
 157 # called at the beginning it just recalls old commands (like cursor up), if
 158 # called after typing something, only lines starting with the typed text are
 159 # returned. Very useful to get old commands quickly - in addition to the
 160 # history commands (!..). Thanks to Mikachu in #zsh on Freenode (2010-01-17
 161 # 12:47 CET) for the information how to a use function with bindkey.
 162 zle -N zshrc-vi-history-beginning-search-backward
 163 zshrc-vi-history-beginning-search-backward() {
 164     local not_at_beginning_of_line
 165     if [[ $CURSOR -ne 0 ]]; then
 166         not_at_beginning_of_line=yes
 167     fi
 168
 169     zle history-beginning-search-backward
 170
 171     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 172     # this counters it).
 173     zle vi-cmd-mode
 174     if [[ -n $not_at_beginning_of_line ]]; then
 175         zle vi-forward-char
 176     fi
 177 }
 178 bindkey '^P' zshrc-vi-history-beginning-search-backward
 179 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 180 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 181 # after calling ^P.
 182 bindkey -a '^N' history-beginning-search-forward
 183
 184 # Automatically push cd-ed directories on the directory stack.
 185 setopt autopushd
 186 # Don't push duplicates on the directory stack.
 187 setopt pushdignoredups
 188 # Exchange the meaning of + and - when specifying a directory on the stack.
 189 # This way cd -<Tab> lists the last used directory first, which is more
 190 # natural because cd - goes to the last directory.
 191 setopt pushdminus
 192
 193
 194 # PROMPT SETTINGS
 195
 196 # Use colorized output, necessary for prompts and completions.
 197 autoload -Uz colors && colors
 198
 199 # Necessary for $EPOCHSECONDS, the UNIX time.
 200 zmodload zsh/datetime
 201
 202 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 203 # doesn't need any space, necessary for correct prompt drawing.
 204 local red="%{${fg[red]}%}"
 205 local blue="%{${fg[blue]}%}"
 206 local green="%{${fg[green]}%}"
 207 local yellow="%{${fg[yellow]}%}"
 208 local default="%{${fg[default]}%}"
 209
 210 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 211 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 212 # symbolic link to current checkout of Zsh's sources).
 213 if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
 214       -d ~/.zsh/functions/vcs_info ]]; then
 215     # Update fpath to allow loading the vcs_info functions.
 216     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 217        fpath=(~/.zsh/functions/vcs_info/
 218               ~/.zsh/functions/vcs_info/Backends
 219               $fpath)
 220     fi
 221
 222     # Load vcs_info to display information about version control repositories.
 223     autoload -Uz vcs_info
 224     # Only look for certain VCS.
 225     zstyle ':vcs_info:*' enable git
 226     # Check the repository for changes so they can be used in %u/%c (see
 227     # below). This comes with a speed penalty for bigger repositories.
 228     zstyle ':vcs_info:*' check-for-changes yes
 229
 230     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 231     # is displayed. If there is an special action going on (merge, rebase)
 232     # it's also displayed (red). Also display if there are unstaged or staged
 233     # (%u/%c) changes.
 234     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
 235           -d ~/.zsh/functions/vcs_info ]]; then
 236         zstyle ':vcs_info:*' formats \
 237             "(${green}%b%u%c${default}:${blue}%s${default}%m)" \
 238             "${green}%u%c${default}"
 239         zstyle ':vcs_info:*' actionformats \
 240             "(${green}%b%u%c${default}/${red}%a${default}:${blue}%s${default}%m)" \
 241             "${green}%u%c${default}"
 242     else
 243         # In older versions %u and %c are not defined yet and are not
 244         # correctly expanded.
 245         zstyle ':vcs_info:*' formats \
 246             "(${green}%b${default}:${blue}%s${default})"
 247         zstyle ':vcs_info:*' actionformats \
 248             "(${green}%b${default}/${red}%a${default}:${blue}%s${default})"
 249     fi
 250     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 251     # changes are detected in the repository; check-for-changes must be set to
 252     # true for this to work. Thanks to Bart Trojanowski
 253     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 254     # (2010-03-11 00:20 CET).
 255     zstyle ':vcs_info:*' unstagedstr '¹'
 256     zstyle ':vcs_info:*' stagedstr   '²'
 257
 258     # Default to run vcs_info. If possible we prevent running it later for
 259     # speed reasons. If set to a non empty value vcs_info is run.
 260     zshrc_force_run_vcs_info=1
 261
 262     # Cache system inspired by Bart Trojanowski
 263     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 264     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 265     +vi-pre-get-data() {
 266         # Only Git and Mercurial support and need caching. Abort if any other
 267         # VCS is used.
 268         [[ "$vcs" != git && "$vcs" != hg ]] && return
 269
 270         # If the shell just started up or we changed directories (or for other
 271         # custom reasons) we must run vcs_info.
 272         if [[ -n $zshrc_force_run_vcs_info ]]; then
 273             zshrc_force_run_vcs_info=
 274             return
 275         fi
 276
 277         # Don't run vcs_info by default to speed up the shell.
 278         ret=1
 279         # If a git/hg command was run then run vcs_info as the status might
 280         # need to be updated.
 281         case "$(fc -ln $(($HISTCMD-1)))" in
 282             git* | g\ *)
 283                 ret=0
 284                 ;;
 285             hg*)
 286                 ret=0
 287                 ;;
 288         esac
 289     }
 290
 291     # Display number of WIP stashes (this excludes manually named commits
 292     # which might be used for something else), thanks to
 293     # http://eseth.org/2010/git-in-zsh.html (viewed on 2013-04-27) for the
 294     # idea to display the stash count.
 295     function +vi-git-stashes() {
 296         if [[ -s ${hook_com[base]/.git/refs/stash} ]]; then
 297             local -a stashes
 298             # Thanks to Valodim in #zsh on Freenode (2013-07-01 14:14 CEST)
 299             # for the solution to "grep" the output with (M) and :#(...).
 300             stashes=( ${(M)${(f)"$(git stash list 2>/dev/null)"}:#(*WIP*)} )
 301
 302             if [[ ${#stashes} -gt 0 ]]; then
 303                 hook_com[misc]+=" ${yellow}${#stashes}s${default}"
 304             fi
 305         fi
 306     }
 307
 308     # Apply hooks to Git.
 309     zstyle ':vcs_info:git*+set-message:*' hooks git-stashes
 310
 311     # Must run vcs_info when changing directories.
 312     prompt_chpwd() {
 313         zshrc_force_run_vcs_info=1
 314     }
 315     chpwd_functions+=(prompt_chpwd)
 316
 317     # Used by prompt code below to determine if vcs_info should be run.
 318     zshrc_use_vcs_info=1
 319 else
 320     zshrc_use_vcs_info=
 321 fi
 322
 323 typeset -a zshrc_longrun_data
 324 zshrc_longrun_data=()
 325 # Display runtime in seconds for long running programs (> 60 seconds) and send
 326 # a bell to notify me.
 327 zshrc_longrun_preexec() {
 328     local program="$3"
 329
 330     # Handle fg.
 331     local REPLY
 332     zshrc_resolve_fg_to_resumed_job_name "$program"
 333     program="$REPLY"
 334
 335     # Don't track the time for certain (possible) long running processes which
 336     # need no automatic notification.
 337     for ignore in elinks man mutt vim; do
 338         case $program in
 339             $ignore | $ignore\ *)
 340                 zshrc_longrun_data=()
 341                 return
 342                 ;;
 343         esac
 344     done
 345
 346     zshrc_longrun_data=("$program" $EPOCHSECONDS)
 347 }
 348 zshrc_longrun_precmd() {
 349     # No previous timestamp available or disabled for this command, ignore.
 350     if [[ -z $zshrc_longrun_data ]]; then
 351         return
 352     fi
 353
 354     local difference=$(( EPOCHSECONDS - zshrc_longrun_data[2] ))
 355     if [[ $difference -gt 60 ]]; then
 356         echo
 357         echo -n "${fg[yellow]}"
 358         echo -n "~> ${(V)zshrc_longrun_data[1]} took $difference seconds."
 359         echo -n "${fg[default]}"
 360         echo    "\a" # send bell
 361     fi
 362
 363     # Clear status. Prevents displaying old status information when pressing
 364     # enter with an empty command line.
 365     zshrc_longrun_data=()
 366 }
 367 preexec_functions+=(zshrc_longrun_preexec)
 368 precmd_functions+=(zshrc_longrun_precmd)
 369
 370 # Set the prompt. A two line prompt is used. On the top left the current
 371 # working directory is displayed, on the right vcs_info (if available) and the
 372 # current time in hex. On the bottom left current user name and host is shown,
 373 # the exit code of the last command if it wasn't 0, the number of running jobs
 374 # if not 0.
 375 #
 376 # The prompt is in green and blue to make easily detectable, the error exit
 377 # code in red and bold and the job count in yellow. Designed for dark
 378 # terminals.
 379 #
 380 # Thanks to Adam's prompt for the basic idea of this prompt.
 381 zshrc_prompt_precmd() {
 382     # Regex to remove elements which take no space. Used to calculate the
 383     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 384     # Functions/Prompts/prompt_*_setup.
 385     local zero='%([BSUbfksu]|([FB]|){*})'
 386
 387     # Call vcs_info before every prompt.
 388     if [[ -n $zshrc_use_vcs_info ]]; then
 389         vcs_info
 390     else
 391         vcs_info_msg_0_=
 392         vcs_info_msg_1_=
 393     fi
 394
 395     # Setup. Create variables holding the formatted content.
 396
 397     # Current directory in yellow, truncated if necessary (WIDTH is replaced
 398     # below).
 399     local directory="${yellow}%WIDTH<..<%~%<<${default}"
 400     # Minimal information about the VCS, only displayed if there are
 401     # unstaged/staged changes.
 402     local vcs_staged="${vcs_info_msg_1_}"
 403
 404     # Information about the VCS in this directory.
 405     local vcs="${vcs_info_msg_0_}"
 406     # Current time (seconds since epoch) in Hex in bright blue.
 407     local seconds="${blue}%B0x$(([##16] EPOCHSECONDS))%b${default}"
 408
 409     # User name (%n) in bright green.
 410     local user="${green}%B%n%b${default}"
 411     # Host name (%m) in bright green; underlined if running on a remote system
 412     # through SSH.
 413     local host="${green}%B%m%b${default}"
 414     if [[ -n $SSH_CONNECTION ]]; then
 415         host="%U${host}%u"
 416     fi
 417
 418     # Number of background processes in yellow if not zero.
 419     local background="%(1j.${yellow}%j${default}.)"
 420     # Exit code in bright red in parentheses if not zero.
 421     local exitcode="%(?..(${red}%B%?%b${default}%) )"
 422     # Prompt symbol, % for normal users, # in red for root.
 423     local symbol="%(!.${red}#${default}.%%)"
 424
 425     # Prefix characters in first and second line.
 426     local top_prefix="${blue}%B.-%b${default}"
 427     local bottom_prefix="${blue}%B'%b${default}"
 428
 429     # Combine them to create the prompt.
 430
 431     local top_left="${vcs_staged}"
 432     local top_right="${vcs}(${seconds})"
 433
 434     local width_top_prefix=${#${(S%%)top_prefix//$~zero/}}
 435     local width_top_left=${#${(S%%)top_left//$~zero/}}
 436     local width_top_right=${#${(S%%)top_right//$~zero/}}
 437
 438     # Calculate the maximum width of ${top_left}. -2 are the braces of
 439     # ${top_left}, -1 is one separator from ${top_separator} (we want at least
 440     # one between left and right parts).
 441     local top_left_width_max=$((
 442         COLUMNS - $width_top_prefix
 443                 - $width_top_left - 2
 444                 - 1
 445                 - $width_top_right
 446     ))
 447     # Truncate directory if necessary.
 448     top_left="(${directory/WIDTH/${top_left_width_max}})${top_left}"
 449     width_top_left=${#${(S%%)top_left//$~zero/}}
 450
 451     # Calculate the width of the top prompt to fill the middle with "-".
 452     local width=$((
 453         COLUMNS - width_top_prefix - width_top_left - width_top_right
 454     ))
 455     local top_separator="%B${blue}${(l:${width}::-:)}%b${default}"
 456
 457     PROMPT="${top_prefix}${top_left}${top_separator}${top_right}
 458 ${bottom_prefix}${user}@${host} ${background}${symbol} ${exitcode}"
 459 }
 460 precmd_functions+=(zshrc_prompt_precmd)
 461
 462
 463 # When GNU screen, tmux, xterm or rxvt is used set the name of the window to
 464 # the currently running program.
 465 #
 466 # When a program is started preexec() sets the window's name to it; when it
 467 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
 468 # the window's name to the resumed job.
 469 #
 470 # It works with GNU screen, tmux, xterm and rxvt.
 471 #
 472 # If a command is run with sudo or if the shell is running as root then a ! is
 473 # added at the beginning of the command to make this clear. If a command is
 474 # running on a different computer with ssh a @ is added at the beginning. If
 475 # screen/tmux is running on the remote machine instead of @screen @:hostname
 476 # (or @tmux ..; hostname replaced by the machine's hostname) is displayed.
 477 # This only works if the .zshrc on the server also uses this command.
 478 #
 479 # screen* is necessary as `screen` uses screen.linux for example for a linux
 480 # console.
 481 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 482     # Is set to a non empty value to reset the window name in the next
 483     # precmd() call.
 484     zshrc_window_reset=yes
 485
 486     zshrc_window_preexec() {
 487         # Get the program name with its arguments.
 488         local program_name=$1
 489
 490         # When sudo is used, use real program name instead, but with an
 491         # exclamation mark at the beginning (handled below).
 492         local program_sudo=
 493         if [[ $program_name == sudo* ]]; then
 494             program_name=${program_name#sudo }
 495             program_sudo=yes
 496         fi
 497
 498         # Handle fg.
 499         local REPLY
 500         zshrc_resolve_fg_to_resumed_job_name "$program_name"
 501         program_name="$REPLY"
 502
 503         # Remove all arguments from the program name.
 504         program_name=${program_name%% *}
 505
 506         # Ignore often used commands which are only running for a very short
 507         # time. This prevents a "blinking" name when it's changed to "cd" for
 508         # example and then some milliseconds later back to "zsh".
 509         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
 510
 511         # Change my shortcuts so the real name of the program is displayed.
 512         case $program_name in
 513             e)
 514                 program_name=elinks
 515                 ;;
 516             g)
 517                 program_name=git
 518                 ;;
 519             m)
 520                 program_name=mutt
 521                 ;;
 522             v)
 523                 program_name=vim
 524                 ;;
 525         esac
 526
 527         # Add an exclamation mark at the beginning if running with sudo or if
 528         # running zsh as root.
 529         if [[ -n $program_sudo || $UID -eq 0 ]]; then
 530             program_name=!$program_name
 531         fi
 532
 533         # Add an at mark at the beginning if running through ssh on a
 534         # different computer.
 535         if [[ -n $SSH_CONNECTION ]]; then
 536             program_name="@$program_name"
 537
 538             # If screen is running in SSH then display "@:hostname" as title
 539             # in the term/outer screen.
 540             if [[ $program_name == @screen || $program_name == @tmux ]]; then
 541                 program_name="@:${HOST//.*/}"
 542             # Use "@:!hostname" for root screens.
 543             elif [[ $program_name == @!screen || $program_name == @!tmux ]]; then
 544                 program_name="@:!${HOST//.*/}"
 545             fi
 546         fi
 547
 548         # Set the window name to the currently running program.
 549         zshrc_window_title "$program_name"
 550
 551         # Tell precmd() to reset the window name when the program stops.
 552         zshrc_window_reset=yes
 553     }
 554
 555     zshrc_window_precmd() {
 556         # Abort if no window name reset is necessary.
 557         [[ -z $zshrc_window_reset ]] && return
 558
 559         # Reset the window name to 'zsh'.
 560         local name=zsh
 561         # If the function was called with an argument then reset the window
 562         # name to '.zsh' (used by clear alias).
 563         if [[ -n $1 ]]; then
 564             name=.zsh
 565         fi
 566
 567         # Prepend prefixes like in zshrc_window_preexec().
 568         if [[ $UID -eq 0 ]]; then
 569             name="!$name"
 570         fi
 571         if [[ -n $SSH_CONNECTION ]]; then
 572             name="@$name"
 573         fi
 574         zshrc_window_title $name
 575
 576         # Just reset the name, so no screen reset necessary for the moment.
 577         zshrc_window_reset=
 578     }
 579
 580     # Sets the window title. Works with GNU screen, tmux (which uses screen as
 581     # TERM), xterm and rxvt. (V) escapes all non-printable characters, thanks
 582     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
 583     if [[ $TERM == screen* ]]; then
 584         zshrc_window_title() {
 585             print -n "\ek${(V)1}\e\\"
 586         }
 587     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 588         zshrc_window_title() {
 589             print -n "\e]2;${(V)1}\e\\"
 590         }
 591     else
 592         # Fallback if another TERM is used.
 593         zshrc_window_title() { }
 594     fi
 595
 596     # Add the preexec() and precmd() hooks.
 597     preexec_functions+=(zshrc_window_preexec)
 598     precmd_functions+=(zshrc_window_precmd)
 599 else
 600     # Fallback if another TERM is used, necessary to run screen (see below in
 601     # "RUN COMMANDS").
 602     zshrc_window_preexec() { }
 603 fi
 604
 605
 606 # COMPLETION SETTINGS
 607
 608 # Load the complist module which provides additional features to completion
 609 # lists (coloring, scrolling).
 610 zmodload zsh/complist
 611 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 612 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 613 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
 614 # problem.
 615 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
 616
 617 # Use cache to speed up some slow completions (dpkg, perl modules, etc.).
 618 zstyle ':completion:*' use-cache yes
 619 zstyle ':completion:*' cache-path ~/.zsh/cache
 620
 621 # Let the completion system handle all completions, including expanding of
 622 # shell wildcards (which is handled by other shell mechanisms if the default
 623 # expand-or-complete is used).
 624 bindkey '^I' complete-word
 625 # If there are multiple matches after pressing <Tab> always display them
 626 # immediately without requiring another <Tab>. a<Tab> completes to aa and
 627 # lists aaa, aab, aac as possible completions if the directory contains aaa,
 628 # aab, aac, bbb instead of only completing to aa.
 629 setopt nolistambiguous
 630 # Support completions in the middle of a word, without this option zsh jumps
 631 # to the end of the word before the completion process begins. Is required for
 632 # the _prefix completer.
 633 setopt completeinword
 634
 635 zstyle ':completion:::::' completer \
 636     _expand _complete _prefix _ignored _approximate
 637
 638 # Match specification to be tried when completing items. Each group ('...') is
 639 # tried after another if no matches were found, once matches are found no
 640 # other groups are tried. Thanks to Mikachu in #zsh on Freenode (2012-08-28
 641 # 18:48 CEST) for explanations.
 642 #
 643 # When matching also include the uppercase variant of typed characters
 644 # ('m:{a-z}={A-Z}'); using '' before this group would try the unmodified match
 645 # first, but I prefer to get all matches immediately (e.g. if Makefile and
 646 # makefile exist in the current directory echo m<tab> matches both, with '' it
 647 # would only match makefile because it found one match). This allows typing in
 648 # lowercase most of the time and completion fixes the case, which is faster.
 649 #
 650 # Don't perform these fixes in _approximate to prevent it from changing the
 651 # input too much. Thanks to the book "From Bash to Z Shell" page 249.
 652 zstyle ':completion:*:(^approximate):*' matcher-list 'm:{a-z}={A-Z}'
 653
 654 # Allow one mistake per three characters. Thanks to the book "From Bash to Z
 655 # Shell" page 248.
 656 zstyle -e ':completion:*:approximate:*' max-errors \
 657     'reply=( $(( ($#PREFIX + $#SUFFIX) / 3 )) )'
 658
 659 # Expand shell wildcards to all matching files after <Tab>. echo *<Tab>
 660 # results in a b c if the directory contains the files a, b, c. Thanks to the
 661 # book "From Bash to Z Shell" page 246.
 662 zstyle ':completion:*:expand:*' tag-order all-expansions
 663 # Keep prefixes unexpanded if possible: $HOME/<Tab> doesn't expand $HOME,
 664 # while $HOME<Tab> does.
 665 zstyle ':completion:*:expand:*' keep-prefix yes
 666
 667 # When completing multiple path components display all matching ambiguous
 668 # components. For example /u/s/d/r/README<Tab> lists all matching READMEs
 669 # instead of just the matching paths up to the r/ component. Can be slow if
 670 # there are many matching files.
 671 zstyle ':completion:*' list-suffixes yes
 672
 673 # Use ls-like colors for completions.
 674 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 675
 676 # Make completion lists scrollable so "do you wish to see all n possibilities"
 677 # is no longer displayed. Display current position in percent (%p).
 678 zstyle ':completion:*:default' list-prompt '%p'
 679 # Display group name (%d) (like 'external command', 'alias', etc.), in bold.
 680 # Also display a message if _approximate found errors and no matches were
 681 # found.
 682 zstyle ':completion:*'             format '    %B%d%b:'
 683 zstyle ':completion:*:corrections' format '    %B%d%b (errors: %e)'
 684 zstyle ':completion:*:warnings'    format '    %Bno matches for %d%b'
 685 # Display different types of matches separately.
 686 zstyle ':completion:*' group-name ''
 687
 688 # Separate man pages by section.
 689 zstyle ':completion:*' separate-sections yes
 690
 691 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
 692 # on Freenode for the fix (2010-12-17 13:46 CET).
 693 zle_highlight=(suffix:none)
 694
 695 # Ignore completion functions.
 696 zstyle ':completion:*:functions' ignored-patterns '_*'
 697 # Ignore parent directory.
 698 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 699 # Always complete file names only once in the current line. This makes it easy
 700 # to complete multiple file names because I can just press tab to get all
 701 # possible values. Otherwise I would have to skip the first value again and
 702 # again. Thanks to Mikachu in #zsh on Freenode (2011-08-11 14:42 CEST) for the
 703 # hint to use other. other is necessary so prefix<Tab> lists both prefix and
 704 # prefixrest if the directory contains prefix and prefixrest.
 705 zstyle ':completion:*:all-files' ignore-line other
 706 # Except for mv and cp, because I often want to use to similar names, so I
 707 # complete to the same and change it.
 708 zstyle ':completion:*:(mv|cp):all-files' ignore-line no
 709
 710 # Don't complete ./config.* files, this makes running ./configure much
 711 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
 712 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 713 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
 714 # Freenode (2010-06-06 04:54 CEST). See below for a way to complete them.
 715 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns \
 716     '*.aux' '*.log' '*.pdf' \
 717     '*.class'
 718
 719 # Provide a fallback completer which always completes files. Useful when Zsh's
 720 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 721 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 722 zle -C complete-files complete-word _generic
 723 zstyle ':completion:complete-files:*' completer _files
 724 bindkey '^F' complete-files
 725
 726
 727 # CUSTOM ALIASES AND FUNCTIONS
 728
 729 # If ^C is pressed while typing a command, add it to the history so it can be
 730 # easily retrieved later and then abort like ^C normally does. This is useful
 731 # when I want to abort an command to do something in between and then finish
 732 # typing the command.
 733 #
 734 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 735 # starting with - don't cause errors; and to Nadav Har'El
 736 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 737 # correctly, both on the Zsh mailing list.
 738 TRAPINT() {
 739     # Don't store this line in history if histignorespace is enabled and the
 740     # line starts with a space.
 741     if [[ -o histignorespace && ${BUFFER[1]} = " " ]]; then
 742         return $1
 743     fi
 744
 745     # Store the current buffer in the history.
 746     zle && print -s -r -- $BUFFER
 747
 748     # Return the default exit code so Zsh aborts the current command.
 749     return $1
 750 }
 751
 752 # Load aliases and similar functions also used by other shells.
 753 if [[ -f ~/.shell/aliases ]]; then
 754     . ~/.shell/aliases
 755 fi
 756
 757 # Make sure aliases are expanded when using sudo.
 758 alias sudo='sudo '
 759
 760 # Global aliases for often used redirections.
 761 alias -g E='2>&1'
 762 alias -g N='>/dev/null'
 763 alias -g EN='2>/dev/null'
 764 alias -g L='2>&1 | less'
 765 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
 766 alias -g D='2>&1 | colordiff | less'
 767 # Global aliases for often used commands.
 768 alias -g A='| awk'
 769 alias -g G='| grep'
 770 alias -g H='| head'
 771 alias -g P='| perl'
 772 alias -g S='| sort'
 773 alias -g T='| tail'
 774 alias -g U='| uniq'
 775
 776 # Make going up directories simple.
 777 alias -g ...='../..'
 778 alias -g ....='../../..'
 779 alias -g .....='../../../..'
 780
 781 # If the window naming feature is used (see above) then use ".zsh" (leading
 782 # dot) as title name after running clear so it's clear to me that the window
 783 # is empty. I open so much windows that I don't know in which I have something
 784 # important. This helps me to remember which windows are empty (I run clear
 785 # after I finished my work in a window).
 786 if [[ -n $zshrc_window_reset ]]; then
 787     alias clear='clear; zshrc_window_reset=yes; zshrc_window_precmd reset'
 788 fi
 789
 790
 791 # CUSTOM COMMANDS
 792
 793 # Display all branches (except stash) in gitk but only 200 commits as this is
 794 # much faster. Also put in the background and disown. Thanks to drizzd in #git
 795 # on Freenode (2010-04-03 17:55 CEST).
 796 (( $+commands[gitk] )) && gitk() {
 797     command gitk --max-count=200 --branches --remotes --tags "$@" &
 798     disown %command
 799 }
 800 # Same for tig (except the disown part as it's no GUI program).
 801 (( $+commands[tig] )) && tig() {
 802     command tig --max-count=200 --branches --remotes --tags "$@"
 803 }
 804
 805 # Pipe output through less.
 806 (( $+commands[tree] )) && tree() {
 807     command tree -C "$@" | less
 808 }
 809
 810 # Choose the "best" PDF viewer available: xpdf, then zathura (in the past
 811 # zathura was preferred, but recent versions are completely broken: still no
 812 # working search and no page-wise scrolling anymore). Also setup completion
 813 # for `pdf`.
 814 if (( $+commands[xpdf] )); then
 815     pdf() {
 816         command xpdf "$@" 2>/dev/null &
 817         disown %command
 818     }
 819     compdef _xpdf pdf
 820 elif (( $+commands[zathura] )); then
 821     pdf() {
 822         command zathura "$@" 2>/dev/null &
 823         disown %command
 824     }
 825     # No completion for zathura yet.
 826     compdef _xpdf pdf
 827 fi
 828
 829 # GHCI doesn't use readline, force it if rlwrap is available.
 830 (( $+commands[rlwrap] )) && ghci() {
 831     command rlwrap \
 832         --always-readline --complete-filenames -t dumb \
 833         --histsize 5000 \
 834         --file ~/.shell/rlwrap/ghci \
 835         ghci "$@" 2>&1
 836 }
 837
 838
 839 # OS SPECIFIC SETTINGS
 840
 841 if [[ $OSTYPE == linux* ]]; then
 842     # Settings when creating Debian packages.
 843     export DEBEMAIL=simon@ruderich.org
 844     export DEBFULLNAME='Simon Ruderich'
 845 fi
 846
 847
 848 # LOAD ADDITIONAL CONFIGURATION FILES
 849
 850 # Configuration options for rc.local.
 851
 852 # Multiplexer to use. By default GNU screen is used. Possible values: screen,
 853 # tmux and empty (no multiplexer).
 854 zshrc_use_multiplexer=screen
 855 # Additional arguments for fortune.
 856 zshrc_fortune_arguments=()
 857
 858 source_config ~/.zsh/rc.local
 859
 860
 861 # RUN COMMANDS
 862
 863 # Make sure the multiplexer is available. Otherwise the exec terminates our
 864 # session.
 865 if [[ -n $zshrc_use_multiplexer ]]; then
 866     if ! (( $+commands[$zshrc_use_multiplexer] )); then
 867         echo "Multiplexer '$zshrc_use_multiplexer' not found." >&2
 868         zshrc_use_multiplexer=
 869     fi
 870 fi
 871
 872 # If not already in screen or tmux, reattach to a running session or create a
 873 # new one. This also starts screen/tmux on a remote server when connecting
 874 # through ssh.
 875 if [[ $TERM != dumb && $TERM != linux && -z $STY && -z $TMUX ]]; then
 876     # Get running detached sessions.
 877     if [[ $zshrc_use_multiplexer = screen ]]; then
 878         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 879     elif [[ $zshrc_use_multiplexer = tmux ]]; then
 880         session=$(tmux list-sessions 2>/dev/null \
 881                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
 882     fi
 883
 884     # As we exec later we have to set the title here.
 885     if [[ $zshrc_use_multiplexer = screen ]]; then
 886         zshrc_window_preexec screen
 887     elif [[ $zshrc_use_multiplexer = tmux ]]; then
 888         zshrc_window_preexec tmux
 889     fi
 890
 891     # Create a new session if none is running.
 892     if [[ -z $session ]]; then
 893         if [[ $zshrc_use_multiplexer = screen ]]; then
 894             exec screen
 895         elif [[ $zshrc_use_multiplexer = tmux ]]; then
 896             exec tmux
 897         fi
 898     # Reattach to a running session.
 899     else
 900         if [[ $zshrc_use_multiplexer = screen ]]; then
 901             exec screen -r $session
 902         elif [[ $zshrc_use_multiplexer = tmux ]]; then
 903             exec tmux attach-session -t $session
 904         fi
 905     fi
 906 fi
 907
 908 # Colorize stderr in bold red. Very useful when looking for errors. Thanks to
 909 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 910 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
 911 # yet perfect and doesn't work with su and git for example, but it can handle
 912 # most interactive output quite well (even with no trailing new line) and in
 913 # cases it doesn't work, the E alias can be used as workaround.
 914 #
 915 # Moved in the "run commands" section to prevent one unnecessary zsh process
 916 # when starting GNU screen/tmux (see above).
 917 exec 2>>(while read -r -k -u 0 line; do
 918     printf '\e[91m%s\e[0m' "$line"
 919     print -n $'\0'
 920 done &)
 921
 922 # Display possible log messages from ~/.xinitrc (if `xmessage` wasn't
 923 # installed). No race condition as xinitrc has finished before a shell is
 924 # executed and only one shell is started on login.
 925 if [[ -f ~/.xinitrc.errors ]]; then
 926     echo "${fg_bold[red]}xinitrc failed!${fg_bold[default]}"
 927     echo
 928     cat ~/.xinitrc.errors
 929     rm ~/.xinitrc.errors
 930     echo
 931 fi
 932
 933 # Run the following programs every 4 hours (and when zsh starts).
 934 PERIOD=14400
 935 periodic() {
 936     # Display fortunes.
 937     (( $+commands[fortune] )) && fortune -ac "${zshrc_fortune_arguments[@]}"
 938     # Display reminders.
 939     (( $+commands[rem] )) && [[ -f ~/.reminders ]] && rem -h
 940 }
 941
 942
 943 # RESTART SETTINGS
 944
 945 zmodload -F zsh/stat b:zstat
 946
 947 # Remember startup time. Used to perform automatic restarts when ~/.zshrc is
 948 # modified.
 949 zshrc_startup_time=$EPOCHSECONDS
 950
 951 # Automatically restart Zsh if ~/.zshrc was modified.
 952 zshrc_restart_precmd() {
 953     local stat
 954     if ! zstat -A stat +mtime ~/.zshrc; then
 955         return
 956     fi
 957
 958     # ~/.zshrc wasn't modified, nothing to do.
 959     if [[ $stat -le $zshrc_startup_time ]]; then
 960         return
 961     fi
 962
 963     local startup
 964     strftime -s startup '%Y-%m-%d %H:%M:%S' "$zshrc_startup_time"
 965
 966     echo -n "${fg[magenta]}"
 967     echo -n "~/.zshrc modified since startup ($startup) ... "
 968     echo -n "${fg[default]}"
 969
 970     if [[ -n $zshrc_disable_restart ]]; then
 971         echo 'automatic restart disabled.'
 972         return
 973     fi
 974
 975     # Don't exec if we have background processes because execing will let us
 976     # lose control over them.
 977     if [[ ${#${(k)jobstates}} -ne 0 ]]; then
 978         echo 'active background jobs!'
 979         return
 980     fi
 981
 982     # Try to start a new interactive shell. If it fails, something is wrong.
 983     # Don't kill our current session by execing it.
 984     zsh -i -c 'exit 42'
 985     if [[ $? -ne 42 ]]; then
 986         echo -n "${fg_bold[red]}"
 987         echo 'failed to start new zsh!'
 988         echo -n "${fg_bold[default]}"
 989         return
 990     fi
 991
 992     echo 'restarting zsh.'
 993     echo
 994
 995     exec zsh
 996 }
 997 precmd_functions+=(zshrc_restart_precmd)
 998
 999
1000 source_debug '. ~/.zsh/rc (done)'
1001
1002 # vim: ft=zsh