zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 149 # doesn't need any space, necessary for correct prompt draw.
 150 local red="%{${fg[red]}%}"
 151 local blue="%{${fg[blue]}%}"
 152 local green="%{${fg[green]}%}"
 153 local yellow="%{${fg[yellow]}%}"
 154 local default="%{${fg[default]}%}"
 155
 156 # Set the default prompt. The current host and working directory is displayed,
 157 # the exit code of the last command if it wasn't 0, the number of running jobs
 158 # if not 0.
 159 #
 160 # The prompt is in green and blue to make easily detectable, the error exit
 161 # code in red and bold and the job count in yellow.
 162 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 163 %(1j.$yellow%j$default.)%# \
 164 %(?..($red%B%?%b$default%) )"
 165
 166 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 167 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 168 # symbolic link to current checkout of Zsh's sources).
 169 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 170       -d ~/.zsh/functions/vcs_info ]]; then
 171     # Update fpath to allow loading the vcs_info functions.
 172     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 173        fpath=(~/.zsh/functions/vcs_info/
 174               ~/.zsh/functions/vcs_info/Backends
 175               $fpath)
 176     fi
 177
 178     # Allow substitutions and expansions in the prompt, necessary for
 179     # vcs_info.
 180     setopt promptsubst
 181     # Load vcs_info to display information about version control repositories.
 182     autoload -Uz vcs_info
 183     # Only look for git and mercurial repositories; the only I use.
 184     zstyle ':vcs_info:*' enable git hg
 185     # Check the repository for changes so they can be used in %u/%c (see
 186     # below). This comes with a speed penalty for bigger repositories.
 187     zstyle ':vcs_info:*' check-for-changes true
 188
 189     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 190     # is displayed. If there is an special action going on (merge, rebase)
 191     # it's also displayed (red). Also display if there are unstaged or staged
 192     # (%u/%c) changes.
 193     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 194           -d ~/.zsh/functions/vcs_info ]]; then
 195         zstyle ':vcs_info:*' formats \
 196             "($green%b%u%c$default:$blue%s$default)"
 197         zstyle ':vcs_info:*' actionformats \
 198             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 199     else
 200         # In older versions %u and %c are not defined yet and are not
 201         # correctly expanded.
 202         zstyle ':vcs_info:*' formats \
 203             "($green%b$default:$blue%s$default)"
 204         zstyle ':vcs_info:*' actionformats \
 205             "($green%b$default/$red%a$default:$blue%s$default)"
 206     fi
 207     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 208     # changes are detected in the repository; check-for-changes must be set to
 209     # true for this to work. Thanks to Bart Trojanowski
 210     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 211     # (2010-03-11 00:20).
 212     zstyle ':vcs_info:*' unstagedstr '¹'
 213     zstyle ':vcs_info:*' stagedstr   '²'
 214
 215     # Call vcs_info as precmd before every prompt.
 216     prompt_precmd() {
 217         vcs_info
 218     }
 219     add-zsh-hook precmd prompt_precmd
 220
 221     # Display the VCS information in the right prompt.
 222     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 223         RPROMPT='${vcs_info_msg_0_}'
 224     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 225     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 226     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 227     else
 228         RPROMPT='${vcs_info_msg_0_:- }'
 229     fi
 230 fi
 231
 232 unset red blue green yellow default
 233
 234 # When screen, xterm or rxvt is used set the name of the window to the
 235 # currently running program.
 236 #
 237 # When a program is started preexec() sets the window's name to it; when it
 238 # stops precmd() resets the window's name to 'zsh'.
 239 #
 240 # It works with screen, xterm and rxvt.
 241 #
 242 # If a command is run with sudo or if the shell is running as root then a ! is
 243 # added at the beginning of the command to make this clear. If a command is
 244 # running on a different computer with ssh a @ is added at the beginning. If
 245 # screen is running on the remote machine instead of @screen @:hostname
 246 # (hostname replaced by the machine's hostname) is displayed. This only works
 247 # if the .zshrc on the server also uses this command.
 248 #
 249 # screen* is necessary as `screen` uses screen.linux for example for a linux
 250 # console.
 251 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 252     # Is set to a non empty value to reset the window name in the next
 253     # precmd() call.
 254     window_reset=yes
 255     # Is set to a non empty value when the shell is running as root.
 256     if [[ $(id -u) -eq 0 ]]; then
 257         window_root=yes
 258     fi
 259
 260     window_preexec() {
 261         # Get the program name with its arguments.
 262         local program_name=$1
 263
 264         # When sudo is used use real program name instead, but with an
 265         # exclamation mark at the beginning (handled below).
 266         local program_sudo=
 267         if [[ $program_name == sudo* ]]; then
 268             program_name=${program_name#sudo }
 269             program_sudo=yes
 270         fi
 271         # Remove all arguments from the program name.
 272         program_name=${program_name%% *}
 273
 274         # Ignore often used commands which are only running for a very short
 275         # time. This prevents a "blinking" name when it's changed to "cd" for
 276         # example and then some milliseconds later back to "zsh".
 277         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 278
 279         # Change my shortcuts so the real name of the program is displayed.
 280         case $program_name in
 281             e)
 282                 program_name=elinks
 283                 ;;
 284             g)
 285                 program_name=git
 286                 ;;
 287             m)
 288                 program_name=mutt
 289                 ;;
 290             v)
 291                 program_name=vim
 292                 ;;
 293         esac
 294
 295         # Add an exclamation mark at the beginning if running with sudo or if
 296         # running zsh as root.
 297         if [[ -n $program_sudo || -n $window_root ]]; then
 298             program_name=!$program_name
 299         fi
 300
 301         # Add an at mark at the beginning if running through ssh on a
 302         # different computer.
 303         if [[ -n $SSH_CONNECTION ]]; then
 304             program_name="@$program_name"
 305
 306             # If screen is running in SSH then display "@:hostname" as title
 307             # in the term/outer screen.
 308             if [[ $program_name == @screen ]]; then
 309                 program_name="@:${$(hostname)//.*/}"
 310             fi
 311         fi
 312
 313         # Set the window name to the currently running program.
 314         window_title "$program_name"
 315
 316         # Tell precmd() to reset the window name when the program stops.
 317         window_reset=yes
 318     }
 319
 320     window_precmd() {
 321         # Abort if no window name reset is necessary.
 322         [[ -z $window_reset ]] && return
 323
 324         # Reset the window name to 'zsh'.
 325         local name=zsh
 326         # If the function was called with an argument then reset the window
 327         # name to '.zsh' (used by clear alias).
 328         if [[ -n $1 ]]; then
 329             name=.zsh
 330         fi
 331
 332         # Prepend prefixes like in window_preexec().
 333         if [[ -n $window_root ]]; then
 334             name="!$name"
 335         fi
 336         if [[ -n $SSH_CONNECTION ]]; then
 337             name="@$name"
 338         fi
 339         window_title $name
 340
 341         # Just reset the name, so no screen reset necessary for the moment.
 342         window_reset=
 343     }
 344
 345     # Sets the window title. Works with screen, xterm and rxvt.
 346     if [[ $TERM == screen* ]]; then
 347         window_title() {
 348             print -n "\ek$1\e\\"
 349         }
 350     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 351         window_title() {
 352             print -n "\e]2;$1\e\\"
 353         }
 354     else
 355         # Fallback if another TERM is used.
 356         window_title() { }
 357     fi
 358
 359     # Add the preexec() and precmd() hooks.
 360     add-zsh-hook preexec window_preexec
 361     add-zsh-hook precmd window_precmd
 362 fi
 363
 364
 365 # COMPLETION SETTINGS
 366
 367 # Load the complist module which provides additions to completion lists
 368 # (coloring, scrollable).
 369 zmodload zsh/complist
 370 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 371 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 372 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 373 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 374
 375 # Use cache to speed up completions.
 376 zstyle ':completion:*' use-cache on
 377 zstyle ':completion:*' cache-path ~/.zsh/cache
 378
 379 # Complete arguments and fix spelling mistakes when possible.
 380 zstyle ':completion:*' completer _complete _match _correct _approximate
 381
 382 # Make sure the list of possible completions is displayed after pressing <TAB>
 383 # the first time.
 384 setopt nolistambiguous
 385 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 386 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 387 bindkey '^I' expand-or-complete-prefix
 388 # Try uppercase if the currently typed string doesn't match. This allows
 389 # typing in lowercase most of the time and completion fixes the case.
 390 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 391
 392 # Use ls like colors for completions.
 393 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 394
 395 # Make completion lists scrollable so "do you wish to see all n possibilities"
 396 # is no longer displayed.
 397 zstyle ':completion:*' list-prompt '%p'
 398 # Display group name (like 'external command', 'alias', etc.) when there are
 399 # multiple matches in bold.
 400 zstyle ':completion:*' format '    %B%d%b:'
 401 # Display different types of matches separately.
 402 zstyle ':completion:*' group-name ''
 403
 404 # Ignore completion functions.
 405 zstyle ':completion:*:functions' ignored-patterns '_*'
 406 # Ignore parent directory.
 407 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 408 # Always complete one value (file name) only once in the current line. This
 409 # makes it easy to complete multiple values because I can just press tab to
 410 # get all possible values. Otherwise I would have to skip the first value
 411 # again and again.
 412 zstyle ':completion:*' ignore-line yes
 413 # Except for mv and cp, because I often want to use to similar names, so I
 414 # complete to the same and change it.
 415 zstyle ':completion:*:(mv|cp):*' ignore-line no
 416
 417
 418 # CUSTOM ALIASES AND FUNCTIONS
 419
 420 # If ^C is pressed while typing a command, add it to the history so it can be
 421 # easily retrieved later and then abort like ^C normally does. This is useful
 422 # when I want to abort an command to do something in between and then finish
 423 # typing the command.
 424 #
 425 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 426 # starting with - don't cause errors; and to Nadav Har'El
 427 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 428 # correctly, both on the Zsh mailing list.
 429 TRAPINT() {
 430     # Store the current buffer in the history.
 431     zle && print -s -r -- $BUFFER
 432
 433     # Return the default exit code so Zsh aborts the current command.
 434     return $1
 435 }
 436
 437 # Colorize stderr. Very useful when looking for errors. Thanks to
 438 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 439 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 440 # perfect and doesn't work with su and git for example, but it can handle most
 441 # interactive output quite well (even with no trailing new line) and in those
 442 # cases the E alias can be used as workaround.
 443 exec 2>>(while read -r -k -u 0 line; do
 444     printf '\e[91m%s\e[0m' "$line";
 445     print -n $'\0';
 446 done &)
 447
 448 # Load aliases and similar functions also used by other shells.
 449 if [[ -f ~/.shell/aliases ]]; then
 450     . ~/.shell/aliases
 451 fi
 452
 453 # Make sure aliases are expanded when using sudo.
 454 alias sudo='sudo '
 455
 456 # Global aliases for often used commands in the command line.
 457 alias -g E='2>&1'
 458 alias -g L='E | less'
 459 alias -g D='E | colordiff L'
 460 alias -g G='| grep'
 461 alias -g S='| sort'
 462 alias -g U='| uniq'
 463 alias -g H='| head'
 464 alias -g T='| tail'
 465
 466 # Make going up directories simple.
 467 alias -g ...='../..'
 468 alias -g ....='../../..'
 469 alias -g .....='../../../..'
 470
 471 # If the window naming feature is used (see above) then use ".zsh" (leading
 472 # dot) as title name after running clear so it's clear to me that the window
 473 # is empty. I open so much windows that I don't know in which I have something
 474 # important. This helps me to remember which windows are empty (I run clear
 475 # after I finished my work in a window).
 476 if [[ -n $window_reset ]]; then
 477     alias clear='clear; window_reset=yes; window_precmd reset'
 478 fi
 479
 480 # Display all branches (except stash) in gitk but only 200 commits as this is
 481 # much faster. Also put in the background and disown. Thanks to sitaram in
 482 # #git on Freenode (2009-04-20 15:51).
 483 gitk() {
 484     command gitk \
 485         --max-count=200 \
 486         $(git rev-parse --symbolic-full-name --remotes --branches) \
 487         $@ &
 488     disown %command
 489 }
 490 # Same for tig (except the disown part as it's no GUI program).
 491 tig() {
 492     command tig \
 493         --max-count=200 \
 494         $(git rev-parse --symbolic-full-name --remotes --branches) \
 495         $@
 496 }
 497
 498
 499 # OS SPECIFIC SETTINGS
 500
 501 local uname=$(uname)
 502
 503 if [[ $uname == Linux ]]; then
 504     # Settings when creating Debian packages.
 505     DEBEMAIL=simon@ruderich.org
 506     export DEBEMAIL
 507     DEBFULLNAME='Simon Ruderich'
 508     export DEBFULLNAME
 509
 510 elif [[ $uname == Darwin ]]; then # Mac OS X
 511     # Store the current clipboard in CLIPBOARD before every command so it can
 512     # be used in commands.
 513     os_darwin_preexec() {
 514         export CLIPBOARD="$(pbpaste)"
 515     }
 516     # Add the function as preexec hook.
 517     add-zsh-hook preexec os_darwin_preexec
 518
 519     # Initialize CLIPBOARD so it's available for completion directly after
 520     # startup.
 521     CLIPBOARD=""
 522     export CLIPBOARD
 523
 524     # Fetch current URL in clipboard with wget.
 525     alias wnc='wget --no-proxy $CLIPBOARD'
 526 fi
 527
 528
 529 # LOAD ADDITIONAL CONFIGURATION FILES
 530
 531 # Load rc file for current hostname (first part before a dot) or rc.local.
 532 source_config ~/.zsh host rc ${$(hostname)//.*/}
 533
 534
 535 # RUN COMMANDS
 536
 537 # If not already in screen reattach to a running session or create a new one.
 538 # This also starts screen one a remote server when connecting through ssh.
 539 if [[ $TERM != dumb && -z $STY ]]; then
 540     # Get running detached sessions.
 541     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 542
 543     # As we exec later we have to set the title here.
 544     window_preexec "screen"
 545
 546     # Create a new session if none is running.
 547     if [[ -z $session ]]; then
 548         exec screen
 549     # Reattach to a running session.
 550     else
 551         exec screen -r $session
 552     fi
 553 fi
 554
 555
 556 source_debug "finished sourcing ~/.zsh/rc"
 557
 558 # vim: ft=zsh