zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug ". ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Use jj and jk to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42 bindkey 'jk' vi-cmd-mode
  43
  44 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  45 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  46 # Also not in Vi mode.
  47 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  48
  49
  50 # FUNCTION SETTINGS
  51
  52 # Make sure every entry in $fpath is unique.
  53 typeset -U fpath
  54 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  55 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  56 if [[ -d ~/.zsh/functions/completion ]]; then
  57     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  58 fi
  59 # Set correct fpath to allow loading my functions (including completion
  60 # functions).
  61 fpath=(~/.zsh/functions $fpath)
  62 # Autoload my functions (except completion functions and hidden files). Thanks
  63 # to caphuso from the Zsh example files for this idea.
  64 if [[ -d ~/.zsh/functions ]]; then
  65     autoload -Uz ${fpath[1]}/^_*(^/:t)
  66 fi
  67
  68 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  69 # the moment only precmd(), preexec() and chpwd() are simulated.
  70 #
  71 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  72 # so the compatibility version is used there too.
  73 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  74     # Provide add-zsh-hook which was added in 4.3.4.
  75     fpath=(~/.zsh/functions/compatibility $fpath)
  76
  77     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  78     # arrays.
  79     function precmd() {
  80         for function in $precmd_functions; do
  81             $function $@
  82         done
  83     }
  84     function preexec() {
  85         for function in $preexec_functions; do
  86             $function $@
  87         done
  88     }
  89     function chpwd() {
  90         for function in $chpwd_functions; do
  91             $function $@
  92         done
  93     }
  94 fi
  95
  96 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  97 autoload -Uz add-zsh-hook
  98
  99 # Load zmv (zsh move) which is powerful to rename files.
 100 autoload -Uz zmv
 101
 102
 103 # HISTORY SETTINGS
 104
 105 # Use history and store it in ~/.zsh/history.
 106 HISTSIZE=50000
 107 SAVEHIST=50000
 108 HISTFILE=~/.zsh/history
 109 # Append to the history file instead of overwriting it and do it immediately
 110 # when a command is executed.
 111 setopt appendhistory
 112 setopt incappendhistory
 113 # If the same command is run multiple times store it only once in the history.
 114 setopt histignoredups
 115 # Vim like completions of previous executed commands (also enter Vi-mode). If
 116 # called at the beginning it just recalls old commands (like cursor up), if
 117 # called after typing something, only lines starting with the typed are
 118 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 119 # on Freenode (2010-01-17 12:47 CET) for the information how to a use function
 120 # with bindkey.
 121 zle -N my-vi-history-beginning-search-backward
 122 my-vi-history-beginning-search-backward() {
 123     local not_at_beginning_of_line
 124     if [[ $CURSOR -ne 0 ]]; then
 125         not_at_beginning_of_line=yes
 126     fi
 127
 128     zle history-beginning-search-backward
 129
 130     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 131     # this counters it).
 132     zle vi-cmd-mode
 133     if [[ -n $not_at_beginning_of_line ]]; then
 134         zle vi-forward-char
 135     fi
 136 }
 137 bindkey '^P' my-vi-history-beginning-search-backward
 138 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 139 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 140 # after calling ^P.
 141 bindkey -a '^N' history-beginning-search-forward
 142
 143
 144 # PROMPT SETTINGS
 145
 146 # Use colorized output, necessary for prompts and completions.
 147 autoload -Uz colors && colors
 148
 149 # Necessary for $EPOCHSECONDS, the UNIX time.
 150 zmodload zsh/datetime
 151
 152 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 153 # doesn't need any space, necessary for correct prompt draw.
 154 local red="%{${fg[red]}%}"
 155 local blue="%{${fg[blue]}%}"
 156 local green="%{${fg[green]}%}"
 157 local yellow="%{${fg[yellow]}%}"
 158 local default="%{${fg[default]}%}"
 159
 160 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 161 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 162 # symbolic link to current checkout of Zsh's sources).
 163 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 164       -d ~/.zsh/functions/vcs_info ]]; then
 165     # Update fpath to allow loading the vcs_info functions.
 166     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 167        fpath=(~/.zsh/functions/vcs_info/
 168               ~/.zsh/functions/vcs_info/Backends
 169               $fpath)
 170     fi
 171
 172     # Load vcs_info to display information about version control repositories.
 173     autoload -Uz vcs_info
 174     # Only look for git and mercurial repositories; the only I use.
 175     zstyle ':vcs_info:*' enable git hg
 176     # Check the repository for changes so they can be used in %u/%c (see
 177     # below). This comes with a speed penalty for bigger repositories.
 178     zstyle ':vcs_info:*' check-for-changes true
 179
 180     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 181     # is displayed. If there is an special action going on (merge, rebase)
 182     # it's also displayed (red). Also display if there are unstaged or staged
 183     # (%u/%c) changes.
 184     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 185           -d ~/.zsh/functions/vcs_info ]]; then
 186         zstyle ':vcs_info:*' formats \
 187             "($green%b%u%c$default:$blue%s$default)"
 188         zstyle ':vcs_info:*' actionformats \
 189             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 190     else
 191         # In older versions %u and %c are not defined yet and are not
 192         # correctly expanded.
 193         zstyle ':vcs_info:*' formats \
 194             "($green%b$default:$blue%s$default)"
 195         zstyle ':vcs_info:*' actionformats \
 196             "($green%b$default/$red%a$default:$blue%s$default)"
 197     fi
 198     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 199     # changes are detected in the repository; check-for-changes must be set to
 200     # true for this to work. Thanks to Bart Trojanowski
 201     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 202     # (2010-03-11 00:20 CET).
 203     zstyle ':vcs_info:*' unstagedstr '¹'
 204     zstyle ':vcs_info:*' stagedstr   '²'
 205
 206     # Default to running vcs_info. If possible we prevent running it later for
 207     # speed reasons. If set to a non empty value vcs_info is run.
 208     FORCE_RUN_VCS_INFO=1
 209
 210     # Cache system inspired by Bart Trojanowski
 211     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 212     zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 213     +vi-pre-get-data() {
 214         # Only Git and Mercurial support and need caching. Abort if any other
 215         # VCS is used.
 216         [[ "$vcs" != git && "$vcs" != hg ]] && return
 217
 218         # If the shell just started up or we changed directories (or for other
 219         # custom reasons) we must run vcs_info.
 220         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 221             FORCE_RUN_VCS_INFO=
 222             return
 223         fi
 224
 225         # Don't run vcs_info by default to speed up the shell.
 226         ret=1
 227         # If a git/hg command was run then run vcs_info as the status might
 228         # need to be updated.
 229         case "$(fc -ln $(($HISTCMD-1)))" in
 230             git* | g\ *)
 231                 ret=0
 232                 ;;
 233             hg*)
 234                 ret=0
 235                 ;;
 236         esac
 237     }
 238
 239     # Must run vcs_info when changing directories.
 240     prompt_chpwd() {
 241         FORCE_RUN_VCS_INFO=1
 242     }
 243     add-zsh-hook chpwd prompt_chpwd
 244
 245     # Used by prompt code below to determine if vcs_info should be run.
 246     RUN_VCS_INFO=1
 247 else
 248     RUN_VCS_INFO=
 249 fi
 250
 251 # Set the prompt. A two line prompt is used. On the top left the current
 252 # working directory is displayed, on the right vcs_info (if available). On the
 253 # bottom left current user name and host is shown, the exit code of the last
 254 # command if it wasn't 0, the number of running jobs if not 0.
 255 #
 256 # The prompt is in green and blue to make easily detectable, the error exit
 257 # code in red and bold and the job count in yellow.
 258 #
 259 # Thanks to Adam's prompt for the basic idea of this prompt.
 260 #
 261 # The current time is display in hex in the right prompt.
 262 prompt_precmd() {
 263     # Regex to remove elements which take no space. Used to calculate the
 264     # width of the top prompt. Thanks to Bart's and Adam's prompt code in
 265     # Functions/Prompts/prompt_*_setup.
 266     local zero='%([BSUbfksu]|([FB]|){*})'
 267
 268     # Call vcs_info before every prompt.
 269     if [[ -n $RUN_VCS_INFO ]]; then
 270         vcs_info
 271     else
 272         vcs_info_msg_0_=
 273     fi
 274
 275     local width width_left width_right
 276     local top_left top_right
 277
 278     # Display the current time in HEX in bright blue and vcs_info (if used) on
 279     # the right in the top prompt.
 280     top_right="$vcs_info_msg_0_($blue%B0x$(([##16] EPOCHSECONDS))%b$default)"
 281     width_right=${#${(S%%)top_right//$~zero/}}
 282     # Remove it if it would get too long.
 283     if [[ $(( COLUMNS - 4 - 1 - width_right )) -lt 0 ]]; then
 284         top_right=
 285         width_right=0
 286     fi
 287
 288     # Display current directory on the left in the top prompt. Truncate the
 289     # directory if necessary.
 290     width=$(( COLUMNS - 4 - 1 - width_right ))
 291     top_left=".-$default%b($yellow%$width<..<%~%<<$default)%B$blue"
 292
 293     # Calculate the width of the top prompt to fill the middle with "-".
 294     width_left=${#${(S%%)top_left//$~zero/}}
 295     width_right=${#${(S%%)top_right//$~zero/}}
 296     width=$(( COLUMNS - width_left - width_right ))
 297
 298     PROMPT="$blue%B$top_left${(l:$width::-:)}%b$default$top_right
 299 $blue%B'%b$default\
 300 $green%B%n%b$default@$green%B%m%b$default %(1j.$yellow%j$default.)%# \
 301 %(?..($red%B%?%b$default%) )"
 302 }
 303 add-zsh-hook precmd prompt_precmd
 304
 305
 306 # When screen, xterm or rxvt is used set the name of the window to the
 307 # currently running program.
 308 #
 309 # When a program is started preexec() sets the window's name to it; when it
 310 # stops precmd() resets the window's name to 'zsh'.
 311 #
 312 # It works with screen, xterm and rxvt.
 313 #
 314 # If a command is run with sudo or if the shell is running as root then a ! is
 315 # added at the beginning of the command to make this clear. If a command is
 316 # running on a different computer with ssh a @ is added at the beginning. If
 317 # screen is running on the remote machine instead of @screen @:hostname
 318 # (hostname replaced by the machine's hostname) is displayed. This only works
 319 # if the .zshrc on the server also uses this command.
 320 #
 321 # screen* is necessary as `screen` uses screen.linux for example for a linux
 322 # console.
 323 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 324     # Is set to a non empty value to reset the window name in the next
 325     # precmd() call.
 326     window_reset=yes
 327     # Is set to a non empty value when the shell is running as root.
 328     if [[ $UID -eq 0 ]]; then
 329         window_root=yes
 330     fi
 331
 332     window_preexec() {
 333         # Get the program name with its arguments.
 334         local program_name=$1
 335
 336         # When sudo is used use real program name instead, but with an
 337         # exclamation mark at the beginning (handled below).
 338         local program_sudo=
 339         if [[ $program_name == sudo* ]]; then
 340             program_name=${program_name#sudo }
 341             program_sudo=yes
 342         fi
 343         # Remove all arguments from the program name.
 344         program_name=${program_name%% *}
 345
 346         # Ignore often used commands which are only running for a very short
 347         # time. This prevents a "blinking" name when it's changed to "cd" for
 348         # example and then some milliseconds later back to "zsh".
 349         [[ $program_name == (cd*|d|ls|l|la|ll|clear|c) ]] && return
 350
 351         # Change my shortcuts so the real name of the program is displayed.
 352         case $program_name in
 353             e)
 354                 program_name=elinks
 355                 ;;
 356             g)
 357                 program_name=git
 358                 ;;
 359             m)
 360                 program_name=mutt
 361                 ;;
 362             v)
 363                 program_name=vim
 364                 ;;
 365         esac
 366
 367         # Add an exclamation mark at the beginning if running with sudo or if
 368         # running zsh as root.
 369         if [[ -n $program_sudo || -n $window_root ]]; then
 370             program_name=!$program_name
 371         fi
 372
 373         # Add an at mark at the beginning if running through ssh on a
 374         # different computer.
 375         if [[ -n $SSH_CONNECTION ]]; then
 376             program_name="@$program_name"
 377
 378             # If screen is running in SSH then display "@:hostname" as title
 379             # in the term/outer screen.
 380             if [[ $program_name == @screen ]]; then
 381                 program_name="@:${HOST//.*/}"
 382             # Use "@:!hostname" for root screens.
 383             elif [[ $program_name == @!screen ]]; then
 384                 program_name="@:!${HOST//.*/}"
 385             fi
 386         fi
 387
 388         # Set the window name to the currently running program.
 389         window_title "$program_name"
 390
 391         # Tell precmd() to reset the window name when the program stops.
 392         window_reset=yes
 393     }
 394
 395     window_precmd() {
 396         # Abort if no window name reset is necessary.
 397         [[ -z $window_reset ]] && return
 398
 399         # Reset the window name to 'zsh'.
 400         local name=zsh
 401         # If the function was called with an argument then reset the window
 402         # name to '.zsh' (used by clear alias).
 403         if [[ -n $1 ]]; then
 404             name=.zsh
 405         fi
 406
 407         # Prepend prefixes like in window_preexec().
 408         if [[ -n $window_root ]]; then
 409             name="!$name"
 410         fi
 411         if [[ -n $SSH_CONNECTION ]]; then
 412             name="@$name"
 413         fi
 414         window_title $name
 415
 416         # Just reset the name, so no screen reset necessary for the moment.
 417         window_reset=
 418     }
 419
 420     # Sets the window title. Works with screen, xterm and rxvt. (V) escapes
 421     # all non-printable characters. Thanks to Mikachu in #zsh on Freenode
 422     # (2010-08-07 17:09 CEST).
 423     if [[ $TERM == screen* ]]; then
 424         window_title() {
 425             print -n "\ek${(V)1}\e\\"
 426         }
 427     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 428         window_title() {
 429             print -n "\e]2;${(V)1}\e\\"
 430         }
 431     else
 432         # Fallback if another TERM is used.
 433         window_title() { }
 434     fi
 435
 436     # Add the preexec() and precmd() hooks.
 437     add-zsh-hook preexec window_preexec
 438     add-zsh-hook precmd window_precmd
 439 else
 440     # Fallback if another TERM is used, necessary to run screen (see below in
 441     # "RUN COMMANDS").
 442     window_preexec() { }
 443 fi
 444
 445
 446 # COMPLETION SETTINGS
 447
 448 # Load the complist module which provides additions to completion lists
 449 # (coloring, scrollable).
 450 zmodload zsh/complist
 451 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 452 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 453 # #zsh on Freenode (2009-08-07 21:05 CEST) for reminding me of the $fpath
 454 # problem.
 455 autoload -Uz compinit && compinit -d ~/.zsh/cache/zcompdump
 456
 457 # Use cache to speed up completions.
 458 zstyle ':completion:*' use-cache on
 459 zstyle ':completion:*' cache-path ~/.zsh/cache
 460
 461 # Complete arguments and fix spelling mistakes when possible.
 462 zstyle ':completion:*' completer _complete _match _correct _approximate
 463
 464 # Make sure the list of possible completions is displayed after pressing <TAB>
 465 # the first time.
 466 setopt nolistambiguous
 467 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 468 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 469 bindkey '^I' expand-or-complete-prefix
 470 # Try uppercase if the currently typed string doesn't match. This allows
 471 # typing in lowercase most of the time and completion fixes the case.
 472 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 473
 474 # Use ls like colors for completions.
 475 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 476
 477 # Make completion lists scrollable so "do you wish to see all n possibilities"
 478 # is no longer displayed.
 479 zstyle ':completion:*' list-prompt '%p'
 480 # Display group name (like 'external command', 'alias', etc.) when there are
 481 # multiple matches in bold.
 482 zstyle ':completion:*' format '    %B%d%b:'
 483 # Display different types of matches separately.
 484 zstyle ':completion:*' group-name ''
 485
 486 # Don't draw trailing / in bold (new in zsh 4.3.11). Thanks to Mikachu in #zsh
 487 # on Freenode for the fix (2010-12-17 13:46 CET).
 488 zle_highlight=(suffix:none)
 489
 490 # Ignore completion functions.
 491 zstyle ':completion:*:functions' ignored-patterns '_*'
 492 # Ignore parent directory.
 493 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 494 # Always complete one value (file name) only once in the current line. This
 495 # makes it easy to complete multiple values because I can just press tab to
 496 # get all possible values. Otherwise I would have to skip the first value
 497 # again and again.
 498 zstyle ':completion:*' ignore-line yes
 499 # Except for mv and cp, because I often want to use to similar names, so I
 500 # complete to the same and change it.
 501 zstyle ':completion:*:(mv|cp):*' ignore-line no
 502 # Don't complete ./config.* files, this makes running ./configure much
 503 # simpler. Thanks to Nomexous in #zsh on Freenode (2010-03-16 01:54 CET)
 504 zstyle ':completion:*:*:-command-:*' ignored-patterns './config.*'
 505
 506 # Don't complete unwanted files with Vim. Thanks to Nomexous in #zsh on
 507 # Freenode (2010-06-06 04:54 CEST). See below to complete them.
 508 zstyle ':completion:*:*:vim:*:all-files' ignored-patterns '*.aux' '*.log' \
 509                                                           '*.pdf' '*.class'
 510
 511 # Provide a fallback completer which always completes files. Useful when Zsh's
 512 # completion is too "smart". Thanks to Frank Terbeck <ft@bewatermyfriend.org>
 513 # (http://www.zsh.org/mla/users/2009/msg01038.html).
 514 zle -C complete-files complete-word _generic
 515 zstyle ':completion:complete-files:*' completer _files
 516 bindkey '^F' complete-files
 517
 518
 519 # CUSTOM ALIASES AND FUNCTIONS
 520
 521 # If ^C is pressed while typing a command, add it to the history so it can be
 522 # easily retrieved later and then abort like ^C normally does. This is useful
 523 # when I want to abort an command to do something in between and then finish
 524 # typing the command.
 525 #
 526 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 527 # starting with - don't cause errors; and to Nadav Har'El
 528 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 529 # correctly, both on the Zsh mailing list.
 530 TRAPINT() {
 531     # Store the current buffer in the history.
 532     zle && print -s -r -- $BUFFER
 533
 534     # Return the default exit code so Zsh aborts the current command.
 535     return $1
 536 }
 537
 538 # Load aliases and similar functions also used by other shells.
 539 if [[ -f ~/.shell/aliases ]]; then
 540     . ~/.shell/aliases
 541 fi
 542
 543 # Make sure aliases are expanded when using sudo.
 544 alias sudo='sudo '
 545
 546 # Global aliases for often used commands in the command line.
 547 alias -g E='2>&1'
 548 alias -g L='E | less'
 549 alias -g D='E | colordiff L'
 550 alias -g G='| grep'
 551 alias -g S='| sort'
 552 alias -g U='| uniq'
 553 alias -g H='| head'
 554 alias -g T='| tail'
 555
 556 # Make going up directories simple.
 557 alias -g ...='../..'
 558 alias -g ....='../../..'
 559 alias -g .....='../../../..'
 560
 561 # If the window naming feature is used (see above) then use ".zsh" (leading
 562 # dot) as title name after running clear so it's clear to me that the window
 563 # is empty. I open so much windows that I don't know in which I have something
 564 # important. This helps me to remember which windows are empty (I run clear
 565 # after I finished my work in a window).
 566 if [[ -n $window_reset ]]; then
 567     alias clear='clear; window_reset=yes; window_precmd reset'
 568 fi
 569
 570 # Display all branches (except stash) in gitk but only 200 commits as this is
 571 # much faster. Also put in the background and disown. Thanks to sitaram in
 572 # #git on Freenode (2009-04-20 15:51).
 573 gitk() {
 574     command gitk \
 575         --max-count=200 \
 576         $(git rev-parse --symbolic-full-name --remotes --branches) \
 577         $@ &
 578     disown %command
 579 }
 580 # Same for tig (except the disown part as it's no GUI program).
 581 tig() {
 582     command tig \
 583         --max-count=200 \
 584         $(git rev-parse --symbolic-full-name --remotes --branches) \
 585         $@
 586 }
 587
 588 # Pipe output through less.
 589 tree() {
 590     command tree -C "$@" | less
 591 }
 592
 593 # Automatically disown.
 594 xpdf() {
 595     command xpdf "$@" &
 596     disown %command
 597 }
 598
 599
 600 # OS SPECIFIC SETTINGS
 601
 602 if [[ $OSTYPE == linux* ]]; then
 603     # Settings when creating Debian packages.
 604     DEBEMAIL=simon@ruderich.org
 605     export DEBEMAIL
 606     DEBFULLNAME='Simon Ruderich'
 607     export DEBFULLNAME
 608 fi
 609
 610
 611 # LOAD ADDITIONAL CONFIGURATION FILES
 612
 613 source_config ~/.zsh/rc.local
 614
 615
 616 # RUN COMMANDS
 617
 618 # If not already in screen reattach to a running session or create a new one.
 619 # This also starts screen on a remote server when connecting through ssh.
 620 if [[ $TERM != dumb && $TERM != linux && -z $STY ]]; then
 621     # Get running detached sessions.
 622     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 623
 624     # As we exec later we have to set the title here.
 625     window_preexec "screen"
 626
 627     # Create a new session if none is running.
 628     if [[ -z $session ]]; then
 629         exec screen
 630     # Reattach to a running session.
 631     else
 632         exec screen -r $session
 633     fi
 634 fi
 635
 636 # Colorize stderr in red. Very useful when looking for errors. Thanks to
 637 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 638 # Freenode (2010-03-07 04:03 CET) for some improvements (-r, printf). It's not
 639 # yet perfect and doesn't work with su and git for example, but it can handle
 640 # most interactive output quite well (even with no trailing new line) and in
 641 # cases it doesn't work, the E alias can be used as workaround.
 642 #
 643 # Moved in the "run commands" section to prevent one unnecessary zsh process
 644 # when starting screen (see above).
 645 exec 2>>(while read -r -k -u 0 line; do
 646     printf '\e[91m%s\e[0m' "$line";
 647     print -n $'\0';
 648 done &)
 649
 650 # Run reminder and redisplay it every four hours (if it's available).
 651 PERIOD=14400
 652 periodic() {
 653     which rem > /dev/null && [ -f ~/.reminders ] && rem -h
 654 }
 655
 656
 657 source_debug ". ~/.zsh/rc (done)"
 658
 659 # vim: ft=zsh