]> ruderich.org/simon Gitweb - config/dotfiles.git/blob - vimrc
vimrc: :make writes all files and not only the current one.
[config/dotfiles.git] / vimrc
1 " Vim main configuration file.
2
3 " Copyright (C) 2008-2012  Simon Ruderich
4 "
5 " This file is free software: you can redistribute it and/or modify
6 " it under the terms of the GNU General Public License as published by
7 " the Free Software Foundation, either version 3 of the License, or
8 " (at your option) any later version.
9 "
10 " This file is distributed in the hope that it will be useful,
11 " but WITHOUT ANY WARRANTY; without even the implied warranty of
12 " MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
13 " GNU General Public License for more details.
14 "
15 " You should have received a copy of the GNU General Public License
16 " along with this file.  If not, see <http://www.gnu.org/licenses/>.
17
18
19 " EDITOR SETTINGS
20
21 " Save 'runtimepath' in case it was changed by the system's configuration
22 " files. Also save 'diff' as set all& resets it; but somehow later (after
23 " sourcing the vimrc - for example in a VimEnter autocmd) it gets
24 " automagically restored to the correct value.
25 if has('eval')
26     let s:save_runtimepath = &runtimepath
27     let s:save_diff = &diff
28 endif
29 " Reset all options (except 'term', 'lines' and 'columns'). This makes sure a
30 " system wide configuration file doesn't change default values.
31 set all&
32 " And restore it after all other options were reset.
33 if has('eval')
34     let &runtimepath = s:save_runtimepath
35     let &diff = s:save_diff
36     unlet s:save_runtimepath
37     unlet s:save_diff
38 endif
39
40 " Make sure Vim (and not Vi) settings are used.
41 set nocompatible
42
43 " Use UTF-8 for all internal data (buffers, registers, etc.). This doesn't
44 " affect reading files in different encodings, see 'fileencodings' for that.
45 set encoding=utf-8
46
47 " Load my scripts from ~/.vim (my scripts) and ~/.vim/runtime (checkout of Vim
48 " runtime files) if available.
49 set runtimepath-=~/.vim
50 set runtimepath^=~/.vim,~/.vim/runtime
51
52 " Don't store swap files in the same directory as the edited file. But only if
53 " we have a "safe" writable directory available.
54 if filewritable('~/.tmp') == 2 || filewritable('~/tmp') == 2
55     set directory-=.
56 endif
57 " But store them in ~/.tmp or ~/tmp (already set by default) if available.
58 set directory^=~/.tmp
59
60 " Disable modelines as they may cause security problems. Instead use
61 " securemodelines (Vim script #1876).
62 set nomodeline
63
64 " Complete to longest common string (list:longest) and then complete all full
65 " matches after another (full). Thanks to pbrisbin
66 " (http://pbrisbin.com:8080/dotfiles/vimrc).
67 set wildmode=list:longest,full
68 " Ignore case when completing files/directories.
69 if exists('+wildignorecase')
70     set wildignorecase
71 endif
72
73 " Ignore files with the following extensions because I almost never want to
74 " edit them in Vim (specifying them manually still works of course).
75 set wildignore=
76 " C
77 set wildignore+=*.o,*.d,*.so
78 " Java
79 set wildignore+=*.class
80 " LaTeX
81 set wildignore+=*.aux,*.log,*.out,*.toc,*.pdf
82 " Python
83 set wildignore+=*.pyc
84
85 " Show completion menu even if only one entry matches.
86 if exists('+completeopt')
87     set completeopt+=menuone
88 endif
89
90 " Increase history of executed commands (:) and search patterns (/).
91 set history=1000
92
93 " Increase number of possible undos.
94 set undolevels=1000
95
96 " Remember marks (including the last cursor position) for more files. ^= is
97 " necessary because 'viminfo' is parsed from the beginning and the first match
98 " is used.
99 if has('viminfo')
100     set viminfo^='1000
101 endif
102
103 " Use strong encryption if possible, also used for swap/undo files.
104 if exists('+cryptmethod')
105     set cryptmethod=blowfish
106 endif
107
108 " Create new split windows on the right (and not left).
109 set splitright
110
111 " Clear all vimrc-related autocmds. Has to be done here as the vimrc augroup
112 " is used multiple times. Necessary to support reloading the vimrc.
113 if has('autocmd')
114     augroup vimrc
115         autocmd!
116     augroup END
117 endif
118
119
120 " HELPER FUNCTIONS
121
122 if has('eval')
123 " Check if the given syntax group is available. Thanks to bairui in #vim on
124 " Freenode (2012-02-19 01:15 CET) for the try/catch silent highlight idea.
125     function! s:HasSyntaxGroup(group)
126         try
127             execute 'silent highlight ' . a:group
128         " \a = [A-Za-z]
129         catch /^Vim\%((\a\+)\)\=:E411/ " 'highlight group not found'
130             return 0
131         endtry
132         return 1
133     endfunction
134
135 " Check if the given Vim version and patch is available.
136     function! s:HasVersionAndPatch(version, patch)
137         return v:version > a:version
138             \ || (v:version == a:version && has('patch' . a:patch))
139     endfunction
140 endif
141
142
143 " TERMINAL SETTINGS
144
145 " Also enable fast terminal mode in GNU screen and tmux, but not for SSH
146 " connections.
147 if &term =~# '^screen' && !exists('$SSH_CONNECTION')
148     set ttyfast
149 endif
150
151
152 " EDIT SETTINGS
153
154 " Enable automatic file detection, plugin and indention support.
155 if has('autocmd')
156     filetype off " necessary for pathogen to force a reload of ftplugins
157     filetype plugin indent on
158 endif
159
160 " Use UTF-8 file encoding for all files. Automatically recognize latin1 in
161 " existing files.
162 set fileencodings=utf-8,latin1
163
164 " Always use unix line-endings for new files.
165 set fileformats=unix,dos
166
167 " Wrap text after 78 characters.
168 set textwidth=78
169
170 " Set tabs to 4 spaces, use softtabs.
171 set shiftwidth=4
172 set softtabstop=4
173 set expandtab
174 " When < and > is used indent/deindent to the next 'shiftwidth' boundary.
175 set shiftround
176 " Use the default value for real tabs.
177 set tabstop=8
178
179 " Enable auto indention.
180 set autoindent
181
182 " When joining lines only add one space after a sentence.
183 set nojoinspaces
184
185 " Allow backspacing over autoindent and line breaks.
186 set backspace=indent,eol
187
188 " Start a comment when hitting enter after a commented line (r) and when using
189 " o or O around a commented line (o).
190 set formatoptions+=ro
191 " Don't break a line if was already longer then 'textwidth' when insert mode
192 " started.
193 set formatoptions+=l
194 " Remove comment leader when joining lines where it makes sense.
195 if <SID>HasVersionAndPatch(703, 541)
196     set formatoptions+=j
197 endif
198
199 " Allow virtual editing (cursor can be positioned anywhere, even when there is
200 " no character) in visual block mode.
201 set virtualedit=block
202
203 " Already display matches while typing the search command. This makes spotting
204 " typos easy and searching faster.
205 set incsearch
206
207 " Activate syntax folding.
208 if has('folding')
209     set foldmethod=syntax
210     " Only use fold column if we have enough space (for example not in a
211     " (virtual) terminal which has only 80 columns).
212     if &columns > 80
213         set foldcolumn=2
214     endif
215     set foldlevel=99 " no closed folds at default, 'foldenable' would disable
216                      " folding which is not what I want
217     " Don't open folds for block movements like '(', '{', '[[', '[{', etc.
218     set foldopen-=block
219 endif
220
221 " Only check case if the searched word contains a capital character.
222 set ignorecase
223 set smartcase
224
225 " Activate spell checking, use English as default.
226 if exists('+spell') && has('syntax')
227     " But not when diffing because spell checking is distracting in this case.
228     if !&diff
229         set spell
230     endif
231     set spelllang=en_us
232 endif
233
234 " Allow buffers with changes to be hidden. Very important for effective
235 " editing with multiple buffers. Prevents the "E37: No write since last change
236 " (add ! to override)" warning when switching buffers.
237 set hidden
238
239
240 " DISPLAY SETTINGS
241
242 " Use a dark background. Doesn't change the background color, only sets text
243 " colors for a dark terminal.
244 set background=dark
245
246 " Use my color scheme if 256 colors are available.
247 if &t_Co == 256 || has('gui_running')
248     colorscheme simon
249 endif
250
251 " Display line numbers.
252 set number
253 " But use as little space as possible for the numbers column. Thanks to James
254 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
255 if exists('+numberwidth')
256     set numberwidth=1
257 endif
258 " Display the ruler with current line/file position. If 'statusline' is used
259 " then this only affects <C-G>.
260 set ruler
261 " Display partial commands in the status line.
262 set showcmd
263
264 " Don't redraw screen when executing macros; increases speed. Thanks to James
265 " Vega (http://git.jamessan.com/?p=etc/vim.git;a=summary).
266 set lazyredraw
267
268 " Visualize the line the cursor is currently in.
269 if exists('+cursorline')
270     set cursorline
271 endif
272
273 " Highlight all matches on the screen when searching. Use <C-L> (see below) to
274 " remove the highlighting until the next search.
275 set hlsearch
276
277 " Display some special characters.
278 set list
279 set listchars=
280 " Display tabs as ">--------".
281 set listchars+=tab:>-
282 " Display trailing whitespace as "-".
283 set listchars+=trail:-
284 " Display markers for long lines when wrapping is disabled.
285 set listchars+=extends:>,precedes:<
286 " Display non-breakable space as "!".
287 if v:version >= 700
288     set listchars+=nbsp:!
289 endif
290
291 " Don't draw the vertical split separator by using space as character. Thanks
292 " to scp1 in #vim on Freenode (2012-06-16 16:12 CEST) for the idea to use a
293 " non-breakable space. But a simple space works as well, as long as the
294 " current color scheme is not reset.
295 if has('windows') && has('folding')
296     set fillchars+=vert:\  " comment to prevent trailing whitespace
297 endif
298
299 if has('statusline')
300     " Always display the status line even if there is only one window.
301     set laststatus=2
302
303     " If there's more than one buffer return "/<nr>" (e.g. "/05") where <nr>
304     " is the highest buffer number, otherwise return nothing. Used in
305     " 'statusline' to get an overview of available buffer numbers.
306     function! s:StatuslineBufferCount()
307         let l:bufnr = bufnr('$')
308         if l:bufnr > 1
309             let l:result = '/'
310             if exists('*printf')
311                 let l:result .= printf('%02d', l:bufnr)
312             else
313                 " Older Vims don't have printf() (and no .= either). Emulate
314                 " "%02d".
315                 if l:bufnr < 10
316                     let l:result = l:result . '0'
317                 endif
318                 let l:result = l:result . l:bufnr
319             endif
320             return l:result
321         else
322             return ''
323         endif
324     endfunction
325
326     " Like %f but use relative filename if it's shorter than the absolute path
327     " (e.g. '../../file' vs. '~/long/path/to/file'). fnamemodify()'s ':.' is
328     " not enough because it doesn't create '../'s.
329     function! s:StatuslineRelativeFilename()
330         " Display only filename for help files.
331         if &buftype == 'help'
332             return expand('%:t')
333         endif
334         " Special case for scratch files.
335         if &buftype == 'nofile'
336             return '[Scratch]'
337         endif
338
339         let l:path = expand('%')
340         " No file.
341         if l:path == ''
342             return '[No Name]'
343         endif
344         " Path is already relative, nothing to do.
345         if stridx(l:path, '/') != 0
346             return l:path
347         endif
348
349         " Absolute path to this file.
350         let l:path = expand('%:p')
351         " Shortened path to this file, thanks to bairui in #vim on Freenode
352         " (2012-06-23 00:54) for the tip to use fnamemodify(). This is what
353         " Vim normally uses as %f (minus some exceptions).
354         let l:original_path = fnamemodify(l:path, ':~')
355         " Absolute path to the current working directory.
356         let l:cwd = getcwd()
357
358         " Working directory completely contained in path, replace it with a
359         " relative path. Happens for example when opening a file with netrw.
360         " %f displays this as absolute path, but we want a relative path of
361         " course.
362         if stridx(l:path, l:cwd) == 0
363             return strpart(l:path, strlen(l:cwd) + 1)
364         endif
365
366         let l:path_list = split(l:path, '/')
367         let l:cwd_list  = split(l:cwd,  '/')
368
369         " Remove the common path.
370         while l:path_list[0] == l:cwd_list[0]
371             call remove(l:path_list, 0)
372             call remove(l:cwd_list,  0)
373         endwhile
374
375         " Add as many '..' as necessary for the relative path and join the
376         " path. Thanks to Raimondi in #vim on Freenode (2012-06-23 01:13) for
377         " the hint to use repeat() instead of a loop.
378         let l:path = repeat('../', len(l:cwd_list)) . join(l:path_list, '/')
379
380         " Use the shorter path, either relative or absolute.
381         if strlen(l:path) < strlen(l:original_path)
382             return l:path
383         else
384             return l:original_path
385         endif
386     endfunction
387
388     " Return current syntax group in brackets or nothing if there's none.
389     function! s:StatuslineSyntaxGroup()
390         let l:group = synIDattr(synID(line('.'), col('.'), 1), 'name')
391         if l:group != ''
392             return '[' . l:group . '] '
393         else
394             return ''
395         endif
396     endfunction
397
398     " Short function names to make 'statusline' more readable.
399     function! SBC()
400         return <SID>StatuslineBufferCount()
401     endfunction
402     function! SRF()
403         return <SID>StatuslineRelativeFilename()
404     endfunction
405     function! SSG()
406         return <SID>StatuslineSyntaxGroup()
407     endfunction
408
409     set statusline=
410     " on the left
411     set statusline+=%02n              " buffer number
412     set statusline+=%{SBC()}          " highest buffer number
413     set statusline+=:
414     if has('modify_fname') && v:version >= 700 " some functions need 7.0
415         set statusline+=%{SRF()}      " path to current file
416         set statusline+=\             " space after path
417     else
418         set statusline+=%f\           " path to current file in buffer
419     endif
420     set statusline+=%h                " [help] if buffer is help file
421     set statusline+=%w                " [Preview] if buffer is preview buffer
422     set statusline+=%m                " [+] if buffer was modified,
423                                       " [-] if 'modifiable' is off
424     set statusline+=%r                " [RO] if buffer is read only
425
426     " on the right
427     set statusline+=%=                " right align
428     set statusline+=0x%-8B\           " current character under cursor as hex
429     set statusline+=%-12.(%l,%c%V%)\  " line number (%l),
430                                       " column number (%c),
431                                       " virtual column number if different
432                                       "                       than %c (%V)
433     set statusline+=%P                " position in file in percent
434 endif
435
436
437 " MAPPINGS (except for plugins, see PLUGIN SETTINGS below)
438
439 " noremap is used to make sure the right side is executed as is and can't be
440 " modified by a plugin or other settings. Except for <Nop> which isn't
441 " affected by mappings.
442
443 " Easy way to exit insert mode. jk is preferred because it's faster.
444 inoremap jj <Esc>
445 inoremap jk <Esc>
446 " Also for command mode, thanks to http://github.com/mitechie/pyvim
447 " (2010-10-15).
448 cnoremap jj <C-C>
449 cnoremap jk <C-C>
450
451 " Disable arrow keys for all modes except command modes. Thanks to James Vega
452 " (http://git.jamessan.com/?p=etc/vim.git;a=summary).
453 map <Right>  <Nop>
454 map <Left>   <Nop>
455 map <Up>     <Nop>
456 map <Down>   <Nop>
457 imap <Right> <Nop>
458 imap <Left>  <Nop>
459 imap <Up>    <Nop>
460 imap <Down>  <Nop>
461 " Also disable arrow keys in command mode, use <C-P>/<C-N> as replacement (see
462 " below).
463 cmap <Up>    <Nop>
464 cmap <Down>  <Nop>
465 cmap <Right> <Nop>
466 cmap <Left>  <Nop>
467
468 " Use <C-P>/<C-N> as replacement for <Up>/<Down> in command mode. Thanks to
469 " abstrakt and grayw in #vim on Freenode (2010-04-12 21:20 CEST).
470 cnoremap <C-P> <Up>
471 cnoremap <C-N> <Down>
472
473 if has('eval')
474 " Don't move the cursor to the first column for certain scroll commands (<C-F,
475 " <C-B>, <C-D>, <C-U>). Thanks to jamessan in #vim on Freenode (2011-08-31
476 " 02:27 CEST) for the 'nostartofline' tip. But I can't use 'nostartofline'
477 " directly because it also enables that feature for other commands which I
478 " don't want.
479
480     " Set 'nostartofline' for a single movement.
481     function! s:TemporaryNostartofline(movement)
482         let l:startofline = &startofline
483         set nostartofline
484         execute 'normal! ' . a:movement
485         let &startofline = l:startofline
486     endfunction
487
488     " Thanks to fow in #vim on Freenode (2012-02-16 15:38 CET) for the idea to
489     " use "<Bslash><Lt>"; Vim documentation reference: :help <>.
490     nnoremap <silent> <C-F>
491         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-F>")<CR>
492     nnoremap <silent> <C-B>
493         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-B>")<CR>
494     nnoremap <silent> <C-D>
495         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-D>")<CR>
496     nnoremap <silent> <C-U>
497         \ :call <SID>TemporaryNostartofline("<Bslash><Lt>C-U>")<CR>
498 endif
499
500 " Write before suspending, thanks to deryni in #vim on Freenode (2011-05-09
501 " 20:02 CEST). To suspend without saving either unmap this or use :stop<CR>.
502 " Only the current buffer is written, thus switching to another buffer works
503 " too.
504 nnoremap <silent> <C-Z> :update<CR>:stop<CR>
505
506 " 2<C-G> gives more verbose information, use it by default. Thanks to NCS_One
507 " in #vim on Freenode (2011-08-15 00:17 CEST).
508 nnoremap <C-G> 2<C-G>
509
510 " Use <Space> to move down a page and - to move up one like in mutt. Don't use
511 " nnoremap so the <C-F>/<C-B> 'nostartofline' fix (see above) works.
512 nmap <Space> <C-F>
513 nmap - <C-B>
514
515 " Go to next and previous buffer. Thanks to elik in #vim on Freenode
516 " (2010-05-16 18:38 CEST) for this idea.
517 nnoremap <silent> gb :bnext<CR>
518 nnoremap <silent> gB :bprevious<CR>
519 if has('eval')
520     " But when starting again at the first buffer, print a warning which
521     " reminds me that I've already seen that buffer.
522     function! s:NextBuffer()
523         " Are we currently on the last buffer and moving to the first?
524         let l:last_buffer = 0
525         if bufnr('%') == bufnr('$') && bufnr('$') > 1
526             let l:last_buffer = 1
527         endif
528
529         " Go to the next buffer.
530         if !l:last_buffer
531             bnext
532
533         " Go to the first buffer, silent is necessary or the following message
534         " won't be displayed because it's overwritten by the status message
535         " displayed when entering a buffer.
536         else
537             silent bnext
538
539             echohl WarningMsg
540             echo 'Starting again at first buffer.'
541             echohl None
542         endif
543     endfunction
544     nnoremap <silent> gb :call <SID>NextBuffer()<CR>
545 endif
546
547 " Fast access to buffers.
548 nnoremap <silent> <Leader>1 :1buffer<CR>
549 nnoremap <silent> <Leader>2 :2buffer<CR>
550 nnoremap <silent> <Leader>3 :3buffer<CR>
551 nnoremap <silent> <Leader>4 :4buffer<CR>
552 nnoremap <silent> <Leader>5 :5buffer<CR>
553 nnoremap <silent> <Leader>6 :6buffer<CR>
554 nnoremap <silent> <Leader>7 :7buffer<CR>
555 nnoremap <silent> <Leader>8 :8buffer<CR>
556 nnoremap <silent> <Leader>9 :9buffer<CR>
557 nnoremap <silent> <Leader>0 :10buffer<CR>
558
559 " Make last active window the only window. Similar to <C-W> o.
560 nnoremap <C-W>O <C-W>p<C-W>o
561
562 " Maps to change spell language between English and German and disable spell
563 " checking.
564 if exists('+spell')
565     nnoremap <silent> <Leader>sn :set nospell<CR>
566     nnoremap <silent> <Leader>se :set spell spelllang=en_us<CR>
567     nnoremap <silent> <Leader>sd :set spell spelllang=de_de<CR>
568 " If no spell support is available, these mappings do nothing.
569 else
570     nmap <Leader>sn <Nop>
571     nmap <Leader>se <Nop>
572     nmap <Leader>sd <Nop>
573 endif
574
575 " Add semicolon to the end of the line. Thanks to
576 " http://www.van-laarhoven.org/vim/.vimrc for this idea and godlygeek in #vim
577 " on Freenode for an improved version which doesn't clobber any marks.
578 nnoremap <silent> <Leader>; :call setline(line('.'), getline('.') . ';')<CR>
579
580 " * and # for selections in visual mode. Thanks to
581 " http://got-ravings.blogspot.com/2008/07/vim-pr0n-visual-search-mappings.html
582 " and all nerds involved (godlygeek, strull in #vim on Freenode).
583 if has('eval')
584     function! s:VSetSearch()
585         let l:temp = @@
586         normal! gvy
587         " Added \C to force 'noignorecase' while searching the current visual
588         " selection. I want to search for the exact string in this case.
589         let @/ = '\C' . '\V' . substitute(escape(@@, '\'), '\n', '\\n', 'g')
590         let @@ = l:temp
591     endfunction
592     vnoremap * :<C-U>call <SID>VSetSearch()<CR>//<CR>
593     vnoremap # :<C-U>call <SID>VSetSearch()<CR>??<CR>
594 endif
595
596 " I often type "W" instead of "w" when trying to save a file. Fix my mistake.
597 " Thanks to Tony Mechelynck <antoine.mechelynck@gmail.com> from the Vim
598 " mailing list for the commands.
599 if v:version < 700
600     cnoreabbrev W w
601     cnoreabbrev Wa wa
602     cnoreabbrev Wq wq
603     cnoreabbrev Wqa wqa
604 else
605     cnoreabbrev <expr> W
606         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'w' : 'W')
607     cnoreabbrev <expr> Wa
608         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wa' : 'Wa')
609     cnoreabbrev <expr> Wq
610         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'wq' : 'Wq')
611     cnoreabbrev <expr> Wqa
612         \ ((getcmdtype() == ':' && getcmdpos() <= 4) ? 'wqa' : 'Wqa')
613 endif
614 " Also fix my typo with "Q".
615 if v:version < 700
616     cnoreabbrev Q q
617     cnoreabbrev Qa qa
618 else
619     cnoreabbrev <expr> Q
620         \ ((getcmdtype() == ':' && getcmdpos() <= 2) ? 'q' : 'Q')
621     cnoreabbrev <expr> Qa
622         \ ((getcmdtype() == ':' && getcmdpos() <= 3) ? 'qa' : 'Qa')
623 endif
624
625 " In case 'hlsearch' is used disable it with <C-L>. Thanks to frogonwheels and
626 " vimgor (bot) in #vim on Freenode (2010-03-30 05:58 CEST).
627 nnoremap <silent> <C-L> :nohlsearch<CR><C-L>
628
629 " <C-U> in insert mode deletes a lot, break undo sequence before deleting the
630 " line so the change can be undone. Thanks to the vimrc_example.vim file in
631 " Vim's source.
632 inoremap <C-U> <C-G>u<C-U>
633 " Same for <C-@> (insert previously inserted text and leave insert mode).
634 inoremap <C-@> <C-G>u<C-@>
635 " And for <C-A> (insert previously inserted text).
636 inoremap <C-A> <C-G>u<C-A>
637 " And for <C-W> (delete word before cursor).
638 inoremap <C-W> <C-G>u<C-W>
639
640 if has('eval')
641 " New text-objects ii and ai to work on text with the same indentation. Thanks
642 " to http://vim.wikia.com/index.php?title=Indent_text_object&oldid=27126
643 " (visited on 2011-11-19).
644     onoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR>
645     onoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR>
646     vnoremap <silent> ai :<C-U>call <SID>IndTxtObj(0)<CR><Esc>gv
647     vnoremap <silent> ii :<C-U>call <SID>IndTxtObj(1)<CR><Esc>gv
648
649     function! s:IndTxtObj(inner)
650         let curline = line(".")
651         let lastline = line("$")
652         let i = indent(line(".")) - &shiftwidth * (v:count1 - 1)
653         let i = i < 0 ? 0 : i
654         if getline(".") !~ "^\\s*$"
655             let p = line(".") - 1
656             let nextblank = getline(p) =~ "^\\s*$"
657             while p > 0
658                     \ && ((i == 0 && !nextblank)
659                         \ || (i > 0 && ((indent(p) >= i
660                             \ && !(nextblank && a:inner))
661                             \ || (nextblank && !a:inner))))
662                 -
663                 let p = line(".") - 1
664                 let nextblank = getline(p) =~ "^\\s*$"
665             endwhile
666             normal! 0V
667             call cursor(curline, 0)
668             let p = line(".") + 1
669             let nextblank = getline(p) =~ "^\\s*$"
670             while p <= lastline
671                     \ && ((i == 0 && !nextblank)
672                         \ || (i > 0 && ((indent(p) >= i
673                             \ && !(nextblank && a:inner))
674                             \ || (nextblank && !a:inner))))
675                 +
676                 let p = line(".") + 1
677                 let nextblank = getline(p) =~ "^\\s*$"
678             endwhile
679             normal! $
680         endif
681     endfunction
682 endif
683
684
685 " ABBREVIATIONS
686
687 " Fix some of my spelling mistakes (German).
688 inoreabbrev relle reelle
689 inoreabbrev reele reelle
690 " Fix some of my spelling mistakes (English).
691 inoreabbrev completly completely
692
693
694 " SYNTAX SETTINGS
695
696 " Activate syntax coloring.
697 if has('syntax')
698     syntax enable
699
700 " Don't highlight more than 500 columns as I normally don't have that long
701 " lines and they slow down syntax coloring. Thanks to Derek Wyatt
702 " (http://www.derekwyatt.org/vim/the-vimrc-file/).
703     if exists('+synmaxcol')
704         set synmaxcol=500
705     endif
706
707 " Use (limited) syntax based omni completion if no other omni completion is
708 " available. Taken from :help ft-syntax-omni.
709     if has('autocmd') && exists('+omnifunc')
710         augroup vimrc
711             autocmd FileType *
712                 \ if &omnifunc == '' |
713                 \     setlocal omnifunc=syntaxcomplete#Complete |
714                 \ endif
715         augroup END
716     endif
717
718 " Function to enable all custom highlights. Necessary as highlights are
719 " window-local and thus must be set for each new window.
720     function! s:CustomSyntaxHighlights()
721         " Not the first time called, nothing to do.
722         if exists('w:vimrc_syntax_run')
723             return
724         endif
725         let w:vimrc_syntax_run = 1
726
727 " Highlight lines longer than 78 characters. Thanks to Tony Mechelynck
728 " <antoine.mechelynck@gmail.com> from the Vim mailing list. It can easily be
729 " disabled when necessary with :2match (in Vim >= 700).
730         if !&diff && exists(':2match')
731             " Use ColorColumn for overlong lines if available and my color
732             " scheme is used.
733             if &t_Co == 256 && <SID>HasSyntaxGroup('ColorColumn')
734                 2match ColorColumn /\%>78v./
735             else
736                 2match Todo /\%>78v./
737             endif
738         elseif !&diff
739             match Todo /\%>78v./
740         endif
741
742         if exists('*matchadd')
743 " Highlight some important keywords in all documents.
744             let l:todos = ['TODO', 'XXX', 'FIXME',
745                          \ 'CHANGED', 'REMOVED', 'DELETED']
746             " Compatibility fix for Vim 6.4 which can't handle for in function
747             " (without function it's ignored).
748             execute '  for l:x in l:todos'
749                   \ '|     call matchadd("Todo", l:x)'
750                   \ '| endfor'
751
752 " Highlight Unicode whitespace which is no normal whitespace (0x20).
753             let l:spaces = ['00a0', '1680', '180e', '2000', '2001', '2002',
754                           \ '2003', '2004', '2005', '2006', '2007', '2008',
755                           \ '2009', '200a', '200b', '200c', '200d', '202f',
756                           \ '205f', '2060', '3000', 'feff']
757             " Compatibility fix for Vim 6.4. Escape \ inside the " string or
758             " it won't work!
759             execute '  for l:x in l:spaces'
760                   \ '|     call matchadd("Error", "\\%u" . l:x)'
761                   \ '| endfor'
762
763 " Special highlight for tabs to reduce their visibility in contrast to other
764 " SpecialKey characters (e.g. ^L).
765             if &t_Co == 256 && <SID>HasSyntaxGroup('specialKeyTab')
766                 call matchadd('specialKeyTab', '\t')
767             endif
768         endif
769     endfunction
770 " Enable highlights for the current and all new windows. Thanks to bairui in
771 " #vim on Freenode (2012-04-01 00:22 CEST) for the WinEnter suggestion.
772     call <SID>CustomSyntaxHighlights()
773     if has('autocmd')
774         augroup vimrc
775             autocmd WinEnter * call <SID>CustomSyntaxHighlights()
776         augroup END
777     endif
778
779 " Settings for specific filetypes.
780
781     " C
782     let g:c_no_if0_fold = 1 " fix weird double fold in #if0 in recent versions
783     " Haskell.
784     let g:hs_highlight_delimiters = 1
785     let g:hs_highlight_boolean = 1
786     let g:hs_highlight_types = 1
787     let g:hs_highlight_more_types = 1
788     " Java.
789     let g:java_highlight_java_lang_ids = 1 " color java.lang.* identifiers
790     " Perl.
791     let g:perl_fold = 1
792     let g:perl_fold_blocks = 1
793     let g:perl_nofold_packages = 1
794     let g:perl_include_pod = 1 " syntax coloring for PODs
795     " PHP.
796     let g:php_folding = 3    " fold functions
797     let g:php_short_tags = 0 " no short tags (<? .. ?>), not always usable
798     let g:php_sql_query = 1  " highlight SQL queries in strings
799     " Python.
800     let g:python_highlight_all = 1
801     " Shell.
802     let g:sh_noisk = 1        " don't add . to 'iskeyword'
803     let g:sh_is_posix = 1     " POSIX shell (e.g. dash) is compatible enough
804     let g:sh_fold_enabled = 7 " functions (1), heredoc (2) and if/do/for (4)
805     " Vim.
806     let g:vimsyn_embed = 0      " don't highlight embedded languages
807     let g:vimsyn_folding = 'af' " folding for autogroups (a) and functions (f)
808     " XML.
809     let g:xml_syntax_folding = 1
810 endif
811
812
813 " PLUGIN SETTINGS
814
815 if has('eval')
816 " Use pathogen which allows one 'runtimepath' entry per plugin. This makes
817 " installing/removing/updating plugins simple. (Used for plugins with more
818 " than one file.) Ignore errors in case pathogen is not installed.
819     if v:version >= 700
820         silent! execute 'call pathogen#infect()'
821     endif
822
823 " Settings for securemodelines.
824     " Only allow items I need (also includes spl which is not enabled by
825     " default).
826     if v:version >= 700 " need lists
827         let g:secure_modelines_allowed_items = ['ft', 'spl', 'fdm',
828                                               \ 'sw', 'sts', 'noet']
829     endif
830
831 " Settings for the NERD commenter.
832     " Don't create any mappings I don't want to use.
833     let g:NERDCreateDefaultMappings = 0
834     " Map toggle comment.
835     nmap <Leader><Leader> <Plug>NERDCommenterToggle
836
837 " XPTemplate settings.
838     " Try to maintain snippet rendering even after editing outside of a
839     " snippet.
840     let g:xptemplate_strict = 0
841     " Don't complete any braces automatically.
842     let g:xptemplate_brace_complete = 0
843     " Only highlight the current placeholder.
844     let g:xptemplate_highlight = 'current'
845
846 " CtrlP settings.
847     " Don't manage the working directory (the default setting is too slow for
848     " me).
849     let g:ctrlp_working_path_mode = 0
850     " Path to cache directory. I prefer to keep generated files as local as
851     " possible.
852     let g:ctrlp_cache_dir = $HOME . '/.vim/cache/ctrlp'
853     " Permanent cache, cleared by a crontab entry.
854     let g:ctrlp_clear_cache_on_exit = 0
855
856 " FSWitch settings.
857     " Default don't work well for my projects.
858     augroup vimrc
859         autocmd BufEnter *.cc let b:fswitchdst  = 'h'
860                           \ | let b:fswitchlocs = './'
861         autocmd BufEnter *.h  let b:fswitchdst  = 'cc,c'
862                           \ | let b:fswitchlocs = './'
863     augroup END
864
865     " Switch to corresponding header/source file.
866     nnoremap <silent> <Leader>h :FSHere<CR>
867 endif
868
869
870 " AUTO COMMANDS
871
872 " Use a custom auto group to prevent problems when the vimrc files is sourced
873 " twice.
874 if has('autocmd')
875     augroup vimrc
876
877 " Go to last position of opened files. Taken from :help last-position-jump.
878         autocmd BufReadPost *
879             \ if line("'\"") > 1 && line("'\"") <= line('$') |
880             \     execute "normal! g'\"" |
881             \ endif
882 " But not for Git commits, go to beginning of the file.
883         autocmd BufReadPost COMMIT_EDITMSG normal! gg
884
885 " Make sure 'list' and 'number' is disabled in help files. This is necessary
886 " when switching to a help buffer which is in the background with :buffer as
887 " these options are local to windows (and not only to buffers). This happens
888 " because I often want to use only one window and thus the help buffer is in
889 " the background.
890         autocmd BufWinEnter *.txt
891             \ if &filetype == 'help' |
892             \     setlocal nolist |
893             \     setlocal nonumber |
894             \ endif
895
896 " Automatically disable 'paste' mode when leaving insert mode. Thanks to
897 " Raimondi in #vim on Freenode (2010-08-14 23:01 CEST). Very useful as I only
898 " want to paste once and then 'paste' gets automatically unset. InsertLeave
899 " doesn't exist in older Vims.
900         if exists('##InsertLeave')
901             autocmd InsertLeave * set nopaste
902         endif
903
904 " Write all files when running :mak[e] before 'makeprg' is called.
905 " QuickFixCmdPre doesn't exist in older Vims.
906         if exists('##QuickFixCmdPre')
907             autocmd QuickFixCmdPre * wall
908         endif
909
910 " Don't ignore case while in insert mode, but ignore case in all other modes.
911 " This causes <C-N>/<C-P> to honor the case and thus only complete matching
912 " capitalization. But while searching (/) 'ignorecase' is used.
913 " InsertEnter/InsertLeave doesn't exist in older Vims.
914         if exists('##InsertEnter') && exists('##InsertLeave')
915             autocmd InsertEnter * set noignorecase
916             autocmd InsertLeave * set   ignorecase
917         endif
918
919 " Display a warning when editing a file which contains "do not edit" (ignoring
920 " the case, \c), for example template files which were preprocessed or
921 " auto-generated files. Especially useful when the header is not displayed on
922 " the first screen, e.g. when the old position is restored. Not for vimrc
923 " though.
924         function! s:SearchForDoNotEditHeader()
925             if search('\cdo not edit', 'n') == 0
926                     \ || expand('<afile>:t') =~# '^.\?vimrc$'
927                 return
928             endif
929
930             echohl WarningMsg
931             echo 'Do not edit this file! (Maybe a template file.)'
932             echohl None
933         endfunction
934         autocmd BufRead * call <SID>SearchForDoNotEditHeader()
935
936 " AFTER/FTPLUGIN AUTO COMMANDS
937
938 " Disable spell checking for files which don't need it.
939         autocmd FileType deb  setlocal nospell
940         autocmd FileType diff setlocal nospell
941         autocmd FileType tar  setlocal nospell
942 " Fix to allow Vim edit crontab files as crontab doesn't work with
943 " backupcopy=auto.
944         autocmd FileType crontab setlocal backupcopy=yes
945 " Don't use the modeline in git commits as the diff created by `git commit -v`
946 " may contain one which could change the filetype or other settings of the
947 " commit buffer. Also make sure we use only 72 characters per line which is
948 " the recommendation for git commit messages (http://tpope.net/node/106).
949         autocmd FileType gitcommit let g:secure_modelines_allowed_items = [] |
950                                  \ setlocal textwidth=72
951 " Use the same comment string as for Vim files in Vimperator files.
952         autocmd FileType vimperator setlocal commentstring=\"%s
953 " Use TeX compiler for (La)TeX files.
954         autocmd FileType tex compiler tex
955
956 " FTDETECT AUTO COMMANDS
957
958 " Recognize .md as markdown files (Vim default is .mkd).
959         autocmd BufRead,BufNewFile *.md set filetype=mkd
960 " Recognize .test as Tcl files.
961         autocmd BufRead,BufNewFile *.test set filetype=tcl
962
963 " OTHER AUTO COMMANDS
964
965 " Disable spell checking, displaying of list characters and long lines when
966 " viewing documentation.
967         autocmd BufReadPost /usr/share/doc/* setlocal nospell nolist | 2match
968
969 " Use diff filetype for mercurial patches in patch queue.
970         autocmd BufReadPost */.hg/patches/* set filetype=diff
971
972     augroup END
973 endif
974
975
976 " CUSTOM FUNCTIONS AND COMMANDS
977
978 if has('eval')
979 " Convenient command to see the difference between the current buffer and the
980 " file it was loaded from, thus the changes you made. Thanks to the
981 " vimrc_example.vim file in Vim's source. Modified to use the same filetype
982 " for the diffed file than the filetype for the original file.
983     if !exists(':DiffOrig')
984         command DiffOrig
985             \ let s:diff_orig_filetype = &filetype
986             \ | vertical new
987             \ | let &filetype = s:diff_orig_filetype
988             \ | unlet s:diff_orig_filetype
989             \ | set buftype=nofile
990             \ | read ++edit #
991             \ | 0d_
992             \ | diffthis
993             \ | wincmd p
994             \ | diffthis
995     endif
996 endif