zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 149 # doesn't need any space, necessary for correct prompt draw.
 150 local red="%{${fg[red]}%}"
 151 local blue="%{${fg[blue]}%}"
 152 local green="%{${fg[green]}%}"
 153 local yellow="%{${fg[yellow]}%}"
 154 local default="%{${fg[default]}%}"
 155
 156 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 157 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 158 # symbolic link to current checkout of Zsh's sources).
 159 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 160       -d ~/.zsh/functions/vcs_info ]]; then
 161     # Update fpath to allow loading the vcs_info functions.
 162     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 163        fpath=(~/.zsh/functions/vcs_info/
 164               ~/.zsh/functions/vcs_info/Backends
 165               $fpath)
 166     fi
 167
 168     # Load vcs_info to display information about version control repositories.
 169     autoload -Uz vcs_info
 170     # Only look for git and mercurial repositories; the only I use.
 171     zstyle ':vcs_info:*' enable git hg
 172     # Check the repository for changes so they can be used in %u/%c (see
 173     # below). This comes with a speed penalty for bigger repositories.
 174     zstyle ':vcs_info:*' check-for-changes true
 175
 176     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 177     # is displayed. If there is an special action going on (merge, rebase)
 178     # it's also displayed (red). Also display if there are unstaged or staged
 179     # (%u/%c) changes.
 180     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 181           -d ~/.zsh/functions/vcs_info ]]; then
 182         zstyle ':vcs_info:*' formats \
 183             "($green%b%u%c$default:$blue%s$default)"
 184         zstyle ':vcs_info:*' actionformats \
 185             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 186     else
 187         # In older versions %u and %c are not defined yet and are not
 188         # correctly expanded.
 189         zstyle ':vcs_info:*' formats \
 190             "($green%b$default:$blue%s$default)"
 191         zstyle ':vcs_info:*' actionformats \
 192             "($green%b$default/$red%a$default:$blue%s$default)"
 193     fi
 194     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 195     # changes are detected in the repository; check-for-changes must be set to
 196     # true for this to work. Thanks to Bart Trojanowski
 197     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 198     # (2010-03-11 00:20).
 199     zstyle ':vcs_info:*' unstagedstr '¹'
 200     zstyle ':vcs_info:*' stagedstr   '²'
 201
 202     # Default to running vcs_info. If possible we prevent running it later for
 203     # speed reasons. If set to a non empty value vcs_info is run.
 204     FORCE_RUN_VCS_INFO=1
 205
 206     # Cache system inspired by Bart Trojanowski
 207     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 208     #zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 209     +vi-pre-get-data() {
 210         # Only Git and Mercurial support and need caching. Abort if any other
 211         # VCS is used.
 212         [[ "$vcs" != git && "$vcs" != hg ]] && return
 213
 214         # If the shell just started up or we changed directories (or for other
 215         # custom reasons) we must run vcs_info.
 216         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 217             FORCE_RUN_VCS_INFO=
 218             return
 219         fi
 220
 221         # Don't run vcs_info by default to speed up the shell.
 222         ret=1
 223         # If a git/hg command was run then run vcs_info as the status might
 224         # need to be updated.
 225         case "$(fc -ln $(($HISTCMD-1)))" in
 226             git* | g\ *)
 227                 ret=0
 228                 ;;
 229             hg*)
 230                 ret=0
 231                 ;;
 232         esac
 233     }
 234
 235     # Must run vcs_info when changing directories.
 236     prompt_chpwd() {
 237         FORCE_RUN_VCS_INFO=1
 238     }
 239     add-zsh-hook chpwd prompt_chpwd
 240
 241     # Used by prompt code below to determine if vcs_info should be run.
 242     RUN_VCS_INFO=1
 243 else
 244     RUN_VCS_INFO=
 245 fi
 246
 247 # Set the default prompt. The current host and working directory is displayed,
 248 # the exit code of the last command if it wasn't 0, the number of running jobs
 249 # if not 0.
 250 #
 251 # The prompt is in green and blue to make easily detectable, the error exit
 252 # code in red and bold and the job count in yellow.
 253 prompt_precmd() {
 254     # Call vcs_info before every prompt.
 255     if [[ -n $RUN_VCS_INFO ]]; then
 256         vcs_info
 257
 258         # Display the VCS information in the right prompt.
 259         if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 260             RPROMPT="${vcs_info_msg_0_}"
 261         # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 262         # ${vcs_info_msg_0_} is empty. Provide a workaround for those
 263         # versions, thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 264         else
 265             RPROMPT="${vcs_info_msg_0_:- }"
 266         fi
 267     fi
 268
 269     PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 270 %(1j.$yellow%j$default.)%# \
 271 %(?..($red%B%?%b$default%) )"
 272 }
 273 add-zsh-hook precmd prompt_precmd
 274
 275
 276 # When screen, xterm or rxvt is used set the name of the window to the
 277 # currently running program.
 278 #
 279 # When a program is started preexec() sets the window's name to it; when it
 280 # stops precmd() resets the window's name to 'zsh'.
 281 #
 282 # It works with screen, xterm and rxvt.
 283 #
 284 # If a command is run with sudo or if the shell is running as root then a ! is
 285 # added at the beginning of the command to make this clear. If a command is
 286 # running on a different computer with ssh a @ is added at the beginning. If
 287 # screen is running on the remote machine instead of @screen @:hostname
 288 # (hostname replaced by the machine's hostname) is displayed. This only works
 289 # if the .zshrc on the server also uses this command.
 290 #
 291 # screen* is necessary as `screen` uses screen.linux for example for a linux
 292 # console.
 293 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 294     # Is set to a non empty value to reset the window name in the next
 295     # precmd() call.
 296     window_reset=yes
 297     # Is set to a non empty value when the shell is running as root.
 298     if [[ $(id -u) -eq 0 ]]; then
 299         window_root=yes
 300     fi
 301
 302     window_preexec() {
 303         # Get the program name with its arguments.
 304         local program_name=$1
 305
 306         # When sudo is used use real program name instead, but with an
 307         # exclamation mark at the beginning (handled below).
 308         local program_sudo=
 309         if [[ $program_name == sudo* ]]; then
 310             program_name=${program_name#sudo }
 311             program_sudo=yes
 312         fi
 313         # Remove all arguments from the program name.
 314         program_name=${program_name%% *}
 315
 316         # Ignore often used commands which are only running for a very short
 317         # time. This prevents a "blinking" name when it's changed to "cd" for
 318         # example and then some milliseconds later back to "zsh".
 319         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 320
 321         # Change my shortcuts so the real name of the program is displayed.
 322         case $program_name in
 323             e)
 324                 program_name=elinks
 325                 ;;
 326             g)
 327                 program_name=git
 328                 ;;
 329             m)
 330                 program_name=mutt
 331                 ;;
 332             v)
 333                 program_name=vim
 334                 ;;
 335         esac
 336
 337         # Add an exclamation mark at the beginning if running with sudo or if
 338         # running zsh as root.
 339         if [[ -n $program_sudo || -n $window_root ]]; then
 340             program_name=!$program_name
 341         fi
 342
 343         # Add an at mark at the beginning if running through ssh on a
 344         # different computer.
 345         if [[ -n $SSH_CONNECTION ]]; then
 346             program_name="@$program_name"
 347
 348             # If screen is running in SSH then display "@:hostname" as title
 349             # in the term/outer screen.
 350             if [[ $program_name == @screen ]]; then
 351                 program_name="@:${$(hostname)//.*/}"
 352             fi
 353         fi
 354
 355         # Set the window name to the currently running program.
 356         window_title "$program_name"
 357
 358         # Tell precmd() to reset the window name when the program stops.
 359         window_reset=yes
 360     }
 361
 362     window_precmd() {
 363         # Abort if no window name reset is necessary.
 364         [[ -z $window_reset ]] && return
 365
 366         # Reset the window name to 'zsh'.
 367         local name=zsh
 368         # If the function was called with an argument then reset the window
 369         # name to '.zsh' (used by clear alias).
 370         if [[ -n $1 ]]; then
 371             name=.zsh
 372         fi
 373
 374         # Prepend prefixes like in window_preexec().
 375         if [[ -n $window_root ]]; then
 376             name="!$name"
 377         fi
 378         if [[ -n $SSH_CONNECTION ]]; then
 379             name="@$name"
 380         fi
 381         window_title $name
 382
 383         # Just reset the name, so no screen reset necessary for the moment.
 384         window_reset=
 385     }
 386
 387     # Sets the window title. Works with screen, xterm and rxvt.
 388     if [[ $TERM == screen* ]]; then
 389         window_title() {
 390             print -n "\ek$1\e\\"
 391         }
 392     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 393         window_title() {
 394             print -n "\e]2;$1\e\\"
 395         }
 396     else
 397         # Fallback if another TERM is used.
 398         window_title() { }
 399     fi
 400
 401     # Add the preexec() and precmd() hooks.
 402     add-zsh-hook preexec window_preexec
 403     add-zsh-hook precmd window_precmd
 404 fi
 405
 406
 407 # COMPLETION SETTINGS
 408
 409 # Load the complist module which provides additions to completion lists
 410 # (coloring, scrollable).
 411 zmodload zsh/complist
 412 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 413 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 414 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 415 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 416
 417 # Use cache to speed up completions.
 418 zstyle ':completion:*' use-cache on
 419 zstyle ':completion:*' cache-path ~/.zsh/cache
 420
 421 # Complete arguments and fix spelling mistakes when possible.
 422 zstyle ':completion:*' completer _complete _match _correct _approximate
 423
 424 # Make sure the list of possible completions is displayed after pressing <TAB>
 425 # the first time.
 426 setopt nolistambiguous
 427 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 428 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 429 bindkey '^I' expand-or-complete-prefix
 430 # Try uppercase if the currently typed string doesn't match. This allows
 431 # typing in lowercase most of the time and completion fixes the case.
 432 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 433
 434 # Use ls like colors for completions.
 435 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 436
 437 # Make completion lists scrollable so "do you wish to see all n possibilities"
 438 # is no longer displayed.
 439 zstyle ':completion:*' list-prompt '%p'
 440 # Display group name (like 'external command', 'alias', etc.) when there are
 441 # multiple matches in bold.
 442 zstyle ':completion:*' format '    %B%d%b:'
 443 # Display different types of matches separately.
 444 zstyle ':completion:*' group-name ''
 445
 446 # Ignore completion functions.
 447 zstyle ':completion:*:functions' ignored-patterns '_*'
 448 # Ignore parent directory.
 449 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 450 # Always complete one value (file name) only once in the current line. This
 451 # makes it easy to complete multiple values because I can just press tab to
 452 # get all possible values. Otherwise I would have to skip the first value
 453 # again and again.
 454 zstyle ':completion:*' ignore-line yes
 455 # Except for mv and cp, because I often want to use to similar names, so I
 456 # complete to the same and change it.
 457 zstyle ':completion:*:(mv|cp):*' ignore-line no
 458
 459
 460 # CUSTOM ALIASES AND FUNCTIONS
 461
 462 # If ^C is pressed while typing a command, add it to the history so it can be
 463 # easily retrieved later and then abort like ^C normally does. This is useful
 464 # when I want to abort an command to do something in between and then finish
 465 # typing the command.
 466 #
 467 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 468 # starting with - don't cause errors; and to Nadav Har'El
 469 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 470 # correctly, both on the Zsh mailing list.
 471 TRAPINT() {
 472     # Store the current buffer in the history.
 473     zle && print -s -r -- $BUFFER
 474
 475     # Return the default exit code so Zsh aborts the current command.
 476     return $1
 477 }
 478
 479 # Colorize stderr. Very useful when looking for errors. Thanks to
 480 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 481 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 482 # perfect and doesn't work with su and git for example, but it can handle most
 483 # interactive output quite well (even with no trailing new line) and in those
 484 # cases the E alias can be used as workaround.
 485 exec 2>>(while read -r -k -u 0 line; do
 486     printf '\e[91m%s\e[0m' "$line";
 487     print -n $'\0';
 488 done &)
 489
 490 # Load aliases and similar functions also used by other shells.
 491 if [[ -f ~/.shell/aliases ]]; then
 492     . ~/.shell/aliases
 493 fi
 494
 495 # Make sure aliases are expanded when using sudo.
 496 alias sudo='sudo '
 497
 498 # Global aliases for often used commands in the command line.
 499 alias -g E='2>&1'
 500 alias -g L='E | less'
 501 alias -g D='E | colordiff L'
 502 alias -g G='| grep'
 503 alias -g S='| sort'
 504 alias -g U='| uniq'
 505 alias -g H='| head'
 506 alias -g T='| tail'
 507
 508 # Make going up directories simple.
 509 alias -g ...='../..'
 510 alias -g ....='../../..'
 511 alias -g .....='../../../..'
 512
 513 # If the window naming feature is used (see above) then use ".zsh" (leading
 514 # dot) as title name after running clear so it's clear to me that the window
 515 # is empty. I open so much windows that I don't know in which I have something
 516 # important. This helps me to remember which windows are empty (I run clear
 517 # after I finished my work in a window).
 518 if [[ -n $window_reset ]]; then
 519     alias clear='clear; window_reset=yes; window_precmd reset'
 520 fi
 521
 522 # Display all branches (except stash) in gitk but only 200 commits as this is
 523 # much faster. Also put in the background and disown. Thanks to sitaram in
 524 # #git on Freenode (2009-04-20 15:51).
 525 gitk() {
 526     command gitk \
 527         --max-count=200 \
 528         $(git rev-parse --symbolic-full-name --remotes --branches) \
 529         $@ &
 530     disown %command
 531 }
 532 # Same for tig (except the disown part as it's no GUI program).
 533 tig() {
 534     command tig \
 535         --max-count=200 \
 536         $(git rev-parse --symbolic-full-name --remotes --branches) \
 537         $@
 538 }
 539
 540
 541 # OS SPECIFIC SETTINGS
 542
 543 local uname=$(uname)
 544
 545 if [[ $uname == Linux ]]; then
 546     # Settings when creating Debian packages.
 547     DEBEMAIL=simon@ruderich.org
 548     export DEBEMAIL
 549     DEBFULLNAME='Simon Ruderich'
 550     export DEBFULLNAME
 551
 552 elif [[ $uname == Darwin ]]; then # Mac OS X
 553     # Store the current clipboard in CLIPBOARD before every command so it can
 554     # be used in commands.
 555     os_darwin_preexec() {
 556         export CLIPBOARD="$(pbpaste)"
 557     }
 558     # Add the function as preexec hook.
 559     add-zsh-hook preexec os_darwin_preexec
 560
 561     # Initialize CLIPBOARD so it's available for completion directly after
 562     # startup.
 563     CLIPBOARD=""
 564     export CLIPBOARD
 565
 566     # Fetch current URL in clipboard with wget.
 567     alias wnc='wget --no-proxy $CLIPBOARD'
 568 fi
 569
 570
 571 # LOAD ADDITIONAL CONFIGURATION FILES
 572
 573 # Load rc file for current hostname (first part before a dot) or rc.local.
 574 source_config ~/.zsh host rc ${$(hostname)//.*/}
 575
 576
 577 # RUN COMMANDS
 578
 579 # If not already in screen reattach to a running session or create a new one.
 580 # This also starts screen one a remote server when connecting through ssh.
 581 if [[ $TERM != dumb && -z $STY ]]; then
 582     # Get running detached sessions.
 583     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 584
 585     # As we exec later we have to set the title here.
 586     window_preexec "screen"
 587
 588     # Create a new session if none is running.
 589     if [[ -z $session ]]; then
 590         exec screen
 591     # Reattach to a running session.
 592     else
 593         exec screen -r $session
 594     fi
 595 fi
 596
 597
 598 source_debug "finished sourcing ~/.zsh/rc"
 599
 600 # vim: ft=zsh