zsh/rc

   1 # Zsh configuration file.
   2
   3
   4 source_debug "sourcing ~/.zsh/rc"
   5
   6 # MISCELLANEOUS SETTINGS
   7
   8 # Be paranoid, new files are readable/writable by me only.
   9 umask 077
  10
  11 # Disable beeps.
  12 setopt nobeep
  13
  14 # Prevent overwriting existing files with '> filename', use '>| filename'
  15 # (or >!) instead.
  16 setopt noclobber
  17
  18 # Entering the name of a directory (if it's not a command) will automatically
  19 # cd to that directory.
  20 setopt autocd
  21
  22 # When entering a nonexistent command name automatically try to find a similar
  23 # one.
  24 setopt correct
  25
  26 # Enable zsh's extended glob abilities.
  27 setopt extendedglob
  28
  29 # Don't exit if <C-d> is pressed.
  30 setopt ignoreeof
  31
  32
  33 # KEY BINDINGS
  34
  35 # Not all bindings are done here, only those not specific to a given section.
  36
  37 # Use Vi(m) style key bindings.
  38 bindkey -v
  39
  40 # Also use jj to exit insert mode.
  41 bindkey 'jj' vi-cmd-mode
  42
  43 # I don't need the arrow keys, I use ^N and ^P for this (see below).
  44 bindkey -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  45 # Also not in Vi mode.
  46 bindkey -a -r '^[OA' '^[OB' '^[OC' '^[OD' '^[[A' '^[[B' '^[[C' '^[[D'
  47
  48
  49 # FUNCTION SETTINGS
  50
  51 # Make sure every entry in $fpath is unique.
  52 typeset -U fpath
  53 # ~/.zsh/functions/completion is a symbolic link to the Completion directory
  54 # of a Zsh CVS checkout. Use it to get the newest completions if available.
  55 if [[ -d ~/.zsh/functions/completion ]]; then
  56     fpath=(~/.zsh/functions/completion/*/*(/) $fpath)
  57 fi
  58 # Set correct fpath to allow loading my functions (including completion
  59 # functions).
  60 fpath=(~/.zsh/functions $fpath)
  61 # Autoload my functions (except completion functions and hidden files). Thanks
  62 # to caphuso from the Zsh example files for this idea.
  63 if [[ -d ~/.zsh/functions ]]; then
  64     autoload ${fpath[1]}/^_*(^/:t)
  65 fi
  66
  67 # Simulate hooks using _functions arrays for Zsh versions older than 4.3.4. At
  68 # the moment only precmd(), preexec() and chpwd() are simulated.
  69 #
  70 # At least 4.3.4 (not sure about later versions) has an error in add-zsh-hook
  71 # so the compatibility version is used there too.
  72 if [[ $ZSH_VERSION != (4.3.<5->|4.<4->*|<5->*) ]]; then
  73     # Provide add-zsh-hook which was added in 4.3.4.
  74     fpath=(~/.zsh/functions/compatibility $fpath)
  75
  76     # Run all functions defined in the ${precmd,preexec,chpwd}_functions
  77     # arrays.
  78     function precmd() {
  79         for function in $precmd_functions; do
  80             $function $@
  81         done
  82     }
  83     function preexec() {
  84         for function in $preexec_functions; do
  85             $function $@
  86         done
  87     }
  88     function chpwd() {
  89         for function in $chpwd_functions; do
  90             $function $@
  91         done
  92     }
  93 fi
  94
  95 # Autoload add-zsh-hook to add/remove zsh hook functions easily.
  96 autoload -Uz add-zsh-hook
  97
  98 # Load zmv (zsh move) which is powerful to rename files.
  99 autoload zmv
 100
 101
 102 # HISTORY SETTINGS
 103
 104 # Use history and store it in ~/.zsh/history.
 105 HISTSIZE=50000
 106 SAVEHIST=50000
 107 HISTFILE=~/.zsh/history
 108 # Append to the history file instead of overwriting it and do it immediately
 109 # when a command is executed.
 110 setopt appendhistory
 111 setopt incappendhistory
 112 # If the same command is run multiple times store it only once in the history.
 113 setopt histignoredups
 114 # Vim like completions of previous executed commands (also enter Vi-mode). If
 115 # called at the beginning it just recalls old commands (like cursor up), if
 116 # called after typing something, only lines starting with the typed are
 117 # returned. Very useful to get old commands quickly. Thanks to Mikachu in #zsh
 118 # on Freenode (2010-01-17 12:47) for the information how to a use function
 119 # with bindkey.
 120 zle -N my-vi-history-beginning-search-backward
 121 my-vi-history-beginning-search-backward() {
 122     local not_at_beginning_of_line
 123     if [[ $CURSOR -ne 0 ]]; then
 124         not_at_beginning_of_line=yes
 125     fi
 126
 127     zle history-beginning-search-backward
 128
 129     # Start Vi-mode and stay at the same position (Vi-mode moves one left,
 130     # this counters it).
 131     zle vi-cmd-mode
 132     if [[ -n $not_at_beginning_of_line ]]; then
 133         zle vi-forward-char
 134     fi
 135 }
 136 bindkey '^P' my-vi-history-beginning-search-backward
 137 bindkey -a '^P' history-beginning-search-backward # binding for Vi-mode
 138 # Here only Vi-mode is necessary as ^P enters Vi-mode and ^N only makes sense
 139 # after calling ^P.
 140 bindkey -a '^N' history-beginning-search-forward
 141
 142
 143 # PROMPT SETTINGS
 144
 145 # Use colorized output, necessary for prompts and completions.
 146 autoload -U colors && colors
 147
 148 # Some shortcuts for colors. The %{...%} tells zsh that the data in between
 149 # doesn't need any space, necessary for correct prompt draw.
 150 local red="%{${fg[red]}%}"
 151 local blue="%{${fg[blue]}%}"
 152 local green="%{${fg[green]}%}"
 153 local yellow="%{${fg[yellow]}%}"
 154 local default="%{${fg[default]}%}"
 155
 156 # Set the default prompt. The current host and working directory is displayed,
 157 # the exit code of the last command if it wasn't 0, the number of running jobs
 158 # if not 0.
 159 #
 160 # The prompt is in green and blue to make easily detectable, the error exit
 161 # code in red and bold and the job count in yellow.
 162 PROMPT="$green%B%m%b$default:$blue%B%~%b$default \
 163 %(1j.$yellow%j$default.)%# \
 164 %(?..($red%B%?%b$default%) )"
 165
 166 # vcs_info was added in 4.3.9 but it works in earlier versions too. So load it
 167 # if the necessary files are available in ~/.zsh/functions/vcs_info (often a
 168 # symbolic link to current checkout of Zsh's sources).
 169 if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ||
 170       -d ~/.zsh/functions/vcs_info ]]; then
 171     # Update fpath to allow loading the vcs_info functions.
 172     if [[ -d ~/.zsh/functions/vcs_info ]]; then
 173        fpath=(~/.zsh/functions/vcs_info/
 174               ~/.zsh/functions/vcs_info/Backends
 175               $fpath)
 176     fi
 177
 178     # Allow substitutions and expansions in the prompt, necessary for
 179     # vcs_info.
 180     setopt promptsubst
 181     # Load vcs_info to display information about version control repositories.
 182     autoload -Uz vcs_info
 183     # Only look for git and mercurial repositories; the only I use.
 184     zstyle ':vcs_info:*' enable git hg
 185     # Check the repository for changes so they can be used in %u/%c (see
 186     # below). This comes with a speed penalty for bigger repositories.
 187     zstyle ':vcs_info:*' check-for-changes true
 188
 189     # Set style of vcs_info display. The current branch (green) and VCS (blue)
 190     # is displayed. If there is an special action going on (merge, rebase)
 191     # it's also displayed (red). Also display if there are unstaged or staged
 192     # (%u/%c) changes.
 193     if [[ $ZSH_VERSION == (4.3.<11->|4.<4->*|<5->*) ||
 194           -d ~/.zsh/functions/vcs_info ]]; then
 195         zstyle ':vcs_info:*' formats \
 196             "($green%b%u%c$default:$blue%s$default)"
 197         zstyle ':vcs_info:*' actionformats \
 198             "($green%b%u%c$default/$red%a$default:$blue%s$default)"
 199     else
 200         # In older versions %u and %c are not defined yet and are not
 201         # correctly expanded.
 202         zstyle ':vcs_info:*' formats \
 203             "($green%b$default:$blue%s$default)"
 204         zstyle ':vcs_info:*' actionformats \
 205             "($green%b$default/$red%a$default:$blue%s$default)"
 206     fi
 207     # Set style for formats/actionformats when unstaged (%u) and staged (%c)
 208     # changes are detected in the repository; check-for-changes must be set to
 209     # true for this to work. Thanks to Bart Trojanowski
 210     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt) for the idea
 211     # (2010-03-11 00:20).
 212     zstyle ':vcs_info:*' unstagedstr '¹'
 213     zstyle ':vcs_info:*' stagedstr   '²'
 214
 215     # Default to running vcs_info. If possible we prevent running it later for
 216     # speed reasons. If set to a non empty value vcs_info is run.
 217     FORCE_RUN_VCS_INFO=1
 218
 219     # Cache system inspired by Bart Trojanowski
 220     # (http://jukie.net/~bart/blog/pimping-out-zsh-prompt).
 221     #zstyle ':vcs_info:*+pre-get-data:*' hooks pre-get-data
 222     +vi-pre-get-data() {
 223         # Only Git and Mercurial support and need caching. Abort if any other
 224         # VCS is used.
 225         [[ "$vcs" != git && "$vcs" != hg ]] && return
 226
 227         # If the shell just started up or we changed directories (or for other
 228         # custom reasons) we must run vcs_info.
 229         if [[ -n $FORCE_RUN_VCS_INFO ]]; then
 230             FORCE_RUN_VCS_INFO=
 231             return
 232         fi
 233
 234         # Don't run vcs_info by default to speed up the shell.
 235         ret=1
 236         # If a git/hg command was run then run vcs_info as the status might
 237         # need to be updated.
 238         case "$(fc -ln $(($HISTCMD-1)))" in
 239             git* | g\ *)
 240                 ret=0
 241                 ;;
 242             hg*)
 243                 ret=0
 244                 ;;
 245         esac
 246     }
 247
 248     # Must run vcs_info when changing directories.
 249     prompt_chpwd() {
 250         FORCE_RUN_VCS_INFO=1
 251     }
 252     add-zsh-hook chpwd prompt_chpwd
 253
 254     # Call vcs_info as precmd before every prompt.
 255     prompt_precmd() {
 256         vcs_info
 257     }
 258     add-zsh-hook precmd prompt_precmd
 259
 260     # Display the VCS information in the right prompt.
 261     if [[ $ZSH_VERSION == (4.3.<9->|4.<4->*|<5->*) ]]; then
 262         RPROMPT='${vcs_info_msg_0_}'
 263     # There is a bug in Zsh below 4.3.9 which displays a wrong symbol when
 264     # ${vcs_info_msg_0_} is empty. Provide a workaround for those versions,
 265     # thanks to Frank Terbeck <ft@bewatermyfriend.org> for it.
 266     else
 267         RPROMPT='${vcs_info_msg_0_:- }'
 268     fi
 269 fi
 270
 271 unset red blue green yellow default
 272
 273 # When screen, xterm or rxvt is used set the name of the window to the
 274 # currently running program.
 275 #
 276 # When a program is started preexec() sets the window's name to it; when it
 277 # stops precmd() resets the window's name to 'zsh'.
 278 #
 279 # It works with screen, xterm and rxvt.
 280 #
 281 # If a command is run with sudo or if the shell is running as root then a ! is
 282 # added at the beginning of the command to make this clear. If a command is
 283 # running on a different computer with ssh a @ is added at the beginning. If
 284 # screen is running on the remote machine instead of @screen @:hostname
 285 # (hostname replaced by the machine's hostname) is displayed. This only works
 286 # if the .zshrc on the server also uses this command.
 287 #
 288 # screen* is necessary as `screen` uses screen.linux for example for a linux
 289 # console.
 290 if [[ $TERM == screen* || $TERM == xterm* || $TERM == rxvt* ]]; then
 291     # Is set to a non empty value to reset the window name in the next
 292     # precmd() call.
 293     window_reset=yes
 294     # Is set to a non empty value when the shell is running as root.
 295     if [[ $(id -u) -eq 0 ]]; then
 296         window_root=yes
 297     fi
 298
 299     window_preexec() {
 300         # Get the program name with its arguments.
 301         local program_name=$1
 302
 303         # When sudo is used use real program name instead, but with an
 304         # exclamation mark at the beginning (handled below).
 305         local program_sudo=
 306         if [[ $program_name == sudo* ]]; then
 307             program_name=${program_name#sudo }
 308             program_sudo=yes
 309         fi
 310         # Remove all arguments from the program name.
 311         program_name=${program_name%% *}
 312
 313         # Ignore often used commands which are only running for a very short
 314         # time. This prevents a "blinking" name when it's changed to "cd" for
 315         # example and then some milliseconds later back to "zsh".
 316         [[ $program_name == (cd*|ls|la|ll|clear|c) ]] && return
 317
 318         # Change my shortcuts so the real name of the program is displayed.
 319         case $program_name in
 320             e)
 321                 program_name=elinks
 322                 ;;
 323             g)
 324                 program_name=git
 325                 ;;
 326             m)
 327                 program_name=mutt
 328                 ;;
 329             v)
 330                 program_name=vim
 331                 ;;
 332         esac
 333
 334         # Add an exclamation mark at the beginning if running with sudo or if
 335         # running zsh as root.
 336         if [[ -n $program_sudo || -n $window_root ]]; then
 337             program_name=!$program_name
 338         fi
 339
 340         # Add an at mark at the beginning if running through ssh on a
 341         # different computer.
 342         if [[ -n $SSH_CONNECTION ]]; then
 343             program_name="@$program_name"
 344
 345             # If screen is running in SSH then display "@:hostname" as title
 346             # in the term/outer screen.
 347             if [[ $program_name == @screen ]]; then
 348                 program_name="@:${$(hostname)//.*/}"
 349             fi
 350         fi
 351
 352         # Set the window name to the currently running program.
 353         window_title "$program_name"
 354
 355         # Tell precmd() to reset the window name when the program stops.
 356         window_reset=yes
 357     }
 358
 359     window_precmd() {
 360         # Abort if no window name reset is necessary.
 361         [[ -z $window_reset ]] && return
 362
 363         # Reset the window name to 'zsh'.
 364         local name=zsh
 365         # If the function was called with an argument then reset the window
 366         # name to '.zsh' (used by clear alias).
 367         if [[ -n $1 ]]; then
 368             name=.zsh
 369         fi
 370
 371         # Prepend prefixes like in window_preexec().
 372         if [[ -n $window_root ]]; then
 373             name="!$name"
 374         fi
 375         if [[ -n $SSH_CONNECTION ]]; then
 376             name="@$name"
 377         fi
 378         window_title $name
 379
 380         # Just reset the name, so no screen reset necessary for the moment.
 381         window_reset=
 382     }
 383
 384     # Sets the window title. Works with screen, xterm and rxvt.
 385     if [[ $TERM == screen* ]]; then
 386         window_title() {
 387             print -n "\ek$1\e\\"
 388         }
 389     elif [[ $TERM == xterm* || $TERM == rxvt* ]]; then
 390         window_title() {
 391             print -n "\e]2;$1\e\\"
 392         }
 393     else
 394         # Fallback if another TERM is used.
 395         window_title() { }
 396     fi
 397
 398     # Add the preexec() and precmd() hooks.
 399     add-zsh-hook preexec window_preexec
 400     add-zsh-hook precmd window_precmd
 401 fi
 402
 403
 404 # COMPLETION SETTINGS
 405
 406 # Load the complist module which provides additions to completion lists
 407 # (coloring, scrollable).
 408 zmodload zsh/complist
 409 # Use new completion system, store dumpfile in ~/.zsh/cache to prevent
 410 # cluttering of ~/. $fpath must be set before calling this. Thanks to Adlai in
 411 # #zsh on Freenode (2009-08-07 21:05) for reminding me of the $fpath problem.
 412 autoload -U compinit && compinit -d ~/.zsh/cache/zcompdump
 413
 414 # Use cache to speed up completions.
 415 zstyle ':completion:*' use-cache on
 416 zstyle ':completion:*' cache-path ~/.zsh/cache
 417
 418 # Complete arguments and fix spelling mistakes when possible.
 419 zstyle ':completion:*' completer _complete _match _correct _approximate
 420
 421 # Make sure the list of possible completions is displayed after pressing <TAB>
 422 # the first time.
 423 setopt nolistambiguous
 424 # Allow completions in the middle of a text, i.e. "/usr/bin/<TAB>whatever"
 425 # completes like "/usr/bin/<TAB>". Useful when adding new options to commands.
 426 bindkey '^I' expand-or-complete-prefix
 427 # Try uppercase if the currently typed string doesn't match. This allows
 428 # typing in lowercase most of the time and completion fixes the case.
 429 zstyle ':completion:*' matcher-list '' 'm:{a-z}={A-Z}'
 430
 431 # Use ls like colors for completions.
 432 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 433
 434 # Make completion lists scrollable so "do you wish to see all n possibilities"
 435 # is no longer displayed.
 436 zstyle ':completion:*' list-prompt '%p'
 437 # Display group name (like 'external command', 'alias', etc.) when there are
 438 # multiple matches in bold.
 439 zstyle ':completion:*' format '    %B%d%b:'
 440 # Display different types of matches separately.
 441 zstyle ':completion:*' group-name ''
 442
 443 # Ignore completion functions.
 444 zstyle ':completion:*:functions' ignored-patterns '_*'
 445 # Ignore parent directory.
 446 zstyle ':completion:*:(cd|mv|cp):*' ignore-parents parent pwd
 447 # Always complete one value (file name) only once in the current line. This
 448 # makes it easy to complete multiple values because I can just press tab to
 449 # get all possible values. Otherwise I would have to skip the first value
 450 # again and again.
 451 zstyle ':completion:*' ignore-line yes
 452 # Except for mv and cp, because I often want to use to similar names, so I
 453 # complete to the same and change it.
 454 zstyle ':completion:*:(mv|cp):*' ignore-line no
 455
 456
 457 # CUSTOM ALIASES AND FUNCTIONS
 458
 459 # If ^C is pressed while typing a command, add it to the history so it can be
 460 # easily retrieved later and then abort like ^C normally does. This is useful
 461 # when I want to abort an command to do something in between and then finish
 462 # typing the command.
 463 #
 464 # Thanks to Vadim Zeitlin <vz-zsh@zeitlins.org> for a fix (--) so lines
 465 # starting with - don't cause errors; and to Nadav Har'El
 466 # <nyh@math.technion.ac.il> for a fix (-r) to handle whitespace/quotes
 467 # correctly, both on the Zsh mailing list.
 468 TRAPINT() {
 469     # Store the current buffer in the history.
 470     zle && print -s -r -- $BUFFER
 471
 472     # Return the default exit code so Zsh aborts the current command.
 473     return $1
 474 }
 475
 476 # Colorize stderr. Very useful when looking for errors. Thanks to
 477 # http://gentoo-wiki.com/wiki/Zsh for the basic script and Mikachu in #zsh on
 478 # Freenode (2010-03-07 04:03) for some improvements (-r, printf). It's not yet
 479 # perfect and doesn't work with su and git for example, but it can handle most
 480 # interactive output quite well (even with no trailing new line) and in those
 481 # cases the E alias can be used as workaround.
 482 exec 2>>(while read -r -k -u 0 line; do
 483     printf '\e[91m%s\e[0m' "$line";
 484     print -n $'\0';
 485 done &)
 486
 487 # Load aliases and similar functions also used by other shells.
 488 if [[ -f ~/.shell/aliases ]]; then
 489     . ~/.shell/aliases
 490 fi
 491
 492 # Make sure aliases are expanded when using sudo.
 493 alias sudo='sudo '
 494
 495 # Global aliases for often used commands in the command line.
 496 alias -g E='2>&1'
 497 alias -g L='E | less'
 498 alias -g D='E | colordiff L'
 499 alias -g G='| grep'
 500 alias -g S='| sort'
 501 alias -g U='| uniq'
 502 alias -g H='| head'
 503 alias -g T='| tail'
 504
 505 # Make going up directories simple.
 506 alias -g ...='../..'
 507 alias -g ....='../../..'
 508 alias -g .....='../../../..'
 509
 510 # If the window naming feature is used (see above) then use ".zsh" (leading
 511 # dot) as title name after running clear so it's clear to me that the window
 512 # is empty. I open so much windows that I don't know in which I have something
 513 # important. This helps me to remember which windows are empty (I run clear
 514 # after I finished my work in a window).
 515 if [[ -n $window_reset ]]; then
 516     alias clear='clear; window_reset=yes; window_precmd reset'
 517 fi
 518
 519 # Display all branches (except stash) in gitk but only 200 commits as this is
 520 # much faster. Also put in the background and disown. Thanks to sitaram in
 521 # #git on Freenode (2009-04-20 15:51).
 522 gitk() {
 523     command gitk \
 524         --max-count=200 \
 525         $(git rev-parse --symbolic-full-name --remotes --branches) \
 526         $@ &
 527     disown %command
 528 }
 529 # Same for tig (except the disown part as it's no GUI program).
 530 tig() {
 531     command tig \
 532         --max-count=200 \
 533         $(git rev-parse --symbolic-full-name --remotes --branches) \
 534         $@
 535 }
 536
 537
 538 # OS SPECIFIC SETTINGS
 539
 540 local uname=$(uname)
 541
 542 if [[ $uname == Linux ]]; then
 543     # Settings when creating Debian packages.
 544     DEBEMAIL=simon@ruderich.org
 545     export DEBEMAIL
 546     DEBFULLNAME='Simon Ruderich'
 547     export DEBFULLNAME
 548
 549 elif [[ $uname == Darwin ]]; then # Mac OS X
 550     # Store the current clipboard in CLIPBOARD before every command so it can
 551     # be used in commands.
 552     os_darwin_preexec() {
 553         export CLIPBOARD="$(pbpaste)"
 554     }
 555     # Add the function as preexec hook.
 556     add-zsh-hook preexec os_darwin_preexec
 557
 558     # Initialize CLIPBOARD so it's available for completion directly after
 559     # startup.
 560     CLIPBOARD=""
 561     export CLIPBOARD
 562
 563     # Fetch current URL in clipboard with wget.
 564     alias wnc='wget --no-proxy $CLIPBOARD'
 565 fi
 566
 567
 568 # LOAD ADDITIONAL CONFIGURATION FILES
 569
 570 # Load rc file for current hostname (first part before a dot) or rc.local.
 571 source_config ~/.zsh host rc ${$(hostname)//.*/}
 572
 573
 574 # RUN COMMANDS
 575
 576 # If not already in screen reattach to a running session or create a new one.
 577 # This also starts screen one a remote server when connecting through ssh.
 578 if [[ $TERM != dumb && -z $STY ]]; then
 579     # Get running detached sessions.
 580     session=$(screen -list | grep 'Detached' | awk '{ print $1; exit }')
 581
 582     # As we exec later we have to set the title here.
 583     window_preexec "screen"
 584
 585     # Create a new session if none is running.
 586     if [[ -z $session ]]; then
 587         exec screen
 588     # Reattach to a running session.
 589     else
 590         exec screen -r $session
 591     fi
 592 fi
 593
 594
 595 source_debug "finished sourcing ~/.zsh/rc"
 596
 597 # vim: ft=zsh