configure.ac

   1 dnl Copyright (C) 2014  Simon Ruderich
   2 dnl
   3 dnl This program is free software: you can redistribute it and/or modify
   4 dnl it under the terms of the GNU General Public License as published by
   5 dnl the Free Software Foundation, either version 3 of the License, or
   6 dnl (at your option) any later version.
   7 dnl
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 dnl GNU General Public License for more details.
  12 dnl
  13 dnl You should have received a copy of the GNU General Public License
  14 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16
  17 AC_PREREQ([2.69])
  18 AC_INIT([wall-notify],[0.1],[simon@ruderich.org])
  19
  20 AC_CONFIG_AUX_DIR([build-aux])
  21 AC_CONFIG_MACRO_DIR([m4])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_CONFIG_SRCDIR([src/wall-notify.c])
  24
  25 dnl Get functions which are only provided by e.g. _XOPEN_SOURCE.
  26 AC_USE_SYSTEM_EXTENSIONS
  27
  28 AM_INIT_AUTOMAKE([foreign -Wall -Werror])
  29
  30 AC_PROG_CC
  31
  32 if test "x$GCC" = xyes; then
  33     CFLAGS="-Wall -Wextra -Wconversion $CFLAGS"
  34 fi
  35
  36
  37 AC_CHECK_HEADERS([utempter.h utmpx.h])
  38
  39 if test "x$ac_cv_header_utempter_h" = xyes; then
  40     AC_MSG_NOTICE([using utempter])
  41     AC_CHECK_LIB([utempter], [utempter_add_record],
  42                  [], [AC_MSG_ERROR([utempter_add_record() required])])
  43     AC_CHECK_LIB([utempter], [utempter_remove_record],
  44                  [], [AC_MSG_ERROR([utempter_remove_record() required])])
  45     AC_DEFINE([USE_UTEMPTER], 1, [Define to 1 to use utempter.])
  46 elif test "x$ac_cv_header_utmpx_h" = xyes; then
  47     AC_MSG_NOTICE([using utmp])
  48     AC_DEFINE([USE_UTMPX], 1, [Define to 1 to use utmp.])
  49 else
  50     AC_MSG_ERROR([neither utmpx.h nor utempter.h found, aborting])
  51 fi
  52
  53 AC_TYPE_PID_T
  54 AC_TYPE_SIZE_T
  55 AC_TYPE_SSIZE_T
  56
  57 disable_x11_support=
  58 AC_ARG_ENABLE([x11],
  59               [AS_HELP_STRING([--disable-x11], [disable x11 support])],
  60               [if test "x$enableval" = xno; then
  61                    disable_x11_support=yes
  62                    AC_DEFINE([DONT_USE_X11], 1, [Define to not use X11.])
  63                fi])
  64
  65 if test -z "$disable_x11_support"; then
  66     AX_PTHREAD([],[AC_MSG_ERROR([pthread is required, use --disable-x11])])
  67     LIBS="$PTHREAD_LIBS $LIBS"
  68     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
  69     CC="$PTHREAD_CC"
  70
  71     AC_PATH_XTRA
  72     if test x"$no_x" = xyes; then
  73         AC_MSG_ERROR([X11 is required, use --disable-x11])
  74     fi
  75     LIBS="$X_PRE_LIBS $X_EXTRA_LIBS $X_LIBS -lX11 $LIBS"
  76     CFLAGS="$X_CFLAGS $CFLAGS"
  77 fi
  78
  79 AC_CONFIG_FILES([Makefile src/Makefile])
  80 AC_OUTPUT
  81
  82 if test "x$ac_cv_header_utempter_h" != xyes; then
  83     AC_MSG_NOTICE([utempter not found, you must make wall-notify setgid utmp])
  84 fi