]> ruderich.org/simon Gitweb - config/dotfiles.git/blob - zsh/rc
zsh/rc: Prefer xpdf over zathura.
[config/dotfiles.git] / zsh / rc
1 # Zsh configuration file.
2
3 # Copyright (C) 2011-2012  Simon Ruderich
4 #
5 # This file is free software: you can redistribute it and/or modify
6 # it under the terms of the GNU General Public License as published by
7 # the Free Software Foundation, either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # This file is distributed in the hope that it will be useful,
11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 # GNU General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this file.  If not, see <http://www.gnu.org/licenses/>.
17
18
19 source_debug ". ~/.zsh/rc"
20
21 # MISCELLANEOUS SETTINGS
22
23 # Be paranoid, new files are readable/writable by me only.
24 umask 077
25
26 # Disable beeps.
27 setopt nobeep
28
29 # Prevent overwriting existing files with '> filename', use '>| filename'
30 # (or >!) instead.
31 setopt noclobber
32
33 # Entering the name of a directory (if it's not a command) will automatically
34 # cd to that directory.
35 setopt autocd
36
37 # When entering a nonexistent command name automatically try to find a similar
38 # one.
39 setopt correct
40
41 # Enable zsh's extended glob abilities.
42 setopt extendedglob
43
44 # Don't exit if <C-d> is pressed.
45 setopt ignoreeof
46
47
48 # KEY BINDINGS
49
50 # Not all bindings are done here, only those not specific to a given section.
51
52 # Use Vi(m) style key bindings.
53 bindkey -v
54
55 # Use jj and jk to exit insert mode.
56 bindkey 'jj' vi-cmd-mode
57 bindkey 'jk' vi-cmd-mode
58
59 # I don't need the arrow keys, I use ^N and ^P for this (see below).
60 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
61 # Also not in Vi mode.
62 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
63
64
65 # FUNCTION SETTINGS
66
67 # Make sure every entry in $fpath is unique.
68 typeset -U fpath
69 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
70 # of a Zsh CVS checkout. Use it to get the newest completions if available.
71 if [[ -d ~/.zsh/functions/completion ]]; then
72     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
73 fi
74 # Set correct fpath to allow loading my functions (including completion
75 # functions).
76 fpath=(~/.zsh/functions $fpath)
77 # Autoload my functions (except completion functions and hidden files). Thanks
78 # to caphuso from the Zsh example files for this idea.
79 if [[ -d ~/.zsh/functions ]]; then
80     autoload -Uz ${fpath[1]}/^_*(^/:t)
81 fi
82
83 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
84 # the moment only precmd(), preexec() and chpwd() are simulated.
85 if [[ $ZSH_VERSION != (4.3.<4->*|4.<4->*|<5->*) ]]; then
86     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
87     # arrays.
88     function precmd() {
89         for function in $precmd_functions; do
90             $function "$@"
91         done
92     }
93     function preexec() {
94         for function in $preexec_functions; do
95             $function "$@"
96         done
97     }
98     function chpwd() {
99         for function in $chpwd_functions; do
100             $function "$@"
101         done
102     }
103 fi
104
105 # Load zmv (zsh move) which is a powerful file renamer.
106 autoload -Uz zmv
107
108
109 # HISTORY SETTINGS
110
111 # Use history and store it in ~/.zsh/history.
112 HISTSIZE=50000
113 SAVEHIST=50000
114 HISTFILE=~/.zsh/history
115 # Append to the history file instead of overwriting it and do it immediately
116 # when a command is executed.
117 setopt appendhistory
118 setopt incappendhistory
119 # If the same command is run multiple times store it only once in the history.
120 setopt histignoredups
121 # Don't add lines starting with a space to the history.
122 setopt histignorespace
123 # Vim like completions of previous executed commands (also enter Vi-mode). If
124 # called at the beginning it just recalls old commands (like cursor up), if
125 # called after typing something, only lines starting with the typed text are
126 # returned. Very useful to get old commands quickly - in addition to the
127 # history commands (!..). Thanks to Mikachu in #zsh on Freenode (2010-01-17
128 # 12:47 CET) for the information how to a use function with bindkey.
129 zle -N my-vi-history-beginning-search-backward
130 my-vi-history-beginning-search-backward() {
131     local not_at_beginning_of_line
132     if [[ $CURSOR -ne 0 ]]; then
133         not_at_beginning_of_line=yes
134     fi
135
136     zle history-beginning-search-backward
137
138     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
139     # this counters it).
140     zle vi-cmd-mode
141     if [[ -n $not_at_beginning_of_line ]]; then
142         zle vi-forward-char
143     fi
144 }
145 bindkey '^P' my-vi-history-beginning-search-backward
146 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
147 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
148 # after calling ^P.
149 bindkey -a '^N' history-beginning-search-forward
150
151 # Automatically push cd-ed directories on the directory stack.
152 setopt autopushd
153 # Don't push duplicates on the directory stack.
154 setopt pushdignoredups
155 # Exchange the meaning of + and - when specifying a directory on the stack.
156 # This way cd -<Tab> lists the last used directory first, which is more
157 # natural because cd - goes to the last directory.
158 setopt pushdminus
159
160
161 # PROMPT SETTINGS
162
163 # Use colorized output, necessary for prompts and completions.
164 autoload -Uz colors && colors
165
166 # Necessary for $EPOCHSECONDS, the UNIX time.
167 zmodload zsh/datetime
168
169 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
170 # doesn't need any space, necessary for correct prompt drawing.
171 local red="%{${fg[red]}%}"
172 local blue="%{${fg[blue]}%}"
173 local green="%{${fg[green]}%}"
174 local yellow="%{${fg[yellow]}%}"
175 local default="%{${fg[default]}%}"
176
177 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
178 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
179 # symbolic link to current checkout of Zsh's sources).
180 if [[ $ZSH_VERSION == (4.3.<9->*|4.<4->*|<5->*) ||
181       -d ~/.zsh/functions/vcs_info ]]; then
182     # Update fpath to allow loading the vcs_info functions.
183     if [[ -d ~/.zsh/functions/vcs_info ]]; then
184        fpath=(~/.zsh/functions/vcs_info/
185               ~/.zsh/functions/vcs_info/Backends
186               $fpath)
187     fi
188
189     # Load vcs_info to display information about version control repositories.
190     autoload -Uz vcs_info
191     # Only look for git and mercurial repositories; the only I use.
192     zstyle ':vcs_info:*' enable git hg
193     # Check the repository for changes so they can be used in %u/%c (see
194     # below). This comes with a speed penalty for bigger repositories.
195     zstyle ':vcs_info:*' check-for-changes yes
196
197     # Set style of vcs_info display. The current branch (green) and VCS (blue)
198     # is displayed. If there is an special action going on (merge, rebase)
199     # it's also displayed (red). Also display if there are unstaged or staged
200     # (%u/%c) changes.
201     if [[ $ZSH_VERSION == (4.3.<11->*|4.<4->*|<5->*) ||
202           -d ~/.zsh/functions/vcs_info ]]; then
203         zstyle ':vcs_info:*' formats \
204             "($green%b%u%c$default:$blue%s$default)"
205         zstyle ':vcs_info:*' actionformats \
206             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
207     else
208         # In older versions %u and %c are not defined yet and are not
209         # correctly expanded.
210         zstyle ':vcs_info:*' formats \
211             "($green%b$default:$blue%s$default)"
212         zstyle ':vcs_info:*' actionformats \
213             "($green%b$default/$red%a$default:$blue%s$default)"
214     fi
215     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
216     # changes are detected in the repository; check-for-changes must be set to
217     # true for this to work. Thanks to Bart Trojanowski
218     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
219     # (2010-03-11 00:20 CET).
220     zstyle ':vcs_info:*' unstagedstr '¹'
221     zstyle ':vcs_info:*' stagedstr   '²'
222
223     # Default to run vcs_info. If possible we prevent running it later for
224     # speed reasons. If set to a non empty value vcs_info is run.
225     FORCE_RUN_VCS_INFO=1
226
227     # Cache system inspired by Bart Trojanowski
228     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
229     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
230     +vi-pre-get-data() {
231         # Only Git and Mercurial support and need caching. Abort if any other
232         # VCS is used.
233         [[ "$vcs" != git && "$vcs" != hg ]] && return
234
235         # If the shell just started up or we changed directories (or for other
236         # custom reasons) we must run vcs_info.
237         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
238             FORCE_RUN_VCS_INFO=
239             return
240         fi
241
242         # Don't run vcs_info by default to speed up the shell.
243         ret=1
244         # If a git/hg command was run then run vcs_info as the status might
245         # need to be updated.
246         case "$(fc -ln $(($HISTCMD-1)))" in
247             git* | g\ *)
248                 ret=0
249                 ;;
250             hg*)
251                 ret=0
252                 ;;
253         esac
254     }
255
256     # Must run vcs_info when changing directories.
257     prompt_chpwd() {
258         FORCE_RUN_VCS_INFO=1
259     }
260     chpwd_functions+=(prompt_chpwd)
261
262     # Used by prompt code below to determine if vcs_info should be run.
263     RUN_VCS_INFO=1
264 else
265     RUN_VCS_INFO=
266 fi
267
268 # Set the prompt. A two line prompt is used. On the top left the current
269 # working directory is displayed, on the right vcs_info (if available) and the
270 # current time in hex. On the bottom left current user name and host is shown,
271 # the exit code of the last command if it wasn't 0, the number of running jobs
272 # if not 0.
273 #
274 # The prompt is in green and blue to make easily detectable, the error exit
275 # code in red and bold and the job count in yellow.
276 #
277 # Thanks to Adam's prompt for the basic idea of this prompt.
278 prompt_precmd() {
279     # Regex to remove elements which take no space. Used to calculate the
280     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
281     # Functions/Prompts/prompt_*_setup.
282     local zero='%([BSUbfksu]|([FB]|){*})'
283
284     # Call vcs_info before every prompt.
285     if [[ -n $RUN_VCS_INFO ]]; then
286         vcs_info
287     else
288         vcs_info_msg_0_=
289     fi
290
291     local width width_left width_right
292     local top_left top_right
293
294     # Display the current time in HEX in bright blue and vcs_info (if used) on
295     # the right in the top prompt.
296     top_right="$vcs_info_msg_0_($blue%B0x$(([##16] EPOCHSECONDS))%b$default)"
297     width_right=${#${(S%%)top_right//$~zero/}}
298     # Remove it if it would get too long.
299     if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
300         top_right=
301         width_right=0
302     fi
303
304     # Display current directory on the left in the top prompt. Truncate the
305     # directory if necessary.
306     width=$(( COLUMNS - 4 - 1 - width_right ))
307     top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
308
309     # Calculate the width of the top prompt to fill the middle with "-".
310     width_left=${#${(S%%)top_left//$~zero/}}
311     width_right=${#${(S%%)top_right//$~zero/}}
312     width=$(( COLUMNS - width_left - width_right ))
313
314     PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
315 $blue%B'%b$default\
316 $green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
317 %(?..($red%B%?%b$default%) )"
318 }
319 precmd_functions+=(prompt_precmd)
320
321
322 # When screen, tmux, xterm or rxvt is used set the name of the window to the
323 # currently running program.
324 #
325 # When a program is started preexec() sets the window's name to it; when it
326 # stops precmd() resets the window's name to 'zsh'. 'fg' is supported and sets
327 # the window's name to the resumed job.
328 #
329 # It works with screen, tmux, xterm and rxvt.
330 #
331 # If a command is run with sudo or if the shell is running as root then a ! is
332 # added at the beginning of the command to make this clear. If a command is
333 # running on a different computer with ssh a @ is added at the beginning. If
334 # screen/tmux is running on the remote machine instead of @screen @:hostname
335 # (or @tmux ..; hostname replaced by the machine's hostname) is displayed.
336 # This only works if the .zshrc on the server also uses this command.
337 #
338 # screen* is necessary as `screen` uses screen.linux for example for a linux
339 # console.
340 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
341     # Is set to a non empty value to reset the window name in the next
342     # precmd() call.
343     window_reset=yes
344     # Is set to a non empty value when the shell is running as root.
345     if [[ $UID -eq 0 ]]; then
346         window_root=yes
347     fi
348
349     window_preexec() {
350         # Get the program name with its arguments.
351         local program_name=$1
352
353         # When sudo is used use real program name instead, but with an
354         # exclamation mark at the beginning (handled below).
355         local program_sudo=
356         if [[ $program_name == sudo* ]]; then
357             program_name=${program_name#sudo }
358             program_sudo=yes
359         fi
360
361         # Replace fg with the resumed job name.
362         if [[ $program_name == fg ]]; then
363             program_name=${jobtexts[%+]}
364         elif [[ $program_name == fg\ * ]]; then
365             program_name=${jobtexts[${program_name#fg }]}
366         fi
367
368         # Remove all arguments from the program name.
369         program_name=${program_name%% *}
370
371         # Ignore often used commands which are only running for a very short
372         # time. This prevents a "blinking" name when it's changed to "cd" for
373         # example and then some milliseconds later back to "zsh".
374         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
375
376         # Change my shortcuts so the real name of the program is displayed.
377         case $program_name in
378             e)
379                 program_name=elinks
380                 ;;
381             g)
382                 program_name=git
383                 ;;
384             m)
385                 program_name=mutt
386                 ;;
387             v)
388                 program_name=vim
389                 ;;
390         esac
391
392         # Add an exclamation mark at the beginning if running with sudo or if
393         # running zsh as root.
394         if [[ -n $program_sudo || -n $window_root ]]; then
395             program_name=!$program_name
396         fi
397
398         # Add an at mark at the beginning if running through ssh on a
399         # different computer.
400         if [[ -n $SSH_CONNECTION ]]; then
401             program_name="@$program_name"
402
403             # If screen is running in SSH then display "@:hostname" as title
404             # in the term/outer screen.
405             if [[ $program_name == @screen || $program_name == @tmux ]]; then
406                 program_name="@:${HOST//.*/}"
407             # Use "@:!hostname" for root screens.
408             elif [[ $program_name == @!screen || $program_name == @!tmux ]]; then
409                 program_name="@:!${HOST//.*/}"
410             fi
411         fi
412
413         # Set the window name to the currently running program.
414         window_title "$program_name"
415
416         # Tell precmd() to reset the window name when the program stops.
417         window_reset=yes
418     }
419
420     window_precmd() {
421         # Abort if no window name reset is necessary.
422         [[ -z $window_reset ]] && return
423
424         # Reset the window name to 'zsh'.
425         local name=zsh
426         # If the function was called with an argument then reset the window
427         # name to '.zsh' (used by clear alias).
428         if [[ -n $1 ]]; then
429             name=.zsh
430         fi
431
432         # Prepend prefixes like in window_preexec().
433         if [[ -n $window_root ]]; then
434             name="!$name"
435         fi
436         if [[ -n $SSH_CONNECTION ]]; then
437             name="@$name"
438         fi
439         window_title $name
440
441         # Just reset the name, so no screen reset necessary for the moment.
442         window_reset=
443     }
444
445     # Sets the window title. Works with screen, tmux (which uses screen as
446     # TERM), xterm and rxvt. (V) escapes all non-printable characters. Thanks
447     # to Mikachu in #zsh on Freenode (2010-08-07 17:09 CEST).
448     if [[ $TERM == screen* ]]; then
449         window_title() {
450             print -n "\ek${(V)1}\e\\"
451         }
452     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
453         window_title() {
454             print -n "\e]2;${(V)1}\e\\"
455         }
456     else
457         # Fallback if another TERM is used.
458         window_title() { }
459     fi
460
461     # Add the preexec() and precmd() hooks.
462     preexec_functions+=(window_preexec)
463     precmd_functions+=(window_precmd)
464 else
465     # Fallback if another TERM is used, necessary to run screen (see below in
466     # "RUN COMMANDS").
467     window_preexec() { }
468 fi
469
470
471 # COMPLETION SETTINGS
472
473 # Load the complist module which provides additional features to completion
474 # lists (coloring, scrolling).
475 zmodload zsh/complist
476 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
477 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
478 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
479 # problem.
480 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
481
482 # Use cache to speed up some slow completions (dpkg, perl modules, etc.).
483 zstyle ':completion:*' use-cache yes
484 zstyle ':completion:*' cache-path ~/.zsh/cache
485
486 # Let the completion system handle all completions, including expanding of
487 # shell wildcards (which is handled by other shell mechanisms if the default
488 # expand-or-complete is used).
489 bindkey '^I' complete-word
490 # If there are multiple matches after pressing <Tab> always display them
491 # immediately without requiring another <Tab>. a<Tab> completes to aa and
492 # lists aaa, aab, aac as possible completions if the directory contains aaa,
493 # aab, aac, bbb instead of only completing to aa.
494 setopt nolistambiguous
495 # Support completions in the middle of a word, without this option zsh jumps
496 # to the end of the word before the completion process begins. Is required for
497 # the _prefix completer.
498 setopt completeinword
499
500 zstyle ':completion:::::' completer \
501     _expand _complete _prefix _ignored _approximate
502
503 # Match specification to be tried when completing items. Each group ('...') is
504 # tried after another if no matches were found, once matches are found no
505 # other groups are tried. Thanks to Mikachu in #zsh on Freenode (2012-08-28
506 # 18:48 CEST) for explanations.
507 #
508 # When matching also include the uppercase variant of typed characters
509 # ('m:{a-z}={A-Z}'); using '' before this group would try the unmodified match
510 # first, but I prefer to get all matches immediately (e.g. if Makefile and
511 # makefile exist in the current directory echo m<tab> matches both, with '' it
512 # would only match makefile because it found one match). This allows typing in
513 # lowercase most of the time and completion fixes the case, which is faster.
514 #
515 # Don't perform these fixes in _approximate to prevent it from changing the
516 # input too much. Thanks to the book "From Bash to Z Shell" page 249.
517 zstyle ':completion:*:(^approximate):*' matcher-list 'm:{a-z}={A-Z}'
518
519 # Allow one mistake per three characters. Thanks to the book "From Bash to Z
520 # Shell" page 248.
521 zstyle -e ':completion:*:approximate:*' max-errors \
522     'reply=( $(( ($#PREFIX + $#SUFFIX) / 3 )) )'
523
524 # Expand shell wildcards to all matching files after <Tab>. echo *<Tab>
525 # results in a b c if the directory contains the files a, b, c. Thanks to the
526 # book "From Bash to Z Shell" page 246.
527 zstyle ':completion:*:expand:*' tag-order all-expansions
528 # Keep prefixes unexpanded if possible: $HOME/<Tab> doesn't expand $HOME,
529 # while $HOME<Tab> does.
530 zstyle ':completion:*:expand:*' keep-prefix yes
531
532 # When completing multiple path components display all matching ambiguous
533 # components. For example /u/s/d/r/README<Tab> lists all matching READMEs
534 # instead of just the matching paths up to the r/ component. Can be slow if
535 # there are many matching files.
536 zstyle ':completion:*' list-suffixes yes
537
538 # Use ls-like colors for completions.
539 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
540
541 # Make completion lists scrollable so "do you wish to see all n possibilities"
542 # is no longer displayed. Display current position in percent (%p).
543 zstyle ':completion:*:default' list-prompt '%p'
544 # Display group name (%d) (like 'external command', 'alias', etc.), in bold.
545 # Also display a message if _approximate found errors and no matches were
546 # found.
547 zstyle ':completion:*'             format '    %B%d%b:'
548 zstyle ':completion:*:corrections' format '    %B%d%b (errors: %e)'
549 zstyle ':completion:*:warnings'    format '    %Bno matches for %d%b'
550 # Display different types of matches separately.
551 zstyle ':completion:*' group-name ''
552
553 # Separate man pages by section.
554 zstyle ':completion:*' separate-sections yes
555
556 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
557 # on Freenode for the fix (2010-12-17 13:46 CET).
558 zle_highlight=(suffix:none)
559
560 # Ignore completion functions.
561 zstyle ':completion:*:functions' ignored-patterns '_*'
562 # Ignore parent directory.
563 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
564 # Always complete file names only once in the current line. This makes it easy
565 # to complete multiple file names because I can just press tab to get all
566 # possible values. Otherwise I would have to skip the first value again and
567 # again. Thanks to Mikachu in #zsh on Freenode (2011-08-11 14:42 CEST) for the
568 # hint to use other. other is necessary so prefix<Tab> lists both prefix and
569 # prefixrest if the directory contains prefix and prefixrest.
570 zstyle ':completion:*:all-files' ignore-line other
571 # Except for mv and cp, because I often want to use to similar names, so I
572 # complete to the same and change it.
573 zstyle ':completion:*:(mv|cp):all-files' ignore-line no
574
575 # Don't complete ./config.* files, this makes running ./configure much
576 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
577 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
578 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
579 # Freenode (2010-06-06 04:54 CEST). See below for a way to complete them.
580 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns \
581     '*.aux' '*.log' '*.pdf' \
582     '*.class'
583
584 # Provide a fallback completer which always completes files. Useful when Zsh's
585 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
586 # (http://www.zsh.org/mla/users/2009/msg01038.html).
587 zle -C complete-files complete-word _generic
588 zstyle ':completion:complete-files:*' completer _files
589 bindkey '^F' complete-files
590
591
592 # CUSTOM ALIASES AND FUNCTIONS
593
594 # If ^C is pressed while typing a command, add it to the history so it can be
595 # easily retrieved later and then abort like ^C normally does. This is useful
596 # when I want to abort an command to do something in between and then finish
597 # typing the command.
598 #
599 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
600 # starting with - don't cause errors; and to Nadav Har'El
601 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
602 # correctly, both on the Zsh mailing list.
603 TRAPINT() {
604     # Don't store this line in history if histignorespace is enabled and the
605     # line starts with a space.
606     if [[ -o histignorespace && ${BUFFER[1]} = " " ]]; then
607         return $1
608     fi
609
610     # Store the current buffer in the history.
611     zle && print -s -r -- $BUFFER
612
613     # Return the default exit code so Zsh aborts the current command.
614     return $1
615 }
616
617 # Load aliases and similar functions also used by other shells.
618 if [[ -f ~/.shell/aliases ]]; then
619     . ~/.shell/aliases
620 fi
621
622 # Make sure aliases are expanded when using sudo.
623 alias sudo='sudo '
624
625 # Global aliases for often used redirections.
626 alias -g E='2>&1'
627 alias -g N='>/dev/null'
628 alias -g EN='2>/dev/null'
629 alias -g L='2>&1 | less'
630 alias -g LS='2>&1 | less -S' # -S prevents wrapping of long lines
631 alias -g D='2>&1 | colordiff | less'
632 # Global aliases for often used commands in the command line.
633 alias -g A='| awk'
634 alias -g G='| grep'
635 alias -g H='| head'
636 alias -g P='| perl'
637 alias -g S='| sort'
638 alias -g T='| tail'
639 alias -g U='| uniq'
640
641 # Make going up directories simple.
642 alias -g ...='../..'
643 alias -g ....='../../..'
644 alias -g .....='../../../..'
645
646 # If the window naming feature is used (see above) then use ".zsh" (leading
647 # dot) as title name after running clear so it's clear to me that the window
648 # is empty. I open so much windows that I don't know in which I have something
649 # important. This helps me to remember which windows are empty (I run clear
650 # after I finished my work in a window).
651 if [[ -n $window_reset ]]; then
652     alias clear='clear; window_reset=yes; window_precmd reset'
653 fi
654
655
656 # CUSTOM COMMANDS
657
658 # Display all branches (except stash) in gitk but only 200 commits as this is
659 # much faster. Also put in the background and disown. Thanks to drizzd in #git
660 # on Freenode (2010-04-03 17:55 CEST).
661 (( $+commands[gitk] )) && gitk() {
662     command gitk --max-count=200 --branches --remotes --tags "$@" &
663     disown %command
664 }
665 # Same for tig (except the disown part as it's no GUI program).
666 (( $+commands[tig] )) && tig() {
667     command tig --max-count=200 --branches --remotes --tags "$@"
668 }
669
670 # Pipe output through less.
671 (( $+commands[tree] )) && tree() {
672     command tree -C "$@" | less
673 }
674
675 # Choose the "best" PDF viewer available: xpdf, then zathura (in the past
676 # zathura was preferred, but recent versions are completely broken: still no
677 # working search and no page-wise scrolling anymore). Also setup completion
678 # for `pdf`.
679 if (( $+commands[xpdf] )); then
680     pdf() {
681         command xpdf "$@" 2>/dev/null &
682         disown %command
683     }
684     compdef _xpdf pdf
685 elif (( $+commands[zathura] )); then
686     pdf() {
687         command zathura "$@" 2>/dev/null &
688         disown %command
689     }
690     # No completion for zathura yet.
691     compdef _xpdf pdf
692 fi
693
694 # GHCI doesn't use readline, force it if rlwrap is available.
695 (( $+commands[rlwrap] )) && ghci() {
696     command rlwrap \
697         --always-readline --complete-filenames -t dumb \
698         --histsize 5000 \
699         --file ~/.shell/rlwrap/ghci \
700         ghci "$@" 2>&1
701 }
702
703
704 # OS SPECIFIC SETTINGS
705
706 if [[ $OSTYPE == linux* ]]; then
707     # Settings when creating Debian packages.
708     DEBEMAIL=simon@ruderich.org
709     export DEBEMAIL
710     DEBFULLNAME='Simon Ruderich'
711     export DEBFULLNAME
712 fi
713
714
715 # LOAD ADDITIONAL CONFIGURATION FILES
716
717 # Configuration option for rc.local to use GNU screen/tmux. By default GNU
718 # screen is used. Possible values: screen, tmux.
719 use_multiplexer=screen
720
721 source_config ~/.zsh/rc.local
722
723
724 # RUN COMMANDS
725
726 # If not already in screen or tmux, reattach to a running session or create a
727 # new one. This also starts screen/tmux on a remote server when connecting
728 # through ssh.
729 if [[ $TERM != dumb && $TERM != linux && -z $STY && -z $TMUX ]]; then
730     # Get running detached sessions.
731     if [[ $use_multiplexer = screen ]]; then
732         session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
733     elif [[ $use_multiplexer = tmux ]]; then
734         session=$(tmux list-sessions 2>/dev/null \
735                   | sed '/(attached)$/ d; s/^\([0-9]\{1,\}\).*$/\1/; q')
736     fi
737
738     # As we exec later we have to set the title here.
739     if [[ $use_multiplexer = screen ]]; then
740         window_preexec "screen"
741     elif [[ $use_multiplexer = tmux ]]; then
742         window_preexec "tmux"
743     fi
744
745     # Create a new session if none is running.
746     if [[ -z $session ]]; then
747         if [[ $use_multiplexer = screen ]]; then
748             exec screen
749         elif [[ $use_multiplexer = tmux ]]; then
750             exec tmux
751         fi
752     # Reattach to a running session.
753     else
754         if [[ $use_multiplexer = screen ]]; then
755             exec screen -r $session
756         elif [[ $use_multiplexer = tmux ]]; then
757             exec tmux attach-session -t $session
758         fi
759     fi
760 fi
761
762 # Colorize stderr in red. Very useful when looking for errors. Thanks to
763 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
764 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
765 # yet perfect and doesn't work with su and git for example, but it can handle
766 # most interactive output quite well (even with no trailing new line) and in
767 # cases it doesn't work, the E alias can be used as workaround.
768 #
769 # Moved in the "run commands" section to prevent one unnecessary zsh process
770 # when starting screen/tmux (see above).
771 exec 2>>(while read -r -k -u 0 line; do
772     printf '\e[91m%s\e[0m' "$line";
773     print -n $'\0';
774 done &)
775
776 # Run reminder and redisplay it every four hours (if it's available).
777 PERIOD=14400
778 periodic() {
779     (( $+commands[rem] )) && [ -f ~/.reminders ] && rem -h
780 }
781
782
783 source_debug ". ~/.zsh/rc (done)"
784
785 # vim: ft=zsh