zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors.
 149 local red="%{${fg[red]}%}"
 150 local blue="%{${fg[blue]}%}"
 151 local green="%{${fg[green]}%}"
 152 local yellow="%{${fg[yellow]}%}"
 153 local default="%{${fg[default]}%}"
 154
 155 # Set the default prompt. The current host and working directory is displayed,
 156 # the exit code of the last command if it wasn't 0, the number of running jobs
 157 # if not 0.
 158 #
 159 # The prompt is in green and blue to make easily detectable, the error exit
 160 # code in red and bold and the job count in yellow.
 161 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 162 %(1j.$yellow%j$default.)%# \
 163 %(?..($red%B%?%b$default%) )"
 164
 165 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 166 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 167 # symbolic link to current checkout of Zsh's sources).
 168 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 169       -d ~/.zsh/functions/vcs_info ]]; then
 170     # Update fpath to allow loading the vcs_info functions.
 171     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 172        fpath=(~/.zsh/functions/vcs_info/
 173               ~/.zsh/functions/vcs_info/Backends
 174               $fpath)
 175     fi
 176
 177     # Allow substitutions and expansions in the prompt, necessary for
 178     # vcs_info.
 179     setopt promptsubst
 180     # Load vcs_info to display information about version control repositories.
 181     autoload -Uz vcs_info
 182     # Only look for git and mercurial repositories; the only I use.
 183     zstyle ':vcs_info:*' enable git hg
 184     # Check the repository for changes so they can be used in %u/%c (see
 185     # below). This comes with a speed penalty for bigger repositories.
 186     zstyle ':vcs_info:*' check-for-changes true
 187
 188     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 189     # is displayed. If there is an special action going on (merge, rebase)
 190     # it's also displayed (red). Also display if there are unstaged or staged
 191     # (%u/%c) changes.
 192     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 193           -d ~/.zsh/functions/vcs_info ]]; then
 194         zstyle ':vcs_info:*' formats \
 195             "($green%b%u%c$default:$blue%s$default)"
 196         zstyle ':vcs_info:*' actionformats \
 197             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 198     else
 199         # In older versions %u and %c are not defined yet and are not
 200         # correctly expanded.
 201         zstyle ':vcs_info:*' formats \
 202             "($green%b$default:$blue%s$default)"
 203         zstyle ':vcs_info:*' actionformats \
 204             "($green%b$default/$red%a$default:$blue%s$default)"
 205     fi
 206     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 207     # changes are detected in the repository; check-for-changes must be set to
 208     # true for this to work. Thanks to Bart Trojanowski
 209     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 210     # (2010-03-11 00:20).
 211     zstyle ':vcs_info:*' unstagedstr '¹'
 212     zstyle ':vcs_info:*' stagedstr   '²'
 213
 214     # Call vcs_info as precmd before every prompt.
 215     prompt_precmd() {
 216         vcs_info
 217     }
 218     add-zsh-hook precmd prompt_precmd
 219
 220     # Display the VCS information in the right prompt.
 221     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 222         RPROMPT='${vcs_info_msg_0_}'
 223     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 224     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 225     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 226     else
 227         RPROMPT='${vcs_info_msg_0_:- }'
 228     fi
 229 fi
 230
 231 unset red blue green yellow default
 232
 233 # When screen, xterm or rxvt is used set the name of the window to the
 234 # currently running program.
 235 #
 236 # When a program is started preexec() sets the window's name to it; when it
 237 # stops precmd() resets the window's name to 'zsh'.
 238 #
 239 # It works with screen, xterm and rxvt.
 240 #
 241 # If a command is run with sudo or if the shell is running as root then a ! is
 242 # added at the beginning of the command to make this clear. If a command is
 243 # running on a different computer with ssh a @ is added at the beginning. If
 244 # screen is running on the remote machine instead of @screen @:hostname
 245 # (hostname replaced by the machine's hostname) is displayed. This only works
 246 # if the .zshrc on the server also uses this command.
 247 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 248     # Is set to a non empty value to reset the window name in the next
 249     # precmd() call.
 250     window_reset=yes
 251     # Is set to a non empty value when the shell is running as root.
 252     if [[ $(id -u) -eq 0 ]]; then
 253         window_root=yes
 254     fi
 255
 256     window_preexec() {
 257         # Get the program name with its arguments.
 258         local program_name=$1
 259
 260         # When sudo is used use real program name instead, but with an
 261         # exclamation mark at the beginning (handled below).
 262         local program_sudo=
 263         if [[ $program_name == sudo* ]]; then
 264             program_name=${program_name#sudo }
 265             program_sudo=yes
 266         fi
 267         # Remove all arguments from the program name.
 268         program_name=${program_name%% *}
 269
 270         # Ignore often used commands which are only running for a very short
 271         # time. This prevents a "blinking" name when it's changed to "cd" for
 272         # example and then some milliseconds later back to "zsh".
 273         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 274
 275         # Change my shortcuts so the real name of the program is displayed.
 276         case $program_name in
 277             e)
 278                 program_name=elinks
 279                 ;;
 280             g)
 281                 program_name=git
 282                 ;;
 283             m)
 284                 program_name=mutt
 285                 ;;
 286             v|vi)
 287                 program_name=vim
 288                 ;;
 289         esac
 290
 291         # Add an exclamation mark at the beginning if running with sudo or if
 292         # running zsh as root.
 293         if [[ -n $program_sudo || -n $window_root ]]; then
 294             program_name=!$program_name
 295         fi
 296
 297         # Add an at mark at the beginning if running through ssh on a
 298         # different computer.
 299         if [[ -n $SSH_CONNECTION ]]; then
 300             program_name="@$program_name"
 301
 302             # If screen is running in SSH then display "@:hostname" as title
 303             # in the term/outer screen.
 304             if [[ $program_name == @screen ]]; then
 305                 program_name="@:${$(hostname)//.*/}"
 306             fi
 307         fi
 308
 309         # Set the window name to the currently running program.
 310         window_title "$program_name"
 311
 312         # Tell precmd() to reset the window name when the program stops.
 313         window_reset=yes
 314     }
 315
 316     window_precmd() {
 317         # Abort if no window name reset is necessary.
 318         [[ -z $window_reset ]] && return
 319
 320         # Reset the window name to 'zsh'.
 321         local name=zsh
 322         # If the function was called with an argument then reset the window
 323         # name to '.zsh' (used by clear alias).
 324         if [[ -n $1 ]]; then
 325             name=.zsh
 326         fi
 327
 328         # Prepend prefixes like in window_preexec().
 329         if [[ -n $SSH_CONNECTION ]]; then
 330             window_title "@$name"
 331         elif [[ -n $window_root ]]; then
 332             window_title "!$name"
 333         else
 334             window_title $name
 335         fi
 336
 337         # Just reset the name, so no screen reset necessary for the moment.
 338         window_reset=
 339     }
 340
 341     # Sets the window title. Works with screen, xterm and rxvt.
 342     if [[ $TERM == screen* ]]; then
 343         window_title() {
 344             print -n "\ek$1\e\\"
 345         }
 346     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 347         window_title() {
 348             print -n "\e]2;$1\e\\"
 349         }
 350     else
 351         # Fallback if another TERM is used.
 352         window_title() { }
 353     fi
 354
 355     # Add the preexec() and precmd() hooks.
 356     add-zsh-hook preexec window_preexec
 357     add-zsh-hook precmd window_precmd
 358 fi
 359
 360
 361 # COMPLETION SETTINGS
 362
 363 # Load the complist module which provides additions to completion lists
 364 # (coloring, scrollable).
 365 zmodload zsh/complist
 366 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 367 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 368 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 369 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 370
 371 # Use cache to speed up completions.
 372 zstyle ':completion:*' use-cache on
 373 zstyle ':completion:*' cache-path ~/.zsh/cache
 374
 375 # Complete arguments and fix spelling mistakes when possible.
 376 zstyle ':completion:*' completer _complete _match _correct _approximate
 377
 378 # Make sure the list of possible completions is displayed after pressing <TAB>
 379 # the first time.
 380 setopt nolistambiguous
 381 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 382 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 383 bindkey '^I' expand-or-complete-prefix
 384 # Try uppercase if the currently typed string doesn't match. This allows
 385 # typing in lowercase most of the time and completion fixes the case.
 386 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 387
 388 # Use ls like colors for completions.
 389 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 390
 391 # Make completion lists scrollable so "do you wish to see all n possibilities"
 392 # is no longer displayed.
 393 zstyle ':completion:*' list-prompt '%p'
 394 # Display group name (like 'external command', 'alias', etc.) when there are
 395 # multiple matches in bold.
 396 zstyle ':completion:*' format '    %B%d%b:'
 397 # Display different types of matches separately.
 398 zstyle ':completion:*' group-name ''
 399
 400 # Ignore completion functions.
 401 zstyle ':completion:*:functions' ignored-patterns '_*'
 402 # Ignore parent directory.
 403 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 404 # When unsetting variables make sure every variable name is only suggested
 405 # once.
 406 zstyle ':completion:*:unset:*' ignore-line yes
 407 # When working with Mercurial and Git don't complete the same file multiple
 408 # times. Very useful when completing file names.
 409 zstyle ':completion:*:(hg|git)*:*' ignore-line yes
 410
 411
 412 # CUSTOM ALIASES AND FUNCTIONS
 413
 414 # If ^C is pressed while typing a command, add it to the history so it can be
 415 # easily retrieved later and then abort like ^C normally does. This is useful
 416 # when I want to abort an command to do something in between and then finish
 417 # typing the command.
 418 #
 419 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 420 # starting with - don't cause errors.
 421 TRAPINT() {
 422     # Store the current buffer in the history.
 423     zle && print -s -- $BUFFER
 424
 425     # Return the default exit code so Zsh aborts the current command.
 426     return $1
 427 }
 428
 429 # Colorize stderr. Very useful when looking for errors. Thanks to
 430 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 431 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 432 # perfect and doesn't work with su and git for example, but it can handle most
 433 # interactive output quite well (even with no trailing new line) and in those
 434 # cases the E alias can be used as workaround.
 435 exec 2>>(while read -r -k -u 0 line; do
 436     printf '\e[91m%s\e[0m' "$line";
 437     print -n $'\0';
 438 done &)
 439
 440 # Load aliases and similar functions also used by other shells.
 441 if [[ -f ~/.shell/aliases ]]; then
 442     . ~/.shell/aliases
 443 fi
 444
 445 # Make sure aliases are expanded when using sudo.
 446 alias sudo='sudo '
 447
 448 # Global aliases for often used commands in the command line.
 449 alias -g E='2>&1'
 450 alias -g L='E | less'
 451 alias -g D='E | colordiff L'
 452 alias -g G='| grep'
 453 alias -g S='| sort'
 454 alias -g U='| uniq'
 455 alias -g H='| head'
 456 alias -g T='| tail'
 457
 458 # Make going up directories simple.
 459 alias -g ...='../..'
 460 alias -g ....='../../..'
 461 alias -g .....='../../../..'
 462
 463 # If the window naming feature is used (see above) then use ".zsh" (leading
 464 # dot) as title name after running clear so it's clear to me that the window
 465 # is empty. I open so much windows that I don't know in which I have something
 466 # important. This helps me to remember which windows are empty (I run clear
 467 # after I finished my work in a window).
 468 if [[ -n $window_reset ]]; then
 469     alias clear='clear; window_reset=yes; window_precmd reset'
 470 fi
 471
 472 # Display all branches (except stash) in gitk but only 200 commits as this is
 473 # much faster. Also put in the background and disown. Thanks to sitaram in
 474 # #git on Freenode (2009-04-20 15:51).
 475 gitk() {
 476     command gitk \
 477         --max-count=200 \
 478         $(git rev-parse --symbolic-full-name --remotes --branches) \
 479         $@ &
 480     disown %command
 481 }
 482 # Same for tig (except the disown part as it's no GUI program).
 483 tig() {
 484     command tig \
 485         --max-count=200 \
 486         $(git rev-parse --symbolic-full-name --remotes --branches) \
 487         $@
 488 }
 489
 490
 491 # OS SPECIFIC SETTINGS
 492
 493 if [[ $(uname) == Linux ]]; then
 494     # Settings when creating Debian packages.
 495     DEBEMAIL=simon@ruderich.org
 496     export DEBEMAIL
 497     DEBFULLNAME='Simon Ruderich'
 498     export DEBFULLNAME
 499
 500 elif [[ $(uname) == Darwin ]]; then # Mac OS X
 501     # Store the current clipboard in CLIPBOARD before every command so it can
 502     # be used in commands.
 503     os_darwin_preexec() {
 504         export CLIPBOARD="$(pbpaste)"
 505     }
 506     # Add the function as preexec hook.
 507     add-zsh-hook preexec os_darwin_preexec
 508
 509     # Initialize CLIPBOARD so it's available for completion directly after
 510     # startup.
 511     CLIPBOARD=""
 512     export CLIPBOARD
 513
 514     # Fetch current URL in clipboard with wget.
 515     alias wnc='wget --no-proxy $CLIPBOARD'
 516 fi
 517
 518
 519 # LOAD ADDITIONAL CONFIGURATION FILES
 520
 521 # Load rc file for current hostname (first part before a dot) or rc.local.
 522 source_config ~/.zsh host rc ${$(hostname)//.*/}
 523
 524
 525 # RUN COMMANDS
 526
 527 # If not already in screen reattach to a running session or create a new one.
 528 #
 529 # screen* is necessary as `screen` uses screen.linux for example for a linux
 530 # console which would otherwise cause an infinite loop.
 531 if [[ $TERM != screen* && $TERM != 'dumb' ]]; then
 532     # Get running detached sessions.
 533     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 534     # Create a new session if none is running.
 535     if [[ -z $session ]]; then
 536         screen
 537     # Reattach to a running session.
 538     else
 539         screen -r $session
 540     fi
 541 fi
 542
 543
 544 source_debug "finished sourcing ~/.zsh/rc"
 545
 546 # vim: ft=zsh