zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug ". ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload -Uz ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload -Uz zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47 CET) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -Uz colors && colors
 147
 148 # Necessary for $EPOCHSECONDS, the UNIX time.
 149 zmodload zsh/datetime
 150
 151 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 152 # doesn't need any space, necessary for correct prompt draw.
 153 local red="%{${fg[red]}%}"
 154 local blue="%{${fg[blue]}%}"
 155 local green="%{${fg[green]}%}"
 156 local yellow="%{${fg[yellow]}%}"
 157 local default="%{${fg[default]}%}"
 158
 159 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 160 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 161 # symbolic link to current checkout of Zsh's sources).
 162 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 163       -d ~/.zsh/functions/vcs_info ]]; then
 164     # Update fpath to allow loading the vcs_info functions.
 165     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 166        fpath=(~/.zsh/functions/vcs_info/
 167               ~/.zsh/functions/vcs_info/Backends
 168               $fpath)
 169     fi
 170
 171     # Load vcs_info to display information about version control repositories.
 172     autoload -Uz vcs_info
 173     # Only look for git and mercurial repositories; the only I use.
 174     zstyle ':vcs_info:*' enable git hg
 175     # Check the repository for changes so they can be used in %u/%c (see
 176     # below). This comes with a speed penalty for bigger repositories.
 177     zstyle ':vcs_info:*' check-for-changes true
 178
 179     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 180     # is displayed. If there is an special action going on (merge, rebase)
 181     # it's also displayed (red). Also display if there are unstaged or staged
 182     # (%u/%c) changes.
 183     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 184           -d ~/.zsh/functions/vcs_info ]]; then
 185         zstyle ':vcs_info:*' formats \
 186             "($green%b%u%c$default:$blue%s$default)"
 187         zstyle ':vcs_info:*' actionformats \
 188             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 189     else
 190         # In older versions %u and %c are not defined yet and are not
 191         # correctly expanded.
 192         zstyle ':vcs_info:*' formats \
 193             "($green%b$default:$blue%s$default)"
 194         zstyle ':vcs_info:*' actionformats \
 195             "($green%b$default/$red%a$default:$blue%s$default)"
 196     fi
 197     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 198     # changes are detected in the repository; check-for-changes must be set to
 199     # true for this to work. Thanks to Bart Trojanowski
 200     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 201     # (2010-03-11 00:20 CET).
 202     zstyle ':vcs_info:*' unstagedstr '¹'
 203     zstyle ':vcs_info:*' stagedstr   '²'
 204
 205     # Default to running vcs_info. If possible we prevent running it later for
 206     # speed reasons. If set to a non empty value vcs_info is run.
 207     FORCE_RUN_VCS_INFO=1
 208
 209     # Cache system inspired by Bart Trojanowski
 210     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 211     #zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 212     +vi-pre-get-data() {
 213         # Only Git and Mercurial support and need caching. Abort if any other
 214         # VCS is used.
 215         [[ "$vcs" != git && "$vcs" != hg ]] && return
 216
 217         # If the shell just started up or we changed directories (or for other
 218         # custom reasons) we must run vcs_info.
 219         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 220             FORCE_RUN_VCS_INFO=
 221             return
 222         fi
 223
 224         # Don't run vcs_info by default to speed up the shell.
 225         ret=1
 226         # If a git/hg command was run then run vcs_info as the status might
 227         # need to be updated.
 228         case "$(fc -ln $(($HISTCMD-1)))" in
 229             git* | g\ *)
 230                 ret=0
 231                 ;;
 232             hg*)
 233                 ret=0
 234                 ;;
 235         esac
 236     }
 237
 238     # Must run vcs_info when changing directories.
 239     prompt_chpwd() {
 240         FORCE_RUN_VCS_INFO=1
 241     }
 242     add-zsh-hook chpwd prompt_chpwd
 243
 244     # Used by prompt code below to determine if vcs_info should be run.
 245     RUN_VCS_INFO=1
 246 else
 247     RUN_VCS_INFO=
 248 fi
 249
 250 # Set the prompt. A two line prompt is used. On the top left the current
 251 # working directory is displayed, on the right vcs_info (if available). On the
 252 # bottom left current user name and host is shown, the exit code of the last
 253 # command if it wasn't 0, the number of running jobs if not 0.
 254 #
 255 # The prompt is in green and blue to make easily detectable, the error exit
 256 # code in red and bold and the job count in yellow.
 257 #
 258 # Thanks to Adam's prompt for the basic idea of this prompt.
 259 #
 260 # The current time is display in hex in the right prompt.
 261 prompt_precmd() {
 262     # Regex to remove elements which take no space. Used to calculate the
 263     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 264     # Functions/Prompts/prompt_*_setup.
 265     local zero='%([BSUbfksu]|([FB]|){*})'
 266
 267     # Call vcs_info before every prompt.
 268     if [[ -n $RUN_VCS_INFO ]]; then
 269         vcs_info
 270     else
 271         vcs_info_msg_0_=
 272     fi
 273
 274     local width width_left width_right
 275     local top_left top_right
 276
 277     # Display the current time in HEX in bright blue and vcs_info (if used) on
 278     # the right in the top prompt.
 279     top_right="$vcs_info_msg_0_($blue%B0x$(([##16] EPOCHSECONDS))%b$default)"
 280     width_right=${#${(S%%)top_right//$~zero/}}
 281     # Remove it if it would get too long.
 282     if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
 283         top_right=
 284         width_right=0
 285     fi
 286
 287     # Display current directory on the left in the top prompt. Truncate the
 288     # directory if necessary.
 289     width=$(( COLUMNS - 4 - 1 - width_right ))
 290     top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
 291
 292     # Calculate the width of the top prompt to fill the middle with "-".
 293     width_left=${#${(S%%)top_left//$~zero/}}
 294     width_right=${#${(S%%)top_right//$~zero/}}
 295     width=$(( COLUMNS - width_left - width_right ))
 296
 297     PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
 298 $blue%B'%b$default\
 299 $green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
 300 %(?..($red%B%?%b$default%) )"
 301 }
 302 add-zsh-hook precmd prompt_precmd
 303
 304
 305 # When screen, xterm or rxvt is used set the name of the window to the
 306 # currently running program.
 307 #
 308 # When a program is started preexec() sets the window's name to it; when it
 309 # stops precmd() resets the window's name to 'zsh'.
 310 #
 311 # It works with screen, xterm and rxvt.
 312 #
 313 # If a command is run with sudo or if the shell is running as root then a ! is
 314 # added at the beginning of the command to make this clear. If a command is
 315 # running on a different computer with ssh a @ is added at the beginning. If
 316 # screen is running on the remote machine instead of @screen @:hostname
 317 # (hostname replaced by the machine's hostname) is displayed. This only works
 318 # if the .zshrc on the server also uses this command.
 319 #
 320 # screen* is necessary as `screen` uses screen.linux for example for a linux
 321 # console.
 322 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 323     # Is set to a non empty value to reset the window name in the next
 324     # precmd() call.
 325     window_reset=yes
 326     # Is set to a non empty value when the shell is running as root.
 327     if [[ $UID -eq 0 ]]; then
 328         window_root=yes
 329     fi
 330
 331     window_preexec() {
 332         # Get the program name with its arguments.
 333         local program_name=$1
 334
 335         # When sudo is used use real program name instead, but with an
 336         # exclamation mark at the beginning (handled below).
 337         local program_sudo=
 338         if [[ $program_name == sudo* ]]; then
 339             program_name=${program_name#sudo }
 340             program_sudo=yes
 341         fi
 342         # Remove all arguments from the program name.
 343         program_name=${program_name%% *}
 344
 345         # Ignore often used commands which are only running for a very short
 346         # time. This prevents a "blinking" name when it's changed to "cd" for
 347         # example and then some milliseconds later back to "zsh".
 348         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
 349
 350         # Change my shortcuts so the real name of the program is displayed.
 351         case $program_name in
 352             e)
 353                 program_name=elinks
 354                 ;;
 355             g)
 356                 program_name=git
 357                 ;;
 358             m)
 359                 program_name=mutt
 360                 ;;
 361             v)
 362                 program_name=vim
 363                 ;;
 364         esac
 365
 366         # Add an exclamation mark at the beginning if running with sudo or if
 367         # running zsh as root.
 368         if [[ -n $program_sudo || -n $window_root ]]; then
 369             program_name=!$program_name
 370         fi
 371
 372         # Add an at mark at the beginning if running through ssh on a
 373         # different computer.
 374         if [[ -n $SSH_CONNECTION ]]; then
 375             program_name="@$program_name"
 376
 377             # If screen is running in SSH then display "@:hostname" as title
 378             # in the term/outer screen.
 379             if [[ $program_name == @screen ]]; then
 380                 program_name="@:${HOST//.*/}"
 381             # Use "@:!hostname" for root screens.
 382             elif [[ $program_name == @!screen ]]; then
 383                 program_name="@:!${HOST//.*/}"
 384             fi
 385         fi
 386
 387         # Set the window name to the currently running program.
 388         window_title "$program_name"
 389
 390         # Tell precmd() to reset the window name when the program stops.
 391         window_reset=yes
 392     }
 393
 394     window_precmd() {
 395         # Abort if no window name reset is necessary.
 396         [[ -z $window_reset ]] && return
 397
 398         # Reset the window name to 'zsh'.
 399         local name=zsh
 400         # If the function was called with an argument then reset the window
 401         # name to '.zsh' (used by clear alias).
 402         if [[ -n $1 ]]; then
 403             name=.zsh
 404         fi
 405
 406         # Prepend prefixes like in window_preexec().
 407         if [[ -n $window_root ]]; then
 408             name="!$name"
 409         fi
 410         if [[ -n $SSH_CONNECTION ]]; then
 411             name="@$name"
 412         fi
 413         window_title $name
 414
 415         # Just reset the name, so no screen reset necessary for the moment.
 416         window_reset=
 417     }
 418
 419     # Sets the window title. Works with screen, xterm and rxvt. (V) escapes
 420     # all non-printable characters. Thanks to Mikachu in #zsh on Freenode
 421     # (2010-08-07 17:09 CEST).
 422     if [[ $TERM == screen* ]]; then
 423         window_title() {
 424             print -n "\ek${(V)1}\e\\"
 425         }
 426     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 427         window_title() {
 428             print -n "\e]2;${(V)1}\e\\"
 429         }
 430     else
 431         # Fallback if another TERM is used.
 432         window_title() { }
 433     fi
 434
 435     # Add the preexec() and precmd() hooks.
 436     add-zsh-hook preexec window_preexec
 437     add-zsh-hook precmd window_precmd
 438 else
 439     # Fallback if another TERM is used, necessary to run screen (see below in
 440     # "RUN COMMANDS").
 441     window_preexec() { }
 442 fi
 443
 444
 445 # COMPLETION SETTINGS
 446
 447 # Load the complist module which provides additions to completion lists
 448 # (coloring, scrollable).
 449 zmodload zsh/complist
 450 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 451 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 452 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
 453 # problem.
 454 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
 455
 456 # Use cache to speed up completions.
 457 zstyle ':completion:*' use-cache on
 458 zstyle ':completion:*' cache-path ~/.zsh/cache
 459
 460 # Complete arguments and fix spelling mistakes when possible.
 461 zstyle ':completion:*' completer _complete _match _correct _approximate
 462
 463 # Make sure the list of possible completions is displayed after pressing <TAB>
 464 # the first time.
 465 setopt nolistambiguous
 466 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 467 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 468 bindkey '^I' expand-or-complete-prefix
 469 # Try uppercase if the currently typed string doesn't match. This allows
 470 # typing in lowercase most of the time and completion fixes the case.
 471 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 472
 473 # Use ls like colors for completions.
 474 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 475
 476 # Make completion lists scrollable so "do you wish to see all n possibilities"
 477 # is no longer displayed.
 478 zstyle ':completion:*' list-prompt '%p'
 479 # Display group name (like 'external command', 'alias', etc.) when there are
 480 # multiple matches in bold.
 481 zstyle ':completion:*' format '    %B%d%b:'
 482 # Display different types of matches separately.
 483 zstyle ':completion:*' group-name ''
 484
 485 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
 486 # on Freenode for the fix (2010-12-17 13:46 CET).
 487 zle_highlight=(suffix:none)
 488
 489 # Ignore completion functions.
 490 zstyle ':completion:*:functions' ignored-patterns '_*'
 491 # Ignore parent directory.
 492 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 493 # Always complete one value (file name) only once in the current line. This
 494 # makes it easy to complete multiple values because I can just press tab to
 495 # get all possible values. Otherwise I would have to skip the first value
 496 # again and again.
 497 zstyle ':completion:*' ignore-line yes
 498 # Except for mv and cp, because I often want to use to similar names, so I
 499 # complete to the same and change it.
 500 zstyle ':completion:*:(mv|cp):*' ignore-line no
 501 # Don't complete ./config.* files, this makes running ./configure much
 502 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
 503 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 504
 505 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
 506 # Freenode (2010-06-06 04:54 CEST). See below to complete them.
 507 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns '*.aux' '*.log' \
 508                                                           '*.pdf' '*.class'
 509
 510 # Provide a fallback completer which always completes files. Useful when Zsh's
 511 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 512 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 513 zle -C complete-files complete-word _generic
 514 zstyle ':completion:complete-files:*' completer _files
 515 bindkey '^F' complete-files
 516
 517
 518 # CUSTOM ALIASES AND FUNCTIONS
 519
 520 # If ^C is pressed while typing a command, add it to the history so it can be
 521 # easily retrieved later and then abort like ^C normally does. This is useful
 522 # when I want to abort an command to do something in between and then finish
 523 # typing the command.
 524 #
 525 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 526 # starting with - don't cause errors; and to Nadav Har'El
 527 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 528 # correctly, both on the Zsh mailing list.
 529 TRAPINT() {
 530     # Store the current buffer in the history.
 531     zle && print -s -r -- $BUFFER
 532
 533     # Return the default exit code so Zsh aborts the current command.
 534     return $1
 535 }
 536
 537 # Load aliases and similar functions also used by other shells.
 538 if [[ -f ~/.shell/aliases ]]; then
 539     . ~/.shell/aliases
 540 fi
 541
 542 # Make sure aliases are expanded when using sudo.
 543 alias sudo='sudo '
 544
 545 # Global aliases for often used commands in the command line.
 546 alias -g E='2>&1'
 547 alias -g L='E | less'
 548 alias -g D='E | colordiff L'
 549 alias -g G='| grep'
 550 alias -g S='| sort'
 551 alias -g U='| uniq'
 552 alias -g H='| head'
 553 alias -g T='| tail'
 554
 555 # Make going up directories simple.
 556 alias -g ...='../..'
 557 alias -g ....='../../..'
 558 alias -g .....='../../../..'
 559
 560 # If the window naming feature is used (see above) then use ".zsh" (leading
 561 # dot) as title name after running clear so it's clear to me that the window
 562 # is empty. I open so much windows that I don't know in which I have something
 563 # important. This helps me to remember which windows are empty (I run clear
 564 # after I finished my work in a window).
 565 if [[ -n $window_reset ]]; then
 566     alias clear='clear; window_reset=yes; window_precmd reset'
 567 fi
 568
 569 # Display all branches (except stash) in gitk but only 200 commits as this is
 570 # much faster. Also put in the background and disown. Thanks to sitaram in
 571 # #git on Freenode (2009-04-20 15:51).
 572 gitk() {
 573     command gitk \
 574         --max-count=200 \
 575         $(git rev-parse --symbolic-full-name --remotes --branches) \
 576         $@ &
 577     disown %command
 578 }
 579 # Same for tig (except the disown part as it's no GUI program).
 580 tig() {
 581     command tig \
 582         --max-count=200 \
 583         $(git rev-parse --symbolic-full-name --remotes --branches) \
 584         $@
 585 }
 586
 587 # Pipe output through less.
 588 tree() {
 589     command tree -C "$@" | less
 590 }
 591
 592 # Automatically disown.
 593 xpdf() {
 594     command xpdf "$@" &
 595     disown %command
 596 }
 597
 598
 599 # OS SPECIFIC SETTINGS
 600
 601 if [[ $OSTYPE == linux* ]]; then
 602     # Settings when creating Debian packages.
 603     DEBEMAIL=simon@ruderich.org
 604     export DEBEMAIL
 605     DEBFULLNAME='Simon Ruderich'
 606     export DEBFULLNAME
 607 fi
 608
 609
 610 # LOAD ADDITIONAL CONFIGURATION FILES
 611
 612 source_config ~/.zsh/rc.local
 613
 614
 615 # RUN COMMANDS
 616
 617 # If not already in screen reattach to a running session or create a new one.
 618 # This also starts screen on a remote server when connecting through ssh.
 619 if [[ $TERM != dumb && $TERM != linux && -z $STY ]]; then
 620     # Get running detached sessions.
 621     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 622
 623     # As we exec later we have to set the title here.
 624     window_preexec "screen"
 625
 626     # Create a new session if none is running.
 627     if [[ -z $session ]]; then
 628         exec screen
 629     # Reattach to a running session.
 630     else
 631         exec screen -r $session
 632     fi
 633 fi
 634
 635 # Colorize stderr in red. Very useful when looking for errors. Thanks to
 636 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 637 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
 638 # yet perfect and doesn't work with su and git for example, but it can handle
 639 # most interactive output quite well (even with no trailing new line) and in
 640 # cases it doesn't work, the E alias can be used as workaround.
 641 #
 642 # Moved in the "run commands" section to prevent one unnecessary zsh process
 643 # when starting screen (see above).
 644 exec 2>>(while read -r -k -u 0 line; do
 645     printf '\e[91m%s\e[0m' "$line";
 646     print -n $'\0';
 647 done &)
 648
 649 # Run reminder and redisplay it every four hours (if it's available).
 650 PERIOD=14400
 651 periodic() {
 652     which rem > /dev/null && [ -f ~/.reminders ] && rem -h
 653 }
 654
 655
 656 source_debug ". ~/.zsh/rc (done)"
 657
 658 # vim: ft=zsh