zsh/rc

   1 # Zsh configuration file.
   2
   3 # Copyright (C) 2011-2012  Simon Ruderich
   4 #
   5 # This file is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This file is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
  17
  18
  19 source_debug ". ~/.zsh/rc"
  20
  21
  22 # HELPER FUNCTIONS
  23
  24 # Return the name of the program which is called in the foreground with `fg`.
  25 # $1 is the name of the program (optional). If it's not 'fg' or 'fg *' it's
  26 # returned unchanged.
  27 resolve_fg_to_resumed_job_name() {
  28     # $REPLY is used by convention for scalars ($reply for arrays) to return
  29     # values from functions. unset it here to prevent problems when REPLY is
  30     # bound to an integer or similar. Thanks to Mikachu in #zsh on Freenode
  31     # (2012-09-27 17:14 CEST) for this hint.
  32     unset REPLY
  33
  34     # Replace fg with the resumed job name.
  35     if [[ $1 == fg ]]; then
  36         REPLY="${jobtexts[%+]}"
  37     elif [[ $1 == fg\ * ]]; then
  38         REPLY="${jobtexts[${1#fg }]}"
  39     # Normal program, return as is.
  40     else
  41         REPLY="$1"
  42     fi
  43 }
  44
  45
  46 # MISCELLANEOUS SETTINGS
  47
  48 # Be paranoid, new files are readable/writable by me only, but not as root.
  49 if [[ $UID -ne 0 ]]; then
  50     umask 077
  51 fi
  52
  53 # Disable beeps.
  54 setopt nobeep
  55
  56 # Prevent overwriting existing files with '> filename', use '>| filename'
  57 # (or >!) instead.
  58 setopt noclobber
  59
  60 # Entering the name of a directory (if it's not a command) will automatically
  61 # cd to that directory.
  62 setopt autocd
  63
  64 # When entering a nonexistent command name automatically try to find a similar
  65 # one.
  66 setopt correct
  67
  68 # Enable zsh's extended glob abilities.
  69 setopt extendedglob
  70
  71 # Don't exit if <C-d> is pressed.
  72 setopt ignoreeof
  73
  74
  75 # KEY BINDINGS
  76
  77 # Not all bindings are done here, only those not specific to a given section.
  78
  79 # Use Vi(m) style key bindings.
  80 bindkey -v
  81
  82 # Use jj and jk to exit insert mode.
  83 bindkey 'jj' vi-cmd-mode
  84 bindkey 'jk' vi-cmd-mode
  85
  86 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  87 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  88 # Also not in Vi mode.
  89 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  90
  91
  92 # FUNCTION SETTINGS
  93
  94 # Make sure every entry in $fpath is unique.
  95 typeset -U fpath
  96 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  97 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  98 if [[ -d ~/.zsh/functions/completion ]]; then
  99     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
 100 fi
 101 # Set correct fpath to allow loading my functions (including completion
 102 # functions).
 103 fpath=(~/.zsh/functions $fpath)
 104 # Autoload my functions (except completion functions and hidden files). Thanks
 105 # to caphuso from the Zsh example files for this idea.
 106 if [[ -d ~/.zsh/functions ]]; then
 107     autoload -Uz ${fpath[1]}/^_*(^/:t)
 108 fi
 109
 110 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
 111 # the moment only precmd(), preexec() and chpwd() are simulated.
 112 if [[ $ZSH_VERSION != (4.3.<4->*|4.<4->*|<5->*) ]]; then
 113     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
 114     # arrays.
 115     function precmd() {
 116         for function in $precmd_functions; do
 117             $function "$@"
 118         done
 119     }
 120     function preexec() {
 121         for function in $preexec_functions; do
 122             $function "$@"
 123         done
 124     }
 125     function chpwd() {
 126         for function in $chpwd_functions; do
 127             $function "$@"
 128         done
 129     }
 130 fi
 131
 132 # Load zmv (zsh move) which is a powerful file renamer.
 133 autoload -Uz zmv
 134
 135
 136 # HISTORY SETTINGS
 137
 138 # Use history and store it in ~/.zsh/history.
 139 HISTSIZE=50000
 140 SAVEHIST=50000
 141 HISTFILE=~/.zsh/history
 142 # Append to the history file instead of overwriting it and do it immediately
 143 # when a command is executed.
 144 setopt appendhistory
 145 setopt incappendhistory
 146 # If the same command is run multiple times store it only once in the history.
 147 setopt histignoredups
 148 # Don't add lines starting with a space to the history.
 149 setopt histignorespace
 150 # Vim like completions of previous executed commands (also enter Vi-mode). If
 151 # called at the beginning it just recalls old commands (like cursor up), if
 152 # called after typing something, only lines starting with the typed text are
 153 # returned. Very useful to get old commands quickly - in addition to the
 154 # history commands (!..). Thanks to Mikachu in #zsh on Freenode (2010-01-17
 155 # 12:47 CET) for the information how to a use function with bindkey.
 156 zle -N my-vi-history-beginning-search-backward
 157 my-vi-history-beginning-search-backward() {
 158     local not_at_beginning_of_line
 159     if [[ $CURSOR -ne 0 ]]; then
 160         not_at_beginning_of_line=yes
 161     fi
 162
 163     zle history-beginning-search-backward
 164
 165     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 166     # this counters it).
 167     zle vi-cmd-mode
 168     if [[ -n $not_at_beginning_of_line ]]; then
 169         zle vi-forward-char
 170     fi
 171 }
 172 bindkey '^P' my-vi-history-beginning-search-backward
 173 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 174 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 175 # after calling ^P.
 176 bindkey -a '^N' history-beginning-search-forward
 177
 178 # Automatically push cd-ed directories on the directory stack.
 179 setopt autopushd
 180 # Don't push duplicates on the directory stack.
 181 setopt pushdignoredups
 182 # Exchange the meaning of + and - when specifying a directory on the stack.
 183 # This way cd -<Tab> lists the last used directory first, which is more
 184 # natural because cd - goes to the last directory.
 185 setopt pushdminus
 186
 187
 188 # PROMPT SETTINGS
 189
 190 # Use colorized output, necessary for prompts and completions.
 191 autoload -Uz colors && colors
 192
 193 # Necessary for $EPOCHSECONDS, the UNIX time.
 194 zmodload zsh/datetime
 195
 196 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 197 # doesn't need any space, necessary for correct prompt drawing.
 198 local red="%{${fg[red]}%}"
 199 local blue="%{${fg[blue]}%}"
 200 local green="%{${fg[green]}%}"
 201 local yellow="%{${fg[yellow]}%}"
 202 local default="%{${fg[default]}%}"
 203
 204 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 205 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 206 # symbolic link to current checkout of Zsh's sources).
 207 if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
 208       -d ~/.zsh/functions/vcs_info ]]; then
 209     # Update fpath to allow loading the vcs_info functions.
 210     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 211        fpath=(~/.zsh/functions/vcs_info/
 212               ~/.zsh/functions/vcs_info/Backends
 213               $fpath)
 214     fi
 215
 216     # Load vcs_info to display information about version control repositories.
 217     autoload -Uz vcs_info
 218     # Only look for git and mercurial repositories; the only I use.
 219     zstyle ':vcs_info:*' enable git hg
 220     # Check the repository for changes so they can be used in %u/%c (see
 221     # below). This comes with a speed penalty for bigger repositories.
 222     zstyle ':vcs_info:*' check-for-changes yes
 223
 224     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 225     # is displayed. If there is an special action going on (merge, rebase)
 226     # it's also displayed (red). Also display if there are unstaged or staged
 227     # (%u/%c) changes.
 228     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
 229           -d ~/.zsh/functions/vcs_info ]]; then
 230         zstyle ':vcs_info:*' formats \
 231             "($green%b%u%c$default:$blue%s$default)"
 232         zstyle ':vcs_info:*' actionformats \
 233             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 234     else
 235         # In older versions %u and %c are not defined yet and are not
 236         # correctly expanded.
 237         zstyle ':vcs_info:*' formats \
 238             "($green%b$default:$blue%s$default)"
 239         zstyle ':vcs_info:*' actionformats \
 240             "($green%b$default/$red%a$default:$blue%s$default)"
 241     fi
 242     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 243     # changes are detected in the repository; check-for-changes must be set to
 244     # true for this to work. Thanks to Bart Trojanowski
 245     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 246     # (2010-03-11 00:20 CET).
 247     zstyle ':vcs_info:*' unstagedstr '¹'
 248     zstyle ':vcs_info:*' stagedstr   '²'
 249
 250     # Default to run vcs_info. If possible we prevent running it later for
 251     # speed reasons. If set to a non empty value vcs_info is run.
 252     FORCE_RUN_VCS_INFO=1
 253
 254     # Cache system inspired by Bart Trojanowski
 255     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 256     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 257     +vi-pre-get-data() {
 258         # Only Git and Mercurial support and need caching. Abort if any other
 259         # VCS is used.
 260         [[ "$vcs" != git && "$vcs" != hg ]] && return
 261
 262         # If the shell just started up or we changed directories (or for other
 263         # custom reasons) we must run vcs_info.
 264         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 265             FORCE_RUN_VCS_INFO=
 266             return
 267         fi
 268
 269         # Don't run vcs_info by default to speed up the shell.
 270         ret=1
 271         # If a git/hg command was run then run vcs_info as the status might
 272         # need to be updated.
 273         case "$(fc -ln $(($HISTCMD-1)))" in
 274             git* | g\ *)
 275                 ret=0
 276                 ;;
 277             hg*)
 278                 ret=0
 279                 ;;
 280         esac
 281     }
 282
 283     # Must run vcs_info when changing directories.
 284     prompt_chpwd() {
 285         FORCE_RUN_VCS_INFO=1
 286     }
 287     chpwd_functions+=(prompt_chpwd)
 288
 289     # Used by prompt code below to determine if vcs_info should be run.
 290     RUN_VCS_INFO=1
 291 else
 292     RUN_VCS_INFO=
 293 fi
 294
 295 typeset -a longrun_data
 296 longrun_data=()
 297 # Display runtime in seconds for long running programs (> 60 seconds) and send
 298 # a bell to notify me.
 299 longrun_preexec() {
 300     local program="$3"
 301
 302     # Handle fg.
 303     local REPLY
 304     resolve_fg_to_resumed_job_name "$program"
 305     program="$REPLY"
 306
 307     # Don't track the time for certain (possible) long running processes which
 308     # need no automatic notification.
 309     for ignore in elinks man mutt vim; do
 310         case $program in
 311             $ignore | $ignore\ *)
 312                 longrun_data=()
 313                 return
 314                 ;;
 315         esac
 316     done
 317
 318     longrun_data=("$program" $EPOCHSECONDS)
 319 }
 320 longrun_precmd() {
 321     # No previous timestamp available or disabled for this command, ignore.
 322     if [[ -z $longrun_data ]]; then
 323         return
 324     fi
 325
 326     local difference=$(( EPOCHSECONDS - longrun_data[2] ))
 327     if [[ $difference -gt 60 ]]; then
 328         echo
 329         echo -n "${fg[yellow]}"
 330         echo -n "~> ${(V)longrun_data[1]} took $difference seconds."
 331         echo -n "${fg[default]}"
 332         echo    "\a" # send bell
 333     fi
 334
 335     # Clear status. Prevents displaying old status information when pressing
 336     # enter with an empty command line.
 337     longrun_data=()
 338 }
 339 preexec_functions+=(longrun_preexec)
 340 precmd_functions+=(longrun_precmd)
 341
 342 # Set the prompt. A two line prompt is used. On the top left the current
 343 # working directory is displayed, on the right vcs_info (if available) and the
 344 # current time in hex. On the bottom left current user name and host is shown,
 345 # the exit code of the last command if it wasn't 0, the number of running jobs
 346 # if not 0.
 347 #
 348 # The prompt is in green and blue to make easily detectable, the error exit
 349 # code in red and bold and the job count in yellow.
 350 #
 351 # Thanks to Adam's prompt for the basic idea of this prompt.
 352 prompt_precmd() {
 353     # Regex to remove elements which take no space. Used to calculate the
 354     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 355     # Functions/Prompts/prompt_*_setup.
 356     local zero='%([BSUbfksu]|([FB]|){*})'
 357
 358     # Call vcs_info before every prompt.
 359     if [[ -n $RUN_VCS_INFO ]]; then
 360         vcs_info
 361     else
 362         vcs_info_msg_0_=
 363     fi
 364
 365     local width width_left width_right
 366     local top_left top_right
 367
 368     # Display the current time in HEX in bright blue and vcs_info (if used) on
 369     # the right in the top prompt.
 370     top_right="$vcs_info_msg_0_($blue%B0x$(([##16] EPOCHSECONDS))%b$default)"
 371     width_right=${#${(S%%)top_right//$~zero/}}
 372     # Remove it if it would get too long.
 373     if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
 374         top_right=
 375         width_right=0
 376     fi
 377
 378     # Display current directory on the left in the top prompt. Truncate the
 379     # directory if necessary.
 380     width=$(( COLUMNS - 4 - 1 - width_right ))
 381     top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
 382
 383     # Calculate the width of the top prompt to fill the middle with "-".
 384     width_left=${#${(S%%)top_left//$~zero/}}
 385     width_right=${#${(S%%)top_right//$~zero/}}
 386     width=$(( COLUMNS - width_left - width_right ))
 387
 388     PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
 389 $blue%B'%b$default\
 390 $green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
 391 %(?..($red%B%?%b$default%) )"
 392 }
 393 precmd_functions+=(prompt_precmd)
 394
 395
 396 # When screen, tmux, xterm or rxvt is used set the name of the window to the
 397 # currently running program.
 398 #
 399 # When a program is started preexec() sets the window's name to it; when it
 400 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
 401 # the window's name to the resumed job.
 402 #
 403 # It works with screen, tmux, xterm and rxvt.
 404 #
 405 # If a command is run with sudo or if the shell is running as root then a ! is
 406 # added at the beginning of the command to make this clear. If a command is
 407 # running on a different computer with ssh a @ is added at the beginning. If
 408 # screen/tmux is running on the remote machine instead of @screen @:hostname
 409 # (or @tmux ..; hostname replaced by the machine's hostname) is displayed.
 410 # This only works if the .zshrc on the server also uses this command.
 411 #
 412 # screen* is necessary as `screen` uses screen.linux for example for a linux
 413 # console.
 414 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 415     # Is set to a non empty value to reset the window name in the next
 416     # precmd() call.
 417     window_reset=yes
 418     # Is set to a non empty value when the shell is running as root.
 419     if [[ $UID -eq 0 ]]; then
 420         window_root=yes
 421     fi
 422
 423     window_preexec() {
 424         # Get the program name with its arguments.
 425         local program_name=$1
 426
 427         # When sudo is used use real program name instead, but with an
 428         # exclamation mark at the beginning (handled below).
 429         local program_sudo=
 430         if [[ $program_name == sudo* ]]; then
 431             program_name=${program_name#sudo }
 432             program_sudo=yes
 433         fi
 434
 435         # Handle fg.
 436         local REPLY
 437         resolve_fg_to_resumed_job_name "$program_name"
 438         program_name="$REPLY"
 439
 440         # Remove all arguments from the program name.
 441         program_name=${program_name%% *}
 442
 443         # Ignore often used commands which are only running for a very short
 444         # time. This prevents a "blinking" name when it's changed to "cd" for
 445         # example and then some milliseconds later back to "zsh".
 446         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
 447
 448         # Change my shortcuts so the real name of the program is displayed.
 449         case $program_name in
 450             e)
 451                 program_name=elinks
 452                 ;;
 453             g)
 454                 program_name=git
 455                 ;;
 456             m)
 457                 program_name=mutt
 458                 ;;
 459             v)
 460                 program_name=vim
 461                 ;;
 462         esac
 463
 464         # Add an exclamation mark at the beginning if running with sudo or if
 465         # running zsh as root.
 466         if [[ -n $program_sudo || -n $window_root ]]; then
 467             program_name=!$program_name
 468         fi
 469
 470         # Add an at mark at the beginning if running through ssh on a
 471         # different computer.
 472         if [[ -n $SSH_CONNECTION ]]; then
 473             program_name="@$program_name"
 474
 475             # If screen is running in SSH then display "@:hostname" as title
 476             # in the term/outer screen.
 477             if [[ $program_name == @screen || $program_name == @tmux ]]; then
 478                 program_name="@:${HOST//.*/}"
 479             # Use "@:!hostname" for root screens.
 480             elif [[ $program_name == @!screen || $program_name == @!tmux ]]; then
 481                 program_name="@:!${HOST//.*/}"
 482             fi
 483         fi
 484
 485         # Set the window name to the currently running program.
 486         window_title "$program_name"
 487
 488         # Tell precmd() to reset the window name when the program stops.
 489         window_reset=yes
 490     }
 491
 492     window_precmd() {
 493         # Abort if no window name reset is necessary.
 494         [[ -z $window_reset ]] && return
 495
 496         # Reset the window name to 'zsh'.
 497         local name=zsh
 498         # If the function was called with an argument then reset the window
 499         # name to '.zsh' (used by clear alias).
 500         if [[ -n $1 ]]; then
 501             name=.zsh
 502         fi
 503
 504         # Prepend prefixes like in window_preexec().
 505         if [[ -n $window_root ]]; then
 506             name="!$name"
 507         fi
 508         if [[ -n $SSH_CONNECTION ]]; then
 509             name="@$name"
 510         fi
 511         window_title $name
 512
 513         # Just reset the name, so no screen reset necessary for the moment.
 514         window_reset=
 515     }
 516
 517     # Sets the window title. Works with screen, tmux (which uses screen as
 518     # TERM), xterm and rxvt. (V) escapes all non-printable characters. Thanks
 519     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
 520     if [[ $TERM == screen* ]]; then
 521         window_title() {
 522             print -n "\ek${(V)1}\e\\"
 523         }
 524     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 525         window_title() {
 526             print -n "\e]2;${(V)1}\e\\"
 527         }
 528     else
 529         # Fallback if another TERM is used.
 530         window_title() { }
 531     fi
 532
 533     # Add the preexec() and precmd() hooks.
 534     preexec_functions+=(window_preexec)
 535     precmd_functions+=(window_precmd)
 536 else
 537     # Fallback if another TERM is used, necessary to run screen (see below in
 538     # "RUN COMMANDS").
 539     window_preexec() { }
 540 fi
 541
 542
 543 # COMPLETION SETTINGS
 544
 545 # Load the complist module which provides additional features to completion
 546 # lists (coloring, scrolling).
 547 zmodload zsh/complist
 548 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 549 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 550 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
 551 # problem.
 552 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
 553
 554 # Use cache to speed up some slow completions (dpkg, perl modules, etc.).
 555 zstyle ':completion:*' use-cache yes
 556 zstyle ':completion:*' cache-path ~/.zsh/cache
 557
 558 # Let the completion system handle all completions, including expanding of
 559 # shell wildcards (which is handled by other shell mechanisms if the default
 560 # expand-or-complete is used).
 561 bindkey '^I' complete-word
 562 # If there are multiple matches after pressing <Tab> always display them
 563 # immediately without requiring another <Tab>. a<Tab> completes to aa and
 564 # lists aaa, aab, aac as possible completions if the directory contains aaa,
 565 # aab, aac, bbb instead of only completing to aa.
 566 setopt nolistambiguous
 567 # Support completions in the middle of a word, without this option zsh jumps
 568 # to the end of the word before the completion process begins. Is required for
 569 # the _prefix completer.
 570 setopt completeinword
 571
 572 zstyle ':completion:::::' completer \
 573     _expand _complete _prefix _ignored _approximate
 574
 575 # Match specification to be tried when completing items. Each group ('...') is
 576 # tried after another if no matches were found, once matches are found no
 577 # other groups are tried. Thanks to Mikachu in #zsh on Freenode (2012-08-28
 578 # 18:48 CEST) for explanations.
 579 #
 580 # When matching also include the uppercase variant of typed characters
 581 # ('m:{a-z}={A-Z}'); using '' before this group would try the unmodified match
 582 # first, but I prefer to get all matches immediately (e.g. if Makefile and
 583 # makefile exist in the current directory echo m<tab> matches both, with '' it
 584 # would only match makefile because it found one match). This allows typing in
 585 # lowercase most of the time and completion fixes the case, which is faster.
 586 #
 587 # Don't perform these fixes in _approximate to prevent it from changing the
 588 # input too much. Thanks to the book "From Bash to Z Shell" page 249.
 589 zstyle ':completion:*:(^approximate):*' matcher-list 'm:{a-z}={A-Z}'
 590
 591 # Allow one mistake per three characters. Thanks to the book "From Bash to Z
 592 # Shell" page 248.
 593 zstyle -e ':completion:*:approximate:*' max-errors \
 594     'reply=( $(( ($#PREFIX + $#SUFFIX) / 3 )) )'
 595
 596 # Expand shell wildcards to all matching files after <Tab>. echo *<Tab>
 597 # results in a b c if the directory contains the files a, b, c. Thanks to the
 598 # book "From Bash to Z Shell" page 246.
 599 zstyle ':completion:*:expand:*' tag-order all-expansions
 600 # Keep prefixes unexpanded if possible: $HOME/<Tab> doesn't expand $HOME,
 601 # while $HOME<Tab> does.
 602 zstyle ':completion:*:expand:*' keep-prefix yes
 603
 604 # When completing multiple path components display all matching ambiguous
 605 # components. For example /u/s/d/r/README<Tab> lists all matching READMEs
 606 # instead of just the matching paths up to the r/ component. Can be slow if
 607 # there are many matching files.
 608 zstyle ':completion:*' list-suffixes yes
 609
 610 # Use ls-like colors for completions.
 611 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 612
 613 # Make completion lists scrollable so "do you wish to see all n possibilities"
 614 # is no longer displayed. Display current position in percent (%p).
 615 zstyle ':completion:*:default' list-prompt '%p'
 616 # Display group name (%d) (like 'external command', 'alias', etc.), in bold.
 617 # Also display a message if _approximate found errors and no matches were
 618 # found.
 619 zstyle ':completion:*'             format '    %B%d%b:'
 620 zstyle ':completion:*:corrections' format '    %B%d%b (errors: %e)'
 621 zstyle ':completion:*:warnings'    format '    %Bno matches for %d%b'
 622 # Display different types of matches separately.
 623 zstyle ':completion:*' group-name ''
 624
 625 # Separate man pages by section.
 626 zstyle ':completion:*' separate-sections yes
 627
 628 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
 629 # on Freenode for the fix (2010-12-17 13:46 CET).
 630 zle_highlight=(suffix:none)
 631
 632 # Ignore completion functions.
 633 zstyle ':completion:*:functions' ignored-patterns '_*'
 634 # Ignore parent directory.
 635 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 636 # Always complete file names only once in the current line. This makes it easy
 637 # to complete multiple file names because I can just press tab to get all
 638 # possible values. Otherwise I would have to skip the first value again and
 639 # again. Thanks to Mikachu in #zsh on Freenode (2011-08-11 14:42 CEST) for the
 640 # hint to use other. other is necessary so prefix<Tab> lists both prefix and
 641 # prefixrest if the directory contains prefix and prefixrest.
 642 zstyle ':completion:*:all-files' ignore-line other
 643 # Except for mv and cp, because I often want to use to similar names, so I
 644 # complete to the same and change it.
 645 zstyle ':completion:*:(mv|cp):all-files' ignore-line no
 646
 647 # Don't complete ./config.* files, this makes running ./configure much
 648 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
 649 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 650 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
 651 # Freenode (2010-06-06 04:54 CEST). See below for a way to complete them.
 652 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns \
 653     '*.aux' '*.log' '*.pdf' \
 654     '*.class'
 655
 656 # Provide a fallback completer which always completes files. Useful when Zsh's
 657 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 658 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 659 zle -C complete-files complete-word _generic
 660 zstyle ':completion:complete-files:*' completer _files
 661 bindkey '^F' complete-files
 662
 663
 664 # CUSTOM ALIASES AND FUNCTIONS
 665
 666 # If ^C is pressed while typing a command, add it to the history so it can be
 667 # easily retrieved later and then abort like ^C normally does. This is useful
 668 # when I want to abort an command to do something in between and then finish
 669 # typing the command.
 670 #
 671 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 672 # starting with - don't cause errors; and to Nadav Har'El
 673 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 674 # correctly, both on the Zsh mailing list.
 675 TRAPINT() {
 676     # Don't store this line in history if histignorespace is enabled and the
 677     # line starts with a space.
 678     if [[ -o histignorespace && ${BUFFER[1]} = " " ]]; then
 679         return $1
 680     fi
 681
 682     # Store the current buffer in the history.
 683     zle && print -s -r -- $BUFFER
 684
 685     # Return the default exit code so Zsh aborts the current command.
 686     return $1
 687 }
 688
 689 # Load aliases and similar functions also used by other shells.
 690 if [[ -f ~/.shell/aliases ]]; then
 691     . ~/.shell/aliases
 692 fi
 693
 694 # Make sure aliases are expanded when using sudo.
 695 alias sudo='sudo '
 696
 697 # Global aliases for often used redirections.
 698 alias -g E='2>&1'
 699 alias -g N='>/dev/null'
 700 alias -g EN='2>/dev/null'
 701 alias -g L='2>&1 | less'
 702 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
 703 alias -g D='2>&1 | colordiff | less'
 704 # Global aliases for often used commands in the command line.
 705 alias -g A='| awk'
 706 alias -g G='| grep'
 707 alias -g H='| head'
 708 alias -g P='| perl'
 709 alias -g S='| sort'
 710 alias -g T='| tail'
 711 alias -g U='| uniq'
 712
 713 # Make going up directories simple.
 714 alias -g ...='../..'
 715 alias -g ....='../../..'
 716 alias -g .....='../../../..'
 717
 718 # If the window naming feature is used (see above) then use ".zsh" (leading
 719 # dot) as title name after running clear so it's clear to me that the window
 720 # is empty. I open so much windows that I don't know in which I have something
 721 # important. This helps me to remember which windows are empty (I run clear
 722 # after I finished my work in a window).
 723 if [[ -n $window_reset ]]; then
 724     alias clear='clear; window_reset=yes; window_precmd reset'
 725 fi
 726
 727
 728 # CUSTOM COMMANDS
 729
 730 # Display all branches (except stash) in gitk but only 200 commits as this is
 731 # much faster. Also put in the background and disown. Thanks to drizzd in #git
 732 # on Freenode (2010-04-03 17:55 CEST).
 733 (( $+commands[gitk] )) && gitk() {
 734     command gitk --max-count=200 --branches --remotes --tags "$@" &
 735     disown %command
 736 }
 737 # Same for tig (except the disown part as it's no GUI program).
 738 (( $+commands[tig] )) && tig() {
 739     command tig --max-count=200 --branches --remotes --tags "$@"
 740 }
 741
 742 # Pipe output through less.
 743 (( $+commands[tree] )) && tree() {
 744     command tree -C "$@" | less
 745 }
 746
 747 # Choose the "best" PDF viewer available: xpdf, then zathura (in the past
 748 # zathura was preferred, but recent versions are completely broken: still no
 749 # working search and no page-wise scrolling anymore). Also setup completion
 750 # for `pdf`.
 751 if (( $+commands[xpdf] )); then
 752     pdf() {
 753         command xpdf "$@" 2>/dev/null &
 754         disown %command
 755     }
 756     compdef _xpdf pdf
 757 elif (( $+commands[zathura] )); then
 758     pdf() {
 759         command zathura "$@" 2>/dev/null &
 760         disown %command
 761     }
 762     # No completion for zathura yet.
 763     compdef _xpdf pdf
 764 fi
 765
 766 # GHCI doesn't use readline, force it if rlwrap is available.
 767 (( $+commands[rlwrap] )) && ghci() {
 768     command rlwrap \
 769         --always-readline --complete-filenames -t dumb \
 770         --histsize 5000 \
 771         --file ~/.shell/rlwrap/ghci \
 772         ghci "$@" 2>&1
 773 }
 774
 775
 776 # OS SPECIFIC SETTINGS
 777
 778 if [[ $OSTYPE == linux* ]]; then
 779     # Settings when creating Debian packages.
 780     DEBEMAIL=simon@ruderich.org
 781     export DEBEMAIL
 782     DEBFULLNAME='Simon Ruderich'
 783     export DEBFULLNAME
 784 fi
 785
 786
 787 # LOAD ADDITIONAL CONFIGURATION FILES
 788
 789 # Configuration option for rc.local to use GNU screen/tmux. By default GNU
 790 # screen is used. Possible values: screen, tmux.
 791 use_multiplexer=screen
 792
 793 source_config ~/.zsh/rc.local
 794
 795
 796 # RUN COMMANDS
 797
 798 # If not already in screen or tmux, reattach to a running session or create a
 799 # new one. This also starts screen/tmux on a remote server when connecting
 800 # through ssh.
 801 if [[ $TERM != dumb && $TERM != linux && -z $STY && -z $TMUX ]]; then
 802     # Get running detached sessions.
 803     if [[ $use_multiplexer = screen ]]; then
 804         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 805     elif [[ $use_multiplexer = tmux ]]; then
 806         session=$(tmux list-sessions 2>/dev/null \
 807                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
 808     fi
 809
 810     # As we exec later we have to set the title here.
 811     if [[ $use_multiplexer = screen ]]; then
 812         window_preexec "screen"
 813     elif [[ $use_multiplexer = tmux ]]; then
 814         window_preexec "tmux"
 815     fi
 816
 817     # Create a new session if none is running.
 818     if [[ -z $session ]]; then
 819         if [[ $use_multiplexer = screen ]]; then
 820             exec screen
 821         elif [[ $use_multiplexer = tmux ]]; then
 822             exec tmux
 823         fi
 824     # Reattach to a running session.
 825     else
 826         if [[ $use_multiplexer = screen ]]; then
 827             exec screen -r $session
 828         elif [[ $use_multiplexer = tmux ]]; then
 829             exec tmux attach-session -t $session
 830         fi
 831     fi
 832 fi
 833
 834 # Colorize stderr in red. Very useful when looking for errors. Thanks to
 835 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 836 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
 837 # yet perfect and doesn't work with su and git for example, but it can handle
 838 # most interactive output quite well (even with no trailing new line) and in
 839 # cases it doesn't work, the E alias can be used as workaround.
 840 #
 841 # Moved in the "run commands" section to prevent one unnecessary zsh process
 842 # when starting screen/tmux (see above).
 843 exec 2>>(while read -r -k -u 0 line; do
 844     printf '\e[91m%s\e[0m' "$line";
 845     print -n $'\0';
 846 done &)
 847
 848 # Run the following programs every 4 hours.
 849 PERIOD=14400
 850 periodic() {
 851     # Display fortunes.
 852     (( $+commands[fortune] )) && fortune -ac
 853     # Display reminders.
 854     (( $+commands[rem] )) && [ -f ~/.reminders ] && rem -h
 855 }
 856
 857
 858 source_debug ". ~/.zsh/rc (done)"
 859
 860 # vim: ft=zsh