zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 149 # doesn't need any space, necessary for correct prompt draw.
 150 local red="%{${fg[red]}%}"
 151 local blue="%{${fg[blue]}%}"
 152 local green="%{${fg[green]}%}"
 153 local yellow="%{${fg[yellow]}%}"
 154 local default="%{${fg[default]}%}"
 155
 156 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 157 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 158 # symbolic link to current checkout of Zsh's sources).
 159 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 160       -d ~/.zsh/functions/vcs_info ]]; then
 161     # Update fpath to allow loading the vcs_info functions.
 162     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 163        fpath=(~/.zsh/functions/vcs_info/
 164               ~/.zsh/functions/vcs_info/Backends
 165               $fpath)
 166     fi
 167
 168     # Load vcs_info to display information about version control repositories.
 169     autoload -Uz vcs_info
 170     # Only look for git and mercurial repositories; the only I use.
 171     zstyle ':vcs_info:*' enable git hg
 172     # Check the repository for changes so they can be used in %u/%c (see
 173     # below). This comes with a speed penalty for bigger repositories.
 174     zstyle ':vcs_info:*' check-for-changes true
 175
 176     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 177     # is displayed. If there is an special action going on (merge, rebase)
 178     # it's also displayed (red). Also display if there are unstaged or staged
 179     # (%u/%c) changes.
 180     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 181           -d ~/.zsh/functions/vcs_info ]]; then
 182         zstyle ':vcs_info:*' formats \
 183             "($green%b%u%c$default:$blue%s$default)"
 184         zstyle ':vcs_info:*' actionformats \
 185             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 186     else
 187         # In older versions %u and %c are not defined yet and are not
 188         # correctly expanded.
 189         zstyle ':vcs_info:*' formats \
 190             "($green%b$default:$blue%s$default)"
 191         zstyle ':vcs_info:*' actionformats \
 192             "($green%b$default/$red%a$default:$blue%s$default)"
 193     fi
 194     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 195     # changes are detected in the repository; check-for-changes must be set to
 196     # true for this to work. Thanks to Bart Trojanowski
 197     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 198     # (2010-03-11 00:20).
 199     zstyle ':vcs_info:*' unstagedstr '¹'
 200     zstyle ':vcs_info:*' stagedstr   '²'
 201
 202     # Default to running vcs_info. If possible we prevent running it later for
 203     # speed reasons. If set to a non empty value vcs_info is run.
 204     FORCE_RUN_VCS_INFO=1
 205
 206     # Cache system inspired by Bart Trojanowski
 207     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 208     #zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 209     +vi-pre-get-data() {
 210         # Only Git and Mercurial support and need caching. Abort if any other
 211         # VCS is used.
 212         [[ "$vcs" != git && "$vcs" != hg ]] && return
 213
 214         # If the shell just started up or we changed directories (or for other
 215         # custom reasons) we must run vcs_info.
 216         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 217             FORCE_RUN_VCS_INFO=
 218             return
 219         fi
 220
 221         # Don't run vcs_info by default to speed up the shell.
 222         ret=1
 223         # If a git/hg command was run then run vcs_info as the status might
 224         # need to be updated.
 225         case "$(fc -ln $(($HISTCMD-1)))" in
 226             git* | g\ *)
 227                 ret=0
 228                 ;;
 229             hg*)
 230                 ret=0
 231                 ;;
 232         esac
 233     }
 234
 235     # Must run vcs_info when changing directories.
 236     prompt_chpwd() {
 237         FORCE_RUN_VCS_INFO=1
 238     }
 239     add-zsh-hook chpwd prompt_chpwd
 240
 241     RUN_VCS_INFO=1
 242 else
 243     RUN_VCS_INFO=
 244 fi
 245
 246 # Set the default prompt. The current host and working directory is displayed,
 247 # the exit code of the last command if it wasn't 0, the number of running jobs
 248 # if not 0.
 249 #
 250 # The prompt is in green and blue to make easily detectable, the error exit
 251 # code in red and bold and the job count in yellow.
 252 prompt_precmd() {
 253     # Call vcs_info before every prompt.
 254     if [[ -n $RUN_VCS_INFO ]]; then
 255         vcs_info
 256
 257         # Display the VCS information in the right prompt.
 258         if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 259             RPROMPT="${vcs_info_msg_0_}"
 260         # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 261         # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 262         # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 263         else
 264             RPROMPT="${vcs_info_msg_0_:- }"
 265         fi
 266     fi
 267
 268     PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 269 %(1j.$yellow%j$default.)%# \
 270 %(?..($red%B%?%b$default%) )"
 271 }
 272 add-zsh-hook precmd prompt_precmd
 273
 274
 275 # When screen, xterm or rxvt is used set the name of the window to the
 276 # currently running program.
 277 #
 278 # When a program is started preexec() sets the window's name to it; when it
 279 # stops precmd() resets the window's name to 'zsh'.
 280 #
 281 # It works with screen, xterm and rxvt.
 282 #
 283 # If a command is run with sudo or if the shell is running as root then a ! is
 284 # added at the beginning of the command to make this clear. If a command is
 285 # running on a different computer with ssh a @ is added at the beginning. If
 286 # screen is running on the remote machine instead of @screen @:hostname
 287 # (hostname replaced by the machine's hostname) is displayed. This only works
 288 # if the .zshrc on the server also uses this command.
 289 #
 290 # screen* is necessary as `screen` uses screen.linux for example for a linux
 291 # console.
 292 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 293     # Is set to a non empty value to reset the window name in the next
 294     # precmd() call.
 295     window_reset=yes
 296     # Is set to a non empty value when the shell is running as root.
 297     if [[ $(id -u) -eq 0 ]]; then
 298         window_root=yes
 299     fi
 300
 301     window_preexec() {
 302         # Get the program name with its arguments.
 303         local program_name=$1
 304
 305         # When sudo is used use real program name instead, but with an
 306         # exclamation mark at the beginning (handled below).
 307         local program_sudo=
 308         if [[ $program_name == sudo* ]]; then
 309             program_name=${program_name#sudo }
 310             program_sudo=yes
 311         fi
 312         # Remove all arguments from the program name.
 313         program_name=${program_name%% *}
 314
 315         # Ignore often used commands which are only running for a very short
 316         # time. This prevents a "blinking" name when it's changed to "cd" for
 317         # example and then some milliseconds later back to "zsh".
 318         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 319
 320         # Change my shortcuts so the real name of the program is displayed.
 321         case $program_name in
 322             e)
 323                 program_name=elinks
 324                 ;;
 325             g)
 326                 program_name=git
 327                 ;;
 328             m)
 329                 program_name=mutt
 330                 ;;
 331             v)
 332                 program_name=vim
 333                 ;;
 334         esac
 335
 336         # Add an exclamation mark at the beginning if running with sudo or if
 337         # running zsh as root.
 338         if [[ -n $program_sudo || -n $window_root ]]; then
 339             program_name=!$program_name
 340         fi
 341
 342         # Add an at mark at the beginning if running through ssh on a
 343         # different computer.
 344         if [[ -n $SSH_CONNECTION ]]; then
 345             program_name="@$program_name"
 346
 347             # If screen is running in SSH then display "@:hostname" as title
 348             # in the term/outer screen.
 349             if [[ $program_name == @screen ]]; then
 350                 program_name="@:${$(hostname)//.*/}"
 351             fi
 352         fi
 353
 354         # Set the window name to the currently running program.
 355         window_title "$program_name"
 356
 357         # Tell precmd() to reset the window name when the program stops.
 358         window_reset=yes
 359     }
 360
 361     window_precmd() {
 362         # Abort if no window name reset is necessary.
 363         [[ -z $window_reset ]] && return
 364
 365         # Reset the window name to 'zsh'.
 366         local name=zsh
 367         # If the function was called with an argument then reset the window
 368         # name to '.zsh' (used by clear alias).
 369         if [[ -n $1 ]]; then
 370             name=.zsh
 371         fi
 372
 373         # Prepend prefixes like in window_preexec().
 374         if [[ -n $window_root ]]; then
 375             name="!$name"
 376         fi
 377         if [[ -n $SSH_CONNECTION ]]; then
 378             name="@$name"
 379         fi
 380         window_title $name
 381
 382         # Just reset the name, so no screen reset necessary for the moment.
 383         window_reset=
 384     }
 385
 386     # Sets the window title. Works with screen, xterm and rxvt.
 387     if [[ $TERM == screen* ]]; then
 388         window_title() {
 389             print -n "\ek$1\e\\"
 390         }
 391     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 392         window_title() {
 393             print -n "\e]2;$1\e\\"
 394         }
 395     else
 396         # Fallback if another TERM is used.
 397         window_title() { }
 398     fi
 399
 400     # Add the preexec() and precmd() hooks.
 401     add-zsh-hook preexec window_preexec
 402     add-zsh-hook precmd window_precmd
 403 fi
 404
 405
 406 # COMPLETION SETTINGS
 407
 408 # Load the complist module which provides additions to completion lists
 409 # (coloring, scrollable).
 410 zmodload zsh/complist
 411 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 412 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 413 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 414 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 415
 416 # Use cache to speed up completions.
 417 zstyle ':completion:*' use-cache on
 418 zstyle ':completion:*' cache-path ~/.zsh/cache
 419
 420 # Complete arguments and fix spelling mistakes when possible.
 421 zstyle ':completion:*' completer _complete _match _correct _approximate
 422
 423 # Make sure the list of possible completions is displayed after pressing <TAB>
 424 # the first time.
 425 setopt nolistambiguous
 426 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 427 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 428 bindkey '^I' expand-or-complete-prefix
 429 # Try uppercase if the currently typed string doesn't match. This allows
 430 # typing in lowercase most of the time and completion fixes the case.
 431 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 432
 433 # Use ls like colors for completions.
 434 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 435
 436 # Make completion lists scrollable so "do you wish to see all n possibilities"
 437 # is no longer displayed.
 438 zstyle ':completion:*' list-prompt '%p'
 439 # Display group name (like 'external command', 'alias', etc.) when there are
 440 # multiple matches in bold.
 441 zstyle ':completion:*' format '    %B%d%b:'
 442 # Display different types of matches separately.
 443 zstyle ':completion:*' group-name ''
 444
 445 # Ignore completion functions.
 446 zstyle ':completion:*:functions' ignored-patterns '_*'
 447 # Ignore parent directory.
 448 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 449 # Always complete one value (file name) only once in the current line. This
 450 # makes it easy to complete multiple values because I can just press tab to
 451 # get all possible values. Otherwise I would have to skip the first value
 452 # again and again.
 453 zstyle ':completion:*' ignore-line yes
 454 # Except for mv and cp, because I often want to use to similar names, so I
 455 # complete to the same and change it.
 456 zstyle ':completion:*:(mv|cp):*' ignore-line no
 457
 458
 459 # CUSTOM ALIASES AND FUNCTIONS
 460
 461 # If ^C is pressed while typing a command, add it to the history so it can be
 462 # easily retrieved later and then abort like ^C normally does. This is useful
 463 # when I want to abort an command to do something in between and then finish
 464 # typing the command.
 465 #
 466 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 467 # starting with - don't cause errors; and to Nadav Har'El
 468 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 469 # correctly, both on the Zsh mailing list.
 470 TRAPINT() {
 471     # Store the current buffer in the history.
 472     zle && print -s -r -- $BUFFER
 473
 474     # Return the default exit code so Zsh aborts the current command.
 475     return $1
 476 }
 477
 478 # Colorize stderr. Very useful when looking for errors. Thanks to
 479 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 480 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 481 # perfect and doesn't work with su and git for example, but it can handle most
 482 # interactive output quite well (even with no trailing new line) and in those
 483 # cases the E alias can be used as workaround.
 484 exec 2>>(while read -r -k -u 0 line; do
 485     printf '\e[91m%s\e[0m' "$line";
 486     print -n $'\0';
 487 done &)
 488
 489 # Load aliases and similar functions also used by other shells.
 490 if [[ -f ~/.shell/aliases ]]; then
 491     . ~/.shell/aliases
 492 fi
 493
 494 # Make sure aliases are expanded when using sudo.
 495 alias sudo='sudo '
 496
 497 # Global aliases for often used commands in the command line.
 498 alias -g E='2>&1'
 499 alias -g L='E | less'
 500 alias -g D='E | colordiff L'
 501 alias -g G='| grep'
 502 alias -g S='| sort'
 503 alias -g U='| uniq'
 504 alias -g H='| head'
 505 alias -g T='| tail'
 506
 507 # Make going up directories simple.
 508 alias -g ...='../..'
 509 alias -g ....='../../..'
 510 alias -g .....='../../../..'
 511
 512 # If the window naming feature is used (see above) then use ".zsh" (leading
 513 # dot) as title name after running clear so it's clear to me that the window
 514 # is empty. I open so much windows that I don't know in which I have something
 515 # important. This helps me to remember which windows are empty (I run clear
 516 # after I finished my work in a window).
 517 if [[ -n $window_reset ]]; then
 518     alias clear='clear; window_reset=yes; window_precmd reset'
 519 fi
 520
 521 # Display all branches (except stash) in gitk but only 200 commits as this is
 522 # much faster. Also put in the background and disown. Thanks to sitaram in
 523 # #git on Freenode (2009-04-20 15:51).
 524 gitk() {
 525     command gitk \
 526         --max-count=200 \
 527         $(git rev-parse --symbolic-full-name --remotes --branches) \
 528         $@ &
 529     disown %command
 530 }
 531 # Same for tig (except the disown part as it's no GUI program).
 532 tig() {
 533     command tig \
 534         --max-count=200 \
 535         $(git rev-parse --symbolic-full-name --remotes --branches) \
 536         $@
 537 }
 538
 539
 540 # OS SPECIFIC SETTINGS
 541
 542 local uname=$(uname)
 543
 544 if [[ $uname == Linux ]]; then
 545     # Settings when creating Debian packages.
 546     DEBEMAIL=simon@ruderich.org
 547     export DEBEMAIL
 548     DEBFULLNAME='Simon Ruderich'
 549     export DEBFULLNAME
 550
 551 elif [[ $uname == Darwin ]]; then # Mac OS X
 552     # Store the current clipboard in CLIPBOARD before every command so it can
 553     # be used in commands.
 554     os_darwin_preexec() {
 555         export CLIPBOARD="$(pbpaste)"
 556     }
 557     # Add the function as preexec hook.
 558     add-zsh-hook preexec os_darwin_preexec
 559
 560     # Initialize CLIPBOARD so it's available for completion directly after
 561     # startup.
 562     CLIPBOARD=""
 563     export CLIPBOARD
 564
 565     # Fetch current URL in clipboard with wget.
 566     alias wnc='wget --no-proxy $CLIPBOARD'
 567 fi
 568
 569
 570 # LOAD ADDITIONAL CONFIGURATION FILES
 571
 572 # Load rc file for current hostname (first part before a dot) or rc.local.
 573 source_config ~/.zsh host rc ${$(hostname)//.*/}
 574
 575
 576 # RUN COMMANDS
 577
 578 # If not already in screen reattach to a running session or create a new one.
 579 # This also starts screen one a remote server when connecting through ssh.
 580 if [[ $TERM != dumb && -z $STY ]]; then
 581     # Get running detached sessions.
 582     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 583
 584     # As we exec later we have to set the title here.
 585     window_preexec "screen"
 586
 587     # Create a new session if none is running.
 588     if [[ -z $session ]]; then
 589         exec screen
 590     # Reattach to a running session.
 591     else
 592         exec screen -r $session
 593     fi
 594 fi
 595
 596
 597 source_debug "finished sourcing ~/.zsh/rc"
 598
 599 # vim: ft=zsh